test/tester.tcl

   1 # 2001 September 15
   2 #
   3 # The author disclaims copyright to this source code.  In place of
   4 # a legal notice, here is a blessing:
   5 #
   6 #    May you do good and not evil.
   7 #    May you find forgiveness for yourself and forgive others.
   8 #    May you share freely, never taking more than you give.
   9 #
  10 #***********************************************************************
  11 # This file implements some common TCL routines used for regression
  12 # testing the SQLite library
  13 #
  14 # $Id: tester.tcl,v 1.143 2009/04/09 01:23:49 drh Exp $
  15
  16 #-------------------------------------------------------------------------
  17 # The commands provided by the code in this file to help with creating
  18 # test cases are as follows:
  19 #
  20 # Commands to manipulate the db and the file-system at a high level:
  21 #
  22 #      is_relative_file
  23 #      test_pwd
  24 #      get_pwd
  25 #      copy_file              FROM TO
  26 #      delete_file            FILENAME
  27 #      drop_all_tables        ?DB?
  28 #      drop_all_indexes       ?DB?
  29 #      forcecopy              FROM TO
  30 #      forcedelete            FILENAME
  31 #
  32 # Test the capability of the SQLite version built into the interpreter to
  33 # determine if a specific test can be run:
  34 #
  35 #      capable                EXPR
  36 #      ifcapable              EXPR
  37 #
  38 # Calulate checksums based on database contents:
  39 #
  40 #      dbcksum                DB DBNAME
  41 #      allcksum               ?DB?
  42 #      cksum                  ?DB?
  43 #
  44 # Commands to execute/explain SQL statements:
  45 #
  46 #      memdbsql               SQL
  47 #      stepsql                DB SQL
  48 #      execsql2               SQL
  49 #      explain_no_trace       SQL
  50 #      explain                SQL ?DB?
  51 #      catchsql               SQL ?DB?
  52 #      execsql                SQL ?DB?
  53 #
  54 # Commands to run test cases:
  55 #
  56 #      do_ioerr_test          TESTNAME ARGS...
  57 #      crashsql               ARGS...
  58 #      integrity_check        TESTNAME ?DB?
  59 #      verify_ex_errcode      TESTNAME EXPECTED ?DB?
  60 #      do_test                TESTNAME SCRIPT EXPECTED
  61 #      do_execsql_test        TESTNAME SQL EXPECTED
  62 #      do_catchsql_test       TESTNAME SQL EXPECTED
  63 #      do_timed_execsql_test  TESTNAME SQL EXPECTED
  64 #
  65 # Commands providing a lower level interface to the global test counters:
  66 #
  67 #      set_test_counter       COUNTER ?VALUE?
  68 #      omit_test              TESTNAME REASON ?APPEND?
  69 #      fail_test              TESTNAME
  70 #      incr_ntest
  71 #
  72 # Command run at the end of each test file:
  73 #
  74 #      finish_test
  75 #
  76 # Commands to help create test files that run with the "WAL" and other
  77 # permutations (see file permutations.test):
  78 #
  79 #      wal_is_wal_mode
  80 #      wal_set_journal_mode   ?DB?
  81 #      wal_check_journal_mode TESTNAME?DB?
  82 #      permutation
  83 #      presql
  84 #
  85 # Command to test whether or not --verbose=1 was specified on the command
  86 # line (returns 0 for not-verbose, 1 for verbose and 2 for "verbose in the
  87 # output file only").
  88 #
  89 #      verbose
  90 #
  91
  92 # Set the precision of FP arithmatic used by the interpreter. And
  93 # configure SQLite to take database file locks on the page that begins
  94 # 64KB into the database file instead of the one 1GB in. This means
  95 # the code that handles that special case can be tested without creating
  96 # very large database files.
  97 #
  98 set tcl_precision 15
  99 sqlite3_test_control_pending_byte 0x0010000
 100
 101
 102 # If the pager codec is available, create a wrapper for the [sqlite3]
 103 # command that appends "-key {xyzzy}" to the command line. i.e. this:
 104 #
 105 #     sqlite3 db test.db
 106 #
 107 # becomes
 108 #
 109 #     sqlite3 db test.db -key {xyzzy}
 110 #
 111 if {[info command sqlite_orig]==""} {
 112   rename sqlite3 sqlite_orig
 113   proc sqlite3 {args} {
 114     if {[llength $args]>=2 && [string index [lindex $args 0] 0]!="-"} {
 115       # This command is opening a new database connection.
 116       #
 117       if {[info exists ::G(perm:sqlite3_args)]} {
 118         set args [concat $args $::G(perm:sqlite3_args)]
 119       }
 120       if {[sqlite_orig -has-codec] && ![info exists ::do_not_use_codec]} {
 121         lappend args -key {xyzzy}
 122       }
 123
 124       set res [uplevel 1 sqlite_orig $args]
 125       if {[info exists ::G(perm:presql)]} {
 126         [lindex $args 0] eval $::G(perm:presql)
 127       }
 128       if {[info exists ::G(perm:dbconfig)]} {
 129         set ::dbhandle [lindex $args 0]
 130         uplevel #0 $::G(perm:dbconfig)
 131       }
 132       set res
 133     } else {
 134       # This command is not opening a new database connection. Pass the
 135       # arguments through to the C implementation as the are.
 136       #
 137       uplevel 1 sqlite_orig $args
 138     }
 139   }
 140 }
 141
 142 proc getFileRetries {} {
 143   if {![info exists ::G(file-retries)]} {
 144     #
 145     # NOTE: Return the default number of retries for [file] operations.  A
 146     #       value of zero or less here means "disabled".
 147     #
 148     return [expr {$::tcl_platform(platform) eq "windows" ? 50 : 0}]
 149   }
 150   return $::G(file-retries)
 151 }
 152
 153 proc getFileRetryDelay {} {
 154   if {![info exists ::G(file-retry-delay)]} {
 155     #
 156     # NOTE: Return the default number of milliseconds to wait when retrying
 157     #       failed [file] operations.  A value of zero or less means "do not
 158     #       wait".
 159     #
 160     return 100; # TODO: Good default?
 161   }
 162   return $::G(file-retry-delay)
 163 }
 164
 165 # Return the string representing the name of the current directory.  On
 166 # Windows, the result is "normalized" to whatever our parent command shell
 167 # is using to prevent case-mismatch issues.
 168 #
 169 proc get_pwd {} {
 170   if {$::tcl_platform(platform) eq "windows"} {
 171     #
 172     # NOTE: Cannot use [file normalize] here because it would alter the
 173     #       case of the result to what Tcl considers canonical, which would
 174     #       defeat the purpose of this procedure.
 175     #
 176     return [string map [list \\ /] \
 177         [string trim [exec -- $::env(ComSpec) /c echo %CD%]]]
 178   } else {
 179     return [pwd]
 180   }
 181 }
 182
 183 # Copy file $from into $to. This is used because some versions of
 184 # TCL for windows (notably the 8.4.1 binary package shipped with the
 185 # current mingw release) have a broken "file copy" command.
 186 #
 187 proc copy_file {from to} {
 188   do_copy_file false $from $to
 189 }
 190
 191 proc forcecopy {from to} {
 192   do_copy_file true $from $to
 193 }
 194
 195 proc do_copy_file {force from to} {
 196   set nRetry [getFileRetries]     ;# Maximum number of retries.
 197   set nDelay [getFileRetryDelay]  ;# Delay in ms before retrying.
 198
 199   # On windows, sometimes even a [file copy -force] can fail. The cause is
 200   # usually "tag-alongs" - programs like anti-virus software, automatic backup
 201   # tools and various explorer extensions that keep a file open a little longer
 202   # than we expect, causing the delete to fail.
 203   #
 204   # The solution is to wait a short amount of time before retrying the copy.
 205   #
 206   if {$nRetry > 0} {
 207     for {set i 0} {$i<$nRetry} {incr i} {
 208       set rc [catch {
 209         if {$force} {
 210           file copy -force $from $to
 211         } else {
 212           file copy $from $to
 213         }
 214       } msg]
 215       if {$rc==0} break
 216       if {$nDelay > 0} { after $nDelay }
 217     }
 218     if {$rc} { error $msg }
 219   } else {
 220     if {$force} {
 221       file copy -force $from $to
 222     } else {
 223       file copy $from $to
 224     }
 225   }
 226 }
 227
 228 # Check if a file name is relative
 229 #
 230 proc is_relative_file { file } {
 231   return [expr {[file pathtype $file] != "absolute"}]
 232 }
 233
 234 # If the VFS supports using the current directory, returns [pwd];
 235 # otherwise, it returns only the provided suffix string (which is
 236 # empty by default).
 237 #
 238 proc test_pwd { args } {
 239   if {[llength $args] > 0} {
 240     set suffix1 [lindex $args 0]
 241     if {[llength $args] > 1} {
 242       set suffix2 [lindex $args 1]
 243     } else {
 244       set suffix2 $suffix1
 245     }
 246   } else {
 247     set suffix1 ""; set suffix2 ""
 248   }
 249   ifcapable curdir {
 250     return "[get_pwd]$suffix1"
 251   } else {
 252     return $suffix2
 253   }
 254 }
 255
 256 # Delete a file or directory
 257 #
 258 proc delete_file {args} {
 259   do_delete_file false {*}$args
 260 }
 261
 262 proc forcedelete {args} {
 263   do_delete_file true {*}$args
 264 }
 265
 266 proc do_delete_file {force args} {
 267   set nRetry [getFileRetries]     ;# Maximum number of retries.
 268   set nDelay [getFileRetryDelay]  ;# Delay in ms before retrying.
 269
 270   foreach filename $args {
 271     # On windows, sometimes even a [file delete -force] can fail just after
 272     # a file is closed. The cause is usually "tag-alongs" - programs like
 273     # anti-virus software, automatic backup tools and various explorer
 274     # extensions that keep a file open a little longer than we expect, causing
 275     # the delete to fail.
 276     #
 277     # The solution is to wait a short amount of time before retrying the
 278     # delete.
 279     #
 280     if {$nRetry > 0} {
 281       for {set i 0} {$i<$nRetry} {incr i} {
 282         set rc [catch {
 283           if {$force} {
 284             file delete -force $filename
 285           } else {
 286             file delete $filename
 287           }
 288         } msg]
 289         if {$rc==0} break
 290         if {$nDelay > 0} { after $nDelay }
 291       }
 292       if {$rc} { error $msg }
 293     } else {
 294       if {$force} {
 295         file delete -force $filename
 296       } else {
 297         file delete $filename
 298       }
 299     }
 300   }
 301 }
 302
 303 if {$::tcl_platform(platform) eq "windows"} {
 304   proc do_remove_win32_dir {args} {
 305     set nRetry [getFileRetries]     ;# Maximum number of retries.
 306     set nDelay [getFileRetryDelay]  ;# Delay in ms before retrying.
 307
 308     foreach dirName $args {
 309       # On windows, sometimes even a [remove_win32_dir] can fail just after
 310       # a directory is emptied. The cause is usually "tag-alongs" - programs
 311       # like anti-virus software, automatic backup tools and various explorer
 312       # extensions that keep a file open a little longer than we expect,
 313       # causing the delete to fail.
 314       #
 315       # The solution is to wait a short amount of time before retrying the
 316       # removal.
 317       #
 318       if {$nRetry > 0} {
 319         for {set i 0} {$i < $nRetry} {incr i} {
 320           set rc [catch {
 321             remove_win32_dir $dirName
 322           } msg]
 323           if {$rc == 0} break
 324           if {$nDelay > 0} { after $nDelay }
 325         }
 326         if {$rc} { error $msg }
 327       } else {
 328         remove_win32_dir $dirName
 329       }
 330     }
 331   }
 332
 333   proc do_delete_win32_file {args} {
 334     set nRetry [getFileRetries]     ;# Maximum number of retries.
 335     set nDelay [getFileRetryDelay]  ;# Delay in ms before retrying.
 336
 337     foreach fileName $args {
 338       # On windows, sometimes even a [delete_win32_file] can fail just after
 339       # a file is closed. The cause is usually "tag-alongs" - programs like
 340       # anti-virus software, automatic backup tools and various explorer
 341       # extensions that keep a file open a little longer than we expect,
 342       # causing the delete to fail.
 343       #
 344       # The solution is to wait a short amount of time before retrying the
 345       # delete.
 346       #
 347       if {$nRetry > 0} {
 348         for {set i 0} {$i < $nRetry} {incr i} {
 349           set rc [catch {
 350             delete_win32_file $fileName
 351           } msg]
 352           if {$rc == 0} break
 353           if {$nDelay > 0} { after $nDelay }
 354         }
 355         if {$rc} { error $msg }
 356       } else {
 357         delete_win32_file $fileName
 358       }
 359     }
 360   }
 361 }
 362
 363 proc execpresql {handle args} {
 364   trace remove execution $handle enter [list execpresql $handle]
 365   if {[info exists ::G(perm:presql)]} {
 366     $handle eval $::G(perm:presql)
 367   }
 368 }
 369
 370 # This command should be called after loading tester.tcl from within
 371 # all test scripts that are incompatible with encryption codecs.
 372 #
 373 proc do_not_use_codec {} {
 374   set ::do_not_use_codec 1
 375   reset_db
 376 }
 377 unset -nocomplain do_not_use_codec
 378
 379 # Return true if the "reserved_bytes" integer on database files is non-zero.
 380 #
 381 proc nonzero_reserved_bytes {} {
 382   return [sqlite3 -has-codec]
 383 }
 384
 385 # Print a HELP message and exit
 386 #
 387 proc print_help_and_quit {} {
 388   puts {Options:
 389   --pause                  Wait for user input before continuing
 390   --soft-heap-limit=N      Set the soft-heap-limit to N
 391   --maxerror=N             Quit after N errors
 392   --verbose=(0|1)          Control the amount of output.  Default '1'
 393   --output=FILE            set --verbose=2 and output to FILE.  Implies -q
 394   -q                       Shorthand for --verbose=0
 395   --help                   This message
 396 }
 397   exit 1
 398 }
 399
 400 # The following block only runs the first time this file is sourced. It
 401 # does not run in slave interpreters (since the ::cmdlinearg array is
 402 # populated before the test script is run in slave interpreters).
 403 #
 404 if {[info exists cmdlinearg]==0} {
 405
 406   # Parse any options specified in the $argv array. This script accepts the
 407   # following options:
 408   #
 409   #   --pause
 410   #   --soft-heap-limit=NN
 411   #   --maxerror=NN
 412   #   --malloctrace=N
 413   #   --backtrace=N
 414   #   --binarylog=N
 415   #   --soak=N
 416   #   --file-retries=N
 417   #   --file-retry-delay=N
 418   #   --start=[$permutation:]$testfile
 419   #   --match=$pattern
 420   #   --verbose=$val
 421   #   --output=$filename
 422   #   -q                                      Reduce output
 423   #   --testdir=$dir                          Run tests in subdirectory $dir
 424   #   --help
 425   #
 426   set cmdlinearg(soft-heap-limit)    0
 427   set cmdlinearg(maxerror)        1000
 428   set cmdlinearg(malloctrace)        0
 429   set cmdlinearg(backtrace)         10
 430   set cmdlinearg(binarylog)          0
 431   set cmdlinearg(soak)               0
 432   set cmdlinearg(file-retries)       0
 433   set cmdlinearg(file-retry-delay)   0
 434   set cmdlinearg(start)             ""
 435   set cmdlinearg(match)             ""
 436   set cmdlinearg(verbose)           ""
 437   set cmdlinearg(output)            ""
 438   set cmdlinearg(testdir)           "testdir"
 439
 440   set leftover [list]
 441   foreach a $argv {
 442     switch -regexp -- $a {
 443       {^-+pause$} {
 444         # Wait for user input before continuing. This is to give the user an
 445         # opportunity to connect profiling tools to the process.
 446         puts -nonewline "Press RETURN to begin..."
 447         flush stdout
 448         gets stdin
 449       }
 450       {^-+soft-heap-limit=.+$} {
 451         foreach {dummy cmdlinearg(soft-heap-limit)} [split $a =] break
 452       }
 453       {^-+maxerror=.+$} {
 454         foreach {dummy cmdlinearg(maxerror)} [split $a =] break
 455       }
 456       {^-+malloctrace=.+$} {
 457         foreach {dummy cmdlinearg(malloctrace)} [split $a =] break
 458         if {$cmdlinearg(malloctrace)} {
 459           sqlite3_memdebug_log start
 460         }
 461       }
 462       {^-+backtrace=.+$} {
 463         foreach {dummy cmdlinearg(backtrace)} [split $a =] break
 464         sqlite3_memdebug_backtrace $cmdlinearg(backtrace)
 465       }
 466       {^-+binarylog=.+$} {
 467         foreach {dummy cmdlinearg(binarylog)} [split $a =] break
 468         set cmdlinearg(binarylog) [file normalize $cmdlinearg(binarylog)]
 469       }
 470       {^-+soak=.+$} {
 471         foreach {dummy cmdlinearg(soak)} [split $a =] break
 472         set ::G(issoak) $cmdlinearg(soak)
 473       }
 474       {^-+file-retries=.+$} {
 475         foreach {dummy cmdlinearg(file-retries)} [split $a =] break
 476         set ::G(file-retries) $cmdlinearg(file-retries)
 477       }
 478       {^-+file-retry-delay=.+$} {
 479         foreach {dummy cmdlinearg(file-retry-delay)} [split $a =] break
 480         set ::G(file-retry-delay) $cmdlinearg(file-retry-delay)
 481       }
 482       {^-+start=.+$} {
 483         foreach {dummy cmdlinearg(start)} [split $a =] break
 484
 485         set ::G(start:file) $cmdlinearg(start)
 486         if {[regexp {(.*):(.*)} $cmdlinearg(start) -> s.perm s.file]} {
 487           set ::G(start:permutation) ${s.perm}
 488           set ::G(start:file)        ${s.file}
 489         }
 490         if {$::G(start:file) == ""} {unset ::G(start:file)}
 491       }
 492       {^-+match=.+$} {
 493         foreach {dummy cmdlinearg(match)} [split $a =] break
 494
 495         set ::G(match) $cmdlinearg(match)
 496         if {$::G(match) == ""} {unset ::G(match)}
 497       }
 498
 499       {^-+output=.+$} {
 500         foreach {dummy cmdlinearg(output)} [split $a =] break
 501         set cmdlinearg(output) [file normalize $cmdlinearg(output)]
 502         if {$cmdlinearg(verbose)==""} {
 503           set cmdlinearg(verbose) 2
 504         }
 505       }
 506       {^-+verbose=.+$} {
 507         foreach {dummy cmdlinearg(verbose)} [split $a =] break
 508         if {$cmdlinearg(verbose)=="file"} {
 509           set cmdlinearg(verbose) 2
 510         } elseif {[string is boolean -strict $cmdlinearg(verbose)]==0} {
 511           error "option --verbose= must be set to a boolean or to \"file\""
 512         }
 513       }
 514       {^-+testdir=.*$} {
 515         foreach {dummy cmdlinearg(testdir)} [split $a =] break
 516       }
 517       {.*help.*} {
 518          print_help_and_quit
 519       }
 520       {^-q$} {
 521         set cmdlinearg(output) test-out.txt
 522         set cmdlinearg(verbose) 2
 523       }
 524
 525       default {
 526         if {[file tail $a]==$a} {
 527           lappend leftover $a
 528         } else {
 529           lappend leftover [file normalize $a]
 530         }
 531       }
 532     }
 533   }
 534   set testdir [file normalize $testdir]
 535   set cmdlinearg(TESTFIXTURE_HOME) [pwd]
 536   set cmdlinearg(INFO_SCRIPT) [file normalize [info script]]
 537   set argv0 [file normalize $argv0]
 538   if {$cmdlinearg(testdir)!=""} {
 539     file mkdir $cmdlinearg(testdir)
 540     cd $cmdlinearg(testdir)
 541   }
 542   set argv $leftover
 543
 544   # Install the malloc layer used to inject OOM errors. And the 'automatic'
 545   # extensions. This only needs to be done once for the process.
 546   #
 547   sqlite3_shutdown
 548   install_malloc_faultsim 1
 549   sqlite3_initialize
 550   autoinstall_test_functions
 551
 552   # If the --binarylog option was specified, create the logging VFS. This
 553   # call installs the new VFS as the default for all SQLite connections.
 554   #
 555   if {$cmdlinearg(binarylog)} {
 556     vfslog new binarylog {} vfslog.bin
 557   }
 558
 559   # Set the backtrace depth, if malloc tracing is enabled.
 560   #
 561   if {$cmdlinearg(malloctrace)} {
 562     sqlite3_memdebug_backtrace $cmdlinearg(backtrace)
 563   }
 564
 565   if {$cmdlinearg(output)!=""} {
 566     puts "Copying output to file $cmdlinearg(output)"
 567     set ::G(output_fd) [open $cmdlinearg(output) w]
 568     fconfigure $::G(output_fd) -buffering line
 569   }
 570
 571   if {$cmdlinearg(verbose)==""} {
 572     set cmdlinearg(verbose) 1
 573   }
 574 }
 575
 576 # Update the soft-heap-limit each time this script is run. In that
 577 # way if an individual test file changes the soft-heap-limit, it
 578 # will be reset at the start of the next test file.
 579 #
 580 sqlite3_soft_heap_limit $cmdlinearg(soft-heap-limit)
 581
 582 # Create a test database
 583 #
 584 proc reset_db {} {
 585   catch {db close}
 586   forcedelete test.db
 587   forcedelete test.db-journal
 588   forcedelete test.db-wal
 589   sqlite3 db ./test.db
 590   set ::DB [sqlite3_connection_pointer db]
 591   if {[info exists ::SETUP_SQL]} {
 592     db eval $::SETUP_SQL
 593   }
 594 }
 595 reset_db
 596
 597 # Abort early if this script has been run before.
 598 #
 599 if {[info exists TC(count)]} return
 600
 601 # Make sure memory statistics are enabled.
 602 #
 603 sqlite3_config_memstatus 1
 604
 605 # Initialize the test counters and set up commands to access them.
 606 # Or, if this is a slave interpreter, set up aliases to write the
 607 # counters in the parent interpreter.
 608 #
 609 if {0==[info exists ::SLAVE]} {
 610   set TC(errors)    0
 611   set TC(count)     0
 612   set TC(fail_list) [list]
 613   set TC(omit_list) [list]
 614   set TC(warn_list) [list]
 615
 616   proc set_test_counter {counter args} {
 617     if {[llength $args]} {
 618       set ::TC($counter) [lindex $args 0]
 619     }
 620     set ::TC($counter)
 621   }
 622 }
 623
 624 # Record the fact that a sequence of tests were omitted.
 625 #
 626 proc omit_test {name reason {append 1}} {
 627   set omitList [set_test_counter omit_list]
 628   if {$append} {
 629     lappend omitList [list $name $reason]
 630   }
 631   set_test_counter omit_list $omitList
 632 }
 633
 634 # Record the fact that a test failed.
 635 #
 636 proc fail_test {name} {
 637   set f [set_test_counter fail_list]
 638   lappend f $name
 639   set_test_counter fail_list $f
 640   set_test_counter errors [expr [set_test_counter errors] + 1]
 641
 642   set nFail [set_test_counter errors]
 643   if {$nFail>=$::cmdlinearg(maxerror)} {
 644     output2 "*** Giving up..."
 645     finalize_testing
 646   }
 647 }
 648
 649 # Remember a warning message to be displayed at the conclusion of all testing
 650 #
 651 proc warning {msg {append 1}} {
 652   output2 "Warning: $msg"
 653   set warnList [set_test_counter warn_list]
 654   if {$append} {
 655     lappend warnList $msg
 656   }
 657   set_test_counter warn_list $warnList
 658 }
 659
 660
 661 # Increment the number of tests run
 662 #
 663 proc incr_ntest {} {
 664   set_test_counter count [expr [set_test_counter count] + 1]
 665 }
 666
 667 # Return true if --verbose=1 was specified on the command line. Otherwise,
 668 # return false.
 669 #
 670 proc verbose {} {
 671   return $::cmdlinearg(verbose)
 672 }
 673
 674 # Use the following commands instead of [puts] for test output within
 675 # this file. Test scripts can still use regular [puts], which is directed
 676 # to stdout and, if one is open, the --output file.
 677 #
 678 # output1: output that should be printed if --verbose=1 was specified.
 679 # output2: output that should be printed unconditionally.
 680 # output2_if_no_verbose: output that should be printed only if --verbose=0.
 681 #
 682 proc output1 {args} {
 683   set v [verbose]
 684   if {$v==1} {
 685     uplevel output2 $args
 686   } elseif {$v==2} {
 687     uplevel puts [lrange $args 0 end-1] $::G(output_fd) [lrange $args end end]
 688   }
 689 }
 690 proc output2 {args} {
 691   set nArg [llength $args]
 692   uplevel puts $args
 693 }
 694 proc output2_if_no_verbose {args} {
 695   set v [verbose]
 696   if {$v==0} {
 697     uplevel output2 $args
 698   } elseif {$v==2} {
 699     uplevel puts [lrange $args 0 end-1] stdout [lrange $args end end]
 700   }
 701 }
 702
 703 # Override the [puts] command so that if no channel is explicitly
 704 # specified the string is written to both stdout and to the file
 705 # specified by "--output=", if any.
 706 #
 707 proc puts_override {args} {
 708   set nArg [llength $args]
 709   if {$nArg==1 || ($nArg==2 && [string first [lindex $args 0] -nonewline]==0)} {
 710     uplevel puts_original $args
 711     if {[info exists ::G(output_fd)]} {
 712       uplevel puts [lrange $args 0 end-1] $::G(output_fd) [lrange $args end end]
 713     }
 714   } else {
 715     # A channel was explicitly specified.
 716     uplevel puts_original $args
 717   }
 718 }
 719 rename puts puts_original
 720 proc puts {args} { uplevel puts_override $args }
 721
 722
 723 # Invoke the do_test procedure to run a single test
 724 #
 725 # The $expected parameter is the expected result.  The result is the return
 726 # value from the last TCL command in $cmd.
 727 #
 728 # Normally, $expected must match exactly.  But if $expected is of the form
 729 # "/regexp/" then regular expression matching is used.  If $expected is
 730 # "~/regexp/" then the regular expression must NOT match.  If $expected is
 731 # of the form "#/value-list/" then each term in value-list must be numeric
 732 # and must approximately match the corresponding numeric term in $result.
 733 # Values must match within 10%.  Or if the $expected term is A..B then the
 734 # $result term must be in between A and B.
 735 #
 736 proc do_test {name cmd expected} {
 737   global argv cmdlinearg
 738
 739   fix_testname name
 740
 741   sqlite3_memdebug_settitle $name
 742
 743 #  if {[llength $argv]==0} {
 744 #    set go 1
 745 #  } else {
 746 #    set go 0
 747 #    foreach pattern $argv {
 748 #      if {[string match $pattern $name]} {
 749 #        set go 1
 750 #        break
 751 #      }
 752 #    }
 753 #  }
 754
 755   if {[info exists ::G(perm:prefix)]} {
 756     set name "$::G(perm:prefix)$name"
 757   }
 758
 759   incr_ntest
 760   output1 -nonewline $name...
 761   flush stdout
 762
 763   if {![info exists ::G(match)] || [string match $::G(match) $name]} {
 764     if {[catch {uplevel #0 "$cmd;\n"} result]} {
 765       output2_if_no_verbose -nonewline $name...
 766       output2 "\nError: $result"
 767       fail_test $name
 768     } else {
 769       if {[regexp {^[~#]?/.*/$} $expected]} {
 770         # "expected" is of the form "/PATTERN/" then the result if correct if
 771         # regular expression PATTERN matches the result.  "~/PATTERN/" means
 772         # the regular expression must not match.
 773         if {[string index $expected 0]=="~"} {
 774           set re [string range $expected 2 end-1]
 775           if {[string index $re 0]=="*"} {
 776             # If the regular expression begins with * then treat it as a glob instead
 777             set ok [string match $re $result]
 778           } else {
 779             set re [string map {# {[-0-9.]+}} $re]
 780             set ok [regexp $re $result]
 781           }
 782           set ok [expr {!$ok}]
 783         } elseif {[string index $expected 0]=="#"} {
 784           # Numeric range value comparison.  Each term of the $result is matched
 785           # against one term of $expect.  Both $result and $expected terms must be
 786           # numeric.  The values must match within 10%.  Or if $expected is of the
 787           # form A..B then the $result term must be between A and B.
 788           set e2 [string range $expected 2 end-1]
 789           foreach i $result j $e2 {
 790             if {[regexp {^(-?\d+)\.\.(-?\d)$} $j all A B]} {
 791               set ok [expr {$i+0>=$A && $i+0<=$B}]
 792             } else {
 793               set ok [expr {$i+0>=0.9*$j && $i+0<=1.1*$j}]
 794             }
 795             if {!$ok} break
 796           }
 797           if {$ok && [llength $result]!=[llength $e2]} {set ok 0}
 798         } else {
 799           set re [string range $expected 1 end-1]
 800           if {[string index $re 0]=="*"} {
 801             # If the regular expression begins with * then treat it as a glob instead
 802             set ok [string match $re $result]
 803           } else {
 804             set re [string map {# {[-0-9.]+}} $re]
 805             set ok [regexp $re $result]
 806           }
 807         }
 808       } elseif {[regexp {^~?\*.*\*$} $expected]} {
 809         # "expected" is of the form "*GLOB*" then the result if correct if
 810         # glob pattern GLOB matches the result.  "~/GLOB/" means
 811         # the glob must not match.
 812         if {[string index $expected 0]=="~"} {
 813           set e [string range $expected 1 end]
 814           set ok [expr {![string match $e $result]}]
 815         } else {
 816           set ok [string match $expected $result]
 817         }
 818       } else {
 819         set ok [expr {[string compare $result $expected]==0}]
 820       }
 821       if {!$ok} {
 822         # if {![info exists ::testprefix] || $::testprefix eq ""} {
 823         #   error "no test prefix"
 824         # }
 825         output1 ""
 826         output2 "! $name expected: \[$expected\]\n! $name got:      \[$result\]"
 827         fail_test $name
 828       } else {
 829         output1 " Ok"
 830       }
 831     }
 832   } else {
 833     output1 " Omitted"
 834     omit_test $name "pattern mismatch" 0
 835   }
 836   flush stdout
 837 }
 838
 839 proc dumpbytes {s} {
 840   set r ""
 841   for {set i 0} {$i < [string length $s]} {incr i} {
 842     if {$i > 0} {append r " "}
 843     append r [format %02X [scan [string index $s $i] %c]]
 844   }
 845   return $r
 846 }
 847
 848 proc catchcmd {db {cmd ""}} {
 849   global CLI
 850   set out [open cmds.txt w]
 851   puts $out $cmd
 852   close $out
 853   set line "exec $CLI $db < cmds.txt"
 854   set rc [catch { eval $line } msg]
 855   list $rc $msg
 856 }
 857
 858 proc catchcmdex {db {cmd ""}} {
 859   global CLI
 860   set out [open cmds.txt w]
 861   fconfigure $out -encoding binary -translation binary
 862   puts -nonewline $out $cmd
 863   close $out
 864   set line "exec -keepnewline -- $CLI $db < cmds.txt"
 865   set chans [list stdin stdout stderr]
 866   foreach chan $chans {
 867     catch {
 868       set modes($chan) [fconfigure $chan]
 869       fconfigure $chan -encoding binary -translation binary -buffering none
 870     }
 871   }
 872   set rc [catch { eval $line } msg]
 873   foreach chan $chans {
 874     catch {
 875       eval fconfigure [list $chan] $modes($chan)
 876     }
 877   }
 878   # puts [dumpbytes $msg]
 879   list $rc $msg
 880 }
 881
 882 proc filepath_normalize {p} {
 883   # test cases should be written to assume "unix"-like file paths
 884   if {$::tcl_platform(platform)!="unix"} {
 885     # lreverse*2 as a hack to remove any unneeded {} after the string map
 886     lreverse [lreverse [string map {\\ /} [regsub -nocase -all {[a-z]:[/\\]+} $p {/}]]]
 887   } {
 888     set p
 889   }
 890 }
 891 proc do_filepath_test {name cmd expected} {
 892   uplevel [list do_test $name [
 893     subst -nocommands { filepath_normalize [ $cmd ] }
 894   ] [filepath_normalize $expected]]
 895 }
 896
 897 proc realnum_normalize {r} {
 898   # different TCL versions display floating point values differently.
 899   string map {1.#INF inf Inf inf .0e e} [regsub -all {(e[+-])0+} $r {\1}]
 900 }
 901 proc do_realnum_test {name cmd expected} {
 902   uplevel [list do_test $name [
 903     subst -nocommands { realnum_normalize [ $cmd ] }
 904   ] [realnum_normalize $expected]]
 905 }
 906
 907 proc fix_testname {varname} {
 908   upvar $varname testname
 909   if {[info exists ::testprefix]
 910    && [string is digit [string range $testname 0 0]]
 911   } {
 912     set testname "${::testprefix}-$testname"
 913   }
 914 }
 915
 916 proc normalize_list {L} {
 917   set L2 [list]
 918   foreach l $L {lappend L2 $l}
 919   set L2
 920 }
 921
 922 # Either:
 923 #
 924 #   do_execsql_test TESTNAME SQL ?RES?
 925 #   do_execsql_test -db DB TESTNAME SQL ?RES?
 926 #
 927 proc do_execsql_test {args} {
 928   set db db
 929   if {[lindex $args 0]=="-db"} {
 930     set db [lindex $args 1]
 931     set args [lrange $args 2 end]
 932   }
 933
 934   if {[llength $args]==2} {
 935     foreach {testname sql} $args {}
 936     set result ""
 937   } elseif {[llength $args]==3} {
 938     foreach {testname sql result} $args {}
 939   } else {
 940     error [string trim {
 941       wrong # args: should be "do_execsql_test ?-db DB? testname sql ?result?"
 942     }]
 943   }
 944
 945   fix_testname testname
 946
 947   uplevel do_test                 \
 948       [list $testname]            \
 949       [list "execsql {$sql} $db"] \
 950       [list [list {*}$result]]
 951 }
 952
 953 proc do_catchsql_test {testname sql result} {
 954   fix_testname testname
 955   uplevel do_test [list $testname] [list "catchsql {$sql}"] [list $result]
 956 }
 957 proc do_timed_execsql_test {testname sql {result {}}} {
 958   fix_testname testname
 959   uplevel do_test [list $testname] [list "execsql_timed {$sql}"]\
 960                                    [list [list {*}$result]]
 961 }
 962
 963 # Run an EXPLAIN QUERY PLAN $sql in database "db".  Then rewrite the output
 964 # as an ASCII-art graph and return a string that is that graph.
 965 #
 966 # Hexadecimal literals in the output text are converted into "xxxxxx" since those
 967 # literals are pointer values that might very from one run of the test to the
 968 # next, yet we want the output to be consistent.
 969 #
 970 proc query_plan_graph {sql} {
 971   db eval "EXPLAIN QUERY PLAN $sql" {
 972     set dx($id) $detail
 973     lappend cx($parent) $id
 974   }
 975   set a "\n  QUERY PLAN\n"
 976   append a [append_graph "  " dx cx 0]
 977   return [regsub -all { 0x[A-F0-9]+\y} $a { xxxxxx}]
 978 }
 979
 980 # Helper routine for [query_plan_graph SQL]:
 981 #
 982 # Output rows of the graph that are children of $level.
 983 #
 984 #   prefix:  Prepend to every output line
 985 #
 986 #   dxname:  Name of an array variable that stores text describe
 987 #            The description for $id is $dx($id)
 988 #
 989 #   cxname:  Name of an array variable holding children of item.
 990 #            Children of $id are $cx($id)
 991 #
 992 #   level:   Render all lines that are children of $level
 993 #
 994 proc append_graph {prefix dxname cxname level} {
 995   upvar $dxname dx $cxname cx
 996   set a ""
 997   set x $cx($level)
 998   set n [llength $x]
 999   for {set i 0} {$i<$n} {incr i} {
1000     set id [lindex $x $i]
1001     if {$i==$n-1} {
1002       set p1 "`--"
1003       set p2 "   "
1004     } else {
1005       set p1 "|--"
1006       set p2 "|  "
1007     }
1008     append a $prefix$p1$dx($id)\n
1009     if {[info exists cx($id)]} {
1010       append a [append_graph "$prefix$p2" dx cx $id]
1011     }
1012   }
1013   return $a
1014 }
1015
1016 # Do an EXPLAIN QUERY PLAN test on input $sql with expected results $res
1017 #
1018 # If $res begins with a "\s+QUERY PLAN\n" then it is assumed to be the
1019 # complete graph which must match the output of [query_plan_graph $sql]
1020 # exactly.
1021 #
1022 # If $res does not begin with "\s+QUERY PLAN\n" then take it is a string
1023 # that must be found somewhere in the query plan output.
1024 #
1025 proc do_eqp_test {name sql res} {
1026   if {[regexp {^\s+QUERY PLAN\n} $res]} {
1027     uplevel do_test $name [list [list query_plan_graph $sql]] [list $res]
1028   } else {
1029     if {[string index $res 0]!="/"} {
1030       set res "/*$res*/"
1031     }
1032     uplevel do_execsql_test $name [list "EXPLAIN QUERY PLAN $sql"] [list $res]
1033   }
1034 }
1035
1036
1037 #-------------------------------------------------------------------------
1038 #   Usage: do_select_tests PREFIX ?SWITCHES? TESTLIST
1039 #
1040 # Where switches are:
1041 #
1042 #   -errorformat FMTSTRING
1043 #   -count
1044 #   -query SQL
1045 #   -tclquery TCL
1046 #   -repair TCL
1047 #
1048 proc do_select_tests {prefix args} {
1049
1050   set testlist [lindex $args end]
1051   set switches [lrange $args 0 end-1]
1052
1053   set errfmt ""
1054   set countonly 0
1055   set tclquery ""
1056   set repair ""
1057
1058   for {set i 0} {$i < [llength $switches]} {incr i} {
1059     set s [lindex $switches $i]
1060     set n [string length $s]
1061     if {$n>=2 && [string equal -length $n $s "-query"]} {
1062       set tclquery [list execsql [lindex $switches [incr i]]]
1063     } elseif {$n>=2 && [string equal -length $n $s "-tclquery"]} {
1064       set tclquery [lindex $switches [incr i]]
1065     } elseif {$n>=2 && [string equal -length $n $s "-errorformat"]} {
1066       set errfmt [lindex $switches [incr i]]
1067     } elseif {$n>=2 && [string equal -length $n $s "-repair"]} {
1068       set repair [lindex $switches [incr i]]
1069     } elseif {$n>=2 && [string equal -length $n $s "-count"]} {
1070       set countonly 1
1071     } else {
1072       error "unknown switch: $s"
1073     }
1074   }
1075
1076   if {$countonly && $errfmt!=""} {
1077     error "Cannot use -count and -errorformat together"
1078   }
1079   set nTestlist [llength $testlist]
1080   if {$nTestlist%3 || $nTestlist==0 } {
1081     error "SELECT test list contains [llength $testlist] elements"
1082   }
1083
1084   eval $repair
1085   foreach {tn sql res} $testlist {
1086     if {$tclquery != ""} {
1087       execsql $sql
1088       uplevel do_test ${prefix}.$tn [list $tclquery] [list [list {*}$res]]
1089     } elseif {$countonly} {
1090       set nRow 0
1091       db eval $sql {incr nRow}
1092       uplevel do_test ${prefix}.$tn [list [list set {} $nRow]] [list $res]
1093     } elseif {$errfmt==""} {
1094       uplevel do_execsql_test ${prefix}.${tn} [list $sql] [list [list {*}$res]]
1095     } else {
1096       set res [list 1 [string trim [format $errfmt {*}$res]]]
1097       uplevel do_catchsql_test ${prefix}.${tn} [list $sql] [list $res]
1098     }
1099     eval $repair
1100   }
1101
1102 }
1103
1104 proc delete_all_data {} {
1105   db eval {SELECT tbl_name AS t FROM sqlite_master WHERE type = 'table'} {
1106     db eval "DELETE FROM '[string map {' ''} $t]'"
1107   }
1108 }
1109
1110 # Run an SQL script.
1111 # Return the number of microseconds per statement.
1112 #
1113 proc speed_trial {name numstmt units sql} {
1114   output2 -nonewline [format {%-21.21s } $name...]
1115   flush stdout
1116   set speed [time {sqlite3_exec_nr db $sql}]
1117   set tm [lindex $speed 0]
1118   if {$tm == 0} {
1119     set rate [format %20s "many"]
1120   } else {
1121     set rate [format %20.5f [expr {1000000.0*$numstmt/$tm}]]
1122   }
1123   set u2 $units/s
1124   output2 [format {%12d uS %s %s} $tm $rate $u2]
1125   global total_time
1126   set total_time [expr {$total_time+$tm}]
1127   lappend ::speed_trial_times $name $tm
1128 }
1129 proc speed_trial_tcl {name numstmt units script} {
1130   output2 -nonewline [format {%-21.21s } $name...]
1131   flush stdout
1132   set speed [time {eval $script}]
1133   set tm [lindex $speed 0]
1134   if {$tm == 0} {
1135     set rate [format %20s "many"]
1136   } else {
1137     set rate [format %20.5f [expr {1000000.0*$numstmt/$tm}]]
1138   }
1139   set u2 $units/s
1140   output2 [format {%12d uS %s %s} $tm $rate $u2]
1141   global total_time
1142   set total_time [expr {$total_time+$tm}]
1143   lappend ::speed_trial_times $name $tm
1144 }
1145 proc speed_trial_init {name} {
1146   global total_time
1147   set total_time 0
1148   set ::speed_trial_times [list]
1149   sqlite3 versdb :memory:
1150   set vers [versdb one {SELECT sqlite_source_id()}]
1151   versdb close
1152   output2 "SQLite $vers"
1153 }
1154 proc speed_trial_summary {name} {
1155   global total_time
1156   output2 [format {%-21.21s %12d uS TOTAL} $name $total_time]
1157
1158   if { 0 } {
1159     sqlite3 versdb :memory:
1160     set vers [lindex [versdb one {SELECT sqlite_source_id()}] 0]
1161     versdb close
1162     output2 "CREATE TABLE IF NOT EXISTS time(version, script, test, us);"
1163     foreach {test us} $::speed_trial_times {
1164       output2 "INSERT INTO time VALUES('$vers', '$name', '$test', $us);"
1165     }
1166   }
1167 }
1168
1169 # Run this routine last
1170 #
1171 proc finish_test {} {
1172   catch {db close}
1173   catch {db1 close}
1174   catch {db2 close}
1175   catch {db3 close}
1176   if {0==[info exists ::SLAVE]} { finalize_testing }
1177 }
1178 proc finalize_testing {} {
1179   global sqlite_open_file_count
1180
1181   set omitList [set_test_counter omit_list]
1182
1183   catch {db close}
1184   catch {db2 close}
1185   catch {db3 close}
1186
1187   vfs_unlink_test
1188   sqlite3 db {}
1189   # sqlite3_clear_tsd_memdebug
1190   db close
1191   sqlite3_reset_auto_extension
1192
1193   sqlite3_soft_heap_limit 0
1194   set nTest [incr_ntest]
1195   set nErr [set_test_counter errors]
1196
1197   set nKnown 0
1198   if {[file readable known-problems.txt]} {
1199     set fd [open known-problems.txt]
1200     set content [read $fd]
1201     close $fd
1202     foreach x $content {set known_error($x) 1}
1203     foreach x [set_test_counter fail_list] {
1204       if {[info exists known_error($x)]} {incr nKnown}
1205     }
1206   }
1207   if {$nKnown>0} {
1208     output2 "[expr {$nErr-$nKnown}] new errors and $nKnown known errors\
1209          out of $nTest tests"
1210   } else {
1211     set cpuinfo {}
1212     if {[catch {exec hostname} hname]==0} {set cpuinfo [string trim $hname]}
1213     append cpuinfo " $::tcl_platform(os)"
1214     append cpuinfo " [expr {$::tcl_platform(pointerSize)*8}]-bit"
1215     append cpuinfo " [string map {E -e} $::tcl_platform(byteOrder)]"
1216     output2 "SQLite [sqlite3 -sourceid]"
1217     output2 "$nErr errors out of $nTest tests on $cpuinfo"
1218   }
1219   if {$nErr>$nKnown} {
1220     output2 -nonewline "!Failures on these tests:"
1221     foreach x [set_test_counter fail_list] {
1222       if {![info exists known_error($x)]} {output2 -nonewline " $x"}
1223     }
1224     output2 ""
1225   }
1226   foreach warning [set_test_counter warn_list] {
1227     output2 "Warning: $warning"
1228   }
1229   run_thread_tests 1
1230   if {[llength $omitList]>0} {
1231     output2 "Omitted test cases:"
1232     set prec {}
1233     foreach {rec} [lsort $omitList] {
1234       if {$rec==$prec} continue
1235       set prec $rec
1236       output2 [format {.  %-12s %s} [lindex $rec 0] [lindex $rec 1]]
1237     }
1238   }
1239   if {$nErr>0 && ![working_64bit_int]} {
1240     output2 "******************************************************************"
1241     output2 "N.B.:  The version of TCL that you used to build this test harness"
1242     output2 "is defective in that it does not support 64-bit integers.  Some or"
1243     output2 "all of the test failures above might be a result from this defect"
1244     output2 "in your TCL build."
1245     output2 "******************************************************************"
1246   }
1247   if {$::cmdlinearg(binarylog)} {
1248     vfslog finalize binarylog
1249   }
1250   if {$sqlite_open_file_count} {
1251     output2 "$sqlite_open_file_count files were left open"
1252     incr nErr
1253   }
1254   if {[lindex [sqlite3_status SQLITE_STATUS_MALLOC_COUNT 0] 1]>0 ||
1255               [sqlite3_memory_used]>0} {
1256     output2 "Unfreed memory: [sqlite3_memory_used] bytes in\
1257          [lindex [sqlite3_status SQLITE_STATUS_MALLOC_COUNT 0] 1] allocations"
1258     incr nErr
1259     ifcapable memdebug||mem5||(mem3&&debug) {
1260       output2 "Writing unfreed memory log to \"./memleak.txt\""
1261       sqlite3_memdebug_dump ./memleak.txt
1262     }
1263   } else {
1264     output2 "All memory allocations freed - no leaks"
1265     ifcapable memdebug||mem5 {
1266       sqlite3_memdebug_dump ./memusage.txt
1267     }
1268   }
1269   show_memstats
1270   output2 "Maximum memory usage: [sqlite3_memory_highwater 1] bytes"
1271   output2 "Current memory usage: [sqlite3_memory_highwater] bytes"
1272   if {[info commands sqlite3_memdebug_malloc_count] ne ""} {
1273     output2 "Number of malloc()  : [sqlite3_memdebug_malloc_count] calls"
1274   }
1275   if {$::cmdlinearg(malloctrace)} {
1276     output2 "Writing mallocs.sql..."
1277     memdebug_log_sql
1278     sqlite3_memdebug_log stop
1279     sqlite3_memdebug_log clear
1280
1281     if {[sqlite3_memory_used]>0} {
1282       output2 "Writing leaks.sql..."
1283       sqlite3_memdebug_log sync
1284       memdebug_log_sql leaks.sql
1285     }
1286   }
1287   foreach f [glob -nocomplain test.db-*-journal] {
1288     forcedelete $f
1289   }
1290   foreach f [glob -nocomplain test.db-mj*] {
1291     forcedelete $f
1292   }
1293   exit [expr {$nErr>0}]
1294 }
1295
1296 # Display memory statistics for analysis and debugging purposes.
1297 #
1298 proc show_memstats {} {
1299   set x [sqlite3_status SQLITE_STATUS_MEMORY_USED 0]
1300   set y [sqlite3_status SQLITE_STATUS_MALLOC_SIZE 0]
1301   set val [format {now %10d  max %10d  max-size %10d} \
1302               [lindex $x 1] [lindex $x 2] [lindex $y 2]]
1303   output1 "Memory used:          $val"
1304   set x [sqlite3_status SQLITE_STATUS_MALLOC_COUNT 0]
1305   set val [format {now %10d  max %10d} [lindex $x 1] [lindex $x 2]]
1306   output1 "Allocation count:     $val"
1307   set x [sqlite3_status SQLITE_STATUS_PAGECACHE_USED 0]
1308   set y [sqlite3_status SQLITE_STATUS_PAGECACHE_SIZE 0]
1309   set val [format {now %10d  max %10d  max-size %10d} \
1310               [lindex $x 1] [lindex $x 2] [lindex $y 2]]
1311   output1 "Page-cache used:      $val"
1312   set x [sqlite3_status SQLITE_STATUS_PAGECACHE_OVERFLOW 0]
1313   set val [format {now %10d  max %10d} [lindex $x 1] [lindex $x 2]]
1314   output1 "Page-cache overflow:  $val"
1315   ifcapable yytrackmaxstackdepth {
1316     set x [sqlite3_status SQLITE_STATUS_PARSER_STACK 0]
1317     set val [format {               max %10d} [lindex $x 2]]
1318     output2 "Parser stack depth:    $val"
1319   }
1320 }
1321
1322 # A procedure to execute SQL
1323 #
1324 proc execsql {sql {db db}} {
1325   # puts "SQL = $sql"
1326   uplevel [list $db eval $sql]
1327 }
1328 proc execsql_timed {sql {db db}} {
1329   set tm [time {
1330     set x [uplevel [list $db eval $sql]]
1331   } 1]
1332   set tm [lindex $tm 0]
1333   output1 -nonewline " ([expr {$tm*0.001}]ms) "
1334   set x
1335 }
1336
1337 # Execute SQL and catch exceptions.
1338 #
1339 proc catchsql {sql {db db}} {
1340   # puts "SQL = $sql"
1341   set r [catch [list uplevel [list $db eval $sql]] msg]
1342   lappend r $msg
1343   return $r
1344 }
1345
1346 # Do an VDBE code dump on the SQL given
1347 #
1348 proc explain {sql {db db}} {
1349   output2 ""
1350   output2 "addr  opcode        p1      p2      p3      p4               p5  #"
1351   output2 "----  ------------  ------  ------  ------  ---------------  --  -"
1352   $db eval "explain $sql" {} {
1353     output2 [format {%-4d  %-12.12s  %-6d  %-6d  %-6d  % -17s %s  %s} \
1354       $addr $opcode $p1 $p2 $p3 $p4 $p5 $comment
1355     ]
1356   }
1357 }
1358
1359 proc explain_i {sql {db db}} {
1360   output2 ""
1361   output2 "addr  opcode        p1      p2      p3      p4                p5  #"
1362   output2 "----  ------------  ------  ------  ------  ----------------  --  -"
1363
1364
1365   # Set up colors for the different opcodes. Scheme is as follows:
1366   #
1367   #   Red:   Opcodes that write to a b-tree.
1368   #   Blue:  Opcodes that reposition or seek a cursor.
1369   #   Green: The ResultRow opcode.
1370   #
1371   if { [catch {fconfigure stdout -mode}]==0 } {
1372     set R "\033\[31;1m"        ;# Red fg
1373     set G "\033\[32;1m"        ;# Green fg
1374     set B "\033\[34;1m"        ;# Red fg
1375     set D "\033\[39;0m"        ;# Default fg
1376   } else {
1377     set R ""
1378     set G ""
1379     set B ""
1380     set D ""
1381   }
1382   foreach opcode {
1383       Seek SeekGE SeekGT SeekLE SeekLT NotFound Last Rewind
1384       NoConflict Next Prev VNext VPrev VFilter
1385       SorterSort SorterNext NextIfOpen
1386   } {
1387     set color($opcode) $B
1388   }
1389   foreach opcode {ResultRow} {
1390     set color($opcode) $G
1391   }
1392   foreach opcode {IdxInsert Insert Delete IdxDelete} {
1393     set color($opcode) $R
1394   }
1395
1396   set bSeenGoto 0
1397   $db eval "explain $sql" {} {
1398     set x($addr) 0
1399     set op($addr) $opcode
1400
1401     if {$opcode == "Goto" && ($bSeenGoto==0 || ($p2 > $addr+10))} {
1402       set linebreak($p2) 1
1403       set bSeenGoto 1
1404     }
1405
1406     if {$opcode=="Once"} {
1407       for {set i $addr} {$i<$p2} {incr i} {
1408         set star($i) $addr
1409       }
1410     }
1411
1412     if {$opcode=="Next"  || $opcode=="Prev"
1413      || $opcode=="VNext" || $opcode=="VPrev"
1414      || $opcode=="SorterNext" || $opcode=="NextIfOpen"
1415     } {
1416       for {set i $p2} {$i<$addr} {incr i} {
1417         incr x($i) 2
1418       }
1419     }
1420
1421     if {$opcode == "Goto" && $p2<$addr && $op($p2)=="Yield"} {
1422       for {set i [expr $p2+1]} {$i<$addr} {incr i} {
1423         incr x($i) 2
1424       }
1425     }
1426
1427     if {$opcode == "Halt" && $comment == "End of coroutine"} {
1428       set linebreak([expr $addr+1]) 1
1429     }
1430   }
1431
1432   $db eval "explain $sql" {} {
1433     if {[info exists linebreak($addr)]} {
1434       output2 ""
1435     }
1436     set I [string repeat " " $x($addr)]
1437
1438     if {[info exists star($addr)]} {
1439       set ii [expr $x($star($addr))]
1440       append I "  "
1441       set I [string replace $I $ii $ii *]
1442     }
1443
1444     set col ""
1445     catch { set col $color($opcode) }
1446
1447     output2 [format {%-4d  %s%s%-12.12s%s  %-6d  %-6d  %-6d  % -17s %s  %s} \
1448       $addr $I $col $opcode $D $p1 $p2 $p3 $p4 $p5 $comment
1449     ]
1450   }
1451   output2 "----  ------------  ------  ------  ------  ----------------  --  -"
1452 }
1453
1454 # Show the VDBE program for an SQL statement but omit the Trace
1455 # opcode at the beginning.  This procedure can be used to prove
1456 # that different SQL statements generate exactly the same VDBE code.
1457 #
1458 proc explain_no_trace {sql} {
1459   set tr [db eval "EXPLAIN $sql"]
1460   return [lrange $tr 7 end]
1461 }
1462
1463 # Another procedure to execute SQL.  This one includes the field
1464 # names in the returned list.
1465 #
1466 proc execsql2 {sql} {
1467   set result {}
1468   db eval $sql data {
1469     foreach f $data(*) {
1470       lappend result $f $data($f)
1471     }
1472   }
1473   return $result
1474 }
1475
1476 # Use a temporary in-memory database to execute SQL statements
1477 #
1478 proc memdbsql {sql} {
1479   sqlite3 memdb :memory:
1480   set result [memdb eval $sql]
1481   memdb close
1482   return $result
1483 }
1484
1485 # Use the non-callback API to execute multiple SQL statements
1486 #
1487 proc stepsql {dbptr sql} {
1488   set sql [string trim $sql]
1489   set r 0
1490   while {[string length $sql]>0} {
1491     if {[catch {sqlite3_prepare $dbptr $sql -1 sqltail} vm]} {
1492       return [list 1 $vm]
1493     }
1494     set sql [string trim $sqltail]
1495 #    while {[sqlite_step $vm N VAL COL]=="SQLITE_ROW"} {
1496 #      foreach v $VAL {lappend r $v}
1497 #    }
1498     while {[sqlite3_step $vm]=="SQLITE_ROW"} {
1499       for {set i 0} {$i<[sqlite3_data_count $vm]} {incr i} {
1500         lappend r [sqlite3_column_text $vm $i]
1501       }
1502     }
1503     if {[catch {sqlite3_finalize $vm} errmsg]} {
1504       return [list 1 $errmsg]
1505     }
1506   }
1507   return $r
1508 }
1509
1510 # Do an integrity check of the entire database
1511 #
1512 proc integrity_check {name {db db}} {
1513   ifcapable integrityck {
1514     do_test $name [list execsql {PRAGMA integrity_check} $db] {ok}
1515   }
1516 }
1517
1518 # Check the extended error code
1519 #
1520 proc verify_ex_errcode {name expected {db db}} {
1521   do_test $name [list sqlite3_extended_errcode $db] $expected
1522 }
1523
1524
1525 # Return true if the SQL statement passed as the second argument uses a
1526 # statement transaction.
1527 #
1528 proc sql_uses_stmt {db sql} {
1529   set stmt [sqlite3_prepare $db $sql -1 dummy]
1530   set uses [uses_stmt_journal $stmt]
1531   sqlite3_finalize $stmt
1532   return $uses
1533 }
1534
1535 proc fix_ifcapable_expr {expr} {
1536   set ret ""
1537   set state 0
1538   for {set i 0} {$i < [string length $expr]} {incr i} {
1539     set char [string range $expr $i $i]
1540     set newstate [expr {[string is alnum $char] || $char eq "_"}]
1541     if {$newstate && !$state} {
1542       append ret {$::sqlite_options(}
1543     }
1544     if {!$newstate && $state} {
1545       append ret )
1546     }
1547     append ret $char
1548     set state $newstate
1549   }
1550   if {$state} {append ret )}
1551   return $ret
1552 }
1553
1554 # Returns non-zero if the capabilities are present; zero otherwise.
1555 #
1556 proc capable {expr} {
1557   set e [fix_ifcapable_expr $expr]; return [expr ($e)]
1558 }
1559
1560 # Evaluate a boolean expression of capabilities.  If true, execute the
1561 # code.  Omit the code if false.
1562 #
1563 proc ifcapable {expr code {else ""} {elsecode ""}} {
1564   #regsub -all {[a-z_0-9]+} $expr {$::sqlite_options(&)} e2
1565   set e2 [fix_ifcapable_expr $expr]
1566   if ($e2) {
1567     set c [catch {uplevel 1 $code} r]
1568   } else {
1569     set c [catch {uplevel 1 $elsecode} r]
1570   }
1571   return -code $c $r
1572 }
1573
1574 # This proc execs a seperate process that crashes midway through executing
1575 # the SQL script $sql on database test.db.
1576 #
1577 # The crash occurs during a sync() of file $crashfile. When the crash
1578 # occurs a random subset of all unsynced writes made by the process are
1579 # written into the files on disk. Argument $crashdelay indicates the
1580 # number of file syncs to wait before crashing.
1581 #
1582 # The return value is a list of two elements. The first element is a
1583 # boolean, indicating whether or not the process actually crashed or
1584 # reported some other error. The second element in the returned list is the
1585 # error message. This is "child process exited abnormally" if the crash
1586 # occurred.
1587 #
1588 #   crashsql -delay CRASHDELAY -file CRASHFILE ?-blocksize BLOCKSIZE? $sql
1589 #
1590 proc crashsql {args} {
1591
1592   set blocksize ""
1593   set crashdelay 1
1594   set prngseed 0
1595   set opendb { sqlite3 db test.db -vfs crash }
1596   set tclbody {}
1597   set crashfile ""
1598   set dc ""
1599   set dfltvfs 0
1600   set sql [lindex $args end]
1601
1602   for {set ii 0} {$ii < [llength $args]-1} {incr ii 2} {
1603     set z [lindex $args $ii]
1604     set n [string length $z]
1605     set z2 [lindex $args [expr $ii+1]]
1606
1607     if     {$n>1 && [string first $z -delay]==0}     {set crashdelay $z2} \
1608     elseif {$n>1 && [string first $z -opendb]==0}    {set opendb $z2} \
1609     elseif {$n>1 && [string first $z -seed]==0}      {set prngseed $z2} \
1610     elseif {$n>1 && [string first $z -file]==0}      {set crashfile $z2}  \
1611     elseif {$n>1 && [string first $z -tclbody]==0}   {set tclbody $z2}  \
1612     elseif {$n>1 && [string first $z -blocksize]==0} {set blocksize "-s $z2" } \
1613     elseif {$n>1 && [string first $z -characteristics]==0} {set dc "-c {$z2}" }\
1614     elseif {$n>1 && [string first $z -dfltvfs]==0} {set dfltvfs $z2 }\
1615     else   { error "Unrecognized option: $z" }
1616   }
1617
1618   if {$crashfile eq ""} {
1619     error "Compulsory option -file missing"
1620   }
1621
1622   # $crashfile gets compared to the native filename in
1623   # cfSync(), which can be different then what TCL uses by
1624   # default, so here we force it to the "nativename" format.
1625   set cfile [string map {\\ \\\\} [file nativename [file join [get_pwd] $crashfile]]]
1626
1627   set f [open crash.tcl w]
1628   puts $f "sqlite3_crash_enable 1 $dfltvfs"
1629   puts $f "sqlite3_crashparams $blocksize $dc $crashdelay $cfile"
1630   puts $f "sqlite3_test_control_pending_byte $::sqlite_pending_byte"
1631
1632   # This block sets the cache size of the main database to 10
1633   # pages. This is done in case the build is configured to omit
1634   # "PRAGMA cache_size".
1635   if {$opendb!=""} {
1636     puts $f $opendb
1637     puts $f {db eval {SELECT * FROM sqlite_master;}}
1638     puts $f {set bt [btree_from_db db]}
1639     puts $f {btree_set_cache_size $bt 10}
1640   }
1641
1642   if {$prngseed} {
1643     set seed [expr {$prngseed%10007+1}]
1644     # puts seed=$seed
1645     puts $f "db eval {SELECT randomblob($seed)}"
1646   }
1647
1648   if {[string length $tclbody]>0} {
1649     puts $f $tclbody
1650   }
1651   if {[string length $sql]>0} {
1652     puts $f "db eval {"
1653     puts $f   "$sql"
1654     puts $f "}"
1655   }
1656   close $f
1657   set r [catch {
1658     exec [info nameofexec] crash.tcl >@stdout
1659   } msg]
1660
1661   # Windows/ActiveState TCL returns a slightly different
1662   # error message.  We map that to the expected message
1663   # so that we don't have to change all of the test
1664   # cases.
1665   if {$::tcl_platform(platform)=="windows"} {
1666     if {$msg=="child killed: unknown signal"} {
1667       set msg "child process exited abnormally"
1668     }
1669   }
1670
1671   lappend r $msg
1672 }
1673
1674 #   crash_on_write ?-devchar DEVCHAR? CRASHDELAY SQL
1675 #
1676 proc crash_on_write {args} {
1677
1678   set nArg [llength $args]
1679   if {$nArg<2 || $nArg%2} {
1680     error "bad args: $args"
1681   }
1682   set zSql [lindex $args end]
1683   set nDelay [lindex $args end-1]
1684
1685   set devchar {}
1686   for {set ii 0} {$ii < $nArg-2} {incr ii 2} {
1687     set opt [lindex $args $ii]
1688     switch -- [lindex $args $ii] {
1689       -devchar {
1690         set devchar [lindex $args [expr $ii+1]]
1691       }
1692
1693       default { error "unrecognized option: $opt" }
1694     }
1695   }
1696
1697   set f [open crash.tcl w]
1698   puts $f "sqlite3_crash_on_write $nDelay"
1699   puts $f "sqlite3_test_control_pending_byte $::sqlite_pending_byte"
1700   puts $f "sqlite3 db test.db -vfs writecrash"
1701   puts $f "db eval {$zSql}"
1702   puts $f "set {} {}"
1703
1704   close $f
1705   set r [catch {
1706     exec [info nameofexec] crash.tcl >@stdout
1707   } msg]
1708
1709   # Windows/ActiveState TCL returns a slightly different
1710   # error message.  We map that to the expected message
1711   # so that we don't have to change all of the test
1712   # cases.
1713   if {$::tcl_platform(platform)=="windows"} {
1714     if {$msg=="child killed: unknown signal"} {
1715       set msg "child process exited abnormally"
1716     }
1717   }
1718
1719   lappend r $msg
1720 }
1721
1722 proc run_ioerr_prep {} {
1723   set ::sqlite_io_error_pending 0
1724   catch {db close}
1725   catch {db2 close}
1726   catch {forcedelete test.db}
1727   catch {forcedelete test.db-journal}
1728   catch {forcedelete test2.db}
1729   catch {forcedelete test2.db-journal}
1730   set ::DB [sqlite3 db test.db; sqlite3_connection_pointer db]
1731   sqlite3_extended_result_codes $::DB $::ioerropts(-erc)
1732   if {[info exists ::ioerropts(-tclprep)]} {
1733     eval $::ioerropts(-tclprep)
1734   }
1735   if {[info exists ::ioerropts(-sqlprep)]} {
1736     execsql $::ioerropts(-sqlprep)
1737   }
1738   expr 0
1739 }
1740
1741 # Usage: do_ioerr_test <test number> <options...>
1742 #
1743 # This proc is used to implement test cases that check that IO errors
1744 # are correctly handled. The first argument, <test number>, is an integer
1745 # used to name the tests executed by this proc. Options are as follows:
1746 #
1747 #     -tclprep          TCL script to run to prepare test.
1748 #     -sqlprep          SQL script to run to prepare test.
1749 #     -tclbody          TCL script to run with IO error simulation.
1750 #     -sqlbody          TCL script to run with IO error simulation.
1751 #     -exclude          List of 'N' values not to test.
1752 #     -erc              Use extended result codes
1753 #     -persist          Make simulated I/O errors persistent
1754 #     -start            Value of 'N' to begin with (default 1)
1755 #
1756 #     -cksum            Boolean. If true, test that the database does
1757 #                       not change during the execution of the test case.
1758 #
1759 proc do_ioerr_test {testname args} {
1760
1761   set ::ioerropts(-start) 1
1762   set ::ioerropts(-cksum) 0
1763   set ::ioerropts(-erc) 0
1764   set ::ioerropts(-count) 100000000
1765   set ::ioerropts(-persist) 1
1766   set ::ioerropts(-ckrefcount) 0
1767   set ::ioerropts(-restoreprng) 1
1768   array set ::ioerropts $args
1769
1770   # TEMPORARY: For 3.5.9, disable testing of extended result codes. There are
1771   # a couple of obscure IO errors that do not return them.
1772   set ::ioerropts(-erc) 0
1773
1774   # Create a single TCL script from the TCL and SQL specified
1775   # as the body of the test.
1776   set ::ioerrorbody {}
1777   if {[info exists ::ioerropts(-tclbody)]} {
1778     append ::ioerrorbody "$::ioerropts(-tclbody)\n"
1779   }
1780   if {[info exists ::ioerropts(-sqlbody)]} {
1781     append ::ioerrorbody "db eval {$::ioerropts(-sqlbody)}"
1782   }
1783
1784   save_prng_state
1785   if {$::ioerropts(-cksum)} {
1786     run_ioerr_prep
1787     eval $::ioerrorbody
1788     set ::goodcksum [cksum]
1789   }
1790
1791   set ::go 1
1792   #reset_prng_state
1793   for {set n $::ioerropts(-start)} {$::go} {incr n} {
1794     set ::TN $n
1795     incr ::ioerropts(-count) -1
1796     if {$::ioerropts(-count)<0} break
1797
1798     # Skip this IO error if it was specified with the "-exclude" option.
1799     if {[info exists ::ioerropts(-exclude)]} {
1800       if {[lsearch $::ioerropts(-exclude) $n]!=-1} continue
1801     }
1802     if {$::ioerropts(-restoreprng)} {
1803       restore_prng_state
1804     }
1805
1806     # Delete the files test.db and test2.db, then execute the TCL and
1807     # SQL (in that order) to prepare for the test case.
1808     do_test $testname.$n.1 {
1809       run_ioerr_prep
1810     } {0}
1811
1812     # Read the 'checksum' of the database.
1813     if {$::ioerropts(-cksum)} {
1814       set ::checksum [cksum]
1815     }
1816
1817     # Set the Nth IO error to fail.
1818     do_test $testname.$n.2 [subst {
1819       set ::sqlite_io_error_persist $::ioerropts(-persist)
1820       set ::sqlite_io_error_pending $n
1821     }] $n
1822
1823     # Execute the TCL script created for the body of this test. If
1824     # at least N IO operations performed by SQLite as a result of
1825     # the script, the Nth will fail.
1826     do_test $testname.$n.3 {
1827       set ::sqlite_io_error_hit 0
1828       set ::sqlite_io_error_hardhit 0
1829       set r [catch $::ioerrorbody msg]
1830       set ::errseen $r
1831       set rc [sqlite3_errcode $::DB]
1832       if {$::ioerropts(-erc)} {
1833         # If we are in extended result code mode, make sure all of the
1834         # IOERRs we get back really do have their extended code values.
1835         # If an extended result code is returned, the sqlite3_errcode
1836         # TCLcommand will return a string of the form:  SQLITE_IOERR+nnnn
1837         # where nnnn is a number
1838         if {[regexp {^SQLITE_IOERR} $rc] && ![regexp {IOERR\+\d} $rc]} {
1839           return $rc
1840         }
1841       } else {
1842         # If we are not in extended result code mode, make sure no
1843         # extended error codes are returned.
1844         if {[regexp {\+\d} $rc]} {
1845           return $rc
1846         }
1847       }
1848       # The test repeats as long as $::go is non-zero.  $::go starts out
1849       # as 1.  When a test runs to completion without hitting an I/O
1850       # error, that means there is no point in continuing with this test
1851       # case so set $::go to zero.
1852       #
1853       if {$::sqlite_io_error_pending>0} {
1854         set ::go 0
1855         set q 0
1856         set ::sqlite_io_error_pending 0
1857       } else {
1858         set q 1
1859       }
1860
1861       set s [expr $::sqlite_io_error_hit==0]
1862       if {$::sqlite_io_error_hit>$::sqlite_io_error_hardhit && $r==0} {
1863         set r 1
1864       }
1865       set ::sqlite_io_error_hit 0
1866
1867       # One of two things must have happened. either
1868       #   1.  We never hit the IO error and the SQL returned OK
1869       #   2.  An IO error was hit and the SQL failed
1870       #
1871       #puts "s=$s r=$r q=$q"
1872       expr { ($s && !$r && !$q) || (!$s && $r && $q) }
1873     } {1}
1874
1875     set ::sqlite_io_error_hit 0
1876     set ::sqlite_io_error_pending 0
1877
1878     # Check that no page references were leaked. There should be
1879     # a single reference if there is still an active transaction,
1880     # or zero otherwise.
1881     #
1882     # UPDATE: If the IO error occurs after a 'BEGIN' but before any
1883     # locks are established on database files (i.e. if the error
1884     # occurs while attempting to detect a hot-journal file), then
1885     # there may 0 page references and an active transaction according
1886     # to [sqlite3_get_autocommit].
1887     #
1888     if {$::go && $::sqlite_io_error_hardhit && $::ioerropts(-ckrefcount)} {
1889       do_test $testname.$n.4 {
1890         set bt [btree_from_db db]
1891         db_enter db
1892         array set stats [btree_pager_stats $bt]
1893         db_leave db
1894         set nRef $stats(ref)
1895         expr {$nRef == 0 || ([sqlite3_get_autocommit db]==0 && $nRef == 1)}
1896       } {1}
1897     }
1898
1899     # If there is an open database handle and no open transaction,
1900     # and the pager is not running in exclusive-locking mode,
1901     # check that the pager is in "unlocked" state. Theoretically,
1902     # if a call to xUnlock() failed due to an IO error the underlying
1903     # file may still be locked.
1904     #
1905     ifcapable pragma {
1906       if { [info commands db] ne ""
1907         && $::ioerropts(-ckrefcount)
1908         && [db one {pragma locking_mode}] eq "normal"
1909         && [sqlite3_get_autocommit db]
1910       } {
1911         do_test $testname.$n.5 {
1912           set bt [btree_from_db db]
1913           db_enter db
1914           array set stats [btree_pager_stats $bt]
1915           db_leave db
1916           set stats(state)
1917         } 0
1918       }
1919     }
1920
1921     # If an IO error occurred, then the checksum of the database should
1922     # be the same as before the script that caused the IO error was run.
1923     #
1924     if {$::go && $::sqlite_io_error_hardhit && $::ioerropts(-cksum)} {
1925       do_test $testname.$n.6 {
1926         catch {db close}
1927         catch {db2 close}
1928         set ::DB [sqlite3 db test.db; sqlite3_connection_pointer db]
1929         set nowcksum [cksum]
1930         set res [expr {$nowcksum==$::checksum || $nowcksum==$::goodcksum}]
1931         if {$res==0} {
1932           output2 "now=$nowcksum"
1933           output2 "the=$::checksum"
1934           output2 "fwd=$::goodcksum"
1935         }
1936         set res
1937       } 1
1938     }
1939
1940     set ::sqlite_io_error_hardhit 0
1941     set ::sqlite_io_error_pending 0
1942     if {[info exists ::ioerropts(-cleanup)]} {
1943       catch $::ioerropts(-cleanup)
1944     }
1945   }
1946   set ::sqlite_io_error_pending 0
1947   set ::sqlite_io_error_persist 0
1948   unset ::ioerropts
1949 }
1950
1951 # Return a checksum based on the contents of the main database associated
1952 # with connection $db
1953 #
1954 proc cksum {{db db}} {
1955   set txt [$db eval {
1956       SELECT name, type, sql FROM sqlite_master order by name
1957   }]\n
1958   foreach tbl [$db eval {
1959       SELECT name FROM sqlite_master WHERE type='table' order by name
1960   }] {
1961     append txt [$db eval "SELECT * FROM $tbl"]\n
1962   }
1963   foreach prag {default_synchronous default_cache_size} {
1964     append txt $prag-[$db eval "PRAGMA $prag"]\n
1965   }
1966   set cksum [string length $txt]-[md5 $txt]
1967   # puts $cksum-[file size test.db]
1968   return $cksum
1969 }
1970
1971 # Generate a checksum based on the contents of the main and temp tables
1972 # database $db. If the checksum of two databases is the same, and the
1973 # integrity-check passes for both, the two databases are identical.
1974 #
1975 proc allcksum {{db db}} {
1976   set ret [list]
1977   ifcapable tempdb {
1978     set sql {
1979       SELECT name FROM sqlite_master WHERE type = 'table' UNION
1980       SELECT name FROM sqlite_temp_master WHERE type = 'table' UNION
1981       SELECT 'sqlite_master' UNION
1982       SELECT 'sqlite_temp_master' ORDER BY 1
1983     }
1984   } else {
1985     set sql {
1986       SELECT name FROM sqlite_master WHERE type = 'table' UNION
1987       SELECT 'sqlite_master' ORDER BY 1
1988     }
1989   }
1990   set tbllist [$db eval $sql]
1991   set txt {}
1992   foreach tbl $tbllist {
1993     append txt [$db eval "SELECT * FROM $tbl"]
1994   }
1995   foreach prag {default_cache_size} {
1996     append txt $prag-[$db eval "PRAGMA $prag"]\n
1997   }
1998   # puts txt=$txt
1999   return [md5 $txt]
2000 }
2001
2002 # Generate a checksum based on the contents of a single database with
2003 # a database connection.  The name of the database is $dbname.
2004 # Examples of $dbname are "temp" or "main".
2005 #
2006 proc dbcksum {db dbname} {
2007   if {$dbname=="temp"} {
2008     set master sqlite_temp_master
2009   } else {
2010     set master $dbname.sqlite_master
2011   }
2012   set alltab [$db eval "SELECT name FROM $master WHERE type='table'"]
2013   set txt [$db eval "SELECT * FROM $master"]\n
2014   foreach tab $alltab {
2015     append txt [$db eval "SELECT * FROM $dbname.$tab"]\n
2016   }
2017   return [md5 $txt]
2018 }
2019
2020 proc memdebug_log_sql {{filename mallocs.sql}} {
2021
2022   set data [sqlite3_memdebug_log dump]
2023   set nFrame [expr [llength [lindex $data 0]]-2]
2024   if {$nFrame < 0} { return "" }
2025
2026   set database temp
2027
2028   set tbl "CREATE TABLE ${database}.malloc(zTest, nCall, nByte, lStack);"
2029
2030   set sql ""
2031   foreach e $data {
2032     set nCall [lindex $e 0]
2033     set nByte [lindex $e 1]
2034     set lStack [lrange $e 2 end]
2035     append sql "INSERT INTO ${database}.malloc VALUES"
2036     append sql "('test', $nCall, $nByte, '$lStack');\n"
2037     foreach f $lStack {
2038       set frames($f) 1
2039     }
2040   }
2041
2042   set tbl2 "CREATE TABLE ${database}.frame(frame INTEGER PRIMARY KEY, line);\n"
2043   set tbl3 "CREATE TABLE ${database}.file(name PRIMARY KEY, content);\n"
2044
2045   foreach f [array names frames] {
2046     set addr [format %x $f]
2047     set cmd "addr2line -e [info nameofexec] $addr"
2048     set line [eval exec $cmd]
2049     append sql "INSERT INTO ${database}.frame VALUES($f, '$line');\n"
2050
2051     set file [lindex [split $line :] 0]
2052     set files($file) 1
2053   }
2054
2055   foreach f [array names files] {
2056     set contents ""
2057     catch {
2058       set fd [open $f]
2059       set contents [read $fd]
2060       close $fd
2061     }
2062     set contents [string map {' ''} $contents]
2063     append sql "INSERT INTO ${database}.file VALUES('$f', '$contents');\n"
2064   }
2065
2066   set fd [open $filename w]
2067   puts $fd "BEGIN; ${tbl}${tbl2}${tbl3}${sql} ; COMMIT;"
2068   close $fd
2069 }
2070
2071 # Drop all tables in database [db]
2072 proc drop_all_tables {{db db}} {
2073   ifcapable trigger&&foreignkey {
2074     set pk [$db one "PRAGMA foreign_keys"]
2075     $db eval "PRAGMA foreign_keys = OFF"
2076   }
2077   foreach {idx name file} [db eval {PRAGMA database_list}] {
2078     if {$idx==1} {
2079       set master sqlite_temp_master
2080     } else {
2081       set master $name.sqlite_master
2082     }
2083     foreach {t type} [$db eval "
2084       SELECT name, type FROM $master
2085       WHERE type IN('table', 'view') AND name NOT LIKE 'sqliteX_%' ESCAPE 'X'
2086     "] {
2087       $db eval "DROP $type \"$t\""
2088     }
2089   }
2090   ifcapable trigger&&foreignkey {
2091     $db eval "PRAGMA foreign_keys = $pk"
2092   }
2093 }
2094
2095 # Drop all auxiliary indexes from the main database opened by handle [db].
2096 #
2097 proc drop_all_indexes {{db db}} {
2098   set L [$db eval {
2099     SELECT name FROM sqlite_master WHERE type='index' AND sql LIKE 'create%'
2100   }]
2101   foreach idx $L { $db eval "DROP INDEX $idx" }
2102 }
2103
2104
2105 #-------------------------------------------------------------------------
2106 # If a test script is executed with global variable $::G(perm:name) set to
2107 # "wal", then the tests are run in WAL mode. Otherwise, they should be run
2108 # in rollback mode. The following Tcl procs are used to make this less
2109 # intrusive:
2110 #
2111 #   wal_set_journal_mode ?DB?
2112 #
2113 #     If running a WAL test, execute "PRAGMA journal_mode = wal" using
2114 #     connection handle DB. Otherwise, this command is a no-op.
2115 #
2116 #   wal_check_journal_mode TESTNAME ?DB?
2117 #
2118 #     If running a WAL test, execute a tests case that fails if the main
2119 #     database for connection handle DB is not currently a WAL database.
2120 #     Otherwise (if not running a WAL permutation) this is a no-op.
2121 #
2122 #   wal_is_wal_mode
2123 #
2124 #     Returns true if this test should be run in WAL mode. False otherwise.
2125 #
2126 proc wal_is_wal_mode {} {
2127   expr {[permutation] eq "wal"}
2128 }
2129 proc wal_set_journal_mode {{db db}} {
2130   if { [wal_is_wal_mode] } {
2131     $db eval "PRAGMA journal_mode = WAL"
2132   }
2133 }
2134 proc wal_check_journal_mode {testname {db db}} {
2135   if { [wal_is_wal_mode] } {
2136     $db eval { SELECT * FROM sqlite_master }
2137     do_test $testname [list $db eval "PRAGMA main.journal_mode"] {wal}
2138   }
2139 }
2140
2141 proc wal_is_capable {} {
2142   ifcapable !wal { return 0 }
2143   if {[permutation]=="journaltest"} { return 0 }
2144   return 1
2145 }
2146
2147 proc permutation {} {
2148   set perm ""
2149   catch {set perm $::G(perm:name)}
2150   set perm
2151 }
2152 proc presql {} {
2153   set presql ""
2154   catch {set presql $::G(perm:presql)}
2155   set presql
2156 }
2157
2158 proc isquick {} {
2159   set ret 0
2160   catch {set ret $::G(isquick)}
2161   set ret
2162 }
2163
2164 #-------------------------------------------------------------------------
2165 #
2166 proc slave_test_script {script} {
2167
2168   # Create the interpreter used to run the test script.
2169   interp create tinterp
2170
2171   # Populate some global variables that tester.tcl expects to see.
2172   foreach {var value} [list              \
2173     ::argv0 $::argv0                     \
2174     ::argv  {}                           \
2175     ::SLAVE 1                            \
2176   ] {
2177     interp eval tinterp [list set $var $value]
2178   }
2179
2180   # If output is being copied into a file, share the file-descriptor with
2181   # the interpreter.
2182   if {[info exists ::G(output_fd)]} {
2183     interp share {} $::G(output_fd) tinterp
2184   }
2185
2186   # The alias used to access the global test counters.
2187   tinterp alias set_test_counter set_test_counter
2188
2189   # Set up the ::cmdlinearg array in the slave.
2190   interp eval tinterp [list array set ::cmdlinearg [array get ::cmdlinearg]]
2191
2192   # Set up the ::G array in the slave.
2193   interp eval tinterp [list array set ::G [array get ::G]]
2194
2195   # Load the various test interfaces implemented in C.
2196   load_testfixture_extensions tinterp
2197
2198   # Run the test script.
2199   interp eval tinterp $script
2200
2201   # Check if the interpreter call [run_thread_tests]
2202   if { [interp eval tinterp {info exists ::run_thread_tests_called}] } {
2203     set ::run_thread_tests_called 1
2204   }
2205
2206   # Delete the interpreter used to run the test script.
2207   interp delete tinterp
2208 }
2209
2210 proc slave_test_file {zFile} {
2211   set tail [file tail $zFile]
2212
2213   if {[info exists ::G(start:permutation)]} {
2214     if {[permutation] != $::G(start:permutation)} return
2215     unset ::G(start:permutation)
2216   }
2217   if {[info exists ::G(start:file)]} {
2218     if {$tail != $::G(start:file) && $tail!="$::G(start:file).test"} return
2219     unset ::G(start:file)
2220   }
2221
2222   # Remember the value of the shared-cache setting. So that it is possible
2223   # to check afterwards that it was not modified by the test script.
2224   #
2225   ifcapable shared_cache { set scs [sqlite3_enable_shared_cache] }
2226
2227   # Run the test script in a slave interpreter.
2228   #
2229   unset -nocomplain ::run_thread_tests_called
2230   reset_prng_state
2231   set ::sqlite_open_file_count 0
2232   set time [time { slave_test_script [list source $zFile] }]
2233   set ms [expr [lindex $time 0] / 1000]
2234
2235   # Test that all files opened by the test script were closed. Omit this
2236   # if the test script has "thread" in its name. The open file counter
2237   # is not thread-safe.
2238   #
2239   if {[info exists ::run_thread_tests_called]==0} {
2240     do_test ${tail}-closeallfiles { expr {$::sqlite_open_file_count>0} } {0}
2241   }
2242   set ::sqlite_open_file_count 0
2243
2244   # Test that the global "shared-cache" setting was not altered by
2245   # the test script.
2246   #
2247   ifcapable shared_cache {
2248     set res [expr {[sqlite3_enable_shared_cache] == $scs}]
2249     do_test ${tail}-sharedcachesetting [list set {} $res] 1
2250   }
2251
2252   # Add some info to the output.
2253   #
2254   output2 "Time: $tail $ms ms"
2255   show_memstats
2256 }
2257
2258 # Open a new connection on database test.db and execute the SQL script
2259 # supplied as an argument. Before returning, close the new conection and
2260 # restore the 4 byte fields starting at header offsets 28, 92 and 96
2261 # to the values they held before the SQL was executed. This simulates
2262 # a write by a pre-3.7.0 client.
2263 #
2264 proc sql36231 {sql} {
2265   set B [hexio_read test.db 92 8]
2266   set A [hexio_read test.db 28 4]
2267   sqlite3 db36231 test.db
2268   catch { db36231 func a_string a_string }
2269   execsql $sql db36231
2270   db36231 close
2271   hexio_write test.db 28 $A
2272   hexio_write test.db 92 $B
2273   return ""
2274 }
2275
2276 proc db_save {} {
2277   foreach f [glob -nocomplain sv_test.db*] { forcedelete $f }
2278   foreach f [glob -nocomplain test.db*] {
2279     set f2 "sv_$f"
2280     forcecopy $f $f2
2281   }
2282 }
2283 proc db_save_and_close {} {
2284   db_save
2285   catch { db close }
2286   return ""
2287 }
2288 proc db_restore {} {
2289   foreach f [glob -nocomplain test.db*] { forcedelete $f }
2290   foreach f2 [glob -nocomplain sv_test.db*] {
2291     set f [string range $f2 3 end]
2292     forcecopy $f2 $f
2293   }
2294 }
2295 proc db_restore_and_reopen {{dbfile test.db}} {
2296   catch { db close }
2297   db_restore
2298   sqlite3 db $dbfile
2299 }
2300 proc db_delete_and_reopen {{file test.db}} {
2301   catch { db close }
2302   foreach f [glob -nocomplain test.db*] { forcedelete $f }
2303   sqlite3 db $file
2304 }
2305
2306 # Close any connections named [db], [db2] or [db3]. Then use sqlite3_config
2307 # to configure the size of the PAGECACHE allocation using the parameters
2308 # provided to this command. Save the old PAGECACHE parameters in a global
2309 # variable so that [test_restore_config_pagecache] can restore the previous
2310 # configuration.
2311 #
2312 # Before returning, reopen connection [db] on file test.db.
2313 #
2314 proc test_set_config_pagecache {sz nPg} {
2315   catch {db close}
2316   catch {db2 close}
2317   catch {db3 close}
2318
2319   sqlite3_shutdown
2320   set ::old_pagecache_config [sqlite3_config_pagecache $sz $nPg]
2321   sqlite3_initialize
2322   autoinstall_test_functions
2323   reset_db
2324 }
2325
2326 # Close any connections named [db], [db2] or [db3]. Then use sqlite3_config
2327 # to configure the size of the PAGECACHE allocation to the size saved in
2328 # the global variable by an earlier call to [test_set_config_pagecache].
2329 #
2330 # Before returning, reopen connection [db] on file test.db.
2331 #
2332 proc test_restore_config_pagecache {} {
2333   catch {db close}
2334   catch {db2 close}
2335   catch {db3 close}
2336
2337   sqlite3_shutdown
2338   eval sqlite3_config_pagecache $::old_pagecache_config
2339   unset ::old_pagecache_config
2340   sqlite3_initialize
2341   autoinstall_test_functions
2342   sqlite3 db test.db
2343 }
2344
2345 proc test_binary_name {nm} {
2346   if {$::tcl_platform(platform)=="windows"} {
2347     set ret "$nm.exe"
2348   } else {
2349     set ret $nm
2350   }
2351   file normalize [file join $::cmdlinearg(TESTFIXTURE_HOME) $ret]
2352 }
2353
2354 proc test_find_binary {nm} {
2355   set ret [test_binary_name $nm]
2356   if {![file executable $ret]} {
2357     finish_test
2358     return ""
2359   }
2360   return $ret
2361 }
2362
2363 # Find the name of the 'shell' executable (e.g. "sqlite3.exe") to use for
2364 # the tests in shell[1-5].test. If no such executable can be found, invoke
2365 # [finish_test ; return] in the callers context.
2366 #
2367 proc test_find_cli {} {
2368   set prog [test_find_binary sqlite3]
2369   if {$prog==""} { return -code return }
2370   return $prog
2371 }
2372
2373 # Find the name of the 'sqldiff' executable (e.g. "sqlite3.exe") to use for
2374 # the tests in sqldiff tests. If no such executable can be found, invoke
2375 # [finish_test ; return] in the callers context.
2376 #
2377 proc test_find_sqldiff {} {
2378   set prog [test_find_binary sqldiff]
2379   if {$prog==""} { return -code return }
2380   return $prog
2381 }
2382
2383 # Call sqlite3_expanded_sql() on all statements associated with database
2384 # connection $db. This sometimes finds use-after-free bugs if run with
2385 # valgrind or address-sanitizer.
2386 proc expand_all_sql {db} {
2387   set stmt ""
2388   while {[set stmt [sqlite3_next_stmt $db $stmt]]!=""} {
2389     sqlite3_expanded_sql $stmt
2390   }
2391 }
2392
2393
2394 # If the library is compiled with the SQLITE_DEFAULT_AUTOVACUUM macro set
2395 # to non-zero, then set the global variable $AUTOVACUUM to 1.
2396 set AUTOVACUUM $sqlite_options(default_autovacuum)
2397
2398 # Make sure the FTS enhanced query syntax is disabled.
2399 set sqlite_fts3_enable_parentheses 0
2400
2401 # During testing, assume that all database files are well-formed.  The
2402 # few test cases that deliberately corrupt database files should rescind
2403 # this setting by invoking "database_can_be_corrupt"
2404 #
2405 database_never_corrupt
2406
2407 source $testdir/thread_common.tcl
2408 source $testdir/malloc_common.tcl