configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 dnl Need autoconf 2.50 or later for AC_ARG_VAR.  2.59 has been around for
   4 dnl long enough, that we might as well just require that.
   5 AC_PREREQ(2.59)
   6 AC_INIT([survex], [1.4.6], [https://trac.survex.com/])
   7 AM_INIT_AUTOMAKE([1.5 gnu -Wall -Wportability -Werror])
   8 RELEASE=1
   9
  10 AC_SUBST(RELEASE)
  11 AC_CONFIG_HEADERS([config.h])
  12 AC_CONFIG_SRCDIR([src/aven.cc])
  13
  14 COPYRIGHT_MSG="Copyright (C) 1990-2023 Olly Betts"
  15 AVEN_COPYRIGHT_MSG="Copyright (C) 1999-2003,2005,2006 Mark R. Shinwell"
  16
  17 AC_DEFINE_UNQUOTED(COPYRIGHT_MSG, ["$COPYRIGHT_MSG"], [Copyright Message])
  18 AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG, ["$AVEN_COPYRIGHT_MSG"],
  19                    [Copyright Message for Aven])
  20
  21 AC_SUBST(COPYRIGHT_MSG)
  22 AC_SUBST(AVEN_COPYRIGHT_MSG)
  23
  24 COPYRIGHT_MSG_UTF8=`echo "$COPYRIGHT_MSG"|sed 's/(C)/©/'`
  25 AVEN_COPYRIGHT_MSG_UTF8=`echo "$AVEN_COPYRIGHT_MSG"|sed 's/(C)/©/'`
  26
  27 AC_DEFINE_UNQUOTED(COPYRIGHT_MSG_UTF8, ["$COPYRIGHT_MSG_UTF8"],
  28                    [Copyright Message in UTF-8])
  29 AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG_UTF8, ["$AVEN_COPYRIGHT_MSG_UTF8"],
  30                    [Copyright Message for Aven in UTF-8])
  31
  32 dnl set PRETTYPACKAGE to PACKAGE with the first character capitalised
  33 PRETTYPACKAGE=`echo "$PACKAGE"|cut -b1|tr a-z A-Z``echo "$PACKAGE"|cut -b2-`
  34 AC_DEFINE_UNQUOTED(PRETTYPACKAGE, "$PRETTYPACKAGE",
  35                    [Name of package (capitalised)])
  36 AC_SUBST(PRETTYPACKAGE)
  37
  38 dnl set COMMAVERSION to VERSION with the dots replaced by commas -
  39 dnl e.g. "0,99" or "1,0,22"
  40 COMMAVERSION=`echo "$VERSION"|tr '.' ','`
  41 AC_DEFINE_UNQUOTED(COMMAVERSION, $COMMAVERSION,
  42                    [Version number of package (comma-separated)])
  43 AC_SUBST(COMMAVERSION)
  44
  45 PKGDOCDIR='${prefix}/share/doc/${PACKAGE}'
  46 AC_ARG_ENABLE(docdir,
  47 [  --enable-docdir=DIR Set directory for installing documentation to DIR],
  48 [case $enableval in
  49  yes|no)
  50   AC_MSG_ERROR([configure: Syntax: configure --enable-docdir=DIR]) ;;
  51 esac
  52 PKGDOCDIR="$enableval"
  53 ]
  54 )
  55 PKGDOCDIR_EXPANDED=`(
  56  test NONE = "$prefix" && prefix="$ac_default_prefix"
  57  test NONE = "$exec_prefix" && exec_prefix="$prefix"
  58  eval echo "$PKGDOCDIR"
  59 )`
  60 AC_SUBST(PKGDOCDIR)
  61 AC_SUBST(PKGDOCDIR_EXPANDED)
  62
  63 AC_CANONICAL_HOST
  64
  65 dnl Checks for programs.
  66 AC_PROG_CC
  67 AC_PROG_CPP
  68
  69 AC_PROG_CXX
  70 AC_PROG_CXXCPP
  71
  72 dnl Probe for any options needed to enable C++11 support.
  73 AX_CXX_COMPILE_STDCXX_11
  74
  75 AM_PROG_CC_C_O
  76
  77 AC_LANG([C])
  78
  79 AC_EXEEXT
  80 AC_OBJEXT
  81
  82 mswindows=no
  83 macos=no
  84 case $host_os in
  85 darwin*) macos=yes ;;
  86 *mingw*|*cygwin*|windows*) mswindows=yes ;;
  87 esac
  88
  89 AC_C_BIGENDIAN
  90
  91 AC_ARG_VAR(STRIP, [Command for discarding symbols from object files])
  92 AC_PATH_TOOL(STRIP, strip, [echo "not stripping "])
  93
  94 AC_CHECK_LIB(m, sqrt)
  95
  96 AC_PATH_XTRA
  97
  98 dnl The wxWidgets libraries we need:
  99 wx_libs="core,gl,html"
 100
 101 AC_ARG_VAR(WXCONFIG, [Old name for WX_CONFIG, accepted for compatibility])
 102 AC_ARG_VAR(WX_CONFIG, [wxWidgets configuration script to use to build Aven])
 103 : ${WX_CONFIG="$WXCONFIG"}
 104
 105 AM_CONDITIONAL(WIN32, [test yes = "$mswindows"])
 106 AM_CONDITIONAL(MACOS, [test yes = "$macos"])
 107
 108 if test -n "$WX_CONFIG" ; then
 109   dnl WX_CONFIG specified - sanity check the value
 110   dnl don't check for --ldflags - older wx-config didn't do that
 111   if (exec >&5 2>&5;$WX_CONFIG --libs --cflags --cxxflags "$wx_libs";exit $?) then
 112     :
 113   else
 114     AC_MSG_ERROR(['$WX_CONFIG --libs --cflags --cxxflags "$wx_libs"' does not work, bailing out])
 115   fi
 116 else
 117   if test yes = "$macos" ; then
 118     wxdef=__WXMAC__
 119   elif test yes = "$mswindows" ; then
 120     wxdef=__WXMSW__
 121   else
 122     wxdef=__WXGTK__
 123   fi
 124   dnl See if wx-config exists and is for the correct version.
 125   dnl Fedora install wx3's wx-config as wx-config-3.0, so look for that in
 126   dnl preference.
 127   dnl Arch Linux uses wx-config-gtk3.
 128   AC_PATH_PROGS(WX_CONFIG, [wx-config-3.0 wx-config-gtk3 wx-config])
 129   if test -n "$WX_CONFIG" ; then
 130     if (exec >&5 2>&5;$WX_CONFIG --cflags "$wx_libs"|grep -e -D"$wxdef";exit $?) then
 131       :
 132     else
 133       AC_MSG_ERROR([wxWidgets not for the right toolkit.  Run ./configure WX_CONFIG=/path/to/wx-config])
 134     fi
 135   else
 136     AC_MSG_ERROR([wxWidgets not found.  Run ./configure WX_CONFIG=/path/to/wx-config])
 137   fi
 138 fi
 139
 140 dnl Unless the user has explicitly specified a --unicode setting, prefer
 141 dnl --unicode=yes if we can get it.
 142 case $WX_CONFIG in
 143   *--unicode=*) ;;
 144   *)
 145     if (exec >&5 2>&5;$WX_CONFIG --unicode=yes --version "$wx_libs";exit $?) ; then
 146       WX_CONFIG="$WX_CONFIG --unicode=yes"
 147     elif (exec >&5 2>&5;$WX_CONFIG --unicode=no --version "$wx_libs";exit $?) ; then
 148       WX_CONFIG="$WX_CONFIG --unicode=no"
 149     fi ;;
 150 esac
 151
 152 WX_LIBS=`$WX_CONFIG --libs "$wx_libs"`
 153 dnl Needed for nvidia drivers on linux (for some setups anyway).
 154 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryVersion, [WX_LIBS="$WX_LIBS -lXxf86vm"], [], [$WX_LIBS])
 155 dnl We use functions from libGLU so always link -lGLU explicitly if it's
 156 dnl present.
 157 AC_CHECK_LIB([GLU], [gluProject], [WX_LIBS="$WX_LIBS -lGLU"], [], [$WX_LIBS])
 158 dnl We use functions from libGL so always link -lGL explicitly if it's
 159 dnl present.
 160 AC_CHECK_LIB([GL], [glPushMatrix], [WX_LIBS="$WX_LIBS -lGL"], [], [$WX_LIBS])
 161 AC_SUBST(WX_LIBS)
 162 dnl macOS has OpenGL/gl.h.
 163 AC_CHECK_HEADERS([GL/gl.h OpenGL/gl.h], [], [], [ ])
 164 dnl The Debian mingw-w64 packages lack GL/glext.h; macOS has OpenGL/glext.h.
 165 AC_CHECK_HEADERS([GL/glext.h OpenGL/glext.h], [], [], [#include <GL/gl.h>])
 166
 167 WX_CFLAGS=`$WX_CONFIG --cflags "$wx_libs"`
 168 AC_SUBST(WX_CFLAGS)
 169 WX_CXXFLAGS=`$WX_CONFIG --cxxflags "$wx_libs"`
 170 AC_SUBST(WX_CXXFLAGS)
 171
 172 AC_LANG([C])
 173 save_CFLAGS=$CFLAGS
 174 CFLAGS="$CFLAGS $WX_CFLAGS"
 175 AC_CHECK_SIZEOF([wxChar], [], [
 176   #include <wx/defs.h>
 177   #include <wx/chartype.h>
 178 ])
 179 CFLAGS=$save_CFLAGS
 180
 181 dnl Check for FFmpeg libraries.
 182 PKG_CHECK_MODULES([FFMPEG], [libavcodec libavformat libswscale libavutil], [
 183   AC_DEFINE([WITH_FFMPEG], [1], [Use FFmpeg for movie export])
 184   save_CXXFLAGS=$CXXFLAGS
 185   save_LIBS=$LIBS
 186   CFLAGS="$CFLAGS $FFMPEG_CFLAGS"
 187   LIBS="$LIBS $FFMPEG_LIBS"
 188   AC_CHECK_FUNCS([av_guess_format avio_open avio_close avformat_write_header avcodec_encode_video2 avcodec_free_frame avcodec_open2 avformat_new_stream av_frame_alloc av_frame_free])
 189   AC_CHECK_DECLS([AVMEDIA_TYPE_VIDEO], [], [], [#include <libavcodec/avcodec.h>])
 190   AC_CHECK_DECLS([AV_CODEC_ID_NONE], [], [], [#include <libavcodec/avcodec.h>])
 191   AC_CHECK_DECLS([AV_PIX_FMT_RGB24], [], [], [#include <libavutil/pixfmt.h>])
 192   AC_CHECK_DECLS([AV_PIX_FMT_YUV420P], [], [], [#include <libavutil/pixfmt.h>])
 193   CXXFLAGS=$save_CXXFLAGS
 194   LIBS=$save_LIBS
 195 ], [
 196   dnl Build without movie export feature.
 197 ])
 198 AC_SUBST([FFMPEG_LIBS])
 199 AC_SUBST([FFMPEG_CFLAGS])
 200
 201 dnl Check for PROJ.
 202 PKG_CHECK_MODULES([PROJ], [proj >= 6.2.0], [
 203 ], [
 204   dnl pkg-config support in proj seems quite new, so probe directly if not
 205   dnl found.  We need proj_create_crs_to_crs_from_pj() which was added in
 206   dnl 6.2.0.
 207   AC_CHECK_LIB([proj], [proj_create_crs_to_crs_from_pj], [
 208       PROJ_LIBS=-lproj
 209       PROJ_CFLAGS=
 210     ], [
 211       AC_MSG_ERROR([PROJ required for coordinate transformations])
 212     ])
 213 ])
 214 AC_SUBST([PROJ_LIBS])
 215 AC_SUBST([PROJ_CFLAGS])
 216
 217 dnl Checks for header files.
 218
 219 dnl don't use AC_CHECK_FUNCS for setjmp - mingw #define-s it to _setjmp
 220 AC_CHECK_HEADERS(limits.h string.h setjmp.h sys/select.h)
 221
 222 dnl Checks for typedefs, structures, and compiler characteristics.
 223 AC_TYPE_SIZE_T
 224 AC_STRUCT_TM
 225
 226 dnl Check for 16-bit and 32-bit integer types.
 227 AC_TYPE_INT16_T
 228 AC_TYPE_UINT16_T
 229 AC_TYPE_INT32_T
 230 AC_TYPE_UINT32_T
 231
 232 dnl Check if there's a declaration of lround().  Below we also check for
 233 dnl lround() with AC_CHECK_FUNCS, which just checks if it can be linked
 234 dnl against.  Some platforms are missing a prototype for lround(), so
 235 dnl both checks are useful.
 236 AC_CHECK_DECLS([lround], [], [], [[#include <math.h>]])
 237 AC_CHECK_FUNCS([popen getpwuid lround hypot mmap])
 238
 239 dnl Much faster than using getc()/putc(), at least on Linux.
 240 AC_CHECK_FUNCS([getc_unlocked putc_unlocked])
 241
 242 AC_CHECK_FUNCS([setenv unsetenv])
 243
 244 AC_PATH_PROG([JW], [jw], [$MISSING jw])
 245 AC_ARG_VAR([JW], [jw from docbook-utils/docbook-tools])
 246
 247 dnl extra warning flags for building with GCC
 248 if test yes = "$GCC"; then
 249   if test yes = "$cross_compiling"; then
 250 dnl    AM_CFLAGS="$AM_CFLAGS -Werror -Wall -Wunused -Wpointer-arith\
 251 dnl      -Wwrite-strings -Wcast-align"
 252 dnl -Wsign-compare causes a warning with the mingw FD_SET macro, so we have
 253 dnl to disable it for mingw builds.
 254     AM_CFLAGS="$AM_CFLAGS -Wall -Wunused -Wpointer-arith\
 255       -Wwrite-strings -Wcast-align"
 256     AM_CXXFLAGS="$AM_CXXFLAGS -Wall -Wunused -Wpointer-arith\
 257       -Wwrite-strings -Wcast-align -Wno-sign-compare"
 258   else
 259     AM_CFLAGS="$AM_CFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
 260       -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wnested-externs\
 261       -Wcast-align"
 262     AM_CXXFLAGS="$AM_CXXFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
 263       -Wwrite-strings -Wcast-align"
 264   fi
 265   dnl too many complaints from headers, etc: -Wconversion
 266 fi
 267 AC_SUBST(AM_CFLAGS)
 268 AC_SUBST(AM_CXXFLAGS)
 269
 270 dnl See if large file support is available.  Survex is unlikely to need to
 271 dnl process files > 2GB in size, but LFS is also needed for stat() to work
 272 dnl on filing systems which return 64 bit inode values, such as CIFS mounts.
 273 AC_SYS_LARGEFILE
 274
 275 AC_ARG_ENABLE(profiling,
 276 [  --enable-profiling Build binaries to generate profiling information],
 277 [case $enableval in
 278   yes) AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 279        AM_CFLAGS="$AM_CFLAGS -pg"
 280        AC_MSG_RESULT(building binaries to generate profiling information);;
 281   no) ;;
 282   *) AC_MSG_ERROR(bad value $enableval for --enable-profiling) ;;
 283 esac])
 284
 285 HTMLFILES="AUTHORS.htm HACKING.htm NEWS.htm OLDNEWS.htm TODO.htm index.htm 3dformat.htm 3dformat-old.htm"
 286 AC_SUBST(HTMLFILES)
 287
 288 EXTRA_TEXT="AUTHORS COPYING NEWS TODO ChangeLog"
 289 AC_SUBST(EXTRA_TEXT)
 290
 291 AC_SUBST_FILE(DESC)
 292 DESC=desc.txt
 293 AC_SUBST_FILE(AVENDESC)
 294 AVENDESC=desc-aven.txt
 295
 296 dnl Don't define DATADIR if building for MS Windows - it won't be used, and
 297 dnl can conflict with the DATADIR typedef in objidl.h
 298 if test no = "$mswindows"; then
 299   AC_DEFINE_DIR(DATADIR, datadir, [Location of platform independent support files])
 300 fi
 301
 302 AH_BOTTOM(
 303 [/* Use getc_unlocked() and putc_unlocked() where available, since they are
 304  * faster, and we don't multithread file accesses.
 305  */
 306
 307 #ifdef HAVE_GETC_UNLOCKED
 308 # define GETC(F) getc_unlocked(F)
 309 #else
 310 # define GETC(F) getc(F)
 311 #endif
 312 #ifdef HAVE_PUTC_UNLOCKED
 313 # define PUTC(C, F) putc_unlocked(C, F)
 314 #else
 315 # define PUTC(C, F) putc(C, F)
 316 #endif
 317
 318 #ifndef __cplusplus
 319 /* C23 added bool, false and true as keywords - let's emulate that and
 320  * avoid every C file which uses these needing to include <stdbool.h>.
 321  */
 322 # include <stdbool.h>
 323 #endif
 324 ])
 325
 326 AC_CONFIG_FILES([
 327  Makefile src/Makefile doc/Makefile lib/Makefile lib/icons/Makefile
 328  lib/images/Makefile
 329  tests/Makefile vim/Makefile survex.iss doc/index.htm doc/survex.7
 330  survex.spec lib/Info.plist
 331  ])
 332 AC_OUTPUT
 333 dnl FIXME update msvc makefile for 1.2 branch
 334 dnl src/msvc/config.h