release/src/router/transmission/qt/qtr.pro

   1 TARGET = transmission-qt
   2 NAME = "Transmission"
   3 DESCRIPTION = "Transmission: a fast, easy, and free BitTorrent client"
   4 VERSION = 2.00
   5 LICENSE = "GPL"
   6
   7 target.path = /bin
   8 INSTALLS += target
   9
  10 unix: INSTALLS += man
  11 man.path = /share/man/man1/
  12 man.files = transmission-qt.1
  13
  14 CONFIG += qt qdbus thread debug link_pkgconfig
  15 QT += network
  16 PKGCONFIG = fontconfig libcurl openssl dbus-1
  17
  18 TRANSMISSION_TOP = ..
  19 INCLUDEPATH += $${TRANSMISSION_TOP}
  20 LIBS += $${TRANSMISSION_TOP}/libtransmission/libtransmission.a
  21 LIBS += $${TRANSMISSION_TOP}/third-party/dht/libdht.a
  22 LIBS += $${TRANSMISSION_TOP}/third-party/miniupnp/libminiupnp.a
  23 LIBS += $${TRANSMISSION_TOP}/third-party/libnatpmp/libnatpmp.a
  24 unix: LIBS += -levent -lz
  25 win32:DEFINES += QT_DBUS
  26 win32:LIBS += -levent -lws2_32 -lintl
  27 win32:LIBS += -lidn -liconv -lwldap32 -liphlpapi
  28
  29 TRANSLATIONS += translations/transmission_en.ts \
  30                 translations/transmission_es.ts \
  31                 translations/transmission_pt_BR.ts \
  32                 translations/transmission_ru.ts
  33
  34 FORMS += mainwin.ui
  35 RESOURCES += application.qrc
  36 SOURCES += about.cc \
  37            add-data.cc \
  38            app.cc \
  39            dbus-adaptor.cc \
  40            details.cc \
  41            favicon.cc \
  42            file-tree.cc \
  43            filterbar.cc \
  44            filters.cc \
  45            formatter.cc \
  46            hig.cc \
  47            license.cc \
  48            mainwin.cc \
  49            make-dialog.cc \
  50            options.cc \
  51            prefs.cc \
  52            prefs-dialog.cc \
  53            relocate.cc \
  54            session.cc \
  55            session-dialog.cc \
  56            squeezelabel.cc \
  57            stats-dialog.cc \
  58            torrent.cc torrent-delegate.cc \
  59            torrent-delegate-min.cc \
  60            torrent-filter.cc \
  61            torrent-model.cc \
  62            tracker-delegate.cc \
  63            tracker-model.cc \
  64            tracker-model-filter.cc \
  65            triconpushbutton.cc \
  66            utils.cc \
  67            watchdir.cc
  68 HEADERS += $$replace(SOURCES, .cc, .h)
  69 HEADERS += speed.h types.h
  70
  71 win32:RC_FILE = qtr.rc