configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 dnl Need autoconf 2.50 or later for AC_ARG_VAR.  2.59 has been around for
   4 dnl long enough, that we might as well just require that.
   5 AC_PREREQ(2.59)
   6 AC_INIT([survex], [1.4.5], [https://trac.survex.com/])
   7 AM_INIT_AUTOMAKE([1.5 gnu -Wall -Wportability -Werror])
   8 RELEASE=1
   9
  10 AC_SUBST(RELEASE)
  11 AC_CONFIG_HEADERS([config.h])
  12 AC_CONFIG_SRCDIR([src/aven.cc])
  13
  14 COPYRIGHT_MSG="Copyright (C) 1990-2023 Olly Betts"
  15 AVEN_COPYRIGHT_MSG="Copyright (C) 1999-2003,2005,2006 Mark R. Shinwell"
  16
  17 AC_DEFINE_UNQUOTED(COPYRIGHT_MSG, ["$COPYRIGHT_MSG"], [Copyright Message])
  18 AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG, ["$AVEN_COPYRIGHT_MSG"],
  19                    [Copyright Message for Aven])
  20
  21 AC_SUBST(COPYRIGHT_MSG)
  22 AC_SUBST(AVEN_COPYRIGHT_MSG)
  23
  24 COPYRIGHT_MSG_UTF8=`echo "$COPYRIGHT_MSG"|sed 's/(C)/©/'`
  25 AVEN_COPYRIGHT_MSG_UTF8=`echo "$AVEN_COPYRIGHT_MSG"|sed 's/(C)/©/'`
  26
  27 AC_DEFINE_UNQUOTED(COPYRIGHT_MSG_UTF8, ["$COPYRIGHT_MSG_UTF8"],
  28                    [Copyright Message in UTF-8])
  29 AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG_UTF8, ["$AVEN_COPYRIGHT_MSG_UTF8"],
  30                    [Copyright Message for Aven in UTF-8])
  31
  32 dnl set PRETTYPACKAGE to PACKAGE with the first character capitalised
  33 PRETTYPACKAGE=`echo "$PACKAGE"|cut -b1|tr a-z A-Z``echo "$PACKAGE"|cut -b2-`
  34 AC_DEFINE_UNQUOTED(PRETTYPACKAGE, "$PRETTYPACKAGE",
  35                    [Name of package (capitalised)])
  36 AC_SUBST(PRETTYPACKAGE)
  37
  38 dnl set COMMAVERSION to VERSION with the dots replaced by commas -
  39 dnl e.g. "0,99" or "1,0,22"
  40 COMMAVERSION=`echo "$VERSION"|tr '.' ','`
  41 AC_DEFINE_UNQUOTED(COMMAVERSION, $COMMAVERSION,
  42                    [Version number of package (comma-separated)])
  43 AC_SUBST(COMMAVERSION)
  44
  45 PKGDOCDIR='${prefix}/share/doc/${PACKAGE}'
  46 AC_ARG_ENABLE(docdir,
  47 [  --enable-docdir=DIR Set directory for installing documentation to DIR],
  48 [case $enableval in
  49  yes|no)
  50   AC_MSG_ERROR([configure: Syntax: configure --enable-docdir=DIR]) ;;
  51 esac
  52 PKGDOCDIR="$enableval"
  53 ]
  54 )
  55 PKGDOCDIR_EXPANDED=`(
  56  test NONE = "$prefix" && prefix="$ac_default_prefix"
  57  test NONE = "$exec_prefix" && exec_prefix="$prefix"
  58  eval echo "$PKGDOCDIR"
  59 )`
  60 AC_SUBST(PKGDOCDIR)
  61 AC_SUBST(PKGDOCDIR_EXPANDED)
  62
  63 AC_CANONICAL_HOST
  64
  65 dnl Checks for programs.
  66 AC_PROG_CC
  67 AC_PROG_CPP
  68
  69 AC_PROG_CXX
  70 AC_PROG_CXXCPP
  71
  72 dnl Probe for any options needed to enable C++11 support.
  73 AX_CXX_COMPILE_STDCXX_11
  74
  75 AM_PROG_CC_C_O
  76
  77 AC_LANG([C])
  78
  79 AC_C_INLINE
  80
  81 AC_EXEEXT
  82 AC_OBJEXT
  83
  84 mswindows=no
  85 macos=no
  86 case $host_os in
  87 darwin*) macos=yes ;;
  88 *mingw*|*cygwin*|windows*) mswindows=yes ;;
  89 esac
  90
  91 AC_C_BIGENDIAN
  92
  93 AC_ARG_VAR(STRIP, [Command for discarding symbols from object files])
  94 AC_PATH_TOOL(STRIP, strip, [echo "not stripping "])
  95
  96 AC_CHECK_LIB(m, sqrt)
  97
  98 AC_PATH_XTRA
  99
 100 dnl The wxWidgets libraries we need:
 101 wx_libs="core,gl,html"
 102
 103 AC_ARG_VAR(WXCONFIG, [Old name for WX_CONFIG, accepted for compatibility])
 104 AC_ARG_VAR(WX_CONFIG, [wxWidgets configuration script to use to build Aven])
 105 : ${WX_CONFIG="$WXCONFIG"}
 106
 107 AM_CONDITIONAL(WIN32, [test yes = "$mswindows"])
 108 AM_CONDITIONAL(MACOS, [test yes = "$macos"])
 109
 110 if test -n "$WX_CONFIG" ; then
 111   dnl WX_CONFIG specified - sanity check the value
 112   dnl don't check for --ldflags - older wx-config didn't do that
 113   if (exec >&5 2>&5;$WX_CONFIG --libs --cflags --cxxflags "$wx_libs";exit $?) then
 114     :
 115   else
 116     AC_MSG_ERROR(['$WX_CONFIG --libs --cflags --cxxflags "$wx_libs"' does not work, bailing out])
 117   fi
 118 else
 119   if test yes = "$macos" ; then
 120     wxdef=__WXMAC__
 121   elif test yes = "$mswindows" ; then
 122     wxdef=__WXMSW__
 123   else
 124     wxdef=__WXGTK__
 125   fi
 126   dnl See if wx-config exists and is for the correct version.
 127   dnl Fedora install wx3's wx-config as wx-config-3.0, so look for that in
 128   dnl preference.
 129   dnl Arch Linux uses wx-config-gtk3.
 130   AC_PATH_PROGS(WX_CONFIG, [wx-config-3.0 wx-config-gtk3 wx-config])
 131   if test -n "$WX_CONFIG" ; then
 132     if (exec >&5 2>&5;$WX_CONFIG --cflags "$wx_libs"|grep -e -D"$wxdef";exit $?) then
 133       :
 134     else
 135       AC_MSG_ERROR([wxWidgets not for the right toolkit.  Run ./configure WX_CONFIG=/path/to/wx-config])
 136     fi
 137   else
 138     AC_MSG_ERROR([wxWidgets not found.  Run ./configure WX_CONFIG=/path/to/wx-config])
 139   fi
 140 fi
 141
 142 dnl Unless the user has explicitly specified a --unicode setting, prefer
 143 dnl --unicode=yes if we can get it.
 144 case $WX_CONFIG in
 145   *--unicode=*) ;;
 146   *)
 147     if (exec >&5 2>&5;$WX_CONFIG --unicode=yes --version "$wx_libs";exit $?) ; then
 148       WX_CONFIG="$WX_CONFIG --unicode=yes"
 149     elif (exec >&5 2>&5;$WX_CONFIG --unicode=no --version "$wx_libs";exit $?) ; then
 150       WX_CONFIG="$WX_CONFIG --unicode=no"
 151     fi ;;
 152 esac
 153
 154 WX_LIBS=`$WX_CONFIG --libs "$wx_libs"`
 155 dnl Needed for nvidia drivers on linux (for some setups anyway).
 156 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryVersion, [WX_LIBS="$WX_LIBS -lXxf86vm"], [], [$WX_LIBS])
 157 dnl We use functions from libGLU so always link -lGLU explicitly if it's
 158 dnl present.
 159 AC_CHECK_LIB([GLU], [gluProject], [WX_LIBS="$WX_LIBS -lGLU"], [], [$WX_LIBS])
 160 dnl We use functions from libGL so always link -lGL explicitly if it's
 161 dnl present.
 162 AC_CHECK_LIB([GL], [glPushMatrix], [WX_LIBS="$WX_LIBS -lGL"], [], [$WX_LIBS])
 163 AC_SUBST(WX_LIBS)
 164 dnl macOS has OpenGL/gl.h.
 165 AC_CHECK_HEADERS([GL/gl.h OpenGL/gl.h], [], [], [ ])
 166 dnl The Debian mingw-w64 packages lack GL/glext.h; macOS has OpenGL/glext.h.
 167 AC_CHECK_HEADERS([GL/glext.h OpenGL/glext.h], [], [], [#include <GL/gl.h>])
 168
 169 WX_CFLAGS=`$WX_CONFIG --cflags "$wx_libs"`
 170 AC_SUBST(WX_CFLAGS)
 171 WX_CXXFLAGS=`$WX_CONFIG --cxxflags "$wx_libs"`
 172 AC_SUBST(WX_CXXFLAGS)
 173
 174 AC_LANG([C])
 175 save_CFLAGS=$CFLAGS
 176 CFLAGS="$CFLAGS $WX_CFLAGS"
 177 AC_CHECK_SIZEOF([wxChar], [], [
 178   #include <wx/defs.h>
 179   #include <wx/chartype.h>
 180 ])
 181 CFLAGS=$save_CFLAGS
 182
 183 dnl Check for libav (FIXME: does our code still work with ffmpeg?)
 184 PKG_CHECK_MODULES([LIBAV], [libavcodec libavformat libswscale libavutil], [
 185   AC_DEFINE([WITH_LIBAV], [1], [Use libav for movie export])
 186   save_CXXFLAGS=$CXXFLAGS
 187   save_LIBS=$LIBS
 188   CFLAGS="$CFLAGS $LIBAV_CFLAGS"
 189   LIBS="$LIBS $LIBAV_LIBS"
 190   AC_CHECK_FUNCS([av_guess_format avio_open avio_close avformat_write_header avcodec_encode_video2 avcodec_free_frame avcodec_open2 avformat_new_stream av_frame_alloc av_frame_free])
 191   AC_CHECK_DECLS([AVMEDIA_TYPE_VIDEO], [], [], [#include <libavcodec/avcodec.h>])
 192   AC_CHECK_DECLS([AV_CODEC_ID_NONE], [], [], [#include <libavcodec/avcodec.h>])
 193   AC_CHECK_DECLS([AV_PIX_FMT_RGB24], [], [], [#include <libavutil/pixfmt.h>])
 194   AC_CHECK_DECLS([AV_PIX_FMT_YUV420P], [], [], [#include <libavutil/pixfmt.h>])
 195   CXXFLAGS=$save_CXXFLAGS
 196   LIBS=$save_LIBS
 197 ], [
 198   dnl Build without movie export feature.
 199 ])
 200 AC_SUBST([LIBAV_LIBS])
 201 AC_SUBST([LIBAV_CFLAGS])
 202
 203 dnl Check for PROJ.
 204 PKG_CHECK_MODULES([PROJ], [proj >= 6.2.0], [
 205 ], [
 206   dnl pkg-config support in proj seems quite new, so probe directly if not
 207   dnl found.  We need proj_create_crs_to_crs_from_pj() which was added in
 208   dnl 6.2.0.
 209   AC_CHECK_LIB([proj], [proj_create_crs_to_crs_from_pj], [
 210       PROJ_LIBS=-lproj
 211       PROJ_CFLAGS=
 212     ], [
 213       AC_MSG_ERROR([PROJ required for coordinate transformations])
 214     ])
 215 ])
 216 AC_SUBST([PROJ_LIBS])
 217 AC_SUBST([PROJ_CFLAGS])
 218
 219 dnl Checks for header files.
 220
 221 dnl don't use AC_CHECK_FUNCS for setjmp - mingw #define-s it to _setjmp
 222 AC_CHECK_HEADERS(limits.h string.h setjmp.h sys/select.h)
 223
 224 dnl Checks for typedefs, structures, and compiler characteristics.
 225 AC_TYPE_SIZE_T
 226 AC_STRUCT_TM
 227
 228 dnl check if CLOCKS_PER_SEC is defined by time.h (as ANSI says it should be)
 229 dnl if it isn't, assume it is 1000000, as it is on SunOS 4
 230 AC_TRY_COMPILE([#include <time.h>],[
 231 #ifndef CLOCKS_PER_SEC
 232 choke me
 233 #endif
 234 ], , AC_DEFINE(CLOCKS_PER_SEC, 1000000, [For old systems which don't define it themselves]))
 235
 236 dnl Check for 16-bit and 32-bit integer types.
 237 AC_TYPE_INT16_T
 238 AC_TYPE_UINT16_T
 239 AC_TYPE_INT32_T
 240 AC_TYPE_UINT32_T
 241
 242 dnl Check if there's a declaration of lround().  Below we also check for
 243 dnl lround() with AC_CHECK_FUNCS, which just checks if it can be linked
 244 dnl against.  Some platforms are missing a prototype for lround(), so
 245 dnl both checks are useful.
 246 AC_CHECK_DECLS([lround], [], [], [[#include <math.h>]])
 247 dnl check for strcasecmp here as well as below - this one is to get
 248 dnl HAVE_STRCASECMP defined if appropriate (for img.c)
 249 AC_CHECK_FUNCS([popen getpwuid lround strcasecmp hypot mmap])
 250
 251 dnl Much faster than using getc()/putc(), at least on Linux.
 252 AC_CHECK_FUNCS([getc_unlocked putc_unlocked])
 253
 254 AC_CHECK_FUNCS([setenv unsetenv])
 255
 256 dnl try to find a case-insensitive compare
 257
 258 strcasecmp=no
 259 dnl The order of these tests is important.
 260 AC_CHECK_FUNC(strcasecmp, [strcasecmp=strcasecmp])
 261 if test no = "$strcasecmp"; then
 262   AC_CHECK_FUNC(stricmp, [strcasecmp=stricmp])
 263 fi
 264 if test no = "$strcasecmp"; then
 265   AC_CHECK_FUNC(strcmpi, [strcasecmp=strcmpi])
 266 fi
 267
 268 AC_MSG_CHECKING([how to compare strings ignoring case])
 269 case $strcasecmp in
 270 no)
 271   AC_LIBOBJ(strcasecmp)
 272   AC_MSG_RESULT([using own implementation of strcasecmp]) ;;
 273 strcasecmp)
 274   AC_MSG_RESULT([strcasecmp]) ;;
 275 *)
 276   AC_DEFINE_UNQUOTED(strcasecmp, "$strcasecmp",
 277     [strcasecmp define for systems which call it something else])
 278   AC_MSG_RESULT([$strcasecmp]) ;;
 279 esac
 280
 281 AC_PATH_PROG([JW], [jw], [$MISSING jw])
 282 AC_ARG_VAR([JW], [jw from docbook-utils/docbook-tools])
 283
 284 dnl extra warning flags for building with GCC
 285 if test yes = "$GCC"; then
 286   if test yes = "$cross_compiling"; then
 287 dnl    AM_CFLAGS="$AM_CFLAGS -Werror -Wall -Wunused -Wpointer-arith\
 288 dnl      -Wwrite-strings -Wcast-align"
 289 dnl -Wsign-compare causes a warning with the mingw FD_SET macro, so we have
 290 dnl to disable it for mingw builds.
 291     AM_CFLAGS="$AM_CFLAGS -Wall -Wunused -Wpointer-arith\
 292       -Wwrite-strings -Wcast-align"
 293     AM_CXXFLAGS="$AM_CXXFLAGS -Wall -Wunused -Wpointer-arith\
 294       -Wwrite-strings -Wcast-align -Wno-sign-compare"
 295   else
 296     AM_CFLAGS="$AM_CFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
 297       -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wnested-externs\
 298       -Wcast-align"
 299     AM_CXXFLAGS="$AM_CXXFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
 300       -Wwrite-strings -Wcast-align"
 301   fi
 302   dnl too many complaints from headers, etc: -Wconversion
 303 fi
 304 AC_SUBST(AM_CFLAGS)
 305 AC_SUBST(AM_CXXFLAGS)
 306
 307 dnl See if large file support is available.  Survex is unlikely to need to
 308 dnl process files > 2GB in size, but LFS is also needed for stat() to work
 309 dnl on filing systems which return 64 bit inode values, such as CIFS mounts.
 310 AC_SYS_LARGEFILE
 311
 312 AC_ARG_ENABLE(profiling,
 313 [  --enable-profiling Build binaries to generate profiling information],
 314 [case $enableval in
 315   yes) AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 316        AM_CFLAGS="$AM_CFLAGS -pg"
 317        AC_MSG_RESULT(building binaries to generate profiling information);;
 318   no) ;;
 319   *) AC_MSG_ERROR(bad value $enableval for --enable-profiling) ;;
 320 esac])
 321
 322 HTMLFILES="AUTHORS.htm HACKING.htm NEWS.htm OLDNEWS.htm TODO.htm index.htm 3dformat.htm 3dformat-old.htm"
 323 AC_SUBST(HTMLFILES)
 324
 325 EXTRA_TEXT="AUTHORS COPYING NEWS TODO ChangeLog"
 326 AC_SUBST(EXTRA_TEXT)
 327
 328 AC_SUBST_FILE(DESC)
 329 DESC=desc.txt
 330 AC_SUBST_FILE(AVENDESC)
 331 AVENDESC=desc-aven.txt
 332
 333 dnl Don't define DATADIR if building for MS Windows - it won't be used, and
 334 dnl can conflict with the DATADIR typedef in objidl.h
 335 if test no = "$mswindows"; then
 336   AC_DEFINE_DIR(DATADIR, datadir, [Location of platform independent support files])
 337 fi
 338
 339 AH_BOTTOM(
 340 [/* Use getc_unlocked() and putc_unlocked() where available, since they are
 341  * faster, and we don't multithread file accesses.
 342  */
 343
 344 #ifdef HAVE_GETC_UNLOCKED
 345 # define GETC(F) getc_unlocked(F)
 346 #else
 347 # define GETC(F) getc(F)
 348 #endif
 349 #ifdef HAVE_PUTC_UNLOCKED
 350 # define PUTC(C, F) putc_unlocked(C, F)
 351 #else
 352 # define PUTC(C, F) putc(C, F)
 353 #endif
 354
 355 #ifndef __cplusplus
 356 /* C23 added bool, false and true as keywords - let's emulate that and
 357  * avoid every C file which uses these needing to include <stdbool.h>.
 358  */
 359 # include <stdbool.h>
 360 #endif
 361 ])
 362
 363 AC_CONFIG_FILES([
 364  Makefile src/Makefile doc/Makefile lib/Makefile lib/icons/Makefile
 365  lib/images/Makefile
 366  tests/Makefile vim/Makefile survex.iss doc/index.htm doc/survex.7
 367  survex.spec lib/Info.plist
 368  ])
 369 AC_OUTPUT
 370 dnl FIXME update msvc makefile for 1.2 branch
 371 dnl src/msvc/config.h