aclocal.m4

   1 # generated automatically by aclocal 1.10 -*- Autoconf -*-
   2
   3 # Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 # 2005, 2006  Free Software Foundation, Inc.
   5 # This file is free software; the Free Software Foundation
   6 # gives unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
  11 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
  12 # PARTICULAR PURPOSE.
  13
  14 # pkg.m4 - Macros to locate and utilise pkg-config.            -*- Autoconf -*-
  15 #
  16 # Copyright © 2004 Scott James Remnant <scott@netsplit.com>.
  17 #
  18 # This program is free software; you can redistribute it and/or modify
  19 # it under the terms of the GNU General Public License as published by
  20 # the Free Software Foundation; either version 2 of the License, or
  21 # (at your option) any later version.
  22 #
  23 # This program is distributed in the hope that it will be useful, but
  24 # WITHOUT ANY WARRANTY; without even the implied warranty of
  25 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  26 # General Public License for more details.
  27 #
  28 # You should have received a copy of the GNU General Public License
  29 # along with this program; if not, write to the Free Software
  30 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  31 #
  32 # As a special exception to the GNU General Public License, if you
  33 # distribute this file as part of a program that contains a
  34 # configuration script generated by Autoconf, you may include it under
  35 # the same distribution terms that you use for the rest of that program.
  36
  37 # PKG_PROG_PKG_CONFIG([MIN-VERSION])
  38 # ----------------------------------
  39 AC_DEFUN([PKG_PROG_PKG_CONFIG],
  40 [m4_pattern_forbid([^_?PKG_[A-Z_]+$])
  41 m4_pattern_allow([^PKG_CONFIG(_PATH)?$])
  42 AC_ARG_VAR([PKG_CONFIG], [path to pkg-config utility])dnl
  43 if test "x$ac_cv_env_PKG_CONFIG_set" != "xset"; then
  44         AC_PATH_TOOL([PKG_CONFIG], [pkg-config])
  45 fi
  46 if test -n "$PKG_CONFIG"; then
  47         _pkg_min_version=m4_default([$1], [0.9.0])
  48         AC_MSG_CHECKING([pkg-config is at least version $_pkg_min_version])
  49         if $PKG_CONFIG --atleast-pkgconfig-version $_pkg_min_version; then
  50                 AC_MSG_RESULT([yes])
  51         else
  52                 AC_MSG_RESULT([no])
  53                 PKG_CONFIG=""
  54         fi
  55
  56 fi[]dnl
  57 ])# PKG_PROG_PKG_CONFIG
  58
  59 # PKG_CHECK_EXISTS(MODULES, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
  60 #
  61 # Check to see whether a particular set of modules exists.  Similar
  62 # to PKG_CHECK_MODULES(), but does not set variables or print errors.
  63 #
  64 #
  65 # Similar to PKG_CHECK_MODULES, make sure that the first instance of
  66 # this or PKG_CHECK_MODULES is called, or make sure to call
  67 # PKG_CHECK_EXISTS manually
  68 # --------------------------------------------------------------
  69 AC_DEFUN([PKG_CHECK_EXISTS],
  70 [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
  71 if test -n "$PKG_CONFIG" && \
  72     AC_RUN_LOG([$PKG_CONFIG --exists --print-errors "$1"]); then
  73   m4_ifval([$2], [$2], [:])
  74 m4_ifvaln([$3], [else
  75   $3])dnl
  76 fi])
  77
  78
  79 # _PKG_CONFIG([VARIABLE], [COMMAND], [MODULES])
  80 # ---------------------------------------------
  81 m4_define([_PKG_CONFIG],
  82 [if test -n "$PKG_CONFIG"; then
  83     if test -n "$$1"; then
  84         pkg_cv_[]$1="$$1"
  85     else
  86         PKG_CHECK_EXISTS([$3],
  87                          [pkg_cv_[]$1=`$PKG_CONFIG --[]$2 "$3" 2>/dev/null`],
  88                          [pkg_failed=yes])
  89     fi
  90 else
  91         pkg_failed=untried
  92 fi[]dnl
  93 ])# _PKG_CONFIG
  94
  95 # _PKG_SHORT_ERRORS_SUPPORTED
  96 # -----------------------------
  97 AC_DEFUN([_PKG_SHORT_ERRORS_SUPPORTED],
  98 [AC_REQUIRE([PKG_PROG_PKG_CONFIG])
  99 if $PKG_CONFIG --atleast-pkgconfig-version 0.20; then
 100         _pkg_short_errors_supported=yes
 101 else
 102         _pkg_short_errors_supported=no
 103 fi[]dnl
 104 ])# _PKG_SHORT_ERRORS_SUPPORTED
 105
 106
 107 # PKG_CHECK_MODULES(VARIABLE-PREFIX, MODULES, [ACTION-IF-FOUND],
 108 # [ACTION-IF-NOT-FOUND])
 109 #
 110 #
 111 # Note that if there is a possibility the first call to
 112 # PKG_CHECK_MODULES might not happen, you should be sure to include an
 113 # explicit call to PKG_PROG_PKG_CONFIG in your configure.ac
 114 #
 115 #
 116 # --------------------------------------------------------------
 117 AC_DEFUN([PKG_CHECK_MODULES],
 118 [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 119 AC_ARG_VAR([$1][_CFLAGS], [C compiler flags for $1, overriding pkg-config])dnl
 120 AC_ARG_VAR([$1][_LIBS], [linker flags for $1, overriding pkg-config])dnl
 121
 122 pkg_failed=no
 123 AC_MSG_CHECKING([for $1])
 124
 125 _PKG_CONFIG([$1][_CFLAGS], [cflags], [$2])
 126 _PKG_CONFIG([$1][_LIBS], [libs], [$2])
 127
 128 m4_define([_PKG_TEXT], [Alternatively, you may set the environment variables $1[]_CFLAGS
 129 and $1[]_LIBS to avoid the need to call pkg-config.
 130 See the pkg-config man page for more details.])
 131
 132 if test $pkg_failed = yes; then
 133         _PKG_SHORT_ERRORS_SUPPORTED
 134         if test $_pkg_short_errors_supported = yes; then
 135                 $1[]_PKG_ERRORS=`$PKG_CONFIG --short-errors --errors-to-stdout --print-errors "$2"`
 136         else
 137                 $1[]_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
 138         fi
 139         # Put the nasty error message in config.log where it belongs
 140         echo "$$1[]_PKG_ERRORS" >&AS_MESSAGE_LOG_FD
 141
 142         ifelse([$4], , [AC_MSG_ERROR(dnl
 143 [Package requirements ($2) were not met:
 144
 145 $$1_PKG_ERRORS
 146
 147 Consider adjusting the PKG_CONFIG_PATH environment variable if you
 148 installed software in a non-standard prefix.
 149
 150 _PKG_TEXT
 151 ])],
 152                 [AC_MSG_RESULT([no])
 153                 $4])
 154 elif test $pkg_failed = untried; then
 155         ifelse([$4], , [AC_MSG_FAILURE(dnl
 156 [The pkg-config script could not be found or is too old.  Make sure it
 157 is in your PATH or set the PKG_CONFIG environment variable to the full
 158 path to pkg-config.
 159
 160 _PKG_TEXT
 161
 162 To get pkg-config, see <http://pkg-config.freedesktop.org/>.])],
 163                 [$4])
 164 else
 165         $1[]_CFLAGS=$pkg_cv_[]$1[]_CFLAGS
 166         $1[]_LIBS=$pkg_cv_[]$1[]_LIBS
 167         AC_MSG_RESULT([yes])
 168         ifelse([$3], , :, [$3])
 169 fi[]dnl
 170 ])# PKG_CHECK_MODULES
 171