release/src/router/libsodium/configure.ac

   1 AC_PREREQ([2.65])
   2 AC_INIT([libsodium],[1.0.0],
   3   [https://github.com/jedisct1/libsodium/issues],
   4   [libsodium],
   5   [https://github.com/jedisct1/libsodium])
   6 AC_CONFIG_MACRO_DIR([m4])
   7 AC_CONFIG_SRCDIR([src/libsodium/sodium/version.c])
   8 AC_CANONICAL_HOST
   9 AM_INIT_AUTOMAKE([1.11 dist-bzip2 tar-ustar foreign subdir-objects])
  10 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  11 AM_MAINTAINER_MODE
  12 AM_DEP_TRACK
  13
  14 AC_SUBST(VERSION)
  15 ISODATE=`date +%Y-%m-%d`
  16 AC_SUBST(ISODATE)
  17
  18 SODIUM_LIBRARY_VERSION_MAJOR=7
  19 SODIUM_LIBRARY_VERSION_MINOR=2
  20 DLL_VERSION=6
  21 SODIUM_LIBRARY_VERSION=13:2:0
  22 #                       | | |
  23 #                +------+ | +---+
  24 #                |        |     |
  25 #             current:revision:age
  26 #                |        |     |
  27 #                |        |     +- increment if interfaces have been added
  28 #                |        |        set to zero if interfaces have been removed
  29 #                |        |        or changed
  30 #                |        +- increment if source code has changed
  31 #                |           set to zero if current is incremented
  32 #                +- increment if interfaces have been added, removed or changed
  33 AC_SUBST(SODIUM_LIBRARY_VERSION_MAJOR)
  34 AC_SUBST(SODIUM_LIBRARY_VERSION_MINOR)
  35 AC_SUBST(SODIUM_LIBRARY_VERSION)
  36 AC_SUBST(DLL_VERSION)
  37
  38 LX_CFLAGS=${CFLAGS-NONE}
  39
  40 dnl Switches
  41
  42 AC_ARG_ENABLE(ssp,
  43 [AS_HELP_STRING(--disable-ssp,Do not compile with -fstack-protector)],
  44 [
  45   AS_IF([test "x$enableval" = "xno"], [
  46     enable_ssp="no"
  47   ], [
  48     enable_ssp="yes"
  49   ])
  50 ],
  51 [
  52   enable_ssp="yes"
  53 ])
  54
  55 AC_ARG_ENABLE(asm,
  56 [AS_HELP_STRING(--disable-asm,Disable assembly implementations)],
  57 [
  58   AS_IF([test "x$enableval" = "xno"], [
  59     enable_asm="no"
  60   ], [
  61     enable_asm="yes"
  62   ])
  63 ],
  64 [
  65   enable_asm="yes"
  66 ])
  67
  68 AS_IF([test "x$EMSCRIPTEN" != "x"],[
  69   enable_asm="no"
  70   AC_MSG_WARN([compiling to javascript - asm implementations disabled])
  71 ])
  72
  73 AC_ARG_ENABLE(pie,
  74 [AS_HELP_STRING(--disable-pie,Do not produce position independent executables)],
  75  enable_pie=$enableval, enable_pie="maybe")
  76
  77 AS_CASE([$host_os], [mingw*|cygwin*|msys], [enable_pie="no"])
  78
  79 AC_ARG_ENABLE(blocking-random,
  80 [AS_HELP_STRING(--enable-blocking-random,Use /dev/random instead of /dev/urandom)],
  81 [
  82   AS_IF([test "x$enableval" = "xyes"], [
  83     AC_DEFINE([USE_BLOCKING_RANDOM], [1], [Use blocking random])
  84   ])
  85 ])
  86
  87 AC_ARG_ENABLE(minimal,
  88 [AS_HELP_STRING(--enable-minimal,
  89   [Only compile the minimum set of functions required for the high-level API])],
  90 [
  91   AS_IF([test "x$enableval" = "xyes"], [
  92     enable_minimal="yes"
  93   ], [
  94     enable_minimal="no"
  95   ])
  96 ],
  97 [
  98   enable_minimal="no"
  99 ])
 100 AM_CONDITIONAL([MINIMAL], [test x$enable_minimal = xyes])
 101
 102 AC_ARG_WITH(safecode,
 103 [AS_HELP_STRING(--with-safecode,For maintainers only - please do not use)],
 104 [AS_IF([test "x$withval" = "xyes"], [
 105     AC_ARG_VAR([SAFECODE_HOME], [set to the safecode base directory])
 106     : ${SAFECODE_HOME:=/opt/safecode}
 107     LDFLAGS="$LDFLAGS -L${SAFECODE_HOME}/lib"
 108     LIBS="$LIBS -lsc_dbg_rt -lpoolalloc_bitmap -lstdc++"
 109     CFLAGS="$CFLAGS -fmemsafety"
 110   ])
 111 ])
 112
 113 AC_ARG_ENABLE(debug,
 114 [AS_HELP_STRING(--enable-debug,For maintainers only - please do not use)],
 115 [
 116   AS_IF([test "x$enableval" = "xyes"], [
 117     AS_IF([test "x$LX_CFLAGS" = "xNONE"], [
 118       nxflags=""
 119       for flag in `echo $CFLAGS`; do
 120         AS_CASE([$flag],
 121           [-O*], [ ],
 122           [-g*], [ ],
 123           [*], [AS_VAR_APPEND([nxflags], [" $flag"])])
 124       done
 125       CFLAGS="$nxflags -O0 -g3"
 126     ])
 127     CPPFLAGS="$CPPFLAGS -DDEBUG=1"
 128   ])
 129 ])
 130
 131 AC_SUBST([MAINT])
 132
 133 dnl Checks
 134
 135 AC_PROG_CC_C99
 136 AM_PROG_AS
 137 AC_USE_SYSTEM_EXTENSIONS
 138 CPPFLAGS="$CPPFLAGS -D_FORTIFY_SOURCE=2"
 139
 140 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],
 141   [CFLAGS="$CFLAGS -fvisibility=hidden"])
 142
 143 AS_CASE([$host_os], [cygwin*|mingw*|msys|pw32*|cegcc*], [ ], [
 144   AX_CHECK_COMPILE_FLAG([-fPIC], [
 145     AX_CHECK_LINK_FLAG([-fPIC],
 146       [CFLAGS="$CFLAGS -fPIC"]
 147     )
 148   ])
 149 ])
 150
 151 AS_IF([test "$enable_pie" != "no"],[
 152   AX_CHECK_COMPILE_FLAG([-fPIE], [
 153     AX_CHECK_LINK_FLAG([-fPIE],
 154       [AX_CHECK_LINK_FLAG([-pie],
 155         [CFLAGS="$CFLAGS -fPIE"
 156          LDFLAGS="$LDFLAGS -pie"])
 157     ])
 158   ])
 159 ])
 160
 161 AX_CHECK_COMPILE_FLAG([-fwrapv], [CFLAGS="$CFLAGS -fwrapv"])
 162 AX_CHECK_COMPILE_FLAG([-fno-strict-aliasing], [CFLAGS="$CFLAGS -fno-strict-aliasing"])
 163 AX_CHECK_COMPILE_FLAG([-fno-strict-overflow], [CFLAGS="$CFLAGS -fno-strict-overflow"])
 164
 165 LIBTOOL_OLD_FLAGS="$LIBTOOL_EXTRA_FLAGS"
 166 LIBTOOL_EXTRA_FLAGS="$LIBTOOL_EXTRA_FLAGS -version-info $SODIUM_LIBRARY_VERSION"
 167 AC_ARG_ENABLE(soname-versions,
 168   [AC_HELP_STRING([--enable-soname-versions], [enable soname versions (must be disabled for Android) (default: enabled)])],
 169     [
 170         AS_IF([test "x$enableval" = "xno"], [
 171           LIBTOOL_EXTRA_FLAGS="$LIBTOOL_OLD_FLAGS -avoid-version"
 172         ])
 173     ]
 174 )
 175
 176 AS_CASE([$host_os],
 177   [cygwin*|mingw*|msys|pw32*|cegcc*], [
 178     AX_CHECK_LINK_FLAG([-Wl,--dynamicbase], [LDFLAGS="$LDFLAGS -Wl,--dynamicbase"])
 179     AX_CHECK_LINK_FLAG([-Wl,--nxcompat], [LDFLAGS="$LDFLAGS -Wl,--nxcompat"])
 180   ])
 181
 182 AS_IF([test "x$enable_ssp" != "xno"],[
 183
 184 AS_CASE([$host_os],
 185   [cygwin*|mingw*|msys|pw32*|cegcc*], [ ],
 186   [*], [
 187     AX_CHECK_COMPILE_FLAG([-fstack-protector], [
 188       AX_CHECK_LINK_FLAG([-fstack-protector],
 189         [CFLAGS="$CFLAGS -fstack-protector"]
 190       )
 191     ])
 192   ])
 193 ])
 194
 195 AX_CHECK_COMPILE_FLAG([-Winit-self], [CFLAGS="$CFLAGS -Winit-self"])
 196 AX_CHECK_COMPILE_FLAG([-Wwrite-strings], [CFLAGS="$CFLAGS -Wwrite-strings"])
 197 AX_CHECK_COMPILE_FLAG([-Wdiv-by-zero], [CFLAGS="$CFLAGS -Wdiv-by-zero"])
 198 AX_CHECK_COMPILE_FLAG([-Wsometimes-uninitialized], [CFLAGS="$CFLAGS -Wsometimes-uninitialized"])
 199
 200 AC_ARG_VAR([CWFLAGS], [define to compilation flags for generating extra warnings])
 201
 202 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wall], [CWFLAGS="$CWFLAGS -Wall"])
 203 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wextra], [CWFLAGS="$CWFLAGS -Wextra"])
 204
 205 AC_MSG_CHECKING(for clang)
 206 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 207 #ifndef __clang__
 208 be sad
 209 #endif
 210 ]])],
 211   [AC_MSG_RESULT(yes)
 212    AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wno-unknown-warning-option],
 213      [CWFLAGS="$CWFLAGS -Wno-unknown-warning-option"])
 214   ],
 215   [AC_MSG_RESULT(no)
 216 ])
 217
 218 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wbad-function-cast], [CWFLAGS="$CWFLAGS -Wbad-function-cast"])
 219 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wcast-align], [CWFLAGS="$CWFLAGS -Wcast-align"])
 220 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wcast-qual], [CWFLAGS="$CWFLAGS -Wcast-qual"])
 221 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wchar-subscripts], [CWFLAGS="$CWFLAGS -Wchar-subscripts"])
 222 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wcomment], [CWFLAGS="$CWFLAGS -Wcomment"])
 223 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wfloat-equal], [CWFLAGS="$CWFLAGS -Wfloat-equal"])
 224 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wformat=2], [CWFLAGS="$CWFLAGS -Wformat=2"])
 225 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wimplicit], [CWFLAGS="$CWFLAGS -Wimplicit"])
 226 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wmissing-declarations], [CWFLAGS="$CWFLAGS -Wmissing-declarations"])
 227 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wmissing-prototypes], [CWFLAGS="$CWFLAGS -Wmissing-prototypes"])
 228 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wnormalized=id], [CWFLAGS="$CWFLAGS -Wnormalized=id"])
 229 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Woverride-init], [CWFLAGS="$CWFLAGS -Woverride-init"])
 230 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wparentheses], [CWFLAGS="$CWFLAGS -Wparentheses"])
 231 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wpointer-arith], [CWFLAGS="$CWFLAGS -Wpointer-arith"])
 232 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wredundant-decls], [CWFLAGS="$CWFLAGS -Wredundant-decls"])
 233 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wstrict-prototypes], [CWFLAGS="$CWFLAGS -Wstrict-prototypes"])
 234 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wswitch-enum], [CWFLAGS="$CWFLAGS -Wswitch-enum"])
 235 AX_CHECK_COMPILE_FLAG([$CWFLAGS -Wvariable-decl], [CWFLAGS="$CWFLAGS -Wvariable-decl"])
 236
 237 AX_CHECK_LINK_FLAG([-Wl,-z,relro], [LDFLAGS="$LDFLAGS -Wl,-z,relro"])
 238 AX_CHECK_LINK_FLAG([-Wl,-z,now], [LDFLAGS="$LDFLAGS -Wl,-z,now"])
 239 AX_CHECK_LINK_FLAG([-Wl,-z,noexecstack], [LDFLAGS="$LDFLAGS -Wl,-z,noexecstack"])
 240
 241 LT_INIT
 242 AC_SUBST(LIBTOOL_DEPS)
 243
 244 AC_ARG_VAR([AR], [path to the ar utility])
 245 AC_CHECK_TOOL([AR], [ar], [ar])
 246
 247 dnl Checks for headers
 248
 249 AS_IF([test "x$EMSCRIPTEN" = "x"],[
 250
 251   AC_MSG_CHECKING(for MMX instructions set)
 252   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 253 #pragma GCC target("mmx")
 254 #include <mmintrin.h>
 255 ]], [[ __m64 x = _mm_setzero_si64(); ]])],
 256     [AC_MSG_RESULT(yes)
 257      AC_DEFINE([HAVE_MMINTRIN_H], [1], [mmx is available])],
 258     [AC_MSG_RESULT(no)])
 259
 260   AC_MSG_CHECKING(for SSE2 instructions set)
 261   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 262 #pragma GCC target("sse2")
 263 #include <emmintrin.h>
 264 ]], [[ __m128d x = _mm_setzero_pd(); ]])],
 265     [AC_MSG_RESULT(yes)
 266      AC_DEFINE([HAVE_EMMINTRIN_H], [1], [sse2 is available])],
 267     [AC_MSG_RESULT(no)])
 268
 269   AC_MSG_CHECKING(for SSE3 instructions set)
 270   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 271 #pragma GCC target("sse3")
 272 #include <pmmintrin.h>
 273 ]], [[ __m128 x = _mm_addsub_ps(_mm_cvtpd_ps(_mm_setzero_pd()),
 274                                 _mm_cvtpd_ps(_mm_setzero_pd())); ]])],
 275     [AC_MSG_RESULT(yes)
 276      AC_DEFINE([HAVE_PMMINTRIN_H], [1], [sse3 is available])],
 277     [AC_MSG_RESULT(no)])
 278
 279   AC_MSG_CHECKING(for SSSE3 instructions set)
 280   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 281 #pragma GCC target("ssse3")
 282 #include <tmmintrin.h>
 283 ]], [[ __m64 x = _mm_abs_pi32(_m_from_int(0)); ]])],
 284     [AC_MSG_RESULT(yes)
 285      AC_DEFINE([HAVE_TMMINTRIN_H], [1], [ssse3 is available])],
 286     [AC_MSG_RESULT(no)])
 287 ])
 288
 289 AC_CHECK_HEADERS([sys/mman.h])
 290
 291 dnl Checks for typedefs, structures, and compiler characteristics.
 292
 293 AC_C_INLINE
 294 AC_C_BIGENDIAN(
 295   AC_DEFINE(NATIVE_BIG_ENDIAN, 1, [machine is bigendian]),
 296   AC_DEFINE(NATIVE_LITTLE_ENDIAN, 1, [machine is littleendian]),
 297   AC_MSG_ERROR([unknown endianess]),
 298   AC_MSG_ERROR([universal endianess is not supported - compile separately and use lipo(1)])
 299 )
 300
 301 AC_MSG_CHECKING(whether __STDC_LIMIT_MACROS is required)
 302 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 303 #include <limits.h>
 304 #include <stdint.h>
 305 ]], [[
 306 (void) SIZE_MAX;
 307 (void) UINT64_MAX;
 308 ]])],
 309   [AC_MSG_RESULT(no)],
 310   [AC_MSG_RESULT(yes)
 311    CPPFLAGS="$CPPFLAGS -D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 312 ])
 313
 314 HAVE_AMD64_ASM_V=0
 315 AS_IF([test "$enable_asm" != "no"],[
 316   AC_MSG_CHECKING(whether we should use x86_64 asm code)
 317   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 318   ]], [[
 319 #if defined(__amd64) || defined(__amd64__) || defined(__x86_64__)
 320 # if defined(__CYGWIN__) || defined(__MINGW32__) || defined(__MINGW64__) || defined(_WIN32) || defined(_WIN64)
 321 #  error Windows x86_64 calling conventions are not supported yet
 322 # endif
 323 /* neat */
 324 #else
 325 # error !x86_64
 326 #endif
 327 __asm__("pxor %xmm12,%xmm6");
 328 ]])],
 329   [AC_MSG_RESULT(yes)
 330    AC_DEFINE([HAVE_AMD64_ASM], [1], [x86_64 asm code should be used])
 331    HAVE_AMD64_ASM_V=1],
 332   [AC_MSG_RESULT(no)])
 333 ])
 334 AM_CONDITIONAL([HAVE_AMD64_ASM], [test $HAVE_AMD64_ASM_V = 1])
 335 AC_SUBST(HAVE_AMD64_ASM_V)
 336
 337 AC_MSG_CHECKING(for 128-bit arithmetic)
 338 HAVE_TI_MODE_V=0
 339 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 340 #ifndef __GNUC__
 341 # error mode(TI) is a gcc extension
 342 #endif
 343 #if defined(__clang__) && !defined(__x86_64__)
 344 # error clang doesn't properly compile smult_curve25519_donna_c64.c
 345 #endif
 346 #ifndef NATIVE_LITTLE_ENDIAN
 347 # error donna_c64 currently requires a little endian CPU
 348 #endif
 349 #ifdef EMSCRIPTEN
 350 # error emscripten currently supports only shift operations on integers \
 351 #       larger than 64 bits
 352 #endif
 353 #include <stdint.h>
 354 typedef unsigned uint128_t __attribute__((mode(TI)));
 355 void fcontract(uint128_t *t) {
 356   *t += 0x8000000000000 - 1;
 357 }
 358 ]], [[
 359 (void) fcontract;
 360 ]])],
 361 [AC_MSG_RESULT(yes)
 362  AC_DEFINE([HAVE_TI_MODE], [1], [gcc TI mode is available])
 363  HAVE_TI_MODE_V=1],
 364 [AC_MSG_RESULT(no)])
 365 AM_CONDITIONAL([HAVE_TI_MODE], [test $HAVE_TI_MODE_V = 1])
 366 AC_SUBST(HAVE_TI_MODE_V)
 367
 368 HAVE_CPUID_V=0
 369 AS_IF([test "$enable_asm" != "no"],[
 370   AC_MSG_CHECKING(for cpuid instruction)
 371   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ ]], [[
 372 unsigned int cpu_info[4];
 373 __asm__ __volatile__ ("xchgl %%ebx, %k1; cpuid; xchgl %%ebx, %k1" :
 374                       "=a" (cpu_info[0]), "=&r" (cpu_info[1]),
 375                       "=c" (cpu_info[2]), "=d" (cpu_info[3]) :
 376                       "0" (0U), "2" (0U));
 377   ]])],
 378   [AC_MSG_RESULT(yes)
 379    AC_DEFINE([HAVE_CPUID], [1], [cpuid instruction is available])
 380    HAVE_CPUID_V=1],
 381   [AC_MSG_RESULT(no)])
 382   ])
 383 AC_SUBST(HAVE_CPUID_V)
 384
 385 AC_MSG_CHECKING(if weak symbols are supported)
 386 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 387 __attribute__((weak)) void __dummy(void *x) { }
 388 void f(void *x) { __dummy(x); }
 389 ]], [[ ]]
 390 )],
 391 [AC_MSG_RESULT(yes)
 392  AC_DEFINE([HAVE_WEAK_SYMBOLS], [1], [weak symbols are supported])],
 393 [AC_MSG_RESULT(no)])
 394
 395 AS_CASE([$host_cpu],
 396   [i*86 | x86_64 | powerpc* | s390*],
 397     [AC_MSG_NOTICE([data alignment is not required on this target])],
 398   [*],
 399     [AC_MSG_NOTICE([data alignment is required on this target])
 400      AC_DEFINE([CPU_ALIGNED_ACCESS_REQUIRED], [1], [data alignment is required])]
 401 )
 402
 403 dnl Checks for functions and headers
 404
 405 AS_IF([test "x$EMSCRIPTEN" = "x"],[
 406   AC_CHECK_FUNCS([arc4random arc4random_buf])
 407 ])
 408 AC_CHECK_FUNCS([mlock mprotect explicit_bzero posix_memalign])
 409
 410 AC_SUBST([LIBTOOL_EXTRA_FLAGS])
 411
 412 dnl Libtool.
 413
 414 LT_INIT([dlopen])
 415 AC_LIBTOOL_WIN32_DLL
 416 gl_LD_OUTPUT_DEF
 417
 418 dnl Output.
 419
 420 AH_VERBATIM([NDEBUG], [/* Always evaluate assert() calls */
 421 #ifdef NDEBUG
 422 #/**/undef/**/ NDEBUG
 423 #endif])
 424
 425 AS_IF([test "x$PKG_CONFIG" != "x"], [
 426   AC_CONFIG_FILES([libsodium.pc])
 427 ])
 428 AC_CONFIG_FILES([Makefile
 429                  dist-build/Makefile
 430                  msvc-scripts/Makefile
 431                  src/Makefile
 432                  src/libsodium/Makefile
 433                  src/libsodium/include/Makefile
 434                  src/libsodium/include/sodium/version.h
 435                  test/default/Makefile
 436                  test/Makefile
 437                  ])
 438 AC_OUTPUT