release/src/router/php/ext/pcre/config0.m4

   1 dnl
   2 dnl $Id$
   3 dnl
   4
   5 dnl By default we'll compile and link against the bundled PCRE library
   6 dnl if DIR is supplied, we'll use that for linking
   7
   8 PHP_ARG_WITH(pcre-regex,,
   9 [  --with-pcre-regex=DIR   Include Perl Compatible Regular Expressions support.
  10                           DIR is the PCRE install prefix [BUNDLED]], yes, no)
  11
  12   if test "$PHP_PCRE_REGEX" != "yes" && test "$PHP_PCRE_REGEX" != "no"; then
  13     AC_MSG_CHECKING([for PCRE headers location])
  14     for i in $PHP_PCRE_REGEX $PHP_PCRE_REGEX/include $PHP_PCRE_REGEX/include/pcre $PHP_PCRE_REGEX/local/include; do
  15       test -f $i/pcre.h && PCRE_INCDIR=$i
  16     done
  17
  18     if test -z "$PCRE_INCDIR"; then
  19       AC_MSG_ERROR([Could not find pcre.h in $PHP_PCRE_REGEX])
  20     fi
  21     AC_MSG_RESULT([$PCRE_INCDIR])
  22
  23     AC_MSG_CHECKING([for PCRE library location])
  24     for j in $PHP_PCRE_REGEX $PHP_PCRE_REGEX/$PHP_LIBDIR; do
  25       test -f $j/libpcre.a || test -f $j/libpcre.$SHLIB_SUFFIX_NAME && PCRE_LIBDIR=$j
  26     done
  27
  28     if test -z "$PCRE_LIBDIR" ; then
  29       AC_MSG_ERROR([Could not find libpcre.(a|$SHLIB_SUFFIX_NAME) in $PHP_PCRE_REGEX])
  30     fi
  31     AC_MSG_RESULT([$PCRE_LIBDIR])
  32
  33     changequote({,})
  34     pcre_major=`grep PCRE_MAJOR $PCRE_INCDIR/pcre.h | sed -e 's/[^0-9]//g'`
  35     pcre_minor=`grep PCRE_MINOR $PCRE_INCDIR/pcre.h | sed -e 's/[^0-9]//g'`
  36     changequote([,])
  37     pcre_minor_length=`echo "$pcre_minor" | wc -c | sed -e 's/[^0-9]//g'`
  38     if test "$pcre_minor_length" -eq 2 ; then
  39       pcre_minor="$pcre_minor"0
  40     fi
  41     pcre_version=$pcre_major$pcre_minor
  42     if test "$pcre_version" -lt 660; then
  43       AC_MSG_ERROR([The PCRE extension requires PCRE library version >= 6.6])
  44     fi
  45
  46     PHP_ADD_LIBRARY_WITH_PATH(pcre, $PCRE_LIBDIR)
  47
  48     AC_DEFINE(HAVE_PCRE, 1, [ ])
  49     PHP_ADD_INCLUDE($PCRE_INCDIR)
  50     PHP_NEW_EXTENSION(pcre, php_pcre.c, no)
  51     PHP_INSTALL_HEADERS([ext/pcre], [php_pcre.h])
  52   else
  53     AC_MSG_CHECKING([for PCRE library to use])
  54     AC_MSG_RESULT([bundled])
  55     pcrelib_sources="pcrelib/pcre_chartables.c pcrelib/pcre_ucd.c \
  56                                  pcrelib/pcre_compile.c pcrelib/pcre_config.c pcrelib/pcre_exec.c \
  57                                  pcrelib/pcre_fullinfo.c pcrelib/pcre_get.c pcrelib/pcre_globals.c \
  58                                  pcrelib/pcre_maketables.c pcrelib/pcre_newline.c \
  59                                  pcrelib/pcre_ord2utf8.c pcrelib/pcre_refcount.c pcrelib/pcre_study.c \
  60                                  pcrelib/pcre_tables.c pcrelib/pcre_valid_utf8.c \
  61                                  pcrelib/pcre_version.c pcrelib/pcre_xclass.c"
  62     PHP_PCRE_CFLAGS="-DHAVE_CONFIG_H -I@ext_srcdir@/pcrelib"
  63     PHP_NEW_EXTENSION(pcre, $pcrelib_sources php_pcre.c, no,,$PHP_PCRE_CFLAGS)
  64     PHP_ADD_BUILD_DIR($ext_builddir/pcrelib)
  65     PHP_INSTALL_HEADERS([ext/pcre], [php_pcre.h pcrelib/])
  66     AC_DEFINE(HAVE_BUNDLED_PCRE, 1, [ ])
  67   fi