Tomato 1.28
[tomato.git] / release / src / router / openssl / crypto / crypto-lib.com
blob0c77fd476375ae529fef50d8bb62aed65245aff2
1 $!
2 $!  CRYPTO-LIB.COM
3 $!  Written By:  Robert Byer
4 $!               Vice-President
5 $!               A-Com Computing, Inc.
6 $!               byer@mail.all-net.net
7 $!
8 $!  Changes by Richard Levitte <richard@levitte.org>
9 $!
10 $!  This command files compiles and creates the "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB" 
11 $!  library for OpenSSL.  The "xxx" denotes the machine architecture of AXP
12 $!  or VAX.
14 $!  It was re-written so it would try to determine what "C" compiler to use 
15 $!  or you can specify which "C" compiler to use.
17 $!  Specify the following as P1 to build just that part or ALL to just
18 $!  build everything.
20 $!              LIBRARY    To just compile the [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library.
21 $!              APPS       To just compile the [.xxx.EXE.CRYPTO]*.EXE
22 $!              ALL        To do both LIBRARY and APPS
24 $!  Specify RSAREF as P2 to compile with the RSAREF library instead of
25 $!  the regular one.  If you specify NORSAREF it will compile with the
26 $!  regular RSAREF routines.  (Note: If you are in the United States
27 $!  you MUST compile with RSAREF unless you have a license from RSA).
29 $!  Note: The RSAREF libraries are NOT INCLUDED and you have to
30 $!        download it from "ftp://ftp.rsa.com/rsaref".  You have to
31 $!        get the ".tar-Z" file as the ".zip" file dosen't have the
32 $!        directory structure stored.  You have to extract the file
33 $!        into the [.RSAREF] directory under the root directory as that
34 $!        is where the scripts will look for the files.
36 $!  Specify DEBUG or NODEBUG as P3 to compile with or without debugger
37 $!  information.
39 $!  Specify which compiler at P4 to try to compile under.
41 $!         VAXC  For VAX C.
42 $!         DECC  For DEC C.
43 $!         GNUC  For GNU C.
45 $!  If you don't speficy a compiler, it will try to determine which
46 $!  "C" compiler to use.
48 $!  P5, if defined, sets a TCP/IP library to use, through one of the following
49 $!  keywords:
51 $!      UCX             for UCX
52 $!      SOCKETSHR       for SOCKETSHR+NETLIB
54 $!  P6, if defined, sets a compiler thread NOT needed on OpenVMS 7.1 (and up)
56 $!  P7, if defined, sets a choice of crypto methods to compile.
57 $!  WARNING: this should only be done to recompile some part of an already
58 $!  fully compiled library.
61 $! Define A TCP/IP Library That We Will Need To Link To.
62 $! (That Is, If We Need To Link To One.)
64 $ TCPIP_LIB = ""
66 $! Check Which Architecture We Are Using.
68 $ IF (F$GETSYI("CPU").GE.128)
69 $ THEN
71 $!  The Architecture Is AXP
73 $   ARCH := AXP
75 $! Else...
77 $ ELSE
79 $!  The Architecture Is VAX.
81 $   ARCH := VAX
83 $! End The Architecture Check.
85 $ ENDIF
87 $! Define The Different Encryption Types.
89 $ ENCRYPT_TYPES = "Basic,MD2,MD4,MD5,SHA,MDC2,HMAC,RIPEMD,"+ -
90                   "DES,RC2,RC4,RC5,IDEA,BF,CAST,"+ -
91                   "BN,RSA,DSA,DH,DSO,"+ -
92                   "BUFFER,BIO,STACK,LHASH,RAND,ERR,OBJECTS,"+ -
93                   "EVP,EVP_2,ASN1,ASN1_2,PEM,X509,X509V3,"+ -
94                   "CONF,TXT_DB,PKCS7,PKCS12,COMP"
95 $ ENCRYPT_PROGRAMS = "DES,PKCS7"
97 $! Check To Make Sure We Have Valid Command Line Parameters.
99 $ GOSUB CHECK_OPTIONS
101 $! Initialise logical names and such
103 $ GOSUB INITIALISE
105 $! Tell The User What Kind of Machine We Run On.
107 $ WRITE SYS$OUTPUT "Compiling On A ",ARCH," Machine."
109 $! Define The OBJ Directory.
111 $ OBJ_DIR := SYS$DISK:[-.'ARCH'.OBJ.CRYPTO]
113 $! Check To See If The Architecture Specific OBJ Directory Exists.
115 $ IF (F$PARSE(OBJ_DIR).EQS."")
116 $ THEN
118 $!  It Dosen't Exist, So Create It.
120 $   CREATE/DIR 'OBJ_DIR'
122 $! End The Architecture Specific OBJ Directory Check.
124 $ ENDIF
126 $! Define The EXE Directory.
128 $ EXE_DIR := SYS$DISK:[-.'ARCH'.EXE.CRYPTO]
130 $! Check To See If The Architecture Specific Directory Exists.
132 $ IF (F$PARSE(EXE_DIR).EQS."")
133 $ THEN
135 $!  It Dosen't Exist, So Create It.
137 $   CREATE/DIRECTORY 'EXE_DIR'
139 $! End The Architecture Specific Directory Check.
141 $ ENDIF
143 $! Define The Library Name.
145 $ LIB_NAME := 'EXE_DIR'LIBCRYPTO.OLB
147 $! Define The CRYPTO-LIB We Are To Use.
149 $ CRYPTO_LIB := 'EXE_DIR'LIBCRYPTO.OLB
151 $! Define The RSAREF-LIB We Are To Use.
153 $ RSAREF_LIB := SYS$DISK:[-.'ARCH'.EXE.RSAREF]LIBRSAGLUE.OLB
155 $! Check To See If We Already Have A "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB" Library...
157 $ IF (F$SEARCH(LIB_NAME).EQS."")
158 $ THEN
160 $! Guess Not, Create The Library.
162 $   LIBRARY/CREATE/OBJECT 'LIB_NAME'
164 $! End The Library Check.
166 $ ENDIF
168 $! Build our options file for the application
170 $ GOSUB CHECK_OPT_FILE
172 $! Define The Different Encryption "library" Strings.
174 $ APPS_DES = "DES/DES,CBC3_ENC"
175 $ APPS_PKCS7 = "ENC/ENC;DEC/DEC;SIGN/SIGN;VERIFY/VERIFY,EXAMPLE"
177 $ LIB_ = "cryptlib,mem,mem_dbg,cversion,ex_data,tmdiff,cpt_err,ebcdic,uid"
178 $ LIB_MD2 = "md2_dgst,md2_one"
179 $ LIB_MD4 = "md4_dgst,md4_one"
180 $ LIB_MD5 = "md5_dgst,md5_one"
181 $ LIB_SHA = "sha_dgst,sha1dgst,sha_one,sha1_one"
182 $ LIB_MDC2 = "mdc2dgst,mdc2_one"
183 $ LIB_HMAC = "hmac"
184 $ LIB_RIPEMD = "rmd_dgst,rmd_one"
185 $ LIB_DES = "set_key,ecb_enc,cbc_enc,"+ -
186         "ecb3_enc,cfb64enc,cfb64ede,cfb_enc,ofb64ede,"+ -
187         "enc_read,enc_writ,ofb64enc,"+ -
188         "ofb_enc,str2key,pcbc_enc,qud_cksm,rand_key,"+ -
189         "des_enc,fcrypt_b,read2pwd,"+ -
190         "fcrypt,xcbc_enc,read_pwd,rpc_enc,cbc_cksm,ede_cbcm_enc"
191 $ LIB_RC2 = "rc2_ecb,rc2_skey,rc2_cbc,rc2cfb64,rc2ofb64"
192 $ LIB_RC4 = "rc4_skey,rc4_enc"
193 $ LIB_RC5 = "rc5_skey,rc5_ecb,rc5_enc,rc5cfb64,rc5ofb64"
194 $ LIB_IDEA = "i_cbc,i_cfb64,i_ofb64,i_ecb,i_skey"
195 $ LIB_BF = "bf_skey,bf_ecb,bf_enc,bf_cfb64,bf_ofb64"
196 $ LIB_CAST = "c_skey,c_ecb,c_enc,c_cfb64,c_ofb64"
197 $ LIB_BN_ASM = "[.asm]vms.mar,vms-helper"
198 $ IF F$TRNLNM("OPENSSL_NO_ASM").OR.ARCH.EQS."AXP" THEN LIB_BN_ASM = "bn_asm"
199 $ LIB_BN = "bn_add,bn_div,bn_exp,bn_lib,bn_ctx,bn_mul,"+ -
200         "bn_print,bn_rand,bn_shift,bn_word,bn_blind,"+ -
201         "bn_gcd,bn_prime,bn_err,bn_sqr,"+LIB_BN_ASM+",bn_recp,bn_mont,"+ -
202         "bn_mpi,bn_exp2"
203 $ LIB_RSA = "rsa_eay,rsa_gen,rsa_lib,rsa_sign,rsa_saos,rsa_err,"+ -
204         "rsa_pk1,rsa_ssl,rsa_none,rsa_oaep,rsa_chk,rsa_null"
205 $ LIB_DSA = "dsa_gen,dsa_key,dsa_lib,dsa_asn1,dsa_vrf,dsa_sign,dsa_err,dsa_ossl"
206 $ LIB_DH = "dh_gen,dh_key,dh_lib,dh_check,dh_err"
207 $ LIB_DSO = "dso_dl,dso_dlfcn,dso_err,dso_lib,dso_null,"+ -
208         "dso_openssl,dso_win32,dso_vms"
209 $ LIB_BUFFER = "buffer,buf_err"
210 $ LIB_BIO = "bio_lib,bio_cb,bio_err,"+ -
211         "bss_mem,bss_null,bss_fd,"+ -
212         "bss_file,bss_sock,bss_conn,"+ -
213         "bf_null,bf_buff,b_print,b_dump,"+ -
214         "b_sock,bss_acpt,bf_nbio,bss_rtcp,bss_bio,bss_log,"+ -
215         "bf_lbuf"
216 $ LIB_STACK = "stack"
217 $ LIB_LHASH = "lhash,lh_stats"
218 $ LIB_RAND = "md_rand,randfile,rand_lib,rand_err,rand_egd,rand_win"
219 $ LIB_ERR = "err,err_all,err_prn"
220 $ LIB_OBJECTS = "o_names,obj_dat,obj_lib,obj_err"
221 $ LIB_EVP = "encode,digest,evp_enc,evp_key,"+ -
222         "e_des,e_bf,e_idea,e_des3,"+ -
223         "e_rc4,names,"+ -
224         "e_xcbc_d,e_rc2,e_cast,e_rc5"
225 $ LIB_EVP_2 = "m_null,m_md2,m_md4,m_md5,m_sha,m_sha1," + -
226         "m_dss,m_dss1,m_mdc2,m_ripemd,"+ -
227         "p_open,p_seal,p_sign,p_verify,p_lib,p_enc,p_dec,"+ -
228         "bio_md,bio_b64,bio_enc,evp_err,e_null,"+ -
229         "c_all,c_allc,c_alld,evp_lib,bio_ok,"+-
230         "evp_pkey,evp_pbe,p5_crpt,p5_crpt2"
231 $ LIB_ASN1 = "a_object,a_bitstr,a_utctm,a_gentm,a_time,a_int,a_octet,"+ -
232         "a_null,a_print,a_type,a_set,a_dup,a_d2i_fp,a_i2d_fp,a_bmp,"+ -
233         "a_enum,a_vis,a_utf8,a_sign,a_digest,a_verify,a_mbstr,a_strex,"+ -
234         "x_algor,x_val,x_pubkey,x_sig,x_req,x_attrib,"+ -
235         "x_name,x_cinf,x_x509,x_x509a,x_crl,x_info,x_spki,nsseq,"+ -
236         "d2i_r_pr,i2d_r_pr,d2i_r_pu,i2d_r_pu,"+ -
237         "d2i_s_pr,i2d_s_pr,d2i_s_pu,i2d_s_pu,"+ -
238         "d2i_pu,d2i_pr,i2d_pu,i2d_pr"
239 $ LIB_ASN1_2 = "t_req,t_x509,t_x509a,t_crl,t_pkey,t_spki,t_bitst,"+ -
240         "p7_i_s,p7_signi,p7_signd,p7_recip,p7_enc_c,p7_evp,"+ -
241         "p7_dgst,p7_s_e,p7_enc,p7_lib,"+ -
242         "f_int,f_string,i2d_dhp,i2d_dsap,d2i_dhp,d2i_dsap,n_pkey,"+ -
243         "f_enum,a_hdr,x_pkey,a_bool,x_exten,"+ -
244         "asn1_par,asn1_lib,asn1_err,a_meth,a_bytes,a_strnid,"+ -
245         "evp_asn1,asn_pack,p5_pbe,p5_pbev2,p8_pkey"
246 $ LIB_PEM = "pem_sign,pem_seal,pem_info,pem_lib,pem_all,pem_err"
247 $ LIB_X509 = "x509_def,x509_d2,x509_r2x,x509_cmp,"+ -
248         "x509_obj,x509_req,x509spki,x509_vfy,"+ -
249         "x509_set,x509rset,x509_err,"+ -
250         "x509name,x509_v3,x509_ext,x509_att,"+ -
251         "x509type,x509_lu,x_all,x509_txt,"+ -
252         "x509_trs,by_file,by_dir"
253 $ LIB_X509V3 = "v3_bcons,v3_bitst,v3_conf,v3_extku,v3_ia5,v3_lib,"+ -
254         "v3_prn,v3_utl,v3err,v3_genn,v3_alt,v3_skey,v3_akey,v3_pku,"+ -
255         "v3_int,v3_enum,v3_sxnet,v3_cpols,v3_crld,v3_purp,v3_info"
256 $ LIB_CONF = "conf_err,conf_lib,conf_api,conf_def"
257 $ LIB_TXT_DB = "txt_db"
258 $ LIB_PKCS7 = "pk7_lib,pkcs7err,pk7_doit,pk7_smime,pk7_attr,pk7_mime"
259 $ LIB_PKCS12 = "p12_add,p12_attr,p12_bags,p12_crpt,p12_crt,p12_decr,"+ -
260         "p12_init,p12_key,p12_kiss,p12_lib,p12_mac,p12_mutl,"+ -
261         "p12_sbag,p12_utl,p12_npas,pk12err"
262 $ LIB_COMP = "comp_lib,"+ -
263         "c_rle,c_zlib"
265 $! Setup exceptional compilations
267 $ COMPILEWITH_CC3 = ",bss_rtcp,"
268 $ COMPILEWITH_CC4 = ",a_utctm,bss_log,"
269 $ COMPILEWITH_CC5 = ",md2_dgst,md4_dgst,md5_dgst,mdc2dgst," + -
270                     "sha_dgst,sha1dgst,rmd_dgst,bf_enc,"
272 $! Check To See If We Are Going To Use RSAREF.
274 $ IF (RSAREF.EQS."TRUE" .AND. ENCRYPT_TYPES - "RSA".NES.ENCRYPT_TYPES -
275       .AND. (BUILDALL .EQS. "TRUE" .OR. BUILDALL .EQS. "LIBRARY"))
276 $ THEN
278 $!  Check To See If The File [-.RSAREF]RSAREF.C Is Actually There.
280 $   IF (F$SEARCH("SYS$DISK:[-.RSAREF]RSAREF.C").EQS."")
281 $   THEN
283 $!    Tell The User That The File Doesn't Exist.
285 $     WRITE SYS$OUTPUT ""
286 $     WRITE SYS$OUTPUT "The File [-.RSAREF]RSAREF.C Doesn't Exist."
287 $     WRITE SYS$OUTPUT ""
289 $!    Exit The Build.
291 $     GOTO EXIT
293 $!  End The [-.RSAREF]RSAREF.C Check.
295 $   ENDIF
297 $!  Tell The User We Are Compiling The [-.RSAREF]RSAREF File.
299 $   WRITE SYS$OUTPUT "Compiling The [-.RSAREF]RSAREF File."
301 $!  Compile [-.RSAREF]RSAREF.C
303 $   CC/OBJECT='OBJ_DIR'RSAREF.OBJ SYS$DISK:[-.RSAREF]RSAREF.C
305 $!  Add It To The Library.
307 $   LIBRARY/REPLACE 'LIB_NAME' 'OBJ_DIR'RSAREF.OBJ
309 $!  Delete The Object File.
311 $   DELETE 'OBJ_DIR'RSAREF.OBJ;*
313 $!  Check To See If The File [-.RSAREF]RSAR_ERR.C Is Actually There.
315 $   IF (F$SEARCH("SYS$DISK:[-.RSAREF]RSAR_ERR.C").EQS."")
316 $   THEN
318 $!    Tell The User That The File Doesn't Exist.
320 $     WRITE SYS$OUTPUT ""
321 $     WRITE SYS$OUTPUT "The File [-.RSAREF]RSAR_ERR.C Doesn't Exist."
322 $     WRITE SYS$OUTPUT ""
324 $!    Exit The Build.
326 $     GOTO EXIT
328 $!  End The [-.RSAREF]RSAR_ERR.C File Check.
330 $   ENDIF
332 $!  Tell The User We Are Compiling The [-.RSAREF]RSAR_ERR File.
334 $   WRITE SYS$OUTPUT "Compiling The [-.RSAREF]RSAR_ERR File."
336 $!  Compile [-.RSAREF]RSAR_ERR.C
338 $   CC/OBJECT='OBJ_DIR'RSAR_ERR.OBJ SYS$DISK:[-.RSAREF]RSAR_ERR.C
340 $!  Add It To The Library.
342 $   LIBRARY/REPLACE 'LIB_NAME' 'OBJ_DIR'RSAR_ERR.OBJ
344 $!  Delete The Object File.
346 $   DELETE 'OBJ_DIR'RSAR_ERR.OBJ;*
348 $! End The RSAREF Check.
350 $ ENDIF
352 $! Figure Out What Other Modules We Are To Build.
354 $ BUILD_SET:
356 $! Define A Module Counter.
358 $ MODULE_COUNTER = 0
360 $! Top Of The Loop.
362 $ MODULE_NEXT:
364 $! Extract The Module Name From The Encryption List.
366 $ MODULE_NAME = F$ELEMENT(MODULE_COUNTER,",",ENCRYPT_TYPES)
367 $ IF MODULE_NAME.EQS."Basic" THEN MODULE_NAME = ""
368 $ MODULE_NAME1 = MODULE_NAME
370 $! Check To See If We Are At The End Of The Module List.
372 $ IF (MODULE_NAME.EQS.",") 
373 $ THEN 
375 $!  We Are At The End Of The Module List, Go To MODULE_DONE.
377 $   GOTO MODULE_DONE
379 $! End The Module List Check.
381 $ ENDIF
383 $! Increment The Moudle Counter.
385 $ MODULE_COUNTER = MODULE_COUNTER + 1
387 $! Create The Library and Apps Module Names.
389 $ LIB_MODULE = "LIB_" + MODULE_NAME
390 $ APPS_MODULE = "APPS_" + MODULE_NAME
391 $ IF (MODULE_NAME.EQS."ASN1_2")
392 $ THEN
393 $   MODULE_NAME = "ASN1"
394 $ ENDIF
395 $ IF (MODULE_NAME.EQS."EVP_2")
396 $ THEN
397 $   MODULE_NAME = "EVP"
398 $ ENDIF
400 $! Set state (can be LIB and APPS)
402 $ STATE = "LIB"
403 $ IF BUILDALL .EQS. "APPS" THEN STATE = "APPS"
405 $! Check if the library module name actually is defined
407 $ IF F$TYPE('LIB_MODULE') .EQS. ""
408 $ THEN
409 $   WRITE SYS$ERROR ""
410 $   WRITE SYS$ERROR "The module ",MODULE_NAME," does not exist.  Continuing..."
411 $   WRITE SYS$ERROR ""
412 $   GOTO MODULE_NEXT
413 $ ENDIF
415 $! Top Of The Module Loop.
417 $ MODULE_AGAIN:
419 $! Tell The User What Module We Are Building.
421 $ IF (MODULE_NAME1.NES."") 
422 $ THEN
423 $   IF STATE .EQS. "LIB"
424 $   THEN
425 $     WRITE SYS$OUTPUT "Compiling The ",MODULE_NAME1," Library Files. (",BUILDALL,",",STATE,")"
426 $   ELSE IF F$TYPE('APPS_MODULE') .NES. ""
427 $     THEN
428 $       WRITE SYS$OUTPUT "Compiling The ",MODULE_NAME1," Applications. (",BUILDALL,",",STATE,")"
429 $     ENDIF
430 $   ENDIF
431 $ ENDIF
433 $!  Define A File Counter And Set It To "0".
435 $ FILE_COUNTER = 0
436 $ APPLICATION = ""
437 $ APPLICATION_COUNTER = 0
439 $! Top Of The File Loop.
441 $ NEXT_FILE:
443 $! Look in the LIB_MODULE is we're in state LIB
445 $ IF STATE .EQS. "LIB"
446 $ THEN
448 $!   O.K, Extract The File Name From The File List.
450 $   FILE_NAME = F$ELEMENT(FILE_COUNTER,",",'LIB_MODULE')
452 $!   else
454 $ ELSE
455 $   FILE_NAME = ","
457 $   IF F$TYPE('APPS_MODULE') .NES. ""
458 $   THEN
460 $!     Extract The File Name From The File List.
461 $!     This part is a bit more complicated.
463 $     IF APPLICATION .EQS. ""
464 $     THEN
465 $       APPLICATION = F$ELEMENT(APPLICATION_COUNTER,";",'APPS_MODULE')
466 $       APPLICATION_COUNTER = APPLICATION_COUNTER + 1
467 $       APPLICATION_OBJECTS = F$ELEMENT(1,"/",APPLICATION)
468 $       APPLICATION = F$ELEMENT(0,"/",APPLICATION)
469 $       FILE_COUNTER = 0
470 $     ENDIF
472 $!     WRITE SYS$OUTPUT "DEBUG: SHOW SYMBOL APPLICATION*"
473 $!     SHOW SYMBOL APPLICATION*
475 $     IF APPLICATION .NES. ";"
476 $     THEN
477 $       FILE_NAME = F$ELEMENT(FILE_COUNTER,",",APPLICATION_OBJECTS)
478 $       IF FILE_NAME .EQS. ","
479 $       THEN
480 $         APPLICATION = ""
481 $         GOTO NEXT_FILE
482 $       ENDIF
483 $     ENDIF
484 $   ENDIF
485 $ ENDIF
487 $! Check To See If We Are At The End Of The File List.
489 $ IF (FILE_NAME.EQS.",") 
490 $ THEN 
492 $!  We Are At The End Of The File List, Change State Or Goto FILE_DONE.
494 $   IF STATE .EQS. "LIB" .AND. BUILDALL .NES. "LIBRARY"
495 $   THEN
496 $     STATE = "APPS"
497 $     GOTO MODULE_AGAIN
498 $   ELSE
499 $     GOTO FILE_DONE
500 $   ENDIF
502 $! End The File List Check.
504 $ ENDIF
506 $! Increment The Counter.
508 $ FILE_COUNTER = FILE_COUNTER + 1
510 $! Create The Source File Name.
512 $ TMP_FILE_NAME = F$ELEMENT(1,"]",FILE_NAME)
513 $ IF TMP_FILE_NAME .EQS. "]" THEN TMP_FILE_NAME = FILE_NAME
514 $ IF F$ELEMENT(0,".",TMP_FILE_NAME) .EQS. TMP_FILE_NAME THEN -
515         FILE_NAME = FILE_NAME + ".c"
516 $ IF (MODULE_NAME.NES."")
517 $ THEN
518 $   SOURCE_FILE = "SYS$DISK:[." + MODULE_NAME+ "]" + FILE_NAME
519 $ ELSE
520 $   SOURCE_FILE = "SYS$DISK:[]" + FILE_NAME
521 $ ENDIF
522 $ SOURCE_FILE = SOURCE_FILE - "]["
524 $! Create The Object File Name.
526 $ OBJECT_FILE = OBJ_DIR + F$PARSE(FILE_NAME,,,"NAME","SYNTAX_ONLY") + ".OBJ"
527 $ ON WARNING THEN GOTO NEXT_FILE
529 $! Check To See If The File We Want To Compile Is Actually There.
531 $ IF (F$SEARCH(SOURCE_FILE).EQS."")
532 $ THEN
534 $!  Tell The User That The File Doesn't Exist.
536 $   WRITE SYS$OUTPUT ""
537 $   WRITE SYS$OUTPUT "The File ",SOURCE_FILE," Doesn't Exist."
538 $   WRITE SYS$OUTPUT ""
540 $!  Exit The Build.
542 $   GOTO EXIT
544 $! End The File Exist Check.
546 $ ENDIF
548 $! Tell The User We Are Compiling The File.
550 $ IF (MODULE_NAME.EQS."")
551 $ THEN
552 $   WRITE SYS$OUTPUT "Compiling The ",FILE_NAME," File.  (",BUILDALL,",",STATE,")"
553 $ ENDIF
554 $ IF (MODULE_NAME.NES."")
555 $ THEN 
556 $   WRITE SYS$OUTPUT "  ",FILE_NAME,""
557 $ ENDIF
559 $! Compile The File.
561 $ ON ERROR THEN GOTO NEXT_FILE
562 $ FILE_NAME0 = F$ELEMENT(0,".",FILE_NAME)
563 $ IF FILE_NAME - ".mar" .NES. FILE_NAME
564 $ THEN
565 $   MACRO/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
566 $ ELSE
567 $   IF COMPILEWITH_CC3 - FILE_NAME0 .NES. COMPILEWITH_CC3
568 $   THEN
569 $     CC3/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
570 $   ELSE
571 $     IF COMPILEWITH_CC4 - FILE_NAME0 .NES. COMPILEWITH_CC4
572 $     THEN
573 $       CC4/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
574 $     ELSE
575 $       IF COMPILEWITH_CC5 - FILE_NAME0 .NES. COMPILEWITH_CC5
576 $       THEN
577 $         CC5/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
578 $       ELSE
579 $         CC/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
580 $       ENDIF
581 $     ENDIF
582 $   ENDIF
583 $ ENDIF
584 $ IF STATE .EQS. "LIB"
585 $ THEN 
587 $!   Add It To The Library.
589 $   LIBRARY/REPLACE 'LIB_NAME' 'OBJECT_FILE'
591 $!   Time To Clean Up The Object File.
593 $   DELETE 'OBJECT_FILE';*
594 $ ENDIF
596 $! Go Back And Do It Again.
598 $ GOTO NEXT_FILE
600 $! All Done With This Library Part.
602 $ FILE_DONE:
604 $! Time To Build Some Applications
606 $ IF F$TYPE('APPS_MODULE') .NES. "" .AND. BUILDALL .NES. "LIBRARY"
607 $ THEN
608 $   APPLICATION_COUNTER = 0
609 $ NEXT_APPLICATION:
610 $   APPLICATION = F$ELEMENT(APPLICATION_COUNTER,";",'APPS_MODULE')
611 $   IF APPLICATION .EQS. ";" THEN GOTO APPLICATION_DONE
613 $   APPLICATION_COUNTER = APPLICATION_COUNTER + 1
614 $   APPLICATION_OBJECTS = F$ELEMENT(1,"/",APPLICATION)
615 $   APPLICATION = F$ELEMENT(0,"/",APPLICATION)
617 $!   WRITE SYS$OUTPUT "DEBUG: SHOW SYMBOL APPLICATION*"
618 $!   SHOW SYMBOL APPLICATION*
620 $! Tell the user what happens
622 $   WRITE SYS$OUTPUT "  ",APPLICATION,".exe"
624 $! Link The Program, Check To See If We Need To Link With RSAREF Or Not.
626 $   IF (RSAREF.EQS."TRUE")
627 $   THEN
629 $!  Check To See If We Are To Link With A Specific TCP/IP Library.
631 $     IF (TCPIP_LIB.NES."")
632 $     THEN
634 $!    Link With The RSAREF Library And A Specific TCP/IP Library.
636 $       LINK/'DEBUGGER'/'TRACEBACK'/EXE='EXE_DIR''APPLICATION'.EXE -
637             'OBJ_DIR''APPLICATION_OBJECTS', -
638             'CRYPTO_LIB'/LIBRARY,'RSAREF_LIB'/LIBRARY, -
639             'TCPIP_LIB','OPT_FILE'/OPTION
641 $!    Else...
643 $     ELSE
645 $!      Link With The RSAREF Library And NO TCP/IP Library.
647 $       LINK/'DEBUGGER'/'TRACEBACK'/EXE='EXE_DIR''APPLICATION'.EXE -
648             'OBJ_DIR''APPLICATION_OBJECTS', -
649             'CRYPTO_LIB'/LIBRARY,'RSAREF_LIB'/LIBRARY, -
650             'OPT_FILE'/OPTION
652 $!    End The TCP/IP Library Check.
654 $     ENDIF
656 $!   Else...
658 $   ELSE
660 $!    Don't Link With The RSAREF Routines.
663 $!    Check To See If We Are To Link With A Specific TCP/IP Library.
665 $     IF (TCPIP_LIB.NES."")
666 $     THEN
668 $!      Don't Link With The RSAREF Routines And TCP/IP Library.
670 $       LINK/'DEBUGGER'/'TRACEBACK'/EXE='EXE_DIR''APPLICATION'.EXE -
671             'OBJ_DIR''APPLICATION_OBJECTS', -
672             'CRYPTO_LIB'/LIBRARY, -
673             'TCPIP_LIB','OPT_FILE'/OPTION
675 $!    Else...
677 $     ELSE
679 $!      Don't Link With The RSAREF Routines And Link With A TCP/IP Library.
681 $       LINK/'DEBUGGER'/'TRACEBACK'/EXE='EXE_DIR''APPLICATION'.EXE -
682             'OBJ_DIR''APPLICATION_OBJECTS',-
683             'CRYPTO_LIB'/LIBRARY, -
684             'OPT_FILE'/OPTION
686 $!    End The TCP/IP Library Check.
688 $     ENDIF
690 $!   End The RSAREF Link Check.
692 $   ENDIF
693 $   GOTO NEXT_APPLICATION
694 $  APPLICATION_DONE:
695 $ ENDIF
697 $! Go Back And Get The Next Module.
699 $ GOTO MODULE_NEXT
701 $! All Done With This Module.
703 $ MODULE_DONE:
705 $! Tell The User That We Are All Done.
707 $ WRITE SYS$OUTPUT "All Done..."
708 $ EXIT:
709 $ GOSUB CLEANUP
710 $ EXIT
712 $! Check For The Link Option FIle.
714 $ CHECK_OPT_FILE:
716 $! Check To See If We Need To Make A VAX C Option File.
718 $ IF (COMPILER.EQS."VAXC")
719 $ THEN
721 $!  Check To See If We Already Have A VAX C Linker Option File.
723 $   IF (F$SEARCH(OPT_FILE).EQS."")
724 $   THEN
726 $!    We Need A VAX C Linker Option File.
728 $     CREATE 'OPT_FILE'
729 $DECK
731 ! Default System Options File To Link Agianst 
732 ! The Sharable VAX C Runtime Library.
734 SYS$SHARE:VAXCRTL.EXE/SHARE
735 $EOD
737 $!  End The Option File Check.
739 $   ENDIF
741 $! End The VAXC Check.
743 $ ENDIF
745 $! Check To See If We Need A GNU C Option File.
747 $ IF (COMPILER.EQS."GNUC")
748 $ THEN
750 $!  Check To See If We Already Have A GNU C Linker Option File.
752 $   IF (F$SEARCH(OPT_FILE).EQS."")
753 $   THEN
755 $!    We Need A GNU C Linker Option File.
757 $     CREATE 'OPT_FILE'
758 $DECK
760 ! Default System Options File To Link Agianst 
761 ! The Sharable C Runtime Library.
763 GNU_CC:[000000]GCCLIB/LIBRARY
764 SYS$SHARE:VAXCRTL/SHARE
765 $EOD
767 $!  End The Option File Check.
769 $   ENDIF
771 $! End The GNU C Check.
773 $ ENDIF
775 $! Check To See If We Need A DEC C Option File.
777 $ IF (COMPILER.EQS."DECC")
778 $ THEN
780 $!  Check To See If We Already Have A DEC C Linker Option File.
782 $   IF (F$SEARCH(OPT_FILE).EQS."")
783 $   THEN
785 $!    Figure Out If We Need An AXP Or A VAX Linker Option File.
787 $     IF ARCH .EQS. "VAX"
788 $     THEN
790 $!      We Need A DEC C Linker Option File For VAX.
792 $       CREATE 'OPT_FILE'
793 $DECK
795 ! Default System Options File To Link Agianst 
796 ! The Sharable DEC C Runtime Library.
798 SYS$SHARE:DECC$SHR.EXE/SHARE
799 $EOD
801 $!    Else...
803 $     ELSE
805 $!      Create The AXP Linker Option File.
807 $       CREATE 'OPT_FILE'
808 $DECK
810 ! Default System Options File For AXP To Link Agianst 
811 ! The Sharable C Runtime Library.
813 SYS$SHARE:CMA$OPEN_LIB_SHR/SHARE
814 SYS$SHARE:CMA$OPEN_RTL/SHARE
815 $EOD
817 $!    End The VAX/AXP DEC C Option File Check.
819 $     ENDIF
821 $!  End The Option File Search.
823 $   ENDIF
825 $! End The DEC C Check.
827 $ ENDIF
829 $!  Tell The User What Linker Option File We Are Using.
831 $ WRITE SYS$OUTPUT "Using Linker Option File ",OPT_FILE,"."     
833 $! Time To RETURN.
835 $ RETURN
837 $! Check The User's Options.
839 $ CHECK_OPTIONS:
841 $! Check To See If P1 Is Blank.
843 $ IF (P1.EQS."ALL")
844 $ THEN
846 $!   P1 Is Blank, So Build Everything.
848 $    BUILDALL = "TRUE"
850 $! Else...
852 $ ELSE
854 $!  Else, Check To See If P1 Has A Valid Arguement.
856 $   IF (P1.EQS."LIBRARY").OR.(P1.EQS."APPS")
857 $   THEN
859 $!    A Valid Arguement.
861 $     BUILDALL = P1
863 $!  Else...
865 $   ELSE
867 $!    Tell The User We Don't Know What They Want.
869 $     WRITE SYS$OUTPUT ""
870 $     WRITE SYS$OUTPUT "The Option ",P1," Is Invalid.  The Valid Options Are:"
871 $     WRITE SYS$OUTPUT ""
872 $     WRITE SYS$OUTPUT "    ALL      :  Just Build Everything."
873 $     WRITE SYS$OUTPUT "    LIBRARY  :  To Compile Just The [.xxx.EXE.SSL]LIBCRYPTO.OLB Library."
874 $     WRITE SYS$OUTPUT "    APPS     :  To Compile Just The [.xxx.EXE.SSL]*.EXE Programs."
875 $     WRITE SYS$OUTPUT ""
876 $     WRITE SYS$OUTPUT " Where 'xxx' Stands For:"
877 $     WRITE SYS$OUTPUT ""
878 $     WRITE SYS$OUTPUT "        AXP  :  Alpha Architecture."
879 $     WRITE SYS$OUTPUT "        VAX  :  VAX Architecture."
880 $     WRITE SYS$OUTPUT ""
882 $!    Time To EXIT.
884 $     EXIT
886 $!  End The Valid Arguement Check.
888 $   ENDIF
890 $! End The P1 Check.
892 $ ENDIF
894 $! Check To See If P2 Is Blank.
896 $ IF (P2.EQS."NORSAREF")
897 $ THEN
899 $!   P2 Is NORSAREF, So Compile With The Regular RSA Libraries.
901 $    RSAREF = "FALSE"
902 $ ELSE
904 $!  Check To See If We Are To Use The RSAREF Library.
906 $   IF (P2.EQS."RSAREF")
907 $   THEN
909 $!    Check To Make Sure We Have The RSAREF Source Code Directory.
911 $     IF (F$SEARCH("SYS$DISK:[-.RSAREF]SOURCE.DIR").EQS."")
912 $     THEN
914 $!      We Don't Have The RSAREF Souce Code Directory, So Tell The
915 $!      User This.
917 $       WRITE SYS$OUTPUT ""
918 $       WRITE SYS$OUTPUT "It appears that you don't have the RSAREF Souce Code."
919 $       WRITE SYS$OUTPUT "You need to go to 'ftp://ftp.rsa.com/rsaref'.  You have to"
920 $       WRITE SYS$OUTPUT "get the '.tar-Z' file as the '.zip' file doesn't have the"
921 $       WRITE SYS$OUTPUT "directory structure stored.  You have to extract the file"
922 $       WRITE SYS$OUTPUT "into the [.RSAREF] directory under the root directory"
923 $       WRITE SYS$OUTPUT "as that is where the scripts will look for the files."
924 $       WRITE SYS$OUTPUT ""
926 $!      Time To Exit.
928 $       EXIT
930 $!    Else, Compile Using The RSAREF Library.
932 $     ELSE
933 $       RSAREF = "TRUE"
934 $     ENDIF
935 $   ELSE 
937 $!    They Entered An Invalid Option..
939 $     WRITE SYS$OUTPUT ""
940 $     WRITE SYS$OUTPUT "The Option ",P2," Is Invalid.  The Valid Options Are:"
941 $     WRITE SYS$OUTPUT ""
942 $     WRITE SYS$OUTPUT "     RSAREF   :  Compile With The RSAREF Library."
943 $     WRITE SYS$OUTPUT "     NORSAREF :  Compile With The Regular RSA Library."
944 $     WRITE SYS$OUTPUT ""
946 $!    Time To EXIT.
948 $     EXIT
950 $!  End The Valid Arguement Check.
952 $   ENDIF
954 $! End The P2 Check.
956 $ ENDIF
958 $! Check To See If P3 Is Blank.
960 $ IF (P3.EQS."NODEBUG")
961 $ THEN
963 $!   P3 Is NODEBUG, So Compile Without The Debugger Information.
965 $    DEBUGGER = "NODEBUG"
966 $    TRACEBACK = "NOTRACEBACK" 
967 $    GCC_OPTIMIZE = "OPTIMIZE"
968 $    CC_OPTIMIZE = "OPTIMIZE"
969 $    MACRO_OPTIMIZE = "OPTIMIZE"
970 $    WRITE SYS$OUTPUT "No Debugger Information Will Be Produced During Compile."
971 $    WRITE SYS$OUTPUT "Compiling With Compiler Optimization."
972 $ ELSE
974 $!  Check To See If We Are To Compile With Debugger Information.
976 $   IF (P3.EQS."DEBUG")
977 $   THEN
979 $!    Compile With Debugger Information.
981 $     DEBUGGER = "DEBUG"
982 $     TRACEBACK = "TRACEBACK"
983 $     GCC_OPTIMIZE = "NOOPTIMIZE"
984 $     CC_OPTIMIZE = "NOOPTIMIZE"
985 $     MACRO_OPTIMIZE = "NOOPTIMIZE"
986 $     WRITE SYS$OUTPUT "Debugger Information Will Be Produced During Compile."
987 $     WRITE SYS$OUTPUT "Compiling Without Compiler Optimization."
988 $   ELSE 
990 $!    They Entered An Invalid Option..
992 $     WRITE SYS$OUTPUT ""
993 $     WRITE SYS$OUTPUT "The Option ",P3," Is Invalid.  The Valid Options Are:"
994 $     WRITE SYS$OUTPUT ""
995 $     WRITE SYS$OUTPUT "     DEBUG   :  Compile With The Debugger Information."
996 $     WRITE SYS$OUTPUT "     NODEBUG :  Compile Without The Debugger Information."
997 $     WRITE SYS$OUTPUT ""
999 $!    Time To EXIT.
1001 $     EXIT
1003 $!  End The Valid Arguement Check.
1005 $   ENDIF
1007 $! End The P3 Check.
1009 $ ENDIF
1011 $! Special Threads For OpenVMS v7.1 Or Later
1013 $! Written By:  Richard Levitte
1014 $!              richard@levitte.org
1017 $! Check To See If We Have A Option For P6.
1019 $ IF (P6.EQS."")
1020 $ THEN
1022 $!  Get The Version Of VMS We Are Using.
1024 $   ISSEVEN :=
1025 $   TMP = F$ELEMENT(0,"-",F$EXTRACT(1,4,F$GETSYI("VERSION")))
1026 $   TMP = F$INTEGER(F$ELEMENT(0,".",TMP)+F$ELEMENT(1,".",TMP))
1028 $!  Check To See If The VMS Version Is v7.1 Or Later.
1030 $   IF (TMP.GE.71)
1031 $   THEN
1033 $!    We Have OpenVMS v7.1 Or Later, So Use The Special Threads.
1035 $     ISSEVEN := ,PTHREAD_USE_D4
1037 $!  End The VMS Version Check.
1039 $   ENDIF
1041 $! End The P6 Check.
1043 $ ENDIF
1045 $! Check To See If P4 Is Blank.
1047 $ IF (P4.EQS."")
1048 $ THEN
1050 $!  O.K., The User Didn't Specify A Compiler, Let's Try To
1051 $!  Find Out Which One To Use.
1053 $!  Check To See If We Have GNU C.
1055 $   IF (F$TRNLNM("GNU_CC").NES."")
1056 $   THEN
1058 $!    Looks Like GNUC, Set To Use GNUC.
1060 $     P4 = "GNUC"
1062 $!  Else...
1064 $   ELSE
1066 $!    Check To See If We Have VAXC Or DECC.
1068 $     IF (ARCH.EQS."AXP").OR.(F$TRNLNM("DECC$CC_DEFAULT").NES."")
1069 $     THEN 
1071 $!      Looks Like DECC, Set To Use DECC.
1073 $       P4 = "DECC"
1075 $!    Else...
1077 $     ELSE
1079 $!      Looks Like VAXC, Set To Use VAXC.
1081 $       P4 = "VAXC"
1083 $!    End The VAXC Compiler Check.
1085 $     ENDIF
1087 $!  End The DECC & VAXC Compiler Check.
1089 $   ENDIF
1091 $!  End The Compiler Check.
1093 $ ENDIF
1095 $! Check To See If We Have A Option For P5.
1097 $ IF (P5.EQS."")
1098 $ THEN
1100 $!  Find out what socket library we have available
1102 $   IF F$PARSE("SOCKETSHR:") .NES. ""
1103 $   THEN
1105 $!    We have SOCKETSHR, and it is my opinion that it's the best to use.
1107 $     P5 = "SOCKETSHR"
1109 $!    Tell the user
1111 $     WRITE SYS$OUTPUT "Using SOCKETSHR for TCP/IP"
1113 $!    Else, let's look for something else
1115 $   ELSE
1117 $!    Like UCX (the reason to do this before Multinet is that the UCX
1118 $!    emulation is easier to use...)
1120 $     IF F$TRNLNM("UCX$IPC_SHR") .NES. "" -
1121          .OR. F$PARSE("SYS$SHARE:UCX$IPC_SHR.EXE") .NES. "" -
1122          .OR. F$PARSE("SYS$LIBRARY:UCX$IPC.OLB") .NES. ""
1123 $     THEN
1125 $!      Last resort: a UCX or UCX-compatible library
1127 $       P5 = "UCX"
1129 $!      Tell the user
1131 $       WRITE SYS$OUTPUT "Using UCX or an emulation thereof for TCP/IP"
1133 $!      That was all...
1135 $     ENDIF
1136 $   ENDIF
1137 $ ENDIF
1139 $! Set Up Initial CC Definitions, Possibly With User Ones
1141 $ CCDEFS = "VMS=1,TCPIP_TYPE_''P5',DSO_VMS"
1142 $ IF F$TRNLNM("OPENSSL_NO_ASM") THEN CCDEFS = CCDEFS + ",NO_ASM"
1143 $ IF F$TRNLNM("OPENSSL_NO_RSA") THEN CCDEFS = CCDEFS + ",NO_RSA"
1144 $ IF F$TRNLNM("OPENSSL_NO_DSA") THEN CCDEFS = CCDEFS + ",NO_DSA"
1145 $ IF F$TRNLNM("OPENSSL_NO_DH") THEN CCDEFS = CCDEFS + ",NO_DH"
1146 $ IF F$TRNLNM("OPENSSL_NO_MD2") THEN CCDEFS = CCDEFS + ",NO_MD2"
1147 $ IF F$TRNLNM("OPENSSL_NO_MD5") THEN CCDEFS = CCDEFS + ",NO_MD5"
1148 $ IF F$TRNLNM("OPENSSL_NO_RIPEMD") THEN CCDEFS = CCDEFS + ",NO_RIPEMD"
1149 $ IF F$TRNLNM("OPENSSL_NO_SHA") THEN CCDEFS = CCDEFS + ",NO_SHA"
1150 $ IF F$TRNLNM("OPENSSL_NO_SHA0") THEN CCDEFS = CCDEFS + ",NO_SHA0"
1151 $ IF F$TRNLNM("OPENSSL_NO_SHA1") THEN CCDEFS = CCDEFS + ",NO_SHA1"
1152 $ IF F$TRNLNM("OPENSSL_NO_DES")
1153 $ THEN
1154 $   CCDEFS = CCDEFS + ",NO_DES,NO_MDC2"
1155 $ ELSE
1156 $   IF F$TRNLNM("OPENSSL_NO_MDC2") THEN CCDEFS = CCDEFS + ",NO_MDC2"
1157 $ ENDIF
1158 $ IF F$TRNLNM("OPENSSL_NO_RC2") THEN CCDEFS = CCDEFS + ",NO_RC2"
1159 $ IF F$TRNLNM("OPENSSL_NO_RC4") THEN CCDEFS = CCDEFS + ",NO_RC4"
1160 $ IF F$TRNLNM("OPENSSL_NO_RC5") THEN CCDEFS = CCDEFS + ",NO_RC5"
1161 $ IF F$TRNLNM("OPENSSL_NO_IDEA") THEN CCDEFS = CCDEFS + ",NO_IDEA"
1162 $ IF F$TRNLNM("OPENSSL_NO_BF") THEN CCDEFS = CCDEFS + ",NO_BF"
1163 $ IF F$TRNLNM("OPENSSL_NO_CAST") THEN CCDEFS = CCDEFS + ",NO_CAST"
1164 $ IF F$TRNLNM("OPENSSL_NO_HMAC") THEN CCDEFS = CCDEFS + ",NO_HMAC"
1165 $ IF F$TRNLNM("OPENSSL_NO_SSL2") THEN CCDEFS = CCDEFS + ",NO_SSL2"
1166 $ IF F$TYPE(USER_CCDEFS) .NES. "" THEN CCDEFS = CCDEFS + "," + USER_CCDEFS
1167 $ CCEXTRAFLAGS = ""
1168 $ IF F$TYPE(USER_CCFLAGS) .NES. "" THEN CCEXTRAFLAGS = USER_CCFLAGS
1169 $ CCDISABLEWARNINGS = "LONGLONGTYPE,LONGLONGSUFX"
1170 $ IF F$TYPE(USER_CCDISABLEWARNINGS) .NES. "" THEN -
1171         CCDISABLEWARNINGS = CCDISABLEWARNINGS + "," + USER_CCDISABLEWARNINGS
1173 $!  Check To See If The User Entered A Valid Paramter.
1175 $ IF (P4.EQS."VAXC").OR.(P4.EQS."DECC").OR.(P4.EQS."GNUC")
1176 $ THEN
1178 $!    Check To See If The User Wanted DECC.
1180 $   IF (P4.EQS."DECC")
1181 $   THEN
1183 $!    Looks Like DECC, Set To Use DECC.
1185 $     COMPILER = "DECC"
1187 $!    Tell The User We Are Using DECC.
1189 $     WRITE SYS$OUTPUT "Using DECC 'C' Compiler."
1191 $!    Use DECC...
1193 $     CC = "CC"
1194 $     IF ARCH.EQS."VAX" .AND. F$TRNLNM("DECC$CC_DEFAULT").NES."/DECC" -
1195          THEN CC = "CC/DECC"
1196 $     CC = CC + "/''CC_OPTIMIZE'/''DEBUGGER'/STANDARD=ANSI89" + -
1197            "/NOLIST/PREFIX=ALL/INCLUDE=SYS$DISK:[]" + CCEXTRAFLAGS
1199 $!    Define The Linker Options File Name.
1201 $     OPT_FILE = "SYS$DISK:[]VAX_DECC_OPTIONS.OPT"
1203 $!  End DECC Check.
1205 $   ENDIF
1207 $!  Check To See If We Are To Use VAXC.
1209 $   IF (P4.EQS."VAXC")
1210 $   THEN
1212 $!    Looks Like VAXC, Set To Use VAXC.
1214 $     COMPILER = "VAXC"
1216 $!    Tell The User We Are Using VAX C.
1218 $     WRITE SYS$OUTPUT "Using VAXC 'C' Compiler."
1220 $!    Compile Using VAXC.
1222 $     CC = "CC"
1223 $     IF ARCH.EQS."AXP"
1224 $     THEN
1225 $       WRITE SYS$OUTPUT "There is no VAX C on Alpha!"
1226 $       EXIT
1227 $     ENDIF
1228 $     IF F$TRNLNM("DECC$CC_DEFAULT").EQS."/DECC" THEN CC = "CC/VAXC"
1229 $     CC = CC + "/''CC_OPTIMIZE'/''DEBUGGER'/NOLIST/INCLUDE=SYS$DISK:[]" + -
1230            CCEXTRAFLAGS
1231 $     CCDEFS = """VAXC""," + CCDEFS
1233 $!    Define <sys> As SYS$COMMON:[SYSLIB]
1235 $     DEFINE/NOLOG SYS SYS$COMMON:[SYSLIB]
1237 $!    Define The Linker Options File Name.
1239 $     OPT_FILE = "SYS$DISK:[]VAX_VAXC_OPTIONS.OPT"
1241 $!  End VAXC Check
1243 $   ENDIF
1245 $!  Check To See If We Are To Use GNU C.
1247 $   IF (P4.EQS."GNUC")
1248 $   THEN
1250 $!    Looks Like GNUC, Set To Use GNUC.
1252 $     COMPILER = "GNUC"
1254 $!    Tell The User We Are Using GNUC.
1256 $     WRITE SYS$OUTPUT "Using GNU 'C' Compiler."
1258 $!    Use GNU C...
1260 $     CC = "GCC/NOCASE_HACK/''GCC_OPTIMIZE'/''DEBUGGER'/NOLIST" + -
1261            "/INCLUDE=SYS$DISK:[]" + CCEXTRAFLAGS
1263 $!    Define The Linker Options File Name.
1265 $     OPT_FILE = "SYS$DISK:[]VAX_GNUC_OPTIONS.OPT"
1267 $!  End The GNU C Check.
1269 $   ENDIF
1271 $!  Set up default defines
1273 $   CCDEFS = """FLAT_INC=1""," + CCDEFS
1275 $!  Check To See If We Are To Compile With RSAREF Routines.
1277 $   IF (RSAREF.EQS."TRUE")
1278 $   THEN
1280 $!    Compile With RSAREF.
1282 $     CCDEFS = CCDEFS + ",""RSAref=1"""
1284 $!    Tell The User This.
1286 $     WRITE SYS$OUTPUT "Compiling With RSAREF Routines."
1288 $!    Else, We Don't Care.  Compile Without The RSAREF Library.
1290 $   ELSE
1292 $!    Tell The User We Are Compile Without The RSAREF Routines.
1294 $     WRITE SYS$OUTPUT "Compiling Without The RSAREF Routines.
1296 $!  End The RSAREF Check.
1298 $   ENDIF
1300 $!  Finish up the definition of CC.
1302 $   IF COMPILER .EQS. "DECC"
1303 $   THEN
1304 $     IF CCDISABLEWARNINGS .EQS. ""
1305 $     THEN
1306 $       CC4DISABLEWARNINGS = "DOLLARID"
1307 $     ELSE
1308 $       CC4DISABLEWARNINGS = CCDISABLEWARNINGS + ",DOLLARID"
1309 $       CCDISABLEWARNINGS = "/WARNING=(DISABLE=(" + CCDISABLEWARNINGS + "))"
1310 $     ENDIF
1311 $     CC4DISABLEWARNINGS = "/WARNING=(DISABLE=(" + CC4DISABLEWARNINGS + "))"
1312 $   ELSE
1313 $     CCDISABLEWARNINGS = ""
1314 $     CC4DISABLEWARNINGS = ""
1315 $   ENDIF
1316 $   CC3 = CC + "/DEFINE=(" + CCDEFS + ISSEVEN + ")" + CCDISABLEWARNINGS
1317 $   CC = CC + "/DEFINE=(" + CCDEFS + ")" + CCDISABLEWARNINGS
1318 $   IF ARCH .EQS. "VAX" .AND. COMPILER .EQS. "DECC" .AND. P3 .NES. "DEBUG"
1319 $   THEN
1320 $     CC5 = CC + "/OPTIMIZE=NODISJOINT"
1321 $   ELSE
1322 $     CC5 = CC + "/NOOPTIMIZE"
1323 $   ENDIF
1324 $   CC4 = CC - CCDISABLEWARNINGS + CC4DISABLEWARNINGS
1326 $!  Show user the result
1328 $   WRITE SYS$OUTPUT "Main C Compiling Command: ",CC
1330 $!  Else The User Entered An Invalid Arguement.
1332 $ ELSE
1334 $!  Tell The User We Don't Know What They Want.
1336 $   WRITE SYS$OUTPUT ""
1337 $   WRITE SYS$OUTPUT "The Option ",P4," Is Invalid.  The Valid Options Are:"
1338 $   WRITE SYS$OUTPUT ""
1339 $   WRITE SYS$OUTPUT "    VAXC  :  To Compile With VAX C."
1340 $   WRITE SYS$OUTPUT "    DECC  :  To Compile With DEC C."
1341 $   WRITE SYS$OUTPUT "    GNUC  :  To Compile With GNU C."
1342 $   WRITE SYS$OUTPUT ""
1344 $!  Time To EXIT.
1346 $   EXIT
1348 $! End The Valid Arguement Check.
1350 $ ENDIF
1352 $! Build a MACRO command for the architecture at hand
1354 $ IF ARCH .EQS. "VAX" THEN MACRO = "MACRO/''DEBUGGER'"
1355 $ IF ARCH .EQS. "AXP" THEN MACRO = "MACRO/MIGRATION/''DEBUGGER'/''MACRO_OPTIMIZE'"
1357 $!  Show user the result
1359 $   WRITE SYS$OUTPUT "Main MACRO Compiling Command: ",MACRO
1361 $! Time to check the contents, and to make sure we get the correct library.
1363 $ IF P5.EQS."SOCKETSHR" .OR. P5.EQS."MULTINET" .OR. P5.EQS."UCX"
1364 $ THEN
1366 $!  Check to see if SOCKETSHR was chosen
1368 $   IF P5.EQS."SOCKETSHR"
1369 $   THEN
1371 $!    Set the library to use SOCKETSHR
1373 $     TCPIP_LIB = "[-.VMS]SOCKETSHR_SHR.OPT/OPT"
1375 $!    Done with SOCKETSHR
1377 $   ENDIF
1379 $!  Check to see if MULTINET was chosen
1381 $   IF P5.EQS."MULTINET"
1382 $   THEN
1384 $!    Set the library to use UCX emulation.
1386 $     P5 = "UCX"
1388 $!    Done with MULTINET
1390 $   ENDIF
1392 $!  Check to see if UCX was chosen
1394 $   IF P5.EQS."UCX"
1395 $   THEN
1397 $!    Set the library to use UCX.
1399 $     TCPIP_LIB = "[-.VMS]UCX_SHR_DECC.OPT/OPT"
1400 $     IF F$TRNLNM("UCX$IPC_SHR") .NES. ""
1401 $     THEN
1402 $       TCPIP_LIB = "[-.VMS]UCX_SHR_DECC_LOG.OPT/OPT"
1403 $     ELSE
1404 $       IF COMPILER .NES. "DECC" .AND. ARCH .EQS. "VAX" THEN -
1405           TCPIP_LIB = "[-.VMS]UCX_SHR_VAXC.OPT/OPT"
1406 $     ENDIF
1408 $!    Done with UCX
1410 $   ENDIF
1412 $!  Print info
1414 $   WRITE SYS$OUTPUT "TCP/IP library spec: ", TCPIP_LIB
1416 $!  Else The User Entered An Invalid Arguement.
1418 $ ELSE
1420 $!  Tell The User We Don't Know What They Want.
1422 $   WRITE SYS$OUTPUT ""
1423 $   WRITE SYS$OUTPUT "The Option ",P5," Is Invalid.  The Valid Options Are:"
1424 $   WRITE SYS$OUTPUT ""
1425 $   WRITE SYS$OUTPUT "    SOCKETSHR  :  To link with SOCKETSHR TCP/IP library."
1426 $   WRITE SYS$OUTPUT "    UCX        :  To link with UCX TCP/IP library."
1427 $   WRITE SYS$OUTPUT ""
1429 $!  Time To EXIT.
1431 $   EXIT
1433 $!  Done with TCP/IP libraries
1435 $ ENDIF
1437 $! Check if the user wanted to compile just a subset of all the encryption
1438 $! methods.
1440 $ IF P7 .NES. ""
1441 $ THEN
1442 $   ENCRYPT_TYPES = P7
1443 $! NYI:   ENCRYPT_PROGRAMS = P7
1444 $ ENDIF
1446 $!  Time To RETURN...
1448 $ RETURN
1450 $ INITIALISE:
1452 $! Save old value of the logical name OPENSSL
1454 $ __SAVE_OPENSSL = F$TRNLNM("OPENSSL","LNM$PROCESS_TABLE")
1456 $! Save directory information
1458 $ __HERE = F$PARSE(F$PARSE("A.;",F$ENVIRONMENT("PROCEDURE"))-"A.;","[]A.;") - "A.;"
1459 $ __HERE = F$EDIT(__HERE,"UPCASE")
1460 $ __TOP = __HERE - "CRYPTO]"
1461 $ __INCLUDE = __TOP + "INCLUDE.OPENSSL]"
1463 $! Set up the logical name OPENSSL to point at the include directory
1465 $ DEFINE OPENSSL/NOLOG '__INCLUDE'
1467 $! Done
1469 $ RETURN
1471 $ CLEANUP:
1473 $! Restore the logical name OPENSSL if it had a value
1475 $ IF __SAVE_OPENSSL .EQS. ""
1476 $ THEN
1477 $   DEASSIGN OPENSSL
1478 $ ELSE
1479 $   DEFINE/NOLOG OPENSSL '__SAVE_OPENSSL'
1480 $ ENDIF
1482 $! Done
1484 $ RETURN