release/src/router/libsodium/m4/ax_check_link_flag.m4

   1 # ===========================================================================
   2 #    http://www.gnu.org/software/autoconf-archive/ax_check_link_flag.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_CHECK_LINK_FLAG(FLAG, [ACTION-SUCCESS], [ACTION-FAILURE], [EXTRA-FLAGS])
   8 #
   9 # DESCRIPTION
  10 #
  11 #   Check whether the given FLAG works with the linker or gives an error.
  12 #   (Warnings, however, are ignored)
  13 #
  14 #   ACTION-SUCCESS/ACTION-FAILURE are shell commands to execute on
  15 #   success/failure.
  16 #
  17 #   If EXTRA-FLAGS is defined, it is added to the linker's default flags
  18 #   when the check is done.  The check is thus made with the flags: "LDFLAGS
  19 #   EXTRA-FLAGS FLAG".  This can for example be used to force the linker to
  20 #   issue an error when a bad flag is given.
  21 #
  22 #   NOTE: Implementation based on AX_CFLAGS_GCC_OPTION. Please keep this
  23 #   macro in sync with AX_CHECK_{PREPROC,COMPILE}_FLAG.
  24 #
  25 # LICENSE
  26 #
  27 #   Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
  28 #   Copyright (c) 2011 Maarten Bosmans <mkbosmans@gmail.com>
  29 #
  30 #   This program is free software: you can redistribute it and/or modify it
  31 #   under the terms of the GNU General Public License as published by the
  32 #   Free Software Foundation, either version 3 of the License, or (at your
  33 #   option) any later version.
  34 #
  35 #   This program is distributed in the hope that it will be useful, but
  36 #   WITHOUT ANY WARRANTY; without even the implied warranty of
  37 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
  38 #   Public License for more details.
  39 #
  40 #   You should have received a copy of the GNU General Public License along
  41 #   with this program. If not, see <http://www.gnu.org/licenses/>.
  42 #
  43 #   As a special exception, the respective Autoconf Macro's copyright owner
  44 #   gives unlimited permission to copy, distribute and modify the configure
  45 #   scripts that are the output of Autoconf when processing the Macro. You
  46 #   need not follow the terms of the GNU General Public License when using
  47 #   or distributing such scripts, even though portions of the text of the
  48 #   Macro appear in them. The GNU General Public License (GPL) does govern
  49 #   all other use of the material that constitutes the Autoconf Macro.
  50 #
  51 #   This special exception to the GPL applies to versions of the Autoconf
  52 #   Macro released by the Autoconf Archive. When you make and distribute a
  53 #   modified version of the Autoconf Macro, you may extend this special
  54 #   exception to the GPL to apply to your modified version as well.
  55
  56 #serial 2
  57
  58 AC_DEFUN([AX_CHECK_LINK_FLAG],
  59 [AC_PREREQ(2.64)dnl for _AC_LANG_PREFIX and AS_VAR_IF
  60 AS_VAR_PUSHDEF([CACHEVAR],[ax_cv_check_ldflags_$4_$1])dnl
  61 AC_CACHE_CHECK([whether the linker accepts $1], CACHEVAR, [
  62   ax_check_save_flags=$LDFLAGS
  63   LDFLAGS="$LDFLAGS $4 $1"
  64   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]],
  65   [[char x[42U];if (fgets(x,1000,stdin)) puts(x)]])],
  66     [AS_VAR_SET(CACHEVAR,[yes])],
  67     [AS_VAR_SET(CACHEVAR,[no])])
  68   LDFLAGS=$ax_check_save_flags])
  69 AS_VAR_IF(CACHEVAR,yes,
  70   [m4_default([$2], :)],
  71   [m4_default([$3], :)])
  72 AS_VAR_POPDEF([CACHEVAR])dnl
  73 ])dnl AX_CHECK_LINK_FLAGS