configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 dnl Need autoconf 2.50 or later for AC_ARG_VAR.  2.59 has been around for
   4 dnl long enough, that we might as well just require that.
   5 AC_PREREQ(2.59)
   6 AC_INIT([survex], [1.2.34], [https://trac.survex.com/])
   7 AM_INIT_AUTOMAKE([1.5 gnu -Wall -Wportability -Werror])
   8 RELEASE=1
   9
  10 AC_SUBST(RELEASE)
  11 AC_CONFIG_HEADERS([config.h])
  12 AC_CONFIG_SRCDIR([src/aven.cc])
  13
  14 COPYRIGHT_MSG="Copyright (C) 1990-2017 Olly Betts"
  15 AVEN_COPYRIGHT_MSG="Copyright (C) 1999-2003,2005,2006 Mark R. Shinwell"
  16
  17 AC_DEFINE_UNQUOTED(COPYRIGHT_MSG, ["$COPYRIGHT_MSG"], [Copyright Message])
  18 AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG, ["$AVEN_COPYRIGHT_MSG"],
  19                    [Copyright Message for Aven])
  20
  21 AC_SUBST(COPYRIGHT_MSG)
  22 AC_SUBST(AVEN_COPYRIGHT_MSG)
  23
  24 COPYRIGHT_MSG_UTF8=`echo "$COPYRIGHT_MSG"|sed 's/(C)/©/'`
  25 AVEN_COPYRIGHT_MSG_UTF8=`echo "$AVEN_COPYRIGHT_MSG"|sed 's/(C)/©/'`
  26
  27 AC_DEFINE_UNQUOTED(COPYRIGHT_MSG_UTF8, ["$COPYRIGHT_MSG_UTF8"],
  28                    [Copyright Message in UTF-8])
  29 AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG_UTF8, ["$AVEN_COPYRIGHT_MSG_UTF8"],
  30                    [Copyright Message for Aven in UTF-8])
  31
  32 dnl set PRETTYPACKAGE to PACKAGE with the first character capitalised
  33 PRETTYPACKAGE=`echo "$PACKAGE"|cut -b1|tr a-z A-Z``echo "$PACKAGE"|cut -b2-`
  34 AC_DEFINE_UNQUOTED(PRETTYPACKAGE, "$PRETTYPACKAGE",
  35                    [Name of package (capitalised)])
  36 AC_SUBST(PRETTYPACKAGE)
  37
  38 dnl set COMMAVERSION to VERSION with the dots replaced by commas -
  39 dnl e.g. "0,99" or "1,0,22"
  40 COMMAVERSION=`echo "$VERSION"|tr '.' ','`
  41 AC_DEFINE_UNQUOTED(COMMAVERSION, $COMMAVERSION,
  42                    [Version number of package (comma-separated)])
  43 AC_SUBST(COMMAVERSION)
  44
  45 PKGDOCDIR='${prefix}/share/doc/${PACKAGE}'
  46 AC_ARG_ENABLE(docdir,
  47 [  --enable-docdir=DIR Set directory for installing documentation to DIR],
  48 [case $enableval in
  49  yes|no)
  50   AC_MSG_ERROR([configure: Syntax: configure --enable-docdir=DIR]) ;;
  51 esac
  52 PKGDOCDIR="$enableval"
  53 ]
  54 )
  55 PKGDOCDIR_EXPANDED=`(
  56  test NONE = "$prefix" && prefix="$ac_default_prefix"
  57  test NONE = "$exec_prefix" && exec_prefix="$prefix"
  58  eval echo "$PKGDOCDIR"
  59 )`
  60 AC_SUBST(PKGDOCDIR)
  61 AC_SUBST(PKGDOCDIR_EXPANDED)
  62
  63 AC_CANONICAL_HOST
  64
  65 dnl Checks for programs.
  66 AC_PROG_CC
  67 AC_PROG_CPP
  68
  69 AC_PROG_CXX
  70 AC_PROG_CXXCPP
  71
  72 dnl Probe for any options needed to enable C++11 support.
  73 AX_CXX_COMPILE_STDCXX_11
  74
  75 AM_PROG_CC_C_O
  76
  77 AC_LANG_C
  78
  79 AC_C_INLINE
  80
  81 AC_EXEEXT
  82 AC_OBJEXT
  83
  84 mswindows=no
  85 macosx=no
  86 case $host_os in
  87 darwin*) macosx=yes ;;
  88 *mingw*|*cygwin*|windows*) mswindows=yes ;;
  89 esac
  90
  91 AC_C_BIGENDIAN
  92
  93 AC_ARG_VAR(STRIP, [Command for discarding symbols from object files])
  94 AC_PATH_TOOL(STRIP, strip, [echo "not stripping "])
  95
  96 AC_CHECK_LIB(m, sqrt)
  97
  98 AC_PATH_XTRA
  99
 100 OSPROGS=
 101 dnl AC_MSG_CHECKING([for OS-specific programs to build])
 102 dnl if test yes = "$mswindows"; then
 103 dnl   OSPROGS=
 104 dnl elif test yes = "$macosx"; then
 105 dnl   OSPROGS=
 106 dnl fi
 107 dnl AC_MSG_RESULT([${OSPROGS:-none}])
 108 AC_SUBST([OSPROGS])
 109
 110 dnl The wxWidgets libraries we need:
 111 wx_libs="core,gl,html"
 112
 113 AC_ARG_VAR(WXCONFIG, [Old name for WX_CONFIG, accepted for compatibility])
 114 AC_ARG_VAR(WX_CONFIG, [wxWidgets configuration script to use to build Aven])
 115 : ${WX_CONFIG="$WXCONFIG"}
 116
 117 AM_CONDITIONAL(WIN32, [test yes = "$mswindows"])
 118 AM_CONDITIONAL(MACOSX, [test yes = "$macosx"])
 119
 120 if test -n "$WX_CONFIG" ; then
 121   dnl WX_CONFIG specified - sanity check the value
 122   dnl don't check for --ldflags - older wx-config didn't do that
 123   if (exec >&5 2>&5;$WX_CONFIG --libs --cflags --cxxflags "$wx_libs";exit $?) then
 124     :
 125   else
 126     AC_MSG_ERROR(['$WX_CONFIG --libs --cflags --cxxflags "$wx_libs"' does not work, bailing out])
 127   fi
 128 else
 129   if test yes = "$macosx" ; then
 130     wxdef=__WXMAC__
 131   elif test yes = "$mswindows" ; then
 132     wxdef=__WXMSW__
 133   else
 134     wxdef=__WXGTK__
 135   fi
 136   dnl See if wx-config exists and is for the correct version.
 137   dnl Fedora install wx3's wx-config as wx-config-3.0, so look for that in
 138   dnl preference.
 139   AC_PATH_PROGS(WX_CONFIG, [wx-config-3.0 wx-config])
 140   if test -n "$WX_CONFIG" ; then
 141     if (exec >&5 2>&5;$WX_CONFIG --cflags "$wx_libs"|grep -e -D"$wxdef";exit $?) then
 142       :
 143     else
 144       AC_MSG_ERROR([wxWidgets not for the right toolkit.  Run ./configure WX_CONFIG=/path/to/wx-config])
 145     fi
 146   else
 147     AC_MSG_ERROR([wxWidgets not found.  Run ./configure WX_CONFIG=/path/to/wx-config])
 148   fi
 149 fi
 150
 151 dnl Unless the user has explicitly specified a --unicode setting, prefer
 152 dnl --unicode=yes if we can get it.
 153 case $WX_CONFIG in
 154   *--unicode=*) ;;
 155   *)
 156     if (exec >&5 2>&5;$WX_CONFIG --unicode=yes --version "$wx_libs";exit $?) ; then
 157       WX_CONFIG="$WX_CONFIG --unicode=yes"
 158     elif (exec >&5 2>&5;$WX_CONFIG --unicode=no --version "$wx_libs";exit $?) ; then
 159       WX_CONFIG="$WX_CONFIG --unicode=no"
 160     fi ;;
 161 esac
 162
 163 WX_LIBS=`$WX_CONFIG --libs "$wx_libs"`
 164 dnl Needed for nvidia drivers on linux (for some setups anyway).
 165 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryVersion, [WX_LIBS="$WX_LIBS -lXxf86vm"], [], [$WX_LIBS])
 166 dnl We use functions from libGLU so always link -lGLU explicitly if it's
 167 dnl present.
 168 AC_CHECK_LIB([GLU], [gluProject], [WX_LIBS="$WX_LIBS -lGLU"], [], [$WX_LIBS])
 169 dnl We use functions from libGL so always link -lGL explicitly if it's
 170 dnl present.
 171 AC_CHECK_LIB([GL], [glPushMatrix], [WX_LIBS="$WX_LIBS -lGL"], [], [$WX_LIBS])
 172 AC_SUBST(WX_LIBS)
 173 dnl Mac OS X has OpenGL/gl.h.
 174 AC_CHECK_HEADERS([GL/gl.h OpenGL/gl.h], [], [], [ ])
 175 dnl The Debian mingw-w64 packages lack GL/glext.h; Mac OS X has OpenGL/glext.h.
 176 AC_CHECK_HEADERS([GL/glext.h OpenGL/glext.h], [], [], [#include <GL/gl.h>])
 177
 178 WX_CFLAGS=`$WX_CONFIG --cflags "$wx_libs"`
 179 AC_SUBST(WX_CFLAGS)
 180 WX_CXXFLAGS=`$WX_CONFIG --cxxflags "$wx_libs"`
 181 AC_SUBST(WX_CXXFLAGS)
 182
 183 AC_LANG_C
 184 save_CFLAGS=$CFLAGS
 185 CFLAGS="$CFLAGS $WX_CFLAGS"
 186 AC_CHECK_SIZEOF([wxChar], [], [
 187   #include <wx/defs.h>
 188   #if wxCHECK_VERSION(2,9,0)
 189   #include <wx/chartype.h>
 190   #else
 191   #include <wx/wxchar.h>
 192   #endif
 193 ])
 194 CFLAGS=$save_CFLAGS
 195
 196 dnl Check for libav (FIXME: does our code still work with ffmpeg?)
 197 PKG_CHECK_MODULES([LIBAV], [libavcodec libavformat libswscale libavutil], [
 198   AC_DEFINE([WITH_LIBAV], [1], [Use libav for movie export])
 199   save_CXXFLAGS=$CXXFLAGS
 200   save_LIBS=$LIBS
 201   CFLAGS="$CFLAGS $LIBAV_CFLAGS"
 202   LIBS="$LIBS $LIBAV_LIBS"
 203   AC_CHECK_FUNCS([av_guess_format avio_open avio_close avformat_write_header avcodec_encode_video2 avcodec_free_frame avcodec_open2 avformat_new_stream av_frame_alloc av_frame_free])
 204   AC_CHECK_DECLS([AVMEDIA_TYPE_VIDEO], [], [], [#include <libavcodec/avcodec.h>])
 205   AC_CHECK_DECLS([AV_CODEC_ID_NONE], [], [], [#include <libavcodec/avcodec.h>])
 206   AC_CHECK_DECLS([AV_PIX_FMT_RGB24], [], [], [#include <libavutil/pixfmt.h>])
 207   AC_CHECK_DECLS([AV_PIX_FMT_YUV420P], [], [], [#include <libavutil/pixfmt.h>])
 208   CXXFLAGS=$save_CXXFLAGS
 209   LIBS=$save_LIBS
 210 ], [
 211   dnl Build without movie export feature.
 212 ])
 213 AC_SUBST([LIBAV_LIBS])
 214 AC_SUBST([LIBAV_CFLAGS])
 215
 216 dnl Check for PROJ4
 217 PKG_CHECK_MODULES([PROJ], [proj], [
 218 ], [
 219   dnl pkg-config support in proj seems quite new, so probe directly if not
 220   dnl found.
 221   AC_CHECK_LIB([proj], [pj_init_plus], [
 222       PROJ_LIBS=-lproj
 223       PROJ_CFLAGS=
 224     ], [
 225       AC_MSG_ERROR([PROJ4 required for coordinate transformations])
 226     ])
 227 ])
 228 AC_SUBST([PROJ_LIBS])
 229 AC_SUBST([PROJ_CFLAGS])
 230
 231 dnl Checks for header files.
 232 AC_HEADER_STDC
 233 dnl don't use AC_CHECK_FUNCS for setjmp - mingw #define-s it to _setjmp
 234 AC_CHECK_HEADERS(limits.h string.h setjmp.h sys/select.h)
 235
 236 dnl Checks for typedefs, structures, and compiler characteristics.
 237 AC_TYPE_SIZE_T
 238 AC_STRUCT_TM
 239 AC_TYPE_SIGNAL
 240
 241 dnl check if CLOCKS_PER_SEC is defined by time.h (as ANSI says it should be)
 242 dnl if it isn't, assume it is 1000000, as it is on SunOS 4
 243 AC_TRY_COMPILE([#include <time.h>],[
 244 #ifndef CLOCKS_PER_SEC
 245 choke me
 246 #endif
 247 ], , AC_DEFINE(CLOCKS_PER_SEC, 1000000, [For old systems which don't define it themselves]))
 248
 249 dnl Check for 16-bit and 32-bit integer types.
 250 AC_TYPE_INT16_T
 251 AC_TYPE_INT32_T
 252
 253 dnl Checks for library functions.
 254 AC_FUNC_STRFTIME
 255 if test yes != "$ac_cv_func_strftime"; then
 256   AC_LIBOBJ(strftime)
 257 fi
 258 AC_FUNC_VPRINTF
 259 dnl Check if there's a declaration of lround().  Below we also check for
 260 dnl lround() with AC_CHECK_FUNCS, which just checks if it can be linked
 261 dnl against.  Some platforms are missing a prototype for lround(), so
 262 dnl both checks are useful.
 263 AC_CHECK_DECLS([lround], [], [], [[#include <math.h>]])
 264 dnl check for strcasecmp here as well as below - this one is to get
 265 dnl HAVE_STRCASECMP defined if appropriate (for img.c)
 266 AC_CHECK_FUNCS([popen getpwuid lround strcasecmp hypot lstat mmap])
 267
 268 dnl difftime seems to be an ANSI invention
 269 AC_CHECK_FUNCS(difftime)
 270
 271 dnl Much faster than using getc()/putc(), at least on Linux.
 272 AC_CHECK_FUNCS([getc_unlocked putc_unlocked])
 273
 274 AC_CHECK_FUNCS([setenv unsetenv])
 275
 276 dnl try to find a case-insensitive compare
 277
 278 strcasecmp=no
 279 dnl The order of these tests is important.
 280 AC_CHECK_FUNC(strcasecmp, [strcasecmp=strcasecmp])
 281 if test no = "$strcasecmp"; then
 282   AC_CHECK_FUNC(stricmp, [strcasecmp=stricmp])
 283 fi
 284 if test no = "$strcasecmp"; then
 285   AC_CHECK_FUNC(strcmpi, [strcasecmp=strcmpi])
 286 fi
 287
 288 AC_MSG_CHECKING([how to compare strings ignoring case])
 289 case $strcasecmp in
 290 no)
 291   AC_LIBOBJ(strcasecmp)
 292   AC_MSG_RESULT([using own implementation of strcasecmp]) ;;
 293 strcasecmp)
 294   AC_MSG_RESULT([strcasecmp]) ;;
 295 *)
 296   AC_DEFINE_UNQUOTED(strcasecmp, "$strcasecmp",
 297     [strcasecmp define for systems which call it something else])
 298   AC_MSG_RESULT([$strcasecmp]) ;;
 299 esac
 300
 301 AC_MSG_CHECKING(for sgmltools v2 or v3)
 302 if test : != "$SGMLTOOLS" ; then
 303   : ${SGMLTOOLS=sgmltools}
 304   case `(exec 2>&5 ; $SGMLTOOLS --version)` in
 305   *" version 3"*)
 306     AC_MSG_RESULT([$SGMLTOOLS]) ;;
 307   *" version 2"*)
 308     AC_MSG_RESULT([$SGMLTOOLS]) ;;
 309   *)
 310     SGMLTOOLS="$MISSING sgmltools"
 311     AC_MSG_RESULT(not found) ;;
 312   esac
 313 else
 314   AC_MSG_RESULT([$SGMLTOOLS])
 315 fi
 316 AC_SUBST(SGMLTOOLS)
 317 AC_ARG_VAR(SGMLTOOLS, [sgmltools command])
 318
 319 AC_MSG_CHECKING(for docbook2man)
 320 if test : != "$DOCBOOK2MAN" ; then
 321   : ${DOCBOOK2MAN=docbook2man}
 322   $DOCBOOK2MAN 2> /dev/null
 323   if test $? = 1 ; then
 324     AC_MSG_RESULT([$DOCBOOK2MAN])
 325   else
 326     DOCBOOK2MAN="$MISSING docbook2man"
 327     AC_MSG_RESULT([not found])
 328   fi
 329 else
 330   AC_MSG_RESULT([$DOCBOOK2MAN])
 331 fi
 332 AC_SUBST(DOCBOOK2MAN)
 333 AC_ARG_VAR(DOCBOOK2MAN, [docbook2man command])
 334
 335 dnl extra warning flags for building with GCC
 336 if test yes = "$GCC"; then
 337   if test yes = "$cross_compiling"; then
 338 dnl    AM_CFLAGS="$AM_CFLAGS -Werror -Wall -Wunused -Wpointer-arith\
 339 dnl      -Wwrite-strings -Wcast-align"
 340 dnl -Wsign-compare causes a warning with the mingw FD_SET macro, so we have
 341 dnl to disable it for mingw builds.
 342     AM_CFLAGS="$AM_CFLAGS -Wall -Wunused -Wpointer-arith\
 343       -Wwrite-strings -Wcast-align"
 344     AM_CXXFLAGS="$AM_CXXFLAGS -Wall -Wunused -Wpointer-arith\
 345       -Wwrite-strings -Wcast-align -Wno-sign-compare"
 346   else
 347     AM_CFLAGS="$AM_CFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
 348       -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wnested-externs\
 349       -Wcast-align"
 350     AM_CXXFLAGS="$AM_CXXFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
 351       -Wwrite-strings -Wcast-align"
 352   fi
 353   dnl too many complaints from headers, etc: -Wconversion
 354 fi
 355 AC_SUBST(AM_CFLAGS)
 356 AC_SUBST(AM_CXXFLAGS)
 357
 358 dnl See if large file support is available.  Survex is unlikely to need to
 359 dnl process files > 2GB in size, but LFS is also needed for stat() to work
 360 dnl on filing systems which return 64 bit inode values, such as CIFS mounts.
 361 AC_SYS_LARGEFILE
 362
 363 AC_ARG_ENABLE(profiling,
 364 [  --enable-profiling Build binaries to generate profiling information],
 365 [case $enableval in
 366   yes) AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 367        AM_CFLAGS="$AM_CFLAGS -pg"
 368        AC_MSG_RESULT(building binaries to generate profiling information);;
 369   no) ;;
 370   *) AC_MSG_ERROR(bad value $enableval for --enable-profiling) ;;
 371 esac])
 372
 373 HTMLFILES="AUTHORS.htm HACKING.htm NEWS.htm OLDNEWS.htm TODO.htm index.htm 3dformat.htm 3dformat-old.htm"
 374 AC_SUBST(HTMLFILES)
 375
 376 EXTRA_TEXT="AUTHORS COPYING NEWS TODO ChangeLog"
 377 AC_SUBST(EXTRA_TEXT)
 378
 379 AC_SUBST_FILE(DESC)
 380 DESC=desc.txt
 381 AC_SUBST_FILE(AVENDESC)
 382 AVENDESC=desc-aven.txt
 383
 384 dnl Don't define DATADIR if building for MS Windows - it won't be used, and
 385 dnl can conflict with the DATADIR typedef in objidl.h
 386 if test no = "$mswindows"; then
 387   AC_DEFINE_DIR(DATADIR, datadir, [Location of platform independent support files])
 388 fi
 389
 390 AH_BOTTOM(
 391 [/* Use getc_unlocked() and putc_unlocked() where available, since they are
 392  * faster, and we don't multithread file accesses.
 393  */
 394
 395 #ifdef HAVE_GETC_UNLOCKED
 396 # define GETC(F) getc_unlocked(F)
 397 #else
 398 # define GETC(F) getc(F)
 399 #endif
 400 #ifdef HAVE_PUTC_UNLOCKED
 401 # define PUTC(C, F) putc_unlocked(C, F)
 402 #else
 403 # define PUTC(C, F) putc(C, F)
 404 #endif
 405 ])
 406
 407 AC_CONFIG_FILES([
 408  Makefile src/Makefile doc/Makefile lib/Makefile lib/icons/Makefile
 409  lib/images/Makefile
 410  tests/Makefile vim/Makefile survex.iss doc/index.htm doc/survex.7
 411  survex.spec lib/Info.plist
 412  ])
 413 AC_OUTPUT
 414 dnl FIXME update msvc makefile for 1.2 branch
 415 dnl src/msvc/config.h