release/src/router/glib/glib.m4

   1 # Configure paths for GLIB
   2 # Owen Taylor     97-11-3
   3
   4 dnl AM_PATH_GLIB([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND [, MODULES]]]])
   5 dnl Test for GLIB, and define GLIB_CFLAGS and GLIB_LIBS, if "gmodule" or
   6 dnl gthread is specified in MODULES, pass to glib-config
   7 dnl
   8 AC_DEFUN([AM_PATH_GLIB],
   9 [dnl
  10 dnl Get the cflags and libraries from the glib-config script
  11 dnl
  12 AC_ARG_WITH(glib-prefix,[  --with-glib-prefix=PFX   Prefix where GLIB is installed (optional)],
  13             glib_config_prefix="$withval", glib_config_prefix="")
  14 AC_ARG_WITH(glib-exec-prefix,[  --with-glib-exec-prefix=PFX Exec prefix where GLIB is installed (optional)],
  15             glib_config_exec_prefix="$withval", glib_config_exec_prefix="")
  16 AC_ARG_ENABLE(glibtest, [  --disable-glibtest       Do not try to compile and run a test GLIB program],
  17                     , enable_glibtest=yes)
  18
  19   if test x$glib_config_exec_prefix != x ; then
  20      glib_config_args="$glib_config_args --exec-prefix=$glib_config_exec_prefix"
  21      if test x${GLIB_CONFIG+set} != xset ; then
  22         GLIB_CONFIG=$glib_config_exec_prefix/bin/glib-config
  23      fi
  24   fi
  25   if test x$glib_config_prefix != x ; then
  26      glib_config_args="$glib_config_args --prefix=$glib_config_prefix"
  27      if test x${GLIB_CONFIG+set} != xset ; then
  28         GLIB_CONFIG=$glib_config_prefix/bin/glib-config
  29      fi
  30   fi
  31
  32   for module in . $4
  33   do
  34       case "$module" in
  35          gmodule)
  36              glib_config_args="$glib_config_args gmodule"
  37          ;;
  38          gthread)
  39              glib_config_args="$glib_config_args gthread"
  40          ;;
  41       esac
  42   done
  43
  44   AC_PATH_PROG(GLIB_CONFIG, glib-config, no)
  45   min_glib_version=ifelse([$1], ,0.99.7,$1)
  46   AC_MSG_CHECKING(for GLIB - version >= $min_glib_version)
  47   no_glib=""
  48   if test "$GLIB_CONFIG" = "no" ; then
  49     no_glib=yes
  50   else
  51     GLIB_CFLAGS=`$GLIB_CONFIG $glib_config_args --cflags`
  52     GLIB_LIBS=`$GLIB_CONFIG $glib_config_args --libs`
  53     glib_config_major_version=`$GLIB_CONFIG $glib_config_args --version | \
  54            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
  55     glib_config_minor_version=`$GLIB_CONFIG $glib_config_args --version | \
  56            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
  57     glib_config_micro_version=`$GLIB_CONFIG $glib_config_args --version | \
  58            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
  59     if test "x$enable_glibtest" = "xyes" ; then
  60       ac_save_CFLAGS="$CFLAGS"
  61       ac_save_LIBS="$LIBS"
  62       CFLAGS="$CFLAGS $GLIB_CFLAGS"
  63       LIBS="$GLIB_LIBS $LIBS"
  64 dnl
  65 dnl Now check if the installed GLIB is sufficiently new. (Also sanity
  66 dnl checks the results of glib-config to some extent
  67 dnl
  68       rm -f conf.glibtest
  69       AC_TRY_RUN([
  70 #include <glib.h>
  71 #include <stdio.h>
  72 #include <stdlib.h>
  73
  74 int
  75 main ()
  76 {
  77   int major, minor, micro;
  78   char *tmp_version;
  79
  80   system ("touch conf.glibtest");
  81
  82   /* HP/UX 9 (%@#!) writes to sscanf strings */
  83   tmp_version = g_strdup("$min_glib_version");
  84   if (sscanf(tmp_version, "%d.%d.%d", &major, &minor, &micro) != 3) {
  85      printf("%s, bad version string\n", "$min_glib_version");
  86      exit(1);
  87    }
  88
  89   if ((glib_major_version != $glib_config_major_version) ||
  90       (glib_minor_version != $glib_config_minor_version) ||
  91       (glib_micro_version != $glib_config_micro_version))
  92     {
  93       printf("\n*** 'glib-config --version' returned %d.%d.%d, but GLIB (%d.%d.%d)\n",
  94              $glib_config_major_version, $glib_config_minor_version, $glib_config_micro_version,
  95              glib_major_version, glib_minor_version, glib_micro_version);
  96       printf ("*** was found! If glib-config was correct, then it is best\n");
  97       printf ("*** to remove the old version of GLIB. You may also be able to fix the error\n");
  98       printf("*** by modifying your LD_LIBRARY_PATH enviroment variable, or by editing\n");
  99       printf("*** /etc/ld.so.conf. Make sure you have run ldconfig if that is\n");
 100       printf("*** required on your system.\n");
 101       printf("*** If glib-config was wrong, set the environment variable GLIB_CONFIG\n");
 102       printf("*** to point to the correct copy of glib-config, and remove the file config.cache\n");
 103       printf("*** before re-running configure\n");
 104     }
 105   else if ((glib_major_version != GLIB_MAJOR_VERSION) ||
 106            (glib_minor_version != GLIB_MINOR_VERSION) ||
 107            (glib_micro_version != GLIB_MICRO_VERSION))
 108     {
 109       printf("*** GLIB header files (version %d.%d.%d) do not match\n",
 110              GLIB_MAJOR_VERSION, GLIB_MINOR_VERSION, GLIB_MICRO_VERSION);
 111       printf("*** library (version %d.%d.%d)\n",
 112              glib_major_version, glib_minor_version, glib_micro_version);
 113     }
 114   else
 115     {
 116       if ((glib_major_version > major) ||
 117         ((glib_major_version == major) && (glib_minor_version > minor)) ||
 118         ((glib_major_version == major) && (glib_minor_version == minor) && (glib_micro_version >= micro)))
 119       {
 120         return 0;
 121        }
 122      else
 123       {
 124         printf("\n*** An old version of GLIB (%d.%d.%d) was found.\n",
 125                glib_major_version, glib_minor_version, glib_micro_version);
 126         printf("*** You need a version of GLIB newer than %d.%d.%d. The latest version of\n",
 127                major, minor, micro);
 128         printf("*** GLIB is always available from ftp://ftp.gtk.org.\n");
 129         printf("***\n");
 130         printf("*** If you have already installed a sufficiently new version, this error\n");
 131         printf("*** probably means that the wrong copy of the glib-config shell script is\n");
 132         printf("*** being found. The easiest way to fix this is to remove the old version\n");
 133         printf("*** of GLIB, but you can also set the GLIB_CONFIG environment to point to the\n");
 134         printf("*** correct copy of glib-config. (In this case, you will have to\n");
 135         printf("*** modify your LD_LIBRARY_PATH enviroment variable, or edit /etc/ld.so.conf\n");
 136         printf("*** so that the correct libraries are found at run-time))\n");
 137       }
 138     }
 139   return 1;
 140 }
 141 ],, no_glib=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 142        CFLAGS="$ac_save_CFLAGS"
 143        LIBS="$ac_save_LIBS"
 144      fi
 145   fi
 146   if test "x$no_glib" = x ; then
 147      AC_MSG_RESULT(yes)
 148      ifelse([$2], , :, [$2])
 149   else
 150      AC_MSG_RESULT(no)
 151      if test "$GLIB_CONFIG" = "no" ; then
 152        echo "*** The glib-config script installed by GLIB could not be found"
 153        echo "*** If GLIB was installed in PREFIX, make sure PREFIX/bin is in"
 154        echo "*** your path, or set the GLIB_CONFIG environment variable to the"
 155        echo "*** full path to glib-config."
 156      else
 157        if test -f conf.glibtest ; then
 158         :
 159        else
 160           echo "*** Could not run GLIB test program, checking why..."
 161           CFLAGS="$CFLAGS $GLIB_CFLAGS"
 162           LIBS="$LIBS $GLIB_LIBS"
 163           AC_TRY_LINK([
 164 #include <glib.h>
 165 #include <stdio.h>
 166 ],      [ return ((glib_major_version) || (glib_minor_version) || (glib_micro_version)); ],
 167         [ echo "*** The test program compiled, but did not run. This usually means"
 168           echo "*** that the run-time linker is not finding GLIB or finding the wrong"
 169           echo "*** version of GLIB. If it is not finding GLIB, you'll need to set your"
 170           echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
 171           echo "*** to the installed location  Also, make sure you have run ldconfig if that"
 172           echo "*** is required on your system"
 173           echo "***"
 174           echo "*** If you have an old version installed, it is best to remove it, although"
 175           echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH"
 176           echo "***"
 177           echo "*** If you have a RedHat 5.0 system, you should remove the GTK package that"
 178           echo "*** came with the system with the command"
 179           echo "***"
 180           echo "***    rpm --erase --nodeps gtk gtk-devel" ],
 181         [ echo "*** The test program failed to compile or link. See the file config.log for the"
 182           echo "*** exact error that occured. This usually means GLIB was incorrectly installed"
 183           echo "*** or that you have moved GLIB since it was installed. In the latter case, you"
 184           echo "*** may want to edit the glib-config script: $GLIB_CONFIG" ])
 185           CFLAGS="$ac_save_CFLAGS"
 186           LIBS="$ac_save_LIBS"
 187        fi
 188      fi
 189      GLIB_CFLAGS=""
 190      GLIB_LIBS=""
 191      ifelse([$3], , :, [$3])
 192   fi
 193   AC_SUBST(GLIB_CFLAGS)
 194   AC_SUBST(GLIB_LIBS)
 195   rm -f conf.glibtest
 196 ])