ext/rtree/rtreeE.test

   1 # 2010 August 28
   2 #
   3 # The author disclaims copyright to this source code.  In place of
   4 # a legal notice, here is a blessing:
   5 #
   6 #    May you do good and not evil.
   7 #    May you find forgiveness for yourself and forgive others.
   8 #    May you share freely, never taking more than you give.
   9 #
  10 #***********************************************************************
  11 # This file contains tests for the r-tree module. Specifically, it tests
  12 # that new-style custom r-tree queries (geometry callbacks) work.
  13 #
  14
  15 if {![info exists testdir]} {
  16   set testdir [file join [file dirname [info script]] .. .. test]
  17 }
  18 source [file join [file dirname [info script]] rtree_util.tcl]
  19 source $testdir/tester.tcl
  20 ifcapable !rtree { finish_test ; return }
  21 ifcapable rtree_int_only { finish_test; return }
  22
  23
  24 #-------------------------------------------------------------------------
  25 # Test the example 2d "circle" geometry callback.
  26 #
  27 register_circle_geom db
  28
  29 do_execsql_test rtreeE-1.0.0 {
  30   PRAGMA page_size=512;
  31   CREATE VIRTUAL TABLE rt1 USING rtree(id,x0,x1,y0,y1);
  32
  33   /* A tight pattern of small boxes near 0,0 */
  34   WITH RECURSIVE
  35     x(x) AS (VALUES(0) UNION ALL SELECT x+1 FROM x WHERE x<4),
  36     y(y) AS (VALUES(0) UNION ALL SELECT y+1 FROM y WHERE y<4)
  37   INSERT INTO rt1 SELECT x+5*y, x, x+2, y, y+2 FROM x, y;
  38
  39   /* A looser pattern of small boxes near 100, 0 */
  40   WITH RECURSIVE
  41     x(x) AS (VALUES(0) UNION ALL SELECT x+1 FROM x WHERE x<4),
  42     y(y) AS (VALUES(0) UNION ALL SELECT y+1 FROM y WHERE y<4)
  43   INSERT INTO rt1 SELECT 100+x+5*y, x*3+100, x*3+102, y*3, y*3+2 FROM x, y;
  44
  45   /* A looser pattern of larger boxes near 0, 200 */
  46   WITH RECURSIVE
  47     x(x) AS (VALUES(0) UNION ALL SELECT x+1 FROM x WHERE x<4),
  48     y(y) AS (VALUES(0) UNION ALL SELECT y+1 FROM y WHERE y<4)
  49   INSERT INTO rt1 SELECT 200+x+5*y, x*7, x*7+15, y*7+200, y*7+215 FROM x, y;
  50 } {}
  51 do_rtree_integrity_test rtreeE-1.0.1 rt1
  52
  53 # Queries against each of the three clusters */
  54 do_execsql_test rtreeE-1.1 {
  55   SELECT id FROM rt1 WHERE id MATCH Qcircle(0.0, 0.0, 50.0, 3) ORDER BY id;
  56 } {0 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24}
  57 do_execsql_test rtreeE-1.1x {
  58   SELECT id FROM rt1 WHERE id MATCH Qcircle('x:0 y:0 r:50.0 e:3') ORDER BY id;
  59 } {0 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24}
  60 do_execsql_test rtreeE-1.2 {
  61   SELECT id FROM rt1 WHERE id MATCH Qcircle(100.0, 0.0, 50.0, 3) ORDER BY id;
  62 } {100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124}
  63 do_execsql_test rtreeE-1.3 {
  64   SELECT id FROM rt1 WHERE id MATCH Qcircle(0.0, 200.0, 50.0, 3) ORDER BY id;
  65 } {200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224}
  66
  67 # The Qcircle geometry function gives a lower score to larger leaf-nodes.
  68 # This causes the 200s to sort before the 100s and the 0s to sort before
  69 # last.
  70 #
  71 do_execsql_test rtreeE-1.4 {
  72   SELECT id FROM rt1 WHERE id MATCH Qcircle('r:1000 e:3') AND id%100==0
  73 } {200 100 0}
  74
  75 # Exclude odd rowids on a depth-first search
  76 do_execsql_test rtreeE-1.5 {
  77   SELECT id FROM rt1 WHERE id MATCH Qcircle('r:1000 e:4') ORDER BY +id
  78 } {0 2 4 6 8 10 12 14 16 18 20 22 24 100 102 104 106 108 110 112 114 116 118 120 122 124 200 202 204 206 208 210 212 214 216 218 220 222 224}
  79
  80 # Exclude odd rowids on a breadth-first search.
  81 do_execsql_test rtreeE-1.6 {
  82   SELECT id FROM rt1 WHERE id MATCH Qcircle(0,0,1000,5) ORDER BY +id
  83 } {0 2 4 6 8 10 12 14 16 18 20 22 24 100 102 104 106 108 110 112 114 116 118 120 122 124 200 202 204 206 208 210 212 214 216 218 220 222 224}
  84
  85 # Test that rtree prefers MATCH to lookup-by-rowid.
  86 #
  87 do_execsql_test rtreeE-1.7 {
  88   SELECT id FROM rt1 WHERE id=18 AND id MATCH Qcircle(0,0,1000,5)
  89 } {18}
  90
  91
  92 # Construct a large 2-D RTree with thousands of random entries.
  93 #
  94 do_test rtreeE-2.1 {
  95   db eval {
  96     CREATE TABLE t2(id,x0,x1,y0,y1);
  97     CREATE VIRTUAL TABLE rt2 USING rtree(id,x0,x1,y0,y1);
  98     BEGIN;
  99   }
 100   expr srand(0)
 101   for {set i 1} {$i<=10000} {incr i} {
 102     set dx [expr {int(rand()*40)+1}]
 103     set dy [expr {int(rand()*40)+1}]
 104     set x0 [expr {int(rand()*(10000 - $dx))}]
 105     set x1 [expr {$x0+$dx}]
 106     set y0 [expr {int(rand()*(10000 - $dy))}]
 107     set y1 [expr {$y0+$dy}]
 108     set id [expr {$i+10000}]
 109     db eval {INSERT INTO t2 VALUES($id,$x0,$x1,$y0,$y1)}
 110   }
 111   db eval {
 112     INSERT INTO rt2 SELECT * FROM t2;
 113     COMMIT;
 114   }
 115 } {}
 116 do_rtree_integrity_test rtreeE-2.1.1 rt2
 117
 118 for {set i 1} {$i<=200} {incr i} {
 119   set dx [expr {int(rand()*100)}]
 120   set dy [expr {int(rand()*100)}]
 121   set x0 [expr {int(rand()*(10000 - $dx))}]
 122   set x1 [expr {$x0+$dx}]
 123   set y0 [expr {int(rand()*(10000 - $dy))}]
 124   set y1 [expr {$y0+$dy}]
 125   set ans [db eval {SELECT id FROM t2 WHERE x1>=$x0 AND x0<=$x1 AND y1>=$y0 AND y0<=$y1 ORDER BY id}]
 126   do_execsql_test rtreeE-2.2.$i {
 127     SELECT id FROM rt2 WHERE id MATCH breadthfirstsearch($x0,$x1,$y0,$y1) ORDER BY id
 128   } $ans
 129 }
 130
 131 # Run query that have very deep priority queues
 132 #
 133 set ans [db eval {SELECT id FROM t2 WHERE x1>=0 AND x0<=5000 AND y1>=0 AND y0<=5000 ORDER BY id}]
 134 do_execsql_test rtreeE-2.3 {
 135   SELECT id FROM rt2 WHERE id MATCH breadthfirstsearch(0,5000,0,5000) ORDER BY id
 136 } $ans
 137 set ans [db eval {SELECT id FROM t2 WHERE x1>=0 AND x0<=10000 AND y1>=0 AND y0<=10000 ORDER BY id}]
 138 do_execsql_test rtreeE-2.4 {
 139   SELECT id FROM rt2 WHERE id MATCH breadthfirstsearch(0,10000,0,10000) ORDER BY id
 140 } $ans
 141
 142
 143 finish_test