release/src/router/apcupsd/platforms/mingw/onbattery.vbs

   1 '///Wriiten by Ed Dondlinger 1/23/2009 - edondlinger@thepylegroup.com ///
   2
   3 '/// MODIFY THE VARIABLES LISTED BELOW IN THE "USER VARIABLES" SECTION.
   4 '/// THEN RENAME FILE WITHOUT THE ".example" SUFFIX.
   5
   6 '///Comment out the next line when testing, then change back when done. ///
   7 On Error Resume Next
   8
   9 Dim Get_Status
  10 Dim oShell
  11 set oShell = CreateObject("WScript.Shell")
  12
  13 '/// Get APCUPS Status Report ///
  14
  15 set Get_Status = oShell.exec("%comspec% /c c:\Progra~1\apcupsd\bin\apcaccess.exe status")
  16 UPS_Status = Get_Status.StdOut.readall
  17
  18 '/// Get Time Zone info from local windows registry ///
  19
  20 atb = "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Control\TimeZoneInformation\StandardName"
  21 TZInfo = oShell.RegRead(atb)
  22
  23
  24
  25 'XXXXXXXXXXXXXXXXXXXX  USER VARIABLES  XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXxXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
  26
  27 MyLocation = "Home"
  28
  29 MyEmailSubject = "POWER FAILURE at: " & MyLocation
  30
  31 MyEmailFromAddress = "xxx@zzz.com"  'you could also use this format to display the common name: """Me"" <user@mydomain.com>"
  32
  33 MyEmailToAddress = "xxx@zzz.com"
  34
  35 MyTextBody = "The utility power has failed at " & MyLocation & " and the UPS is running on batteries." & _
  36                 vbCRLF & "Reported by the APCUPS Server at: " & dateAdd("H",0,Now) & " " & _
  37                 TZInfo & vbcrlf & vbcrlf & UPS_Status
  38
  39 MySMTPServer = "smtp.gmail.com"  'or use a IP address i.e. "10.x.x.x"
  40
  41 MyMailServerUserName = "UName"
  42
  43 MyMailServerPW = "password"
  44
  45 MySMTPServerPort = 465
  46
  47 MySMTPServerSSL = True
  48
  49 'XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXxXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
  50
  51
  52
  53
  54 '////////// Email Section  //////////
  55
  56 '*** NOTE: MSDN CDO Library can be referenced at: http://msdn.microsoft.com/en-us/library/ms872853(EXCHG.65).aspx
  57
  58 Const cdoSendUsingPickup = 1 'Send message using the local SMTP service pickup directory.
  59 Const cdoSendUsingPort = 2 'Send the message using the network (SMTP over the network).
  60 Const cdoSendUsingExchange = 3  'Send the message using MS Exchange Mail Server.
  61
  62 Const cdoAnonymous = 0 'Do not authenticate
  63 Const cdoBasic = 1 'basic (clear-text) authentication
  64 Const cdoNTLM = 2 'NTLM
  65
  66 Const cdoURL = "http://schemas.microsoft.com/cdo/configuration/"
  67
  68 Set objMessage = CreateObject("CDO.Message")
  69
  70         '/// Set the message properties. ///
  71
  72         With objMessage
  73
  74                 .Subject = MyEmailSubject
  75
  76                 .From = MyEmailFromAddress
  77
  78                 .To = MyEmailToAddress
  79
  80                 .TextBody = MyTextBody
  81
  82                 'Set Mail Importance level, you can set [high,normal,low]
  83                 .fields.Item("urn:schemas:mailheader:importance").Value = "high"
  84
  85                 'Set Mail priority level, you can set [1=urgent, 0=normal, -1=nonurgent]
  86                 .fields.Item("urn:schemas:mailheader:priority").Value = 1
  87
  88                 .fields.Update()
  89
  90         End with
  91
  92         '/// This section provides the configuration information for the remote SMTP server. ///
  93
  94         with objMessage.Configuration.Fields
  95
  96                 'Send Using method (1 = local smtp, 2 = remote network smtp, 3 = MS Exchange)
  97                 .Item(cdoURL & "sendusing") = 2
  98
  99                 'Name or IP of Remote SMTP Server
 100                 .Item(cdoURL & "smtpserver") = MySMTPServer
 101
 102                 'Type of authentication, NONE, Basic (Base64 encoded), NTLM
 103                 .Item(cdoURL & "smtpauthenticate") = cdoBasic
 104
 105                 'Your UserID on the SMTP server
 106                 .Item(cdoURL & "sendusername") = MyMailServerUserName
 107
 108                 'Your password on the SMTP server
 109                 .Item(cdoURL & "sendpassword") = MyMailServerPW
 110
 111                 'Server port (typically 25)
 112                 .Item(cdoURL & "smtpserverport") = MySMTPServerPort
 113
 114                 'Use SSL for the connection (False or True)
 115                 .Item(cdoURL & "smtpusessl") = MySMTPServerSSL
 116
 117                 'Connection Timeout in seconds (the maximum time CDO will try to establish a connection to the SMTP server)
 118                 .Item(cdoURL & "smtpconnectiontimeout") = 60
 119
 120                 'Update the config.
 121                 .Update
 122
 123         end with
 124
 125
 126 '/// Send the message ///
 127
 128 objMessage.Send
 129
 130
 131 '/// Clean-up ///
 132
 133 Set objMessage = nothing
 134 set oShell = nothing
 135 set Get_Status = nothing
 136
 137 '/// Exit with a 0 error level to ensure the apccontrol.bat continues ///
 138
 139 Wscript.Quit 0