configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 dnl Need autoconf 2.50 or later for AC_ARG_VAR.  2.59 has been around for
   4 dnl long enough, that we might as well just require that.
   5 AC_PREREQ(2.59)
   6 AC_INIT([survex], [1.2.25], [http://trac.survex.com/])
   7 AM_INIT_AUTOMAKE([1.5 gnu -Wall -Wportability -Werror])
   8 RELEASE=1
   9
  10 AC_SUBST(RELEASE)
  11 AC_CONFIG_HEADERS([config.h])
  12 AC_CONFIG_SRCDIR([src/aven.cc])
  13
  14 COPYRIGHT_MSG="Copyright (C) 1990-2016 Olly Betts"
  15 AVEN_COPYRIGHT_MSG="Copyright (C) 1999-2003,2005,2006 Mark R. Shinwell"
  16
  17 AC_DEFINE_UNQUOTED(COPYRIGHT_MSG, ["$COPYRIGHT_MSG"], [Copyright Message])
  18 AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG, ["$AVEN_COPYRIGHT_MSG"],
  19                    [Copyright Message for Aven])
  20
  21 AC_SUBST(COPYRIGHT_MSG)
  22 AC_SUBST(AVEN_COPYRIGHT_MSG)
  23
  24 COPYRIGHT_MSG_UTF8=`echo "$COPYRIGHT_MSG"|sed 's/(C)/©/'`
  25 AVEN_COPYRIGHT_MSG_UTF8=`echo "$AVEN_COPYRIGHT_MSG"|sed 's/(C)/©/'`
  26
  27 AC_DEFINE_UNQUOTED(COPYRIGHT_MSG_UTF8, ["$COPYRIGHT_MSG_UTF8"],
  28                    [Copyright Message in UTF-8])
  29 AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG_UTF8, ["$AVEN_COPYRIGHT_MSG_UTF8"],
  30                    [Copyright Message for Aven in UTF-8])
  31
  32 dnl set PRETTYPACKAGE to PACKAGE with the first character capitalised
  33 PRETTYPACKAGE=`echo "$PACKAGE"|cut -b1|tr a-z A-Z``echo "$PACKAGE"|cut -b2-`
  34 AC_DEFINE_UNQUOTED(PRETTYPACKAGE, "$PRETTYPACKAGE",
  35                    [Name of package (capitalised)])
  36 AC_SUBST(PRETTYPACKAGE)
  37
  38 dnl set COMMAVERSION to VERSION with the dots replaced by commas -
  39 dnl e.g. "0,99" or "1,0,22"
  40 COMMAVERSION=`echo "$VERSION"|tr '.' ','`
  41 AC_DEFINE_UNQUOTED(COMMAVERSION, $COMMAVERSION,
  42                    [Version number of package (comma-separated)])
  43 AC_SUBST(COMMAVERSION)
  44
  45 PKGDOCDIR='${prefix}/share/doc/${PACKAGE}'
  46 AC_ARG_ENABLE(docdir,
  47 [  --enable-docdir=DIR Set directory for installing documentation to DIR],
  48 [case $enableval in
  49  yes|no)
  50   AC_MSG_ERROR([configure: Syntax: configure --enable-docdir=DIR]) ;;
  51 esac
  52 PKGDOCDIR="$enableval"
  53 ]
  54 )
  55 PKGDOCDIR_EXPANDED=`(
  56  test NONE = "$prefix" && prefix="$ac_default_prefix"
  57  test NONE = "$exec_prefix" && exec_prefix="$prefix"
  58  eval echo "$PKGDOCDIR"
  59 )`
  60 AC_SUBST(PKGDOCDIR)
  61 AC_SUBST(PKGDOCDIR_EXPANDED)
  62
  63 AC_CANONICAL_HOST
  64
  65 dnl Checks for programs.
  66 AC_PROG_CC
  67 AC_PROG_CPP
  68
  69 AC_PROG_CXX
  70 AC_PROG_CXXCPP
  71
  72 AM_PROG_CC_C_O
  73
  74 AC_LANG_C
  75
  76 AC_C_INLINE
  77
  78 AC_EXEEXT
  79 AC_OBJEXT
  80
  81 mswindows=no
  82 macosx=no
  83 case $host_os in
  84 darwin*) macosx=yes ;;
  85 *mingw*|*cygwin*|windows*) mswindows=yes ;;
  86 esac
  87
  88 AC_C_BIGENDIAN
  89
  90 AC_ARG_VAR(STRIP, [Command for discarding symbols from object files])
  91 AC_PATH_TOOL(STRIP, strip, [echo "not stripping "])
  92
  93 AC_CHECK_LIB(m, sqrt)
  94
  95 AC_PATH_XTRA
  96
  97 OSPROGS=
  98 dnl AC_MSG_CHECKING([for OS-specific programs to build])
  99 dnl if test yes = "$mswindows"; then
 100 dnl   OSPROGS=
 101 dnl elif test yes = "$macosx"; then
 102 dnl   OSPROGS=
 103 dnl fi
 104 dnl AC_MSG_RESULT([${OSPROGS:-none}])
 105 AC_SUBST([OSPROGS])
 106
 107 dnl The wxWidgets libraries we need:
 108 wx_libs="core,gl,html"
 109
 110 AC_ARG_VAR(WXCONFIG, [Old name for WX_CONFIG, accepted for compatibility])
 111 AC_ARG_VAR(WX_CONFIG, [wxWidgets configuration script to use to build Aven])
 112 : ${WX_CONFIG="$WXCONFIG"}
 113
 114 AM_CONDITIONAL(WIN32, [test yes = "$mswindows"])
 115 AM_CONDITIONAL(MACOSX, [test yes = "$macosx"])
 116
 117 if test -n "$WX_CONFIG" ; then
 118   dnl WX_CONFIG specified - sanity check the value
 119   dnl don't check for --ldflags - older wx-config didn't do that
 120   if (exec >&5 2>&5;$WX_CONFIG --libs --cflags --cxxflags "$wx_libs";exit $?) then
 121     :
 122   else
 123     AC_MSG_ERROR(['$WX_CONFIG --libs --cflags --cxxflags "$wx_libs"' does not work, bailing out])
 124   fi
 125 else
 126   if test yes = "$macosx" ; then
 127     wxdef=__WXMAC__
 128   elif test yes = "$mswindows" ; then
 129     wxdef=__WXMSW__
 130   else
 131     wxdef=__WXGTK__
 132   fi
 133   dnl See if wx-config exists and is for the correct version.
 134   dnl Fedora install wx3's wx-config as wx-config-3.0, so look for that in
 135   dnl preference.
 136   AC_PATH_PROGS(WX_CONFIG, [wx-config-3.0 wx-config])
 137   if test -n "$WX_CONFIG" ; then
 138     if (exec >&5 2>&5;$WX_CONFIG --cflags "$wx_libs"|grep -e -D"$wxdef";exit $?) then
 139       :
 140     else
 141       AC_MSG_ERROR([wxWidgets not for the right toolkit.  Run ./configure WX_CONFIG=/path/to/wx-config])
 142     fi
 143   else
 144     AC_MSG_ERROR([wxWidgets not found.  Run ./configure WX_CONFIG=/path/to/wx-config])
 145   fi
 146 fi
 147
 148 dnl Unless the user has explicitly specified a --unicode setting, prefer
 149 dnl --unicode=yes if we can get it.
 150 case $WX_CONFIG in
 151   *--unicode=*) ;;
 152   *)
 153     if (exec >&5 2>&5;$WX_CONFIG --unicode=yes --version "$wx_libs";exit $?) ; then
 154       WX_CONFIG="$WX_CONFIG --unicode=yes"
 155     elif (exec >&5 2>&5;$WX_CONFIG --unicode=no --version "$wx_libs";exit $?) ; then
 156       WX_CONFIG="$WX_CONFIG --unicode=no"
 157     fi ;;
 158 esac
 159
 160 WX_LIBS=`$WX_CONFIG --libs "$wx_libs"`
 161 dnl Needed for nvidia drivers on linux (for some setups anyway).
 162 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryVersion, [WX_LIBS="$WX_LIBS -lXxf86vm"], [], [$WX_LIBS])
 163 dnl We use functions from libGLU so always link -lGLU explicitly if it's
 164 dnl present.
 165 AC_CHECK_LIB([GLU], [gluProject], [WX_LIBS="$WX_LIBS -lGLU"], [], [$WX_LIBS])
 166 dnl We use functions from libGL so always link -lGL explicitly if it's
 167 dnl present.
 168 AC_CHECK_LIB([GL], [glPushMatrix], [WX_LIBS="$WX_LIBS -lGL"], [], [$WX_LIBS])
 169 AC_SUBST(WX_LIBS)
 170 dnl Mac OS X has OpenGL/gl.h.
 171 AC_CHECK_HEADERS([GL/gl.h OpenGL/gl.h], [], [], [ ])
 172 dnl The Debian mingw-w64 packages lack GL/glext.h; Mac OS X has OpenGL/glext.h.
 173 AC_CHECK_HEADERS([GL/glext.h OpenGL/glext.h], [], [], [#include <GL/gl.h>])
 174
 175 dnl Older wx-config didn't support --ldflags (2.6.3 doesn't), and neither do
 176 dnl newer ones (3.0.1 doesn't) but presumably some in between did - error goes
 177 dnl to stderr, with nothing to stdout, so just ignore stderr.
 178 WX_LDFLAGS=`$WX_CONFIG --ldflags "$wx_libs" 2> /dev/null`
 179 AC_SUBST(WX_LDFLAGS)
 180 WX_CFLAGS=`$WX_CONFIG --cflags "$wx_libs"`
 181 AC_SUBST(WX_CFLAGS)
 182 WX_CXXFLAGS=`$WX_CONFIG --cxxflags "$wx_libs"`
 183 AC_SUBST(WX_CXXFLAGS)
 184
 185 AC_LANG_C
 186 save_CFLAGS=$CFLAGS
 187 CFLAGS="$CFLAGS $WX_CFLAGS"
 188 AC_CHECK_SIZEOF([wxChar], [], [
 189   #include <wx/defs.h>
 190   #if wxCHECK_VERSION(2,9,0)
 191   #include <wx/chartype.h>
 192   #else
 193   #include <wx/wxchar.h>
 194   #endif
 195 ])
 196 CFLAGS=$save_CFLAGS
 197
 198 dnl Check for libav (FIXME: does our code still work with ffmpeg?)
 199 PKG_CHECK_MODULES([LIBAV], [libavcodec libavformat libswscale libavutil], [
 200   AC_DEFINE([WITH_LIBAV], [1], [Use libav for movie export])
 201   save_CXXFLAGS=$CXXFLAGS
 202   save_LIBS=$LIBS
 203   CFLAGS="$CFLAGS $LIBAV_CFLAGS"
 204   LIBS="$LIBS $LIBAV_LIBS"
 205   AC_CHECK_FUNCS([av_guess_format avio_open avio_close avformat_write_header avcodec_encode_video2 avcodec_free_frame avcodec_open2 avformat_new_stream av_frame_alloc av_frame_free])
 206   AC_CHECK_DECLS([AVMEDIA_TYPE_VIDEO], [], [], [#include <libavcodec/avcodec.h>])
 207   AC_CHECK_DECLS([AV_CODEC_ID_NONE], [], [], [#include <libavcodec/avcodec.h>])
 208   AC_CHECK_DECLS([AV_PIX_FMT_RGB24], [], [], [#include <libavutil/pixfmt.h>])
 209   AC_CHECK_DECLS([AV_PIX_FMT_YUV420P], [], [], [#include <libavutil/pixfmt.h>])
 210   CXXFLAGS=$save_CXXFLAGS
 211   LIBS=$save_LIBS
 212 ], [
 213   dnl Build without movie export feature.
 214 ])
 215 AC_SUBST([LIBAV_LIBS])
 216 AC_SUBST([LIBAV_CFLAGS])
 217
 218 dnl Check for PROJ4
 219 PKG_CHECK_MODULES([PROJ], [proj], [
 220 ], [
 221   dnl pkg-config support in proj seems quite new, so probe directly if not
 222   dnl found.
 223   AC_CHECK_LIB([proj], [pj_init_plus], [
 224       PROJ_LIBS=-lproj
 225       PROJ_CFLAGS=
 226     ], [
 227       AC_MSG_ERROR([PROJ4 required for coordinate transformations])
 228     ])
 229 ])
 230 AC_SUBST([PROJ_LIBS])
 231 AC_SUBST([PROJ_CFLAGS])
 232
 233 dnl Checks for header files.
 234 AC_HEADER_STDC
 235 dnl don't use AC_CHECK_FUNCS for setjmp - mingw #define-s it to _setjmp
 236 AC_CHECK_HEADERS(limits.h string.h setjmp.h sys/select.h)
 237
 238 dnl Checks for typedefs, structures, and compiler characteristics.
 239 AC_TYPE_SIZE_T
 240 AC_STRUCT_TM
 241 AC_TYPE_SIGNAL
 242
 243 dnl check if CLOCKS_PER_SEC is defined by time.h (as ANSI says it should be)
 244 dnl if it isn't, assume it is 1000000, as it is on SunOS 4
 245 AC_TRY_COMPILE([#include <time.h>],[
 246 #ifndef CLOCKS_PER_SEC
 247 choke me
 248 #endif
 249 ], , AC_DEFINE(CLOCKS_PER_SEC, 1000000, [For old systems which don't define it themselves]))
 250
 251 dnl Check for 16-bit and 32-bit integer types.
 252 AC_TYPE_INT16_T
 253 AC_TYPE_INT32_T
 254
 255 dnl Checks for library functions.
 256 AC_FUNC_STRFTIME
 257 if test yes != "$ac_cv_func_strftime"; then
 258   AC_LIBOBJ(strftime)
 259 fi
 260 AC_FUNC_VPRINTF
 261 dnl Check if there's a declaration of lround().  Below we also check for
 262 dnl lround() with AC_CHECK_FUNCS, which just checks if it can be linked
 263 dnl against.  Some platforms are missing a prototype for lround(), so
 264 dnl both checks are useful.
 265 AC_CHECK_DECLS([lround], [], [], [[#include <math.h>]])
 266 dnl check for strcasecmp here as well as below - this one is to get
 267 dnl HAVE_STRCASECMP defined if appropriate (for img.c)
 268 AC_CHECK_FUNCS([popen getpwuid lround strcasecmp hypot lstat mmap])
 269
 270 dnl difftime seems to be an ANSI invention
 271 AC_CHECK_FUNCS(difftime)
 272
 273 dnl Much faster than using getc()/putc(), at least on Linux.
 274 AC_CHECK_FUNCS([getc_unlocked putc_unlocked])
 275
 276 AC_CHECK_FUNCS([setenv unsetenv])
 277
 278 dnl try to find a case-insensitive compare
 279
 280 strcasecmp=no
 281 dnl The order of these tests is important.
 282 AC_CHECK_FUNC(strcasecmp, [strcasecmp=strcasecmp])
 283 if test no = "$strcasecmp"; then
 284   AC_CHECK_FUNC(stricmp, [strcasecmp=stricmp])
 285 fi
 286 if test no = "$strcasecmp"; then
 287   AC_CHECK_FUNC(strcmpi, [strcasecmp=strcmpi])
 288 fi
 289
 290 AC_MSG_CHECKING([how to compare strings ignoring case])
 291 case $strcasecmp in
 292 no)
 293   AC_LIBOBJ(strcasecmp)
 294   AC_MSG_RESULT([using own implementation of strcasecmp]) ;;
 295 strcasecmp)
 296   AC_MSG_RESULT([strcasecmp]) ;;
 297 *)
 298   AC_DEFINE_UNQUOTED(strcasecmp, "$strcasecmp",
 299     [strcasecmp define for systems which call it something else])
 300   AC_MSG_RESULT([$strcasecmp]) ;;
 301 esac
 302
 303 AC_MSG_CHECKING(for sgmltools v2 or v3)
 304 if test : != "$SGMLTOOLS" ; then
 305   : ${SGMLTOOLS=sgmltools}
 306   case `(exec 2>&5 ; $SGMLTOOLS --version)` in
 307   *" version 3"*)
 308     AC_MSG_RESULT([$SGMLTOOLS]) ;;
 309   *" version 2"*)
 310     AC_MSG_RESULT([$SGMLTOOLS]) ;;
 311   *)
 312     SGMLTOOLS="$MISSING sgmltools"
 313     AC_MSG_RESULT(not found) ;;
 314   esac
 315 else
 316   AC_MSG_RESULT([$SGMLTOOLS])
 317 fi
 318 AC_SUBST(SGMLTOOLS)
 319 AC_ARG_VAR(SGMLTOOLS, [sgmltools command])
 320
 321 AC_MSG_CHECKING(for docbook-to-man)
 322 if test : != "$DOCBOOK_TO_MAN" ; then
 323   : ${DOCBOOK_TO_MAN=docbook-to-man}
 324   $DOCBOOK_TO_MAN 2> /dev/null
 325   if test $? = 1 ; then
 326     AC_MSG_RESULT([$DOCBOOK_TO_MAN])
 327   else
 328     DOCBOOK_TO_MAN="$MISSING docbook-to-man"
 329     AC_MSG_RESULT([not found])
 330   fi
 331 else
 332   AC_MSG_RESULT([$DOCBOOK_TO_MAN])
 333 fi
 334 AC_SUBST(DOCBOOK_TO_MAN)
 335 AC_ARG_VAR(DOCBOOK_TO_MAN, [docbook-to-man command])
 336
 337 dnl extra warning flags for building with GCC
 338 if test yes = "$GCC"; then
 339   if test yes = "$cross_compiling"; then
 340 dnl    AM_CFLAGS="$AM_CFLAGS -Werror -Wall -Wunused -Wpointer-arith\
 341 dnl      -Wwrite-strings -Wcast-align"
 342 dnl -Wsign-compare causes a warning with the mingw FD_SET macro, so we have
 343 dnl to disable it for mingw builds.
 344     AM_CFLAGS="$AM_CFLAGS -Wall -Wunused -Wpointer-arith\
 345       -Wwrite-strings -Wcast-align"
 346     AM_CXXFLAGS="$AM_CXXFLAGS -Wall -Wunused -Wpointer-arith\
 347       -Wwrite-strings -Wcast-align -Wno-sign-compare"
 348   else
 349     AM_CFLAGS="$AM_CFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
 350       -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wnested-externs\
 351       -Wcast-align"
 352     AM_CXXFLAGS="$AM_CXXFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
 353       -Wwrite-strings -Wcast-align"
 354   fi
 355   dnl too many complaints from headers, etc: -Wconversion
 356 fi
 357 AC_SUBST(AM_CFLAGS)
 358 AC_SUBST(AM_CXXFLAGS)
 359
 360 dnl See if large file support is available.  Survex is unlikely to need to
 361 dnl process files > 2GB in size, but LFS is also needed for stat() to work
 362 dnl on filing systems which return 64 bit inode values, such as CIFS mounts.
 363 AC_SYS_LARGEFILE
 364
 365 AC_ARG_ENABLE(profiling,
 366 [  --enable-profiling Build binaries to generate profiling information],
 367 [case $enableval in
 368   yes) AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 369        AM_CFLAGS="$AM_CFLAGS -pg"
 370        AC_MSG_RESULT(building binaries to generate profiling information);;
 371   no) ;;
 372   *) AC_MSG_ERROR(bad value $enableval for --enable-profiling) ;;
 373 esac])
 374
 375 HTMLFILES="AUTHORS.htm HACKING.htm NEWS.htm OLDNEWS.htm TODO.htm index.htm 3dformat.htm 3dformat-old.htm"
 376 AC_SUBST(HTMLFILES)
 377
 378 EXTRA_TEXT="AUTHORS COPYING NEWS TODO ChangeLog"
 379 AC_SUBST(EXTRA_TEXT)
 380
 381 AC_SUBST_FILE(DESC)
 382 DESC=desc.txt
 383 AC_SUBST_FILE(AVENDESC)
 384 AVENDESC=desc-aven.txt
 385
 386 dnl Don't define DATADIR if building for MS Windows - it won't be used, and
 387 dnl can conflict with the DATADIR typedef in objidl.h
 388 if test no = "$mswindows"; then
 389   AC_DEFINE_DIR(DATADIR, datadir, [Location of platform independent support files])
 390 fi
 391
 392 AH_BOTTOM(
 393 [/* Use getc_unlocked() and putc_unlocked() where available, since they are
 394  * faster, and we don't multithread file accesses.
 395  */
 396
 397 #ifdef HAVE_GETC_UNLOCKED
 398 # define GETC(F) getc_unlocked(F)
 399 #else
 400 # define GETC(F) getc(F)
 401 #endif
 402 #ifdef HAVE_PUTC_UNLOCKED
 403 # define PUTC(C, F) putc_unlocked(C, F)
 404 #else
 405 # define PUTC(C, F) putc(C, F)
 406 #endif
 407 ])
 408
 409 AC_CONFIG_FILES([
 410  Makefile src/Makefile doc/Makefile lib/Makefile lib/icons/Makefile
 411  lib/images/Makefile
 412  tests/Makefile vim/Makefile survex.iss doc/index.htm doc/survex.7
 413  survex.spec lib/Info.plist
 414  ])
 415 AC_OUTPUT
 416 dnl FIXME update msvc makefile for 1.2 branch
 417 dnl src/msvc/config.h