| blob | 0bc623a0757079b67b345f2719220f77892d9f0c |
1 /*
2 * Compatibility mode system call entry point for x86-64.
3 *
4 * Copyright 2000-2002 Andi Kleen, SuSE Labs.
5 */
7 #include <asm/dwarf2.h>
8 #include <asm/calling.h>
9 #include <asm/asm-offsets.h>
10 #include <asm/current.h>
11 #include <asm/errno.h>
12 #include <asm/ia32_unistd.h>
13 #include <asm/thread_info.h>
14 #include <asm/segment.h>
15 #include <asm/vsyscall32.h>
16 #include <asm/irqflags.h>
17 #include <linux/linkage.h>
19 #define IA32_NR_syscalls ((ia32_syscall_end - ia32_sys_call_table)/8)
21 .macro IA32_ARG_FIXUP noebp=0
22 movl %edi,%r8d
23 .if \noebp
24 .else
25 movl %ebp,%r9d
26 .endif
27 xchg %ecx,%esi
28 movl %ebx,%edi
29 movl %edx,%edx /* zero extension */
30 .endm
32 /* clobbers %eax */
33 .macro CLEAR_RREGS
34 xorl %eax,%eax
35 movq %rax,R11(%rsp)
36 movq %rax,R10(%rsp)
37 movq %rax,R9(%rsp)
38 movq %rax,R8(%rsp)
39 .endm
41 .macro LOAD_ARGS32 offset
42 movl \offset(%rsp),%r11d
43 movl \offset+8(%rsp),%r10d
44 movl \offset+16(%rsp),%r9d
45 movl \offset+24(%rsp),%r8d
46 movl \offset+40(%rsp),%ecx
47 movl \offset+48(%rsp),%edx
48 movl \offset+56(%rsp),%esi
49 movl \offset+64(%rsp),%edi
50 movl \offset+72(%rsp),%eax
51 .endm
53 .macro CFI_STARTPROC32 simple
54 CFI_STARTPROC \simple
55 CFI_UNDEFINED r8
56 CFI_UNDEFINED r9
57 CFI_UNDEFINED r10
58 CFI_UNDEFINED r11
59 CFI_UNDEFINED r12
60 CFI_UNDEFINED r13
61 CFI_UNDEFINED r14
62 CFI_UNDEFINED r15
63 .endm
65 /*
66 * 32bit SYSENTER instruction entry.
67 *
68 * Arguments:
69 * %eax System call number.
70 * %ebx Arg1
71 * %ecx Arg2
72 * %edx Arg3
73 * %esi Arg4
74 * %edi Arg5
75 * %ebp user stack
76 * 0(%ebp) Arg6
77 *
78 * Interrupts off.
79 *
80 * This is purely a fast path. For anything complicated we use the int 0x80
81 * path below. Set up a complete hardware stack frame to share code
82 * with the int 0x80 path.
83 */
84 ENTRY(ia32_sysenter_target)
85 CFI_STARTPROC32 simple
86 CFI_SIGNAL_FRAME
87 CFI_DEF_CFA rsp,0
88 CFI_REGISTER rsp,rbp
89 swapgs
90 movq %gs:pda_kernelstack, %rsp
91 addq $(PDA_STACKOFFSET),%rsp
92 /*
93 * No need to follow this irqs on/off section: the syscall
94 * disabled irqs, here we enable it straight after entry:
95 */
96 sti
97 movl %ebp,%ebp /* zero extension */
98 pushq $__USER32_DS
99 CFI_ADJUST_CFA_OFFSET 8
100 /*CFI_REL_OFFSET ss,0*/
101 pushq %rbp
102 CFI_ADJUST_CFA_OFFSET 8
103 CFI_REL_OFFSET rsp,0
104 pushfq
105 CFI_ADJUST_CFA_OFFSET 8
106 /*CFI_REL_OFFSET rflags,0*/
107 movl $VSYSCALL32_SYSEXIT, %r10d
108 CFI_REGISTER rip,r10
109 pushq $__USER32_CS
110 CFI_ADJUST_CFA_OFFSET 8
111 /*CFI_REL_OFFSET cs,0*/
112 movl %eax, %eax
113 pushq %r10
114 CFI_ADJUST_CFA_OFFSET 8
115 CFI_REL_OFFSET rip,0
116 pushq %rax
117 CFI_ADJUST_CFA_OFFSET 8
118 cld
119 SAVE_ARGS 0,0,0
120 /* no need to do an access_ok check here because rbp has been
121 32bit zero extended */
122 1: movl (%rbp),%r9d
123 .section __ex_table,"a"
124 .quad 1b,ia32_badarg
125 .previous
126 GET_THREAD_INFO(%r10)
127 orl $TS_COMPAT,threadinfo_status(%r10)
128 testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
129 CFI_REMEMBER_STATE
130 jnz sysenter_tracesys
131 sysenter_do_call:
132 cmpl $(IA32_NR_syscalls-1),%eax
133 ja ia32_badsys
134 IA32_ARG_FIXUP 1
135 call *ia32_sys_call_table(,%rax,8)
136 movq %rax,RAX-ARGOFFSET(%rsp)
137 GET_THREAD_INFO(%r10)
138 cli
139 TRACE_IRQS_OFF
140 testl $_TIF_ALLWORK_MASK,threadinfo_flags(%r10)
141 jnz int_ret_from_sys_call
142 andl $~TS_COMPAT,threadinfo_status(%r10)
143 /* clear IF, that popfq doesn't enable interrupts early */
144 andl $~0x200,EFLAGS-R11(%rsp)
145 RESTORE_ARGS 1,24,1,1,1,1
146 popfq
147 CFI_ADJUST_CFA_OFFSET -8
148 /*CFI_RESTORE rflags*/
149 popq %rcx /* User %esp */
150 CFI_ADJUST_CFA_OFFSET -8
151 CFI_REGISTER rsp,rcx
152 movl $VSYSCALL32_SYSEXIT,%edx /* User %eip */
153 CFI_REGISTER rip,rdx
154 TRACE_IRQS_ON
155 swapgs
156 sti /* sti only takes effect after the next instruction */
157 /* sysexit */
158 .byte 0xf, 0x35
160 sysenter_tracesys:
161 CFI_RESTORE_STATE
162 SAVE_REST
163 CLEAR_RREGS
164 movq $-ENOSYS,RAX(%rsp) /* really needed? */
165 movq %rsp,%rdi /* &pt_regs -> arg1 */
166 call syscall_trace_enter
167 LOAD_ARGS32 ARGOFFSET /* reload args from stack in case ptrace changed it */
168 RESTORE_REST
169 movl %ebp, %ebp
170 /* no need to do an access_ok check here because rbp has been
171 32bit zero extended */
172 1: movl (%rbp),%r9d
173 .section __ex_table,"a"
174 .quad 1b,ia32_badarg
175 .previous
176 jmp sysenter_do_call
177 CFI_ENDPROC
178 ENDPROC(ia32_sysenter_target)
180 /*
181 * 32bit SYSCALL instruction entry.
182 *
183 * Arguments:
184 * %eax System call number.
185 * %ebx Arg1
186 * %ecx return EIP
187 * %edx Arg3
188 * %esi Arg4
189 * %edi Arg5
190 * %ebp Arg2 [note: not saved in the stack frame, should not be touched]
191 * %esp user stack
192 * 0(%esp) Arg6
193 *
194 * Interrupts off.
195 *
196 * This is purely a fast path. For anything complicated we use the int 0x80
197 * path below. Set up a complete hardware stack frame to share code
198 * with the int 0x80 path.
199 */
200 ENTRY(ia32_cstar_target)
201 CFI_STARTPROC32 simple
202 CFI_SIGNAL_FRAME
203 CFI_DEF_CFA rsp,PDA_STACKOFFSET
204 CFI_REGISTER rip,rcx
205 /*CFI_REGISTER rflags,r11*/
206 swapgs
207 movl %esp,%r8d
208 CFI_REGISTER rsp,r8
209 movq %gs:pda_kernelstack,%rsp
210 /*
211 * No need to follow this irqs on/off section: the syscall
212 * disabled irqs and here we enable it straight after entry:
213 */
214 sti
215 SAVE_ARGS 8,1,1
216 movl %eax,%eax /* zero extension */
217 movq %rax,ORIG_RAX-ARGOFFSET(%rsp)
218 movq %rcx,RIP-ARGOFFSET(%rsp)
219 CFI_REL_OFFSET rip,RIP-ARGOFFSET
220 movq %rbp,RCX-ARGOFFSET(%rsp) /* this lies slightly to ptrace */
221 movl %ebp,%ecx
222 movq $__USER32_CS,CS-ARGOFFSET(%rsp)
223 movq $__USER32_DS,SS-ARGOFFSET(%rsp)
224 movq %r11,EFLAGS-ARGOFFSET(%rsp)
225 /*CFI_REL_OFFSET rflags,EFLAGS-ARGOFFSET*/
226 movq %r8,RSP-ARGOFFSET(%rsp)
227 CFI_REL_OFFSET rsp,RSP-ARGOFFSET
228 /* no need to do an access_ok check here because r8 has been
229 32bit zero extended */
230 /* hardware stack frame is complete now */
231 1: movl (%r8),%r9d
232 .section __ex_table,"a"
233 .quad 1b,ia32_badarg
234 .previous
235 GET_THREAD_INFO(%r10)
236 orl $TS_COMPAT,threadinfo_status(%r10)
237 testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
238 CFI_REMEMBER_STATE
239 jnz cstar_tracesys
240 cstar_do_call:
241 cmpl $IA32_NR_syscalls-1,%eax
242 ja ia32_badsys
243 IA32_ARG_FIXUP 1
244 call *ia32_sys_call_table(,%rax,8)
245 movq %rax,RAX-ARGOFFSET(%rsp)
246 GET_THREAD_INFO(%r10)
247 cli
248 TRACE_IRQS_OFF
249 testl $_TIF_ALLWORK_MASK,threadinfo_flags(%r10)
250 jnz int_ret_from_sys_call
251 andl $~TS_COMPAT,threadinfo_status(%r10)
252 RESTORE_ARGS 1,-ARG_SKIP,1,1,1
253 movl RIP-ARGOFFSET(%rsp),%ecx
254 CFI_REGISTER rip,rcx
255 movl EFLAGS-ARGOFFSET(%rsp),%r11d
256 /*CFI_REGISTER rflags,r11*/
257 TRACE_IRQS_ON
258 movl RSP-ARGOFFSET(%rsp),%esp
259 CFI_RESTORE rsp
260 swapgs
261 sysretl
263 cstar_tracesys:
264 CFI_RESTORE_STATE
265 SAVE_REST
266 CLEAR_RREGS
267 movq $-ENOSYS,RAX(%rsp) /* really needed? */
268 movq %rsp,%rdi /* &pt_regs -> arg1 */
269 call syscall_trace_enter
270 LOAD_ARGS32 ARGOFFSET /* reload args from stack in case ptrace changed it */
271 RESTORE_REST
272 movl RSP-ARGOFFSET(%rsp), %r8d
273 /* no need to do an access_ok check here because r8 has been
274 32bit zero extended */
275 1: movl (%r8),%r9d
276 .section __ex_table,"a"
277 .quad 1b,ia32_badarg
278 .previous
279 jmp cstar_do_call
280 END(ia32_cstar_target)
282 ia32_badarg:
283 movq $-EFAULT,%rax
284 jmp ia32_sysret
285 CFI_ENDPROC
287 /*
288 * Emulated IA32 system calls via int 0x80.
289 *
290 * Arguments:
291 * %eax System call number.
292 * %ebx Arg1
293 * %ecx Arg2
294 * %edx Arg3
295 * %esi Arg4
296 * %edi Arg5
297 * %ebp Arg6 [note: not saved in the stack frame, should not be touched]
298 *
299 * Notes:
300 * Uses the same stack frame as the x86-64 version.
301 * All registers except %eax must be saved (but ptrace may violate that)
302 * Arguments are zero extended. For system calls that want sign extension and
303 * take long arguments a wrapper is needed. Most calls can just be called
304 * directly.
305 * Assumes it is only called from user space and entered with interrupts off.
306 */
308 ENTRY(ia32_syscall)
309 CFI_STARTPROC simple
310 CFI_SIGNAL_FRAME
311 CFI_DEF_CFA rsp,SS+8-RIP
312 /*CFI_REL_OFFSET ss,SS-RIP*/
313 CFI_REL_OFFSET rsp,RSP-RIP
314 /*CFI_REL_OFFSET rflags,EFLAGS-RIP*/
315 /*CFI_REL_OFFSET cs,CS-RIP*/
316 CFI_REL_OFFSET rip,RIP-RIP
317 swapgs
318 /*
319 * No need to follow this irqs on/off section: the syscall
320 * disabled irqs and here we enable it straight after entry:
321 */
322 sti
323 movl %eax,%eax
324 pushq %rax
325 CFI_ADJUST_CFA_OFFSET 8
326 cld
327 /* note the registers are not zero extended to the sf.
328 this could be a problem. */
329 SAVE_ARGS 0,0,1
330 GET_THREAD_INFO(%r10)
331 orl $TS_COMPAT,threadinfo_status(%r10)
332 testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
333 jnz ia32_tracesys
334 ia32_do_syscall:
335 cmpl $(IA32_NR_syscalls-1),%eax
336 ja ia32_badsys
337 IA32_ARG_FIXUP
338 call *ia32_sys_call_table(,%rax,8) # xxx: rip relative
339 ia32_sysret:
340 movq %rax,RAX-ARGOFFSET(%rsp)
341 jmp int_ret_from_sys_call
343 ia32_tracesys:
344 SAVE_REST
345 movq $-ENOSYS,RAX(%rsp) /* really needed? */
346 movq %rsp,%rdi /* &pt_regs -> arg1 */
347 call syscall_trace_enter
348 LOAD_ARGS32 ARGOFFSET /* reload args from stack in case ptrace changed it */
349 RESTORE_REST
350 jmp ia32_do_syscall
351 END(ia32_syscall)
353 ia32_badsys:
354 movq $0,ORIG_RAX-ARGOFFSET(%rsp)
355 movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
356 jmp int_ret_from_sys_call
358 quiet_ni_syscall:
359 movq $-ENOSYS,%rax
360 ret
361 CFI_ENDPROC
363 .macro PTREGSCALL label, func, arg
364 .globl \label
365 \label:
366 leaq \func(%rip),%rax
367 leaq -ARGOFFSET+8(%rsp),\arg /* 8 for return address */
368 jmp ia32_ptregs_common
369 .endm
371 CFI_STARTPROC32
373 PTREGSCALL stub32_rt_sigreturn, sys32_rt_sigreturn, %rdi
374 PTREGSCALL stub32_sigreturn, sys32_sigreturn, %rdi
375 PTREGSCALL stub32_sigaltstack, sys32_sigaltstack, %rdx
376 PTREGSCALL stub32_sigsuspend, sys32_sigsuspend, %rcx
377 PTREGSCALL stub32_execve, sys32_execve, %rcx
378 PTREGSCALL stub32_fork, sys_fork, %rdi
379 PTREGSCALL stub32_clone, sys32_clone, %rdx
380 PTREGSCALL stub32_vfork, sys_vfork, %rdi
381 PTREGSCALL stub32_iopl, sys_iopl, %rsi
382 PTREGSCALL stub32_rt_sigsuspend, sys_rt_sigsuspend, %rdx
384 ENTRY(ia32_ptregs_common)
385 popq %r11
386 CFI_ENDPROC
387 CFI_STARTPROC32 simple
388 CFI_SIGNAL_FRAME
389 CFI_DEF_CFA rsp,SS+8-ARGOFFSET
390 CFI_REL_OFFSET rax,RAX-ARGOFFSET
391 CFI_REL_OFFSET rcx,RCX-ARGOFFSET
392 CFI_REL_OFFSET rdx,RDX-ARGOFFSET
393 CFI_REL_OFFSET rsi,RSI-ARGOFFSET
394 CFI_REL_OFFSET rdi,RDI-ARGOFFSET
395 CFI_REL_OFFSET rip,RIP-ARGOFFSET
396 /* CFI_REL_OFFSET cs,CS-ARGOFFSET*/
397 /* CFI_REL_OFFSET rflags,EFLAGS-ARGOFFSET*/
398 CFI_REL_OFFSET rsp,RSP-ARGOFFSET
399 /* CFI_REL_OFFSET ss,SS-ARGOFFSET*/
400 SAVE_REST
401 call *%rax
402 RESTORE_REST
403 jmp ia32_sysret /* misbalances the return cache */
404 CFI_ENDPROC
405 END(ia32_ptregs_common)
407 .section .rodata,"a"
408 .align 8
409 ia32_sys_call_table:
410 .quad sys_restart_syscall
411 .quad sys_exit
412 .quad stub32_fork
413 .quad sys_read
414 .quad sys_write
415 .quad compat_sys_open /* 5 */
416 .quad sys_close
417 .quad sys32_waitpid
418 .quad sys_creat
419 .quad sys_link
420 .quad sys_unlink /* 10 */
421 .quad stub32_execve
422 .quad sys_chdir
423 .quad compat_sys_time
424 .quad sys_mknod
425 .quad sys_chmod /* 15 */
426 .quad sys_lchown16
427 .quad quiet_ni_syscall /* old break syscall holder */
428 .quad sys_stat
429 .quad sys32_lseek
430 .quad sys_getpid /* 20 */
431 .quad compat_sys_mount /* mount */
432 .quad sys_oldumount /* old_umount */
433 .quad sys_setuid16
434 .quad sys_getuid16
435 .quad compat_sys_stime /* stime */ /* 25 */
436 .quad sys32_ptrace /* ptrace */
437 .quad sys_alarm
438 .quad sys_fstat /* (old)fstat */
439 .quad sys_pause
440 .quad compat_sys_utime /* 30 */
441 .quad quiet_ni_syscall /* old stty syscall holder */
442 .quad quiet_ni_syscall /* old gtty syscall holder */
443 .quad sys_access
444 .quad sys_nice
445 .quad quiet_ni_syscall /* 35 */ /* old ftime syscall holder */
446 .quad sys_sync
447 .quad sys32_kill
448 .quad sys_rename
449 .quad sys_mkdir
450 .quad sys_rmdir /* 40 */
451 .quad sys_dup
452 .quad sys32_pipe
453 .quad compat_sys_times
454 .quad quiet_ni_syscall /* old prof syscall holder */
455 .quad sys_brk /* 45 */
456 .quad sys_setgid16
457 .quad sys_getgid16
458 .quad sys_signal
459 .quad sys_geteuid16
460 .quad sys_getegid16 /* 50 */
461 .quad sys_acct
462 .quad sys_umount /* new_umount */
463 .quad quiet_ni_syscall /* old lock syscall holder */
464 .quad compat_sys_ioctl
465 .quad compat_sys_fcntl64 /* 55 */
466 .quad quiet_ni_syscall /* old mpx syscall holder */
467 .quad sys_setpgid
468 .quad quiet_ni_syscall /* old ulimit syscall holder */
469 .quad sys32_olduname
470 .quad sys_umask /* 60 */
471 .quad sys_chroot
472 .quad sys32_ustat
473 .quad sys_dup2
474 .quad sys_getppid
475 .quad sys_getpgrp /* 65 */
476 .quad sys_setsid
477 .quad sys32_sigaction
478 .quad sys_sgetmask
479 .quad sys_ssetmask
480 .quad sys_setreuid16 /* 70 */
481 .quad sys_setregid16
482 .quad stub32_sigsuspend
483 .quad compat_sys_sigpending
484 .quad sys_sethostname
485 .quad compat_sys_setrlimit /* 75 */
486 .quad compat_sys_old_getrlimit /* old_getrlimit */
487 .quad compat_sys_getrusage
488 .quad sys32_gettimeofday
489 .quad sys32_settimeofday
490 .quad sys_getgroups16 /* 80 */
491 .quad sys_setgroups16
492 .quad sys32_old_select
493 .quad sys_symlink
494 .quad sys_lstat
495 .quad sys_readlink /* 85 */
496 .quad sys_uselib
497 .quad sys_swapon
498 .quad sys_reboot
499 .quad compat_sys_old_readdir
500 .quad sys32_mmap /* 90 */
501 .quad sys_munmap
502 .quad sys_truncate
503 .quad sys_ftruncate
504 .quad sys_fchmod
505 .quad sys_fchown16 /* 95 */
506 .quad sys_getpriority
507 .quad sys_setpriority
508 .quad quiet_ni_syscall /* old profil syscall holder */
509 .quad compat_sys_statfs
510 .quad compat_sys_fstatfs /* 100 */
511 .quad sys_ioperm
512 .quad compat_sys_socketcall
513 .quad sys_syslog
514 .quad compat_sys_setitimer
515 .quad compat_sys_getitimer /* 105 */
516 .quad compat_sys_newstat
517 .quad compat_sys_newlstat
518 .quad compat_sys_newfstat
519 .quad sys32_uname
520 .quad stub32_iopl /* 110 */
521 .quad sys_vhangup
522 .quad quiet_ni_syscall /* old "idle" system call */
523 .quad sys32_vm86_warning /* vm86old */
524 .quad compat_sys_wait4
525 .quad sys_swapoff /* 115 */
526 .quad compat_sys_sysinfo
527 .quad sys32_ipc
528 .quad sys_fsync
529 .quad stub32_sigreturn
530 .quad stub32_clone /* 120 */
531 .quad sys_setdomainname
532 .quad sys_uname
533 .quad sys_modify_ldt
534 .quad compat_sys_adjtimex
535 .quad sys32_mprotect /* 125 */
536 .quad compat_sys_sigprocmask
537 .quad quiet_ni_syscall /* create_module */
538 .quad sys_init_module
539 .quad sys_delete_module
540 .quad quiet_ni_syscall /* 130 get_kernel_syms */
541 .quad sys_quotactl
542 .quad sys_getpgid
543 .quad sys_fchdir
544 .quad quiet_ni_syscall /* bdflush */
545 .quad sys_sysfs /* 135 */
546 .quad sys_personality
547 .quad quiet_ni_syscall /* for afs_syscall */
548 .quad sys_setfsuid16
549 .quad sys_setfsgid16
550 .quad sys_llseek /* 140 */
551 .quad compat_sys_getdents
552 .quad compat_sys_select
553 .quad sys_flock
554 .quad sys_msync
555 .quad compat_sys_readv /* 145 */
556 .quad compat_sys_writev
557 .quad sys_getsid
558 .quad sys_fdatasync
559 .quad sys32_sysctl /* sysctl */
560 .quad sys_mlock /* 150 */
561 .quad sys_munlock
562 .quad sys_mlockall
563 .quad sys_munlockall
564 .quad sys_sched_setparam
565 .quad sys_sched_getparam /* 155 */
566 .quad sys_sched_setscheduler
567 .quad sys_sched_getscheduler
568 .quad sys_sched_yield
569 .quad sys_sched_get_priority_max
570 .quad sys_sched_get_priority_min /* 160 */
571 .quad sys32_sched_rr_get_interval
572 .quad compat_sys_nanosleep
573 .quad sys_mremap
574 .quad sys_setresuid16
575 .quad sys_getresuid16 /* 165 */
576 .quad sys32_vm86_warning /* vm86 */
577 .quad quiet_ni_syscall /* query_module */
578 .quad sys_poll
579 .quad compat_sys_nfsservctl
580 .quad sys_setresgid16 /* 170 */
581 .quad sys_getresgid16
582 .quad sys_prctl
583 .quad stub32_rt_sigreturn
584 .quad sys32_rt_sigaction
585 .quad sys32_rt_sigprocmask /* 175 */
586 .quad sys32_rt_sigpending
587 .quad compat_sys_rt_sigtimedwait
588 .quad sys32_rt_sigqueueinfo
589 .quad stub32_rt_sigsuspend
590 .quad sys32_pread /* 180 */
591 .quad sys32_pwrite
592 .quad sys_chown16
593 .quad sys_getcwd
594 .quad sys_capget
595 .quad sys_capset
596 .quad stub32_sigaltstack
597 .quad sys32_sendfile
598 .quad quiet_ni_syscall /* streams1 */
599 .quad quiet_ni_syscall /* streams2 */
600 .quad stub32_vfork /* 190 */
601 .quad compat_sys_getrlimit
602 .quad sys32_mmap2
603 .quad sys32_truncate64
604 .quad sys32_ftruncate64
605 .quad sys32_stat64 /* 195 */
606 .quad sys32_lstat64
607 .quad sys32_fstat64
608 .quad sys_lchown
609 .quad sys_getuid
610 .quad sys_getgid /* 200 */
611 .quad sys_geteuid
612 .quad sys_getegid
613 .quad sys_setreuid
614 .quad sys_setregid
615 .quad sys_getgroups /* 205 */
616 .quad sys_setgroups
617 .quad sys_fchown
618 .quad sys_setresuid
619 .quad sys_getresuid
620 .quad sys_setresgid /* 210 */
621 .quad sys_getresgid
622 .quad sys_chown
623 .quad sys_setuid
624 .quad sys_setgid
625 .quad sys_setfsuid /* 215 */
626 .quad sys_setfsgid
627 .quad sys_pivot_root
628 .quad sys_mincore
629 .quad sys_madvise
630 .quad compat_sys_getdents64 /* 220 getdents64 */
631 .quad compat_sys_fcntl64
632 .quad quiet_ni_syscall /* tux */
633 .quad quiet_ni_syscall /* security */
634 .quad sys_gettid
635 .quad sys32_readahead /* 225 */
636 .quad sys_setxattr
637 .quad sys_lsetxattr
638 .quad sys_fsetxattr
639 .quad sys_getxattr
640 .quad sys_lgetxattr /* 230 */
641 .quad sys_fgetxattr
642 .quad sys_listxattr
643 .quad sys_llistxattr
644 .quad sys_flistxattr
645 .quad sys_removexattr /* 235 */
646 .quad sys_lremovexattr
647 .quad sys_fremovexattr
648 .quad sys_tkill
649 .quad sys_sendfile64
650 .quad compat_sys_futex /* 240 */
651 .quad compat_sys_sched_setaffinity
652 .quad compat_sys_sched_getaffinity
653 .quad sys32_set_thread_area
654 .quad sys32_get_thread_area
655 .quad compat_sys_io_setup /* 245 */
656 .quad sys_io_destroy
657 .quad compat_sys_io_getevents
658 .quad compat_sys_io_submit
659 .quad sys_io_cancel
660 .quad sys32_fadvise64 /* 250 */
661 .quad quiet_ni_syscall /* free_huge_pages */
662 .quad sys_exit_group
663 .quad sys32_lookup_dcookie
664 .quad sys_epoll_create
665 .quad sys_epoll_ctl /* 255 */
666 .quad sys_epoll_wait
667 .quad sys_remap_file_pages
668 .quad sys_set_tid_address
669 .quad compat_sys_timer_create
670 .quad compat_sys_timer_settime /* 260 */
671 .quad compat_sys_timer_gettime
672 .quad sys_timer_getoverrun
673 .quad sys_timer_delete
674 .quad compat_sys_clock_settime
675 .quad compat_sys_clock_gettime /* 265 */
676 .quad compat_sys_clock_getres
677 .quad compat_sys_clock_nanosleep
678 .quad compat_sys_statfs64
679 .quad compat_sys_fstatfs64
680 .quad sys_tgkill /* 270 */
681 .quad compat_sys_utimes
682 .quad sys32_fadvise64_64
683 .quad quiet_ni_syscall /* sys_vserver */
684 .quad sys_mbind
685 .quad compat_sys_get_mempolicy /* 275 */
686 .quad sys_set_mempolicy
687 .quad compat_sys_mq_open
688 .quad sys_mq_unlink
689 .quad compat_sys_mq_timedsend
690 .quad compat_sys_mq_timedreceive /* 280 */
691 .quad compat_sys_mq_notify
692 .quad compat_sys_mq_getsetattr
693 .quad compat_sys_kexec_load /* reserved for kexec */
694 .quad compat_sys_waitid
695 .quad quiet_ni_syscall /* 285: sys_altroot */
696 .quad sys_add_key
697 .quad sys_request_key
698 .quad sys_keyctl
699 .quad sys_ioprio_set
700 .quad sys_ioprio_get /* 290 */
701 .quad sys_inotify_init
702 .quad sys_inotify_add_watch
703 .quad sys_inotify_rm_watch
704 .quad sys_migrate_pages
705 .quad compat_sys_openat /* 295 */
706 .quad sys_mkdirat
707 .quad sys_mknodat
708 .quad sys_fchownat
709 .quad compat_sys_futimesat
710 .quad sys32_fstatat /* 300 */
711 .quad sys_unlinkat
712 .quad sys_renameat
713 .quad sys_linkat
714 .quad sys_symlinkat
715 .quad sys_readlinkat /* 305 */
716 .quad sys_fchmodat
717 .quad sys_faccessat
718 .quad compat_sys_pselect6
719 .quad compat_sys_ppoll
720 .quad sys_unshare /* 310 */
721 .quad compat_sys_set_robust_list
722 .quad compat_sys_get_robust_list
723 .quad sys_splice
724 .quad sys32_sync_file_range
725 .quad sys_tee /* 315 */
726 .quad compat_sys_vmsplice
727 .quad compat_sys_move_pages
728 .quad sys_getcpu
729 .quad sys_epoll_pwait
730 .quad compat_sys_utimensat /* 320 */
731 .quad compat_sys_signalfd
732 .quad compat_sys_timerfd
733 .quad sys_eventfd
734 ia32_syscall_end: