release/src/router/libexif/configure.ac

   1 AC_PREREQ(2.59)
   2 AC_INIT([EXIF library], [0.6.19], [libexif-devel@lists.sourceforge.net], [libexif])
   3 AC_CONFIG_SRCDIR([libexif/exif-data.h])
   4 AC_CONFIG_HEADERS([config.h])
   5 AC_CONFIG_MACRO_DIR([auto-m4])
   6 AM_INIT_AUTOMAKE([-Wall gnu 1.9 dist-bzip2 dist-zip check-news])
   7 AM_MAINTAINER_MODE
   8
   9 if test ! -d "$srcdir/m4m"; then
  10 AC_MSG_ERROR([
  11 You are missing the m4m/ directory in your top
  12 $PACKAGE_TARNAME source directory.
  13
  14 You are probably using an ill-maintained CVS tree.
  15 Running
  16
  17     cd $srcdir
  18     cvs co m4m
  19
  20 and re-running autogen.sh might help.
  21 ])
  22 fi
  23
  24 GP_CHECK_SHELL_ENVIRONMENT
  25 GP_CONFIG_MSG([Build])
  26 GP_CONFIG_MSG([Source code location],[${srcdir}])
  27
  28 dnl ---------------------------------------------------------------------------
  29 dnl Advanced information about versioning:
  30 dnl   * "Writing shared libraries" by Mike Hearn
  31 dnl         http://plan99.net/~mike/writing-shared-libraries.html
  32 dnl   * libtool.info chapter "Versioning"
  33 dnl   * libtool.info chapter "Updating library version information"
  34 dnl ---------------------------------------------------------------------------
  35 dnl Versioning:
  36 dnl  - CURRENT (Major):  Increment if the interface has changes. AGE is always
  37 dnl                      *changed* at the same time.
  38 dnl  - AGE (Micro):      Increment if any interfaces have been added; set to 0
  39 dnl                      if any interfaces have been removed. Removal has
  40 dnl                      precedence over adding, so set to 0 if both happened.
  41 dnl                      It denotes upward compatibility.
  42 dnl  - REVISION (Minor): Increment any time the source changes; set to
  43 dnl                      0 if you incremented CURRENT.
  44 dnl
  45 dnl  To summarize. Any interface *change* increment CURRENT. If that interface
  46 dnl  change does not break upward compatibility (ie it is an addition),
  47 dnl  increment AGE, Otherwise AGE is reset to 0. If CURRENT has changed,
  48 dnl  REVISION is set to 0, otherwise REVISION is incremented.
  49 dnl ---------------------------------------------------------------------------
  50 dnl C:A:R
  51 dnl 12:0:1   0.6.13
  52 dnl 13:1:0   added EXIF_DATA_OPTION_DONT_CHANGE_MAKER_NOTE (for 0.6.14)
  53 dnl 14:2:0   added XP_ WinXP tags (for 0.6.15)
  54 dnl 14:2:1   0.6.17
  55 dnl 15:3:0   added exif_loader_get_buf (for 0.6.18)
  56 dnl 15:3:1   0.6.19
  57 LIBEXIF_CURRENT=15
  58 LIBEXIF_AGE=3
  59 LIBEXIF_REVISION=1
  60 AC_SUBST([LIBEXIF_AGE])
  61 AC_SUBST([LIBEXIF_REVISION])
  62 AC_SUBST([LIBEXIF_CURRENT])
  63 AC_SUBST([LIBEXIF_CURRENT_MIN],[`expr $LIBEXIF_CURRENT - $LIBEXIF_AGE`])
  64 LIBEXIF_VERSION_INFO="$LIBEXIF_CURRENT:$LIBEXIF_REVISION:$LIBEXIF_AGE"
  65 AC_SUBST([LIBEXIF_VERSION_INFO])
  66
  67 AC_PROG_CC
  68 AC_C_CONST
  69 AC_C_INLINE
  70 dnl FIXME: AC_LIBTOOL_WIN32_DLL
  71 AM_PROG_LIBTOOL
  72 AM_CPPFLAGS="$CPPFLAGS"
  73 GP_CONFIG_MSG([Compiler],[${CC}])
  74
  75
  76 dnl Create a stdint.h-like file containing size-specific integer definitions
  77 dnl that will always be available
  78 AX_NEED_STDINT_H([libexif/_stdint.h])
  79
  80
  81 dnl ------------------------------------------------------------------------
  82 dnl Whether we're supposed to ship binaries in the tarball
  83 dnl ------------------------------------------------------------------------
  84
  85 ship_binaries=false
  86 AC_ARG_ENABLE([ship-binaries],
  87 [AS_HELP_STRING([--enable-ship-binaries],
  88 [Whether to ship binaries in the tarball [default=no]])],[
  89         if test x$enableval = xyes; then
  90                 ship_binaries=true
  91         fi
  92 ])
  93 AM_CONDITIONAL([SHIP_BINARIES],[$ship_binaries])
  94 GP_CONFIG_MSG([Ship binaries in tarball],[$ship_binaries])
  95
  96
  97 dnl ---------------------------------------------------------------------------
  98 dnl Whether -lm is required for our math functions
  99 dnl ---------------------------------------------------------------------------
 100
 101 # we need sqrt and pow which may be in libm
 102 # We cannot use AC_CHECK_FUNC because if CFLAGS contains
 103 # -Wall -Werror here the check fails because
 104 # char *sqrt() conflicts with double sqrt(double xx)
 105
 106 # Start by assuming -lm is needed, because it's possible that the little
 107 # test program below will be optimized to in-line floating point code that
 108 # doesn't require -lm, whereas the library itself cannot be so optimized
 109 # (this actually seems to be the case on x86 with gcc 4.2). Assuming the
 110 # reverse means that -lm could be needed but wouldn't be detected below.
 111
 112 LIBS_orig="$LIBS"
 113 LIBS="$LIBS -lm"
 114 AC_MSG_CHECKING([for math functions in libm])
 115 AC_LINK_IFELSE([
 116         #include <math.h>
 117         int main() {
 118           double s = sqrt(0);
 119           double p = pow(s,s);
 120           return (int)p;
 121         }
 122 ], [AC_MSG_RESULT(yes)], [
 123         AC_MSG_RESULT(no)
 124         LIBS="$LIBS_orig"
 125         AC_MSG_CHECKING([for math functions without libm])
 126         AC_LINK_IFELSE([
 127                 #include <math.h>
 128                 int main() {
 129                   double s = sqrt(0);
 130                   double p = pow(s,s);
 131                   return (int)p;
 132                 }
 133         ], [
 134                 AC_MSG_RESULT(yes)
 135         ],[
 136                 AC_MSG_RESULT(no)
 137                 AC_MSG_ERROR([*** Could not find sqrt() & pow() functions])
 138         ])
 139 ])
 140
 141 # doc support
 142 GP_CHECK_DOC_DIR
 143 GP_CHECK_DOXYGEN
 144
 145 # Whether to enable the internal docs build.
 146 #
 147 # This takes quite some time due to the generation of lots of call
 148 # graphs, so it is disabled by default.
 149 set_enable_internal_docs=no
 150 AC_ARG_ENABLE([internal-docs], [dnl
 151 AS_HELP_STRING([--enable-internal-docs],
 152 [Build internal code docs if doxygen available])], [dnl
 153 dnl If either --enable-foo nor --disable-foo were given, execute this.
 154   if   test "x$enableval" = xno \
 155     || test "x$enableval" = xoff \
 156     || test "x$enableval" = xfalse;
 157   then
 158     set_enable_internal_docs=no
 159   elif test "x$enableval" = xyes \
 160     || test "x$enableval" = xon \
 161     || test "x$enableval" = xtrue
 162   then
 163     set_enable_internal_docs=yes
 164   fi
 165 ])
 166 AC_MSG_CHECKING([whether to create internal code docs])
 167 AC_MSG_RESULT([${set_enable_internal_docs}])
 168 AM_CONDITIONAL([ENABLE_INTERNAL_DOCS], [test "x${set_enable_internal_docs}" = "xyes"])
 169
 170
 171 # ---------------------------------------------------------------------------
 172 # i18n support
 173 # ---------------------------------------------------------------------------
 174 ALL_LINGUAS="be cs da de en_CA en_GB es fr it ja nl pl pt pt_BR ru sk sq sr sv vi zh_CN"
 175 AM_PO_SUBDIRS
 176 GP_GETTEXT_HACK([${PACKAGE}-${LIBEXIF_CURRENT_MIN}],
 177                 [Lutz Mueller and others])
 178 AM_GNU_GETTEXT_VERSION([0.14.1])
 179 AM_GNU_GETTEXT([external])
 180 AM_ICONV()
 181 GP_GETTEXT_FLAGS()
 182
 183
 184 dnl ---------------------------------------------------------------------------
 185 dnl Thread-safe functions
 186 dnl ---------------------------------------------------------------------------
 187 AC_CHECK_FUNCS(localtime_r)
 188
 189 dnl ---------------------------------------------------------------------------
 190 dnl Compiler/Linker Options and Warnings
 191 dnl ---------------------------------------------------------------------------
 192 AM_CPPFLAGS="$AM_CPPFLAGS -I\$(top_srcdir)"
 193 AM_CPPFLAGS="$AM_CPPFLAGS -I\$(top_builddir)"
 194 AM_LDFLAGS="$LDFLAGS"
 195 if test "x$GCC" = "xyes"; then
 196     AM_CFLAGS="$AM_CFLAGS -ansi -pedantic-error"
 197     AM_CXXFLAGS="$AM_CXXFLAGS -ansi -pedantic-error"
 198     AM_CPPFLAGS="$AM_CPPFLAGS -g -Wall -Wmissing-declarations -Wmissing-prototypes"
 199     AM_LDFLAGS="$AM_LDFLAGS -g -Wall"
 200 fi
 201
 202
 203
 204 AC_SUBST(AM_CPPFLAGS)
 205 AC_SUBST(AM_LDFLAGS)
 206
 207
 208 dnl ---------------------------------------------------------------------------
 209 dnl Output files
 210 dnl ---------------------------------------------------------------------------
 211 AC_CONFIG_FILES([  po/Makefile.in
 212   Makefile
 213   libexif.spec
 214   libexif/Makefile
 215   test/Makefile
 216   test/nls/Makefile
 217   m4m/Makefile
 218   doc/Makefile
 219   doc/Doxyfile
 220   doc/Doxyfile-internals
 221   libexif.pc
 222   libexif-uninstalled.pc
 223   binary/Makefile
 224   contrib/Makefile
 225   contrib/examples/Makefile
 226 ])
 227 AC_OUTPUT
 228
 229 GP_CONFIG_OUTPUT