configure.in

   1 dnl
   2 dnl autoconf input file to generate MCONFIG
   3 dnl
   4
   5 AC_PREREQ(2.61)
   6 AC_INIT(MCONFIG.in)
   7 AC_PREFIX_DEFAULT(/usr)
   8
   9 AC_USE_SYSTEM_EXTENSIONS
  10 AC_ISC_POSIX
  11 AC_PROG_CC
  12
  13 AC_C_CONST
  14 AC_C_INLINE
  15
  16 PA_ADD_CFLAGS(-W)
  17 PA_ADD_CFLAGS(-Wall)
  18 PA_ADD_CFLAGS(-Wpointer-arith)
  19 PA_ADD_CFLAGS(-Wbad-function-cast)
  20 PA_ADD_CFLAGS(-Wcast-equal)
  21 PA_ADD_CFLAGS(-Wstrict-prototypes)
  22 PA_ADD_CFLAGS(-Wmissing-prototypes)
  23 PA_ADD_CFLAGS(-Wmissing-declarations)
  24 PA_ADD_CFLAGS(-Wnested-externs)
  25 PA_ADD_CFLAGS(-Winline)
  26 PA_ADD_CFLAGS(-Wwrite-strings)
  27 PA_ADD_CFLAGS(-Wundef)
  28 PA_ADD_CFLAGS(-Wshadow)
  29 PA_ADD_CFLAGS(-Wsign-compare)
  30 PA_ADD_CFLAGS(-pipe)
  31 PA_ADD_CFLAGS(-fno-strict-aliasing)
  32
  33 AC_HEADER_STDC
  34 AC_CHECK_HEADERS(inttypes.h)
  35 AC_CHECK_HEADERS(stdint.h)
  36 PA_CHECK_INTTYPES_H_SANE
  37 AC_CHECK_HEADERS(fcntl.h)
  38 AC_CHECK_HEADERS(grp.h)
  39 AC_CHECK_HEADERS(libgen.h)
  40 AC_CHECK_HEADERS(memory.h)
  41 AC_CHECK_HEADERS(setjmp.h)
  42 AC_CHECK_HEADERS(stddef.h)
  43 AC_CHECK_HEADERS(stdlib.h)
  44 AC_CHECK_HEADERS(string.h)
  45 AC_CHECK_HEADERS(strings.h)
  46 AC_CHECK_HEADERS(sysexits.h)
  47 AC_CHECK_HEADERS(time.h)
  48 AC_CHECK_HEADERS(unistd.h)
  49 AC_CHECK_HEADERS(sys/filio.h)
  50 AC_CHECK_HEADERS(sys/stat.h)
  51 AC_CHECK_HEADERS(sys/time.h)
  52 AC_CHECK_HEADERS(sys/types.h)
  53 AC_CHECK_HEADERS(arpa/inet.h)
  54 AC_CHECK_HEADERS(netdb.h)
  55 AC_HEADER_TIME
  56 dnl This is needed on some versions of FreeBSD...
  57 AC_CHECK_HEADERS(machine/param.h)
  58 AC_CHECK_HEADERS(sys/socket.h)
  59 AC_CHECK_HEADERS(winsock2.h)
  60 AC_CHECK_HEADERS(winsock.h)
  61
  62 AC_SYS_LARGEFILE
  63
  64 AC_TYPE_OFF_T
  65 AC_TYPE_PID_T
  66 AC_TYPE_MODE_T
  67 AC_TYPE_SIZE_T
  68 AC_CHECK_TYPES(intmax_t)
  69 AC_CHECK_TYPES(long long)
  70 AC_CHECK_TYPES(uint16_t)
  71 AC_CHECK_TYPES(uint32_t)
  72 AC_CHECK_TYPES(u_short)
  73 AC_CHECK_TYPES(u_long)
  74
  75 dnl
  76 dnl <sys/socket.h> isn't among the list of standard headers that autoconf checks,
  77 dnl but POSIX requires <sys/socket.h> for socklen_t to be defined.
  78 dnl
  79 AC_CHECK_TYPES(socklen_t,,,
  80 [
  81 #include <stdio.h>
  82 #if HAVE_SYS_TYPES_H
  83 # include <sys/types.h>
  84 #endif
  85 #if HAVE_SYS_STAT_H
  86 # include <sys/stat.h>
  87 #endif
  88 #if STDC_HEADERS
  89 # include <stdlib.h>
  90 # include <stddef.h>
  91 #else
  92 # if HAVE_STDLIB_H
  93 #  include <stdlib.h>
  94 # endif
  95 #endif
  96 #if HAVE_STRING_H
  97 # if !STDC_HEADERS && HAVE_MEMORY_H
  98 #  include <memory.h>
  99 # endif
 100 # include <string.h>
 101 #endif
 102 #if HAVE_STRINGS_H
 103 # include <strings.h>
 104 #endif
 105 #if HAVE_INTTYPES_H
 106 # include <inttypes.h>
 107 #else
 108 # if HAVE_STDINT_H
 109 #  include <stdint.h>
 110 # endif
 111 #endif
 112 #if HAVE_UNISTD_H
 113 # include <unistd.h>
 114 #endif
 115 #ifdef HAVE_SYS_SOCKET_H
 116 # include <sys/socket.h>
 117 #endif
 118 ])
 119
 120 AC_SEARCH_LIBS(socket, [socket ws2_32 wsock32], , [AC_MSG_ERROR(socket library not found)])
 121
 122 AC_CHECK_FUNCS(fcntl)
 123 AC_CHECK_FUNCS(setsid)
 124 AC_CHECK_FUNCS(recvmsg)
 125 AC_CHECK_FUNCS(ftruncate)
 126 AC_CHECK_FUNCS(setreuid)
 127 AC_CHECK_FUNCS(setregid)
 128 AC_CHECK_FUNCS(initgroups)
 129 AC_CHECK_FUNCS(setgroups)
 130
 131 dnl Solaris 8 has [u]intmax_t but not strtoumax().  How utterly braindamaged.
 132 AC_CHECK_FUNCS(strtoumax)
 133 AC_CHECK_FUNCS(strtoull)
 134
 135 PA_MSGHDR_MSG_CONTROL
 136 PA_STRUCT_IN_PKTINFO
 137 PA_STRUCT_ADDRINFO
 138
 139 PA_HEADER_DEFINES(fcntl.h, int, O_NONBLOCK)
 140 PA_HEADER_DEFINES(fcntl.h, int, O_BINARY)
 141 PA_HEADER_DEFINES(fcntl.h, int, O_TEXT)
 142
 143 AH_TEMPLATE([HAVE_SIGSETJMP],
 144 [Define if we have sigsetjmp, siglongjmp and sigjmp_buf.])
 145 PA_SIGSETJMP([AC_DEFINE(HAVE_SIGSETJMP)])
 146
 147 dnl
 148 dnl Get common paths
 149 dnl
 150 SRCROOT=`cd $srcdir && pwd`
 151 OBJROOT=`pwd`
 152
 153 XTRA=false
 154 PA_SEARCH_LIBS_AND_ADD(xmalloc, iberty)
 155 PA_SEARCH_LIBS_AND_ADD(xstrdup, iberty)
 156 PA_SEARCH_LIBS_AND_ADD(bsd_signal, bsd, bsdsignal)
 157 PA_SEARCH_LIBS_AND_ADD(getopt_long, getopt, getopt_long)
 158 PA_SEARCH_LIBS_AND_ADD(getaddrinfo, [nsl resolv])
 159 if $pa_add_getaddrinfo
 160 then
 161     AC_SEARCH_LIBS(gethostbyname, [nsl resolv],
 162       [AC_SEARCH_LIBS(herror, [nsl resolv], ,
 163          [AC_MSG_ERROR(herror not found)])],
 164       [AC_MSG_ERROR(gethostbyname not found)])
 165 else
 166     AC_SEARCH_LIBS(freeaddrinfo, [nsl resolv], ,
 167       [AC_MSG_ERROR(getaddrinfo but not freeaddrinfo found)])
 168     AC_SEARCH_LIBS(gai_strerror, [nsl resolv], ,
 169       [AC_MSG_ERROR(getaddrinfo but not gai_strerror found)])
 170 fi
 171
 172 PA_SEARCH_LIBS_AND_ADD(inet_ntop, [nsl resolv])
 173 if $pa_add_inet_ntop
 174 then
 175     AC_SEARCH_LIBS(inet_ntoa, [nsl resolv], ,
 176       [AC_MSG_ERROR(inet_ntoa not found)])
 177 fi
 178
 179 AC_CHECK_FUNCS(daemon, , [XTRA=true; AC_LIBOBJ(daemon)])
 180 AC_CHECK_FUNCS(dup2, , [XTRA=true; AC_LIBOBJ(dup2)])
 181 if $XTRA
 182 then
 183   XTRALIBS="$OBJROOT/lib/libxtra.a $XTRALIBS"
 184 fi
 185
 186 dnl
 187 dnl These libraries apply to the server only
 188 dnl
 189
 190 common_libs="$LIBS"
 191
 192 PA_HEADER_DEFINES(netinet/in.h, int, IPPORT_TFTP)
 193
 194 PA_WITH_BOOL(tcpwrappers, 1,
 195 [  --without-tcpwrappers   disable tcpwrapper permissions checking],
 196 [
 197         AC_SEARCH_LIBS(yp_get_default_domain, [nsl resolv])
 198         PA_HAVE_TCPWRAPPERS
 199 ],:)
 200
 201
 202 AH_TEMPLATE([WITH_REGEX],
 203 [Define if we are compiling with regex filename remapping.])
 204
 205 PA_WITH_BOOL(remap, 1,
 206 [  --without-remap         disable regex-based filename remapping],
 207 [
 208         AC_CHECK_HEADER(regex.h,
 209         [
 210                 AC_SEARCH_LIBS(regcomp, [regex rx],
 211                 [
 212                         AC_DEFINE(WITH_REGEX)
 213                         TFTPDOBJS="remap.${OBJEXT} $TFTPDOBJS"
 214                 ])
 215         ])
 216 ],:)
 217
 218 TFTPD_LIBS="$LIBS $XTRALIBS"
 219 LIBS="$common_libs"
 220
 221 dnl
 222 dnl These libraries apply to the client only
 223 dnl
 224
 225 AH_TEMPLATE([WITH_READLINE],
 226 [Define if we are compiling with readline command-line editing.])
 227
 228 PA_WITH_BOOL(readline, 1,
 229 [  --without-readline      disable the use of readline command-line editing],
 230 [
 231         AC_CHECK_HEADER(readline/readline.h,
 232         [
 233                 dnl readline may need libtermcap or somesuch...
 234                 AC_SEARCH_LIBS(tputs, [termcap terminfo])
 235
 236                 AC_SEARCH_LIBS(readline, [readline history],
 237                 [
 238                         AC_DEFINE(WITH_READLINE)
 239                 ],
 240                 [],
 241                 [-ltermcap])
 242                 AC_CHECK_HEADERS(readline/history.h)
 243         ])
 244 ],:)
 245
 246 TFTP_LIBS="$LIBS $XTRALIBS"
 247 LIBS="$common_libs"
 248
 249 dnl
 250 dnl   Check for IPV6 and disable-ipv6
 251 dnl
 252 PA_STRUCT_SOCKADDR_IN6
 253 AC_MSG_CHECKING([for IPv6 support])
 254 PA_WITH_BOOL(ipv6, 1,
 255 [  --without-ipv6      disable the support for IPv6],
 256 [
 257     if  $HAVE_INET6
 258     then
 259         AC_MSG_RESULT(yes)
 260         AC_DEFINE(HAVE_IPV6, 1, [Define if IPv6 support is enabled.])
 261         PA_STRUCT_IN6_PKTINFO
 262     else
 263         AC_MSG_RESULT(no)
 264         AC_MSG_WARN([*** we do not have required IPv6 structs - IPv6 will be disabled])
 265     fi
 266 ],
 267 [AC_MSG_RESULT(disabled)])
 268
 269
 270 AC_SUBST(SRCROOT)
 271 AC_SUBST(OBJROOT)
 272
 273 AC_SUBST(TFTP_LIBS)
 274 AC_SUBST(TFTPD_LIBS)
 275 AC_SUBST(TFTPDOBJS)
 276
 277 AC_PROG_LN_S
 278 AC_PROG_RANLIB
 279
 280 dnl
 281 dnl Make sure the install program has an absolute path if it
 282 dnl has a path at all.  autoconf doesn't do this "in order
 283 dnl to not pollute the cache."  Sigh.
 284 dnl Note: the $ needs to be double-quoted for reasons unknown.
 285 dnl
 286 AC_PROG_INSTALL
 287 [if echo "$INSTALL" | grep '^[^/].*/' > /dev/null 2>&1; then
 288    INSTALL='\${SRCROOT}'/"$INSTALL"
 289 fi]
 290
 291 AC_CONFIG_HEADERS(aconfig.h)
 292 AC_OUTPUT(MCONFIG)