release/src/router/libsodium/configure.ac

   1 AC_PREREQ([2.65])
   2 AC_INIT([libsodium],[0.5.0],
   3   [https://github.com/jedisct1/libsodium/issues],
   4   [libsodium],
   5   [https://github.com/jedisct1/libsodium])
   6 AC_CONFIG_MACRO_DIR([m4])
   7 AC_CONFIG_SRCDIR([src/libsodium/sodium/version.c])
   8 AC_CANONICAL_HOST
   9 AM_INIT_AUTOMAKE([1.11 dist-bzip2 tar-ustar foreign subdir-objects])
  10 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  11 AM_MAINTAINER_MODE
  12 AM_DEP_TRACK
  13
  14 AC_SUBST(VERSION)
  15 ISODATE=`date +%Y-%m-%d`
  16 AC_SUBST(ISODATE)
  17
  18 SODIUM_LIBRARY_VERSION_MAJOR=5
  19 SODIUM_LIBRARY_VERSION_MINOR=0
  20 DLL_VERSION=5
  21 SODIUM_LIBRARY_VERSION=10:0:0
  22 #                       | | |
  23 #                +------+ | +---+
  24 #                |        |     |
  25 #             current:revision:age
  26 #                |        |     |
  27 #                |        |     +- increment if interfaces have been added
  28 #                |        |        set to zero if interfaces have been removed
  29 #                |        |        or changed
  30 #                |        +- increment if source code has changed
  31 #                |           set to zero if current is incremented
  32 #                +- increment if interfaces have been added, removed or changed
  33 AC_SUBST(SODIUM_LIBRARY_VERSION_MAJOR)
  34 AC_SUBST(SODIUM_LIBRARY_VERSION_MINOR)
  35 AC_SUBST(SODIUM_LIBRARY_VERSION)
  36 AC_SUBST(DLL_VERSION)
  37
  38 LX_CFLAGS=${CFLAGS-NONE}
  39
  40 dnl Switches
  41
  42 AC_ARG_ENABLE(ssp,
  43 [AS_HELP_STRING(--disable-ssp,Do not compile with -fstack-protector)],
  44 [
  45   AS_IF([test "x$enableval" = "xno"], [
  46     enable_ssp="no"
  47   ], [
  48     enable_ssp="yes"
  49   ])
  50 ],
  51 [
  52   enable_ssp="yes"
  53 ])
  54
  55 AC_ARG_ENABLE(asm,
  56 [AS_HELP_STRING(--disable-asm,Disable assembly implementations)],
  57 [
  58   AS_IF([test "x$enableval" = "xno"], [
  59     enable_asm="no"
  60   ], [
  61     enable_asm="yes"
  62   ])
  63 ],
  64 [
  65   enable_asm="yes"
  66 ])
  67
  68 AS_IF([test "x$EMSCRIPTEN" != "x"],[
  69   enable_asm="no"
  70   AC_MSG_WARN([compiling to javascript - asm implementations disabled])
  71 ])
  72
  73 AS_CASE([$host], [x86_64-*-mingw* | x86_64-*-cygwin*], [enable_asm="no"])
  74
  75 AC_ARG_ENABLE(pie,
  76 [AS_HELP_STRING(--disable-pie,Do not produce position independent executables)],
  77  enable_pie=$enableval, enable_pie="maybe")
  78
  79 AS_CASE([$host_os], [mingw*], [enable_pie="no"])
  80
  81 AC_ARG_ENABLE(blocking-random,
  82 [AS_HELP_STRING(--enable-blocking-random,Use /dev/random instead of /dev/urandom)],
  83 [
  84   AS_IF([test "x$enableval" = "xyes"], [
  85     AC_DEFINE([USE_BLOCKING_RANDOM], [1], [Use blocking random])
  86   ])
  87 ])
  88
  89 AC_ARG_WITH(safecode,
  90 [AS_HELP_STRING(--with-safecode,For maintainers only - please do not use)],
  91 [AS_IF([test "x$withval" = "xyes"], [
  92     AC_ARG_VAR([SAFECODE_HOME], [set to the safecode base directory])
  93     : ${SAFECODE_HOME:=/opt/safecode}
  94     LDFLAGS="$LDFLAGS -L${SAFECODE_HOME}/lib"
  95     LIBS="$LIBS -lsc_dbg_rt -lpoolalloc_bitmap -lstdc++"
  96     CFLAGS="$CFLAGS -fmemsafety"
  97   ])
  98 ])
  99
 100 AC_ARG_ENABLE(debug,
 101 [AS_HELP_STRING(--enable-debug,For maintainers only - please do not use)],
 102 [
 103   AS_IF([test "x$enableval" = "xyes"], [
 104     AS_IF([test "x$LX_CFLAGS" = "xNONE"], [
 105       nxflags=""
 106       for flag in `echo $CFLAGS`; do
 107         AS_CASE([$flag],
 108           [-O*], [ ],
 109           [-g*], [ ],
 110           [*], [AS_VAR_APPEND([nxflags], [" $flag"])])
 111       done
 112       CFLAGS="$nxflags -O0 -g3"
 113     ])
 114     CPPFLAGS="$CPPFLAGS -DDEBUG=1"
 115   ])
 116 ])
 117
 118 AC_SUBST([MAINT])
 119
 120 dnl Checks
 121
 122 PKG_PROG_PKG_CONFIG([0.23])
 123 AM_CONDITIONAL([HAVE_PKG_CONFIG], [test "x$PKG_CONFIG" != "x"])
 124 AC_SUBST(HAVE_PKG_CONFIG)
 125
 126 AC_PROG_CC_C99
 127 AM_PROG_AS
 128 AC_USE_SYSTEM_EXTENSIONS
 129 CPPFLAGS="$CPPFLAGS -D_FORTIFY_SOURCE=2"
 130
 131 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],
 132   [CFLAGS="$CFLAGS -fvisibility=hidden"])
 133
 134 AX_CHECK_COMPILE_FLAG([-fPIC], [
 135   AX_CHECK_LINK_FLAG([-fPIC],
 136     [CFLAGS="$CFLAGS -fPIC"]
 137   )
 138 ])
 139
 140 AS_IF([test "$enable_pie" != "no"],[
 141   AX_CHECK_COMPILE_FLAG([-fPIE], [
 142     AX_CHECK_LINK_FLAG([-fPIE],
 143       [AX_CHECK_LINK_FLAG([-pie],
 144         [CFLAGS="$CFLAGS -fPIE"
 145          LDFLAGS="$LDFLAGS -pie"])
 146     ])
 147   ])
 148 ])
 149
 150 AX_CHECK_COMPILE_FLAG([-fwrapv], [CFLAGS="$CFLAGS -fwrapv"])
 151 AX_CHECK_COMPILE_FLAG([-fno-strict-aliasing], [CFLAGS="$CFLAGS -fno-strict-aliasing"])
 152 AX_CHECK_COMPILE_FLAG([-fno-strict-overflow], [CFLAGS="$CFLAGS -fno-strict-overflow"])
 153
 154 LIBTOOL_OLD_FLAGS="$LIBTOOL_EXTRA_FLAGS"
 155 LIBTOOL_EXTRA_FLAGS="$LIBTOOL_EXTRA_FLAGS -version-info $SODIUM_LIBRARY_VERSION"
 156 AC_ARG_ENABLE(soname-versions,
 157   [AC_HELP_STRING([--enable-soname-versions], [enable soname versions (must be disabled for android) (default: enabled)])],
 158     [
 159         AS_IF([test "x$enableval" = "xno"], [
 160           LIBTOOL_EXTRA_FLAGS="$LIBTOOL_OLD_FLAGS -avoid-version"
 161         ])
 162     ]
 163 )
 164
 165 AS_CASE([$host_os],
 166   [cygwin* | mingw* | pw32* | cegcc*], [
 167     AX_CHECK_LINK_FLAG([-Wl,--dynamicbase], [LDFLAGS="$LDFLAGS -Wl,--dynamicbase"])
 168     AX_CHECK_LINK_FLAG([-Wl,--nxcompat], [LDFLAGS="$LDFLAGS -Wl,--nxcompat"])
 169   ])
 170
 171 AS_IF([test "x$enable_ssp" != "xno"],[
 172
 173 AS_CASE([$host_os],
 174   [cygwin* | mingw* | pw32* | cegcc*], [ ],
 175   [dragonfly*], [
 176     AX_CHECK_COMPILE_FLAG([-fstack-protector], [
 177       AX_CHECK_LINK_FLAG([-fstack-protector],
 178         [CFLAGS="$CFLAGS -fstack-protector"]
 179       )
 180     ])
 181   ],
 182   [*], [
 183     AX_CHECK_COMPILE_FLAG([-fstack-protector-all], [
 184       AX_CHECK_LINK_FLAG([-fstack-protector-all],
 185         [CFLAGS="$CFLAGS -fstack-protector-all"]
 186       )
 187     ])
 188   ])
 189 ])
 190
 191 AX_CHECK_COMPILE_FLAG([-Winit-self], [CFLAGS="$CFLAGS -Winit-self"])
 192 AX_CHECK_COMPILE_FLAG([-Wwrite-strings], [CFLAGS="$CFLAGS -Wwrite-strings"])
 193 AX_CHECK_COMPILE_FLAG([-Wdiv-by-zero], [CFLAGS="$CFLAGS -Wdiv-by-zero"])
 194 AX_CHECK_COMPILE_FLAG([-Wsometimes-uninitialized], [CFLAGS="$CFLAGS -Wsometimes-uninitialized"])
 195
 196 AC_ARG_VAR([CWFLAGS], [define to compilation flags for generating extra warnings])
 197
 198 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wall], [CWFLAGS="$CWFLAGS -Wall"])
 199 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wextra], [CWFLAGS="$CWFLAGS -Wextra"])
 200
 201 AC_MSG_CHECKING(for clang)
 202 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 203 #ifndef __clang__
 204 be sad
 205 #endif
 206 ]])],
 207   [AC_MSG_RESULT(yes)
 208    AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wno-unknown-warning-option],
 209      [CWFLAGS="$CWFLAGS -Wno-unknown-warning-option"])
 210   ],
 211   [AC_MSG_RESULT(no)
 212 ])
 213
 214 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wbad-function-cast], [CWFLAGS="$CWFLAGS -Wbad-function-cast"])
 215 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wcast-align], [CWFLAGS="$CWFLAGS -Wcast-align"])
 216 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wcast-qual], [CWFLAGS="$CWFLAGS -Wcast-qual"])
 217 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wchar-subscripts], [CWFLAGS="$CWFLAGS -Wchar-subscripts"])
 218 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wcomment], [CWFLAGS="$CWFLAGS -Wcomment"])
 219 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wfloat-equal], [CWFLAGS="$CWFLAGS -Wfloat-equal"])
 220 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wformat=2], [CWFLAGS="$CWFLAGS -Wformat=2"])
 221 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wimplicit], [CWFLAGS="$CWFLAGS -Wimplicit"])
 222 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wmissing-declarations], [CWFLAGS="$CWFLAGS -Wmissing-declarations"])
 223 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wmissing-prototypes], [CWFLAGS="$CWFLAGS -Wmissing-prototypes"])
 224 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wnormalized=id], [CWFLAGS="$CWFLAGS -Wnormalized=id"])
 225 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Woverride-init], [CWFLAGS="$CWFLAGS -Woverride-init"])
 226 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wparentheses], [CWFLAGS="$CWFLAGS -Wparentheses"])
 227 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wpointer-arith], [CWFLAGS="$CWFLAGS -Wpointer-arith"])
 228 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wredundant-decls], [CWFLAGS="$CWFLAGS -Wredundant-decls"])
 229 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wstrict-prototypes], [CWFLAGS="$CWFLAGS -Wstrict-prototypes"])
 230 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wswitch-enum], [CWFLAGS="$CWFLAGS -Wswitch-enum"])
 231 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wvariable-decl], [CWFLAGS="$CWFLAGS -Wvariable-decl"])
 232
 233 AX_CHECK_LINK_FLAG([-Wl,-z,relro], [LDFLAGS="$LDFLAGS -Wl,-z,relro"])
 234 AX_CHECK_LINK_FLAG([-Wl,-z,now], [LDFLAGS="$LDFLAGS -Wl,-z,now"])
 235 AX_CHECK_LINK_FLAG([-Wl,-z,noexecstack], [LDFLAGS="$LDFLAGS -Wl,-z,noexecstack"])
 236
 237 LT_INIT
 238 AC_SUBST(LIBTOOL_DEPS)
 239
 240 AC_ARG_VAR([AR], [path to the ar utility])
 241 AC_CHECK_TOOL([AR], [ar], [ar])
 242
 243 dnl Checks for headers
 244
 245 AS_IF([test "x$EMSCRIPTEN" = "x"],[
 246
 247   AC_MSG_CHECKING(for MMX instructions set)
 248   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 249 #pragma GCC target("mmx")
 250 #include <mmintrin.h>
 251 ]], [[ __m64 x = _mm_setzero_si64(); ]])],
 252     [AC_MSG_RESULT(yes)
 253      AC_DEFINE([HAVE_MMINTRIN_H], [1], [mmx is available])],
 254     [AC_MSG_RESULT(no)])
 255
 256   AC_MSG_CHECKING(for SSE2 instructions set)
 257   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 258 #pragma GCC target("sse2")
 259 #include <emmintrin.h>
 260 ]], [[ __m128d x = _mm_setzero_pd(); ]])],
 261     [AC_MSG_RESULT(yes)
 262      AC_DEFINE([HAVE_EMMINTRIN_H], [1], [sse2 is available])],
 263     [AC_MSG_RESULT(no)])
 264
 265   AC_MSG_CHECKING(for SSE3 instructions set)
 266   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 267 #pragma GCC target("sse3")
 268 #include <pmmintrin.h>
 269 ]], [[ __m128 x = _mm_addsub_ps(_mm_cvtpd_ps(_mm_setzero_pd()),
 270                                 _mm_cvtpd_ps(_mm_setzero_pd())); ]])],
 271     [AC_MSG_RESULT(yes)
 272      AC_DEFINE([HAVE_PMMINTRIN_H], [1], [sse3 is available])],
 273     [AC_MSG_RESULT(no)])
 274
 275 ])
 276
 277 AC_CHECK_HEADERS([sys/mman.h])
 278
 279 dnl Checks for typedefs, structures, and compiler characteristics.
 280
 281 AC_C_INLINE
 282 AC_C_BIGENDIAN(
 283   AC_DEFINE(NATIVE_BIG_ENDIAN, 1, [machine is bigendian]),
 284   AC_DEFINE(NATIVE_LITTLE_ENDIAN, 1, [machine is littleendian]),
 285   AC_MSG_ERROR([unknown endianess]),
 286   AC_MSG_ERROR([universal endianess is not supported - compile separately and use lipo(1)])
 287 )
 288
 289 AC_MSG_CHECKING(whether __STDC_LIMIT_MACROS is required)
 290 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 291 #include <limits.h>
 292 #include <stdint.h>
 293 ]], [[
 294 (void) SIZE_MAX;
 295 (void) UINT64_MAX;
 296 ]])],
 297   [AC_MSG_RESULT(no)],
 298   [AC_MSG_RESULT(yes)
 299    CPPFLAGS="$CPPFLAGS -D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 300 ])
 301
 302 HAVE_AMD64_ASM_V=0
 303 AS_IF([test "$enable_asm" != "no"],[
 304   AC_MSG_CHECKING(whether we can assemble basic amd64 code)
 305   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 306   ]], [[
 307 #if defined(__amd64) || defined(__amd64__) || defined(__x86_64__)
 308 /* neat */
 309 #else
 310 # error !amd64
 311 #endif
 312 __asm__("pxor %xmm12,%xmm6");
 313 ]])],
 314   [AC_MSG_RESULT(yes)
 315    AC_DEFINE([HAVE_AMD64_ASM], [1], [basic amd64 code can be assembled])
 316    HAVE_AMD64_ASM_V=1],
 317   [AC_MSG_RESULT(no)])
 318 ])
 319 AM_CONDITIONAL([HAVE_AMD64_ASM], [test $HAVE_AMD64_ASM_V = 1])
 320 AC_SUBST(HAVE_AMD64_ASM_V)
 321
 322 AC_MSG_CHECKING(for 128-bit arithmetic)
 323 HAVE_TI_MODE_V=0
 324 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 325 #ifndef __GNUC__
 326 # error mode(TI) is a gcc extension
 327 #endif
 328 #if defined(__clang__) && !defined(__x86_64__)
 329 # error clang doesn't properly compile smult_curve25519_donna_c64.c
 330 #endif
 331 #ifndef NATIVE_LITTLE_ENDIAN
 332 # error donna_c64 currently requires a little endian CPU
 333 #endif
 334 #include <stdint.h>
 335 typedef unsigned uint128_t __attribute__((mode(TI)));
 336 void fcontract(uint128_t *t) {
 337   *t += 0x8000000000000 - 1;
 338 }
 339 ]], [[
 340 (void) fcontract;
 341 ]])],
 342 [AC_MSG_RESULT(yes)
 343  AC_DEFINE([HAVE_TI_MODE], [1], [gcc TI mode is available])
 344  HAVE_TI_MODE_V=1],
 345 [AC_MSG_RESULT(no)])
 346 AM_CONDITIONAL([HAVE_TI_MODE], [test $HAVE_TI_MODE_V = 1])
 347 AC_SUBST(HAVE_TI_MODE_V)
 348
 349 HAVE_CPUID_V=0
 350 AS_IF([test "$enable_asm" != "no"],[
 351   AC_MSG_CHECKING(for cpuid instruction)
 352   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ ]], [[
 353 unsigned int cpu_info[4];
 354 __asm__ __volatile__ ("xchgl %%ebx, %k1; cpuid; xchgl %%ebx, %k1" :
 355                       "=a" (cpu_info[0]), "=&r" (cpu_info[1]),
 356                       "=c" (cpu_info[2]), "=d" (cpu_info[3]) :
 357                       "0" (0U), "2" (0U));
 358   ]])],
 359   [AC_MSG_RESULT(yes)
 360    AC_DEFINE([HAVE_CPUID], [1], [cpuid instruction is available])
 361    HAVE_CPUID_V=1],
 362   [AC_MSG_RESULT(no)])
 363   ])
 364 AC_SUBST(HAVE_CPUID_V)
 365
 366 AS_CASE([$host_cpu],
 367   [i*86 | x86_64 | powerpc* | s390*],
 368     [AC_MSG_NOTICE([data alignment is not required on this target])],
 369   [*],
 370     [AC_MSG_NOTICE([data alignment is required on this target])
 371      AC_DEFINE([CPU_ALIGNED_ACCESS_REQUIRED], [1], [data alignment is required])]
 372 )
 373
 374 AC_MSG_CHECKING(for memset_s)
 375 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 376 #include <string.h>
 377 ]], [[
 378 char dummy[42];
 379 (void) memset_s(dummy, (rsize_t) sizeof dummy, 0, (rsize_t) sizeof dummy);
 380 ]])],
 381 [AC_MSG_RESULT(yes)
 382  AC_DEFINE([HAVE_MEMSET_S], [1], [memset_s is available])],
 383 [AC_MSG_RESULT(no)])
 384
 385 dnl Checks for functions and headers
 386
 387 AC_CHECK_FUNC(clock_gettime, , [AC_CHECK_LIB(rt, clock_gettime)])
 388 AC_CHECK_FUNC(fegetenv, , [AC_CHECK_LIB(m, fegetenv)])
 389
 390 AS_IF([test "x$EMSCRIPTEN" = "x"],[
 391   AC_CHECK_FUNCS([arc4random arc4random_buf])
 392 ])
 393 AC_CHECK_FUNCS([mlock VirtualLock])
 394 AC_CHECK_FUNCS([SecureZeroMemory explicit_bzero posix_memalign])
 395
 396 AC_SUBST([LIBTOOL_EXTRA_FLAGS])
 397
 398 dnl Libtool.
 399
 400 LT_INIT([dlopen])
 401 AC_LIBTOOL_WIN32_DLL
 402 gl_LD_OUTPUT_DEF
 403
 404 dnl Output.
 405
 406 AH_VERBATIM([NDEBUG], [/* Never ever ignore assertions */
 407 #ifdef NDEBUG
 408 #/**/undef/**/ NDEBUG
 409 #endif])
 410
 411 AS_IF([test "x$PKG_CONFIG" != "x"], [
 412   AC_CONFIG_FILES([libsodium.pc])
 413 ])
 414 AC_CONFIG_FILES([Makefile
 415                  dist-build/Makefile
 416                  msvc-scripts/Makefile
 417                  src/Makefile
 418                  src/libsodium/Makefile
 419                  src/libsodium/include/Makefile
 420                  src/libsodium/include/sodium/version.h
 421                  test/default/Makefile
 422                  test/Makefile
 423                  ])
 424 AC_OUTPUT