configure.ac

   1 #
   2 # The build process allows for using a cross-compiler.  But the default
   3 # action is to target the same platform that we are running on.  The
   4 # configure script needs to discover the following properties of the
   5 # build and target systems:
   6 #
   7 #    srcdir
   8 #
   9 #        The is the name of the directory that contains the
  10 #        "configure" shell script.  All source files are
  11 #        located relative to this directory.
  12 #
  13 #    bindir
  14 #
  15 #        The name of the directory where executables should be
  16 #        written by the "install" target of the makefile.
  17 #
  18 #    program_prefix
  19 #
  20 #        Add this prefix to the names of all executables that run
  21 #        on the target machine.  Default: ""
  22 #
  23 #    ENABLE_SHARED
  24 #
  25 #        True if shared libraries should be generated.
  26 #
  27 #    BUILD_CC
  28 #
  29 #        The name of a command that is used to convert C
  30 #        source files into executables that run on the build
  31 #        platform.
  32 #
  33 #    BUILD_CFLAGS
  34 #
  35 #        Switches that the build compiler needs in order to construct
  36 #        command-line programs.
  37 #
  38 #    BUILD_LIBS
  39 #
  40 #        Libraries that the build compiler needs in order to construct
  41 #        command-line programs.
  42 #
  43 #    BUILD_EXEEXT
  44 #
  45 #        The filename extension for executables on the build
  46 #        platform.  "" for Unix and ".exe" for Windows.
  47 #
  48 #    TCL_*
  49 #
  50 #        Lots of values are read in from the tclConfig.sh script,
  51 #        if that script is available.  This values are used for
  52 #        constructing and installing the TCL extension.
  53 #
  54 #    TARGET_READLINE_LIBS
  55 #
  56 #        This is the library directives passed to the target linker
  57 #        that cause the executable to link against the readline library.
  58 #        This might be a switch like "-lreadline" or pathnames of library
  59 #        file like "../../src/libreadline.a".
  60 #
  61 #    TARGET_READLINE_INC
  62 #
  63 #        This variables define the directory that contain header
  64 #        files for the readline library.  If the compiler is able
  65 #        to find <readline.h> on its own, then this can be blank.
  66 #
  67 #    TARGET_EXEEXT
  68 #
  69 #        The filename extension for executables on the
  70 #        target platform.  "" for Unix and ".exe" for windows.
  71 #
  72 # This configure.in file is easy to reuse on other projects.  Just
  73 # change the argument to AC_INIT.  And disable any features that
  74 # you don't need (for example BLT) by erasing or commenting out
  75 # the corresponding code.
  76 #
  77 AC_INIT([sqlite],[m4_esyscmd(cat VERSION | tr -d '\n')])
  78
  79 dnl Make sure the local VERSION file matches this configure script
  80 sqlite_version_sanity_check=`cat $srcdir/VERSION | tr -d '\n'`
  81 if test "$PACKAGE_VERSION" != "$sqlite_version_sanity_check" ; then
  82 AC_MSG_ERROR([configure script is out of date:
  83  configure \$PACKAGE_VERSION = $PACKAGE_VERSION
  84  top level VERSION file     = $sqlite_version_sanity_check
  85 please regen with autoconf])
  86 fi
  87
  88 #########
  89 # Programs needed
  90 #
  91 LT_INIT
  92 AC_PROG_INSTALL
  93
  94 #########
  95 # Enable large file support (if special flags are necessary)
  96 #
  97 AC_SYS_LARGEFILE
  98
  99 #########
 100 # Check for needed/wanted data types
 101 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, intptr_t, uint8_t,
 102                 uint16_t, uint32_t, uint64_t, uintptr_t])
 103
 104 #########
 105 # Check for needed/wanted headers
 106 AC_CHECK_HEADERS([sys/types.h stdlib.h stdint.h inttypes.h malloc.h])
 107
 108 #########
 109 # Figure out whether or not we have these functions
 110 #
 111 AC_CHECK_FUNCS([fdatasync gmtime_r isnan localtime_r localtime_s malloc_usable_size strchrnul usleep utime pread pread64 pwrite pwrite64])
 112
 113 #########
 114 # By default, we use the amalgamation (this may be changed below...)
 115 #
 116 USE_AMALGAMATION=1
 117
 118 #########
 119 # See whether we can run specific tclsh versions known to work well;
 120 # if not, then we fall back to plain tclsh.
 121 # TODO: try other versions before falling back?
 122 #
 123 AC_CHECK_PROGS(TCLSH_CMD, [tclsh8.7 tclsh8.6 tclsh8.5 tclsh], none)
 124 if test "$TCLSH_CMD" = "none"; then
 125   # If we can't find a local tclsh, then building the amalgamation will fail.
 126   # We act as though --disable-amalgamation has been used.
 127   echo "Warning: can't find tclsh - defaulting to non-amalgamation build."
 128   USE_AMALGAMATION=0
 129   TCLSH_CMD="tclsh"
 130 fi
 131 AC_SUBST(TCLSH_CMD)
 132
 133 AC_ARG_VAR([TCLLIBDIR], [Where to install tcl plugin])
 134 if test "x${TCLLIBDIR+set}" != "xset" ; then
 135   TCLLIBDIR='$(libdir)'
 136   for i in `echo 'puts stdout $auto_path' | ${TCLSH_CMD}` ; do
 137     if test -d $i ; then
 138       TCLLIBDIR=$i
 139       break
 140     fi
 141   done
 142   TCLLIBDIR="${TCLLIBDIR}/sqlite3"
 143 fi
 144
 145
 146 #########
 147 # Set up an appropriate program prefix
 148 #
 149 if test "$program_prefix" = "NONE"; then
 150   program_prefix=""
 151 fi
 152 AC_SUBST(program_prefix)
 153
 154 VERSION=[`cat $srcdir/VERSION | sed 's/^\([0-9]*\.*[0-9]*\).*/\1/'`]
 155 AC_MSG_NOTICE(Version set to $VERSION)
 156 AC_SUBST(VERSION)
 157 RELEASE=`cat $srcdir/VERSION`
 158 AC_MSG_NOTICE(Release set to $RELEASE)
 159 AC_SUBST(RELEASE)
 160
 161 ##########
 162 # Handle --with-wasi-sdk=DIR
 163 #
 164 # This must be early because it changes the toolchain.
 165 #
 166 AC_ARG_WITH(wasi-sdk,
 167 AS_HELP_STRING([--with-wasi-sdk=DIR],
 168        [directory containing the WASI SDK. Triggers cross-compile to WASM.]), with_wasisdk=${withval})
 169 AC_MSG_CHECKING([for WASI SDK directory])
 170 AC_CACHE_VAL(ac_cv_c_wasi_sdk,[
 171   # First check to see if --with-tcl was specified.
 172   if test x"${with_wasi_sdk}" != x ; then
 173     if ! test -d "${with_wasi_sdk}" ; then
 174       AC_MSG_ERROR([${with_wasi_sdk} directory doesn't exist])
 175     fi
 176     AC_MSG_RESULT([${with_wasi_sdk}: using wasi-sdk clang, disabling: tcl, CLI shell, DLL])
 177     use_wasi_sdk=yes
 178   else
 179     use_wasi_sdk=no
 180   fi
 181 ])
 182 if test "${use_wasi_sdk}" = "no" ; then
 183   HAVE_WASI_SDK=""
 184   AC_MSG_RESULT([no])
 185 else
 186   HAVE_WASI_SDK=1
 187 # Changing --host and --target have no effect here except to possibly
 188 # cause confusion. autoconf has finished processing them by this
 189 # point.
 190 #
 191 #  host_alias=wasm32-wasi
 192 #  target=wasm32-wasi
 193 #
 194 # Merely changing CC and LD to the wasi-sdk's is enough to get
 195 # sqlite3.o building in WASM format.
 196   CC="${with_wasi_sdk}/bin/clang"
 197   LD="${with_wasi_sdk}/bin/wasm-ld"
 198   RANLIB="${with_wasi_sdk}/bin/llvm-ranlib"
 199   cross_compiling=yes
 200   enable_threadsafe=no
 201   use_tcl=no
 202   enable_tcl=no
 203   # libtool is apparently hard-coded to use gcc for linking DLLs, so
 204   # we disable the DLL build...
 205   enable_shared=no
 206   AC_MSG_RESULT([yes])
 207 fi
 208 AC_SUBST(HAVE_WASI_SDK)
 209
 210
 211 #########
 212 # Locate a compiler for the build machine.  This compiler should
 213 # generate command-line programs that run on the build machine.
 214 #
 215 if test x"$cross_compiling" = xno; then
 216         BUILD_CC=$CC
 217         BUILD_CFLAGS=$CFLAGS
 218 else
 219         if test "${BUILD_CC+set}" != set; then
 220                 AC_CHECK_PROGS(BUILD_CC, gcc cc cl)
 221         fi
 222         if test "${BUILD_CFLAGS+set}" != set; then
 223                 BUILD_CFLAGS="-g"
 224         fi
 225 fi
 226 AC_SUBST(BUILD_CC)
 227
 228 ##########
 229 # Do we want to support multithreaded use of sqlite
 230 #
 231 AC_ARG_ENABLE(threadsafe,
 232 AS_HELP_STRING([--disable-threadsafe],[Disable mutexing]))
 233 AC_MSG_CHECKING([whether to support threadsafe operation])
 234 if test "$enable_threadsafe" = "no"; then
 235   SQLITE_THREADSAFE=0
 236   AC_MSG_RESULT([no])
 237 else
 238   SQLITE_THREADSAFE=1
 239   AC_MSG_RESULT([yes])
 240 fi
 241 AC_SUBST(SQLITE_THREADSAFE)
 242
 243 if test "$SQLITE_THREADSAFE" = "1"; then
 244   AC_SEARCH_LIBS(pthread_create, pthread)
 245   AC_SEARCH_LIBS(pthread_mutexattr_init, pthread)
 246 fi
 247
 248 ##########
 249 # Do we want to support release
 250 #
 251 AC_ARG_ENABLE(releasemode,
 252 AS_HELP_STRING([--enable-releasemode],[Support libtool link to release mode]),,enable_releasemode=no)
 253 AC_MSG_CHECKING([whether to support shared library linked as release mode or not])
 254 if test "$enable_releasemode" = "no"; then
 255   ALLOWRELEASE=""
 256   AC_MSG_RESULT([no])
 257 else
 258   ALLOWRELEASE="-release `cat $srcdir/VERSION`"
 259   AC_MSG_RESULT([yes])
 260 fi
 261 AC_SUBST(ALLOWRELEASE)
 262
 263 ##########
 264 # Do we want temporary databases in memory
 265 #
 266 AC_ARG_ENABLE(tempstore,
 267 AS_HELP_STRING([--enable-tempstore],[Use an in-ram database for temporary tables (never,no,yes,always)]),,enable_tempstore=no)
 268 AC_MSG_CHECKING([whether to use an in-ram database for temporary tables])
 269 case "$enable_tempstore" in
 270   never )
 271     TEMP_STORE=0
 272     AC_MSG_RESULT([never])
 273   ;;
 274   no )
 275     TEMP_STORE=1
 276     AC_MSG_RESULT([no])
 277   ;;
 278   yes )
 279      TEMP_STORE=2
 280     AC_MSG_RESULT([yes])
 281   ;;
 282   always )
 283      TEMP_STORE=3
 284     AC_MSG_RESULT([always])
 285   ;;
 286   * )
 287     TEMP_STORE=1
 288     AC_MSG_RESULT([no])
 289   ;;
 290 esac
 291
 292 AC_SUBST(TEMP_STORE)
 293
 294 ###########
 295 # Lots of things are different if we are compiling for Windows using
 296 # the CYGWIN environment.  So check for that special case and handle
 297 # things accordingly.
 298 #
 299 AC_MSG_CHECKING([if executables have the .exe suffix])
 300 if test "$config_BUILD_EXEEXT" = ".exe"; then
 301   CYGWIN=yes
 302   AC_MSG_RESULT(yes)
 303 else
 304   AC_MSG_RESULT(unknown)
 305 fi
 306 if test "$CYGWIN" != "yes"; then
 307   m4_warn([obsolete],
 308 [AC_CYGWIN is obsolete: use AC_CANONICAL_HOST and check if $host_os
 309 matches *cygwin*])dnl
 310 AC_CANONICAL_HOST
 311 case $host_os in
 312   *cygwin* ) CYGWIN=yes;;
 313          * ) CYGWIN=no;;
 314 esac
 315
 316 fi
 317 if test "$CYGWIN" = "yes"; then
 318   BUILD_EXEEXT=.exe
 319 else
 320   BUILD_EXEEXT=$EXEEXT
 321 fi
 322 if test x"$cross_compiling" = xno; then
 323   TARGET_EXEEXT=$BUILD_EXEEXT
 324 else
 325   TARGET_EXEEXT=$config_TARGET_EXEEXT
 326 fi
 327 if test "$TARGET_EXEEXT" = ".exe"; then
 328   SQLITE_OS_UNIX=0
 329   SQLITE_OS_WIN=1
 330   CFLAGS="$CFLAGS -DSQLITE_OS_WIN=1"
 331 else
 332   SQLITE_OS_UNIX=1
 333   SQLITE_OS_WIN=0
 334   CFLAGS="$CFLAGS -DSQLITE_OS_UNIX=1"
 335 fi
 336
 337 AC_SUBST(BUILD_EXEEXT)
 338 AC_SUBST(SQLITE_OS_UNIX)
 339 AC_SUBST(SQLITE_OS_WIN)
 340 AC_SUBST(TARGET_EXEEXT)
 341
 342 ##########
 343 # Figure out all the parameters needed to compile against Tcl.
 344 #
 345 # This code is derived from the SC_PATH_TCLCONFIG and SC_LOAD_TCLCONFIG
 346 # macros in the in the tcl.m4 file of the standard TCL distribution.
 347 # Those macros could not be used directly since we have to make some
 348 # minor changes to accomodate systems that do not have TCL installed.
 349 #
 350 AC_ARG_ENABLE(tcl, AS_HELP_STRING([--disable-tcl],[do not build TCL extension]),
 351       [use_tcl=$enableval],[use_tcl=yes])
 352 if test "${use_tcl}" = "yes" ; then
 353   AC_ARG_WITH(tcl, AS_HELP_STRING([--with-tcl=DIR],[directory containing tcl configuration (tclConfig.sh)]), with_tclconfig=${withval})
 354   AC_MSG_CHECKING([for Tcl configuration])
 355   AC_CACHE_VAL(ac_cv_c_tclconfig,[
 356     # First check to see if --with-tcl was specified.
 357     if test x"${with_tclconfig}" != x ; then
 358       if test -f "${with_tclconfig}/tclConfig.sh" ; then
 359         ac_cv_c_tclconfig=`(cd ${with_tclconfig}; pwd)`
 360       else
 361         AC_MSG_ERROR([${with_tclconfig} directory doesn't contain tclConfig.sh])
 362       fi
 363     fi
 364
 365     # Start autosearch by asking tclsh
 366     if test x"${ac_cv_c_tclconfig}" = x ; then
 367       if test x"$cross_compiling" = xno; then
 368         for i in `echo 'puts stdout $auto_path' | ${TCLSH_CMD}`
 369         do
 370           if test -f "$i/tclConfig.sh" ; then
 371             ac_cv_c_tclconfig="$i"
 372             break
 373           fi
 374         done
 375       fi
 376     fi
 377
 378     # On ubuntu 14.10, $auto_path on tclsh is not quite correct.
 379     # So try again after applying corrections.
 380     if test x"${ac_cv_c_tclconfig}" = x ; then
 381       if test x"$cross_compiling" = xno; then
 382         for i in `echo 'puts stdout $auto_path' | ${TCLSH_CMD} | sed 's,/tcltk/tcl,/tcl,g'`
 383         do
 384           if test -f "$i/tclConfig.sh" ; then
 385             ac_cv_c_tclconfig="$i"
 386             break
 387           fi
 388         done
 389       fi
 390     fi
 391
 392     # Recent versions of Xcode on Macs hid the tclConfig.sh file
 393     # in a strange place.
 394     if test x"${ac_cv_c_tclconfig}" = x ; then
 395       if test x"$cross_compiling" = xno; then
 396         for i in /Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs/MacOSX*.sdk/usr/lib
 397         do
 398           if test -f "$i/tclConfig.sh" ; then
 399             ac_cv_c_tclconfig="$i"
 400             break
 401           fi
 402         done
 403       fi
 404     fi
 405
 406     # then check for a private Tcl installation
 407     if test x"${ac_cv_c_tclconfig}" = x ; then
 408       for i in \
 409             ../tcl \
 410             `ls -dr ../tcl[[8-9]].[[0-9]].[[0-9]]* 2>/dev/null` \
 411             `ls -dr ../tcl[[8-9]].[[0-9]] 2>/dev/null` \
 412             `ls -dr ../tcl[[8-9]].[[0-9]]* 2>/dev/null` \
 413             ../../tcl \
 414             `ls -dr ../../tcl[[8-9]].[[0-9]].[[0-9]]* 2>/dev/null` \
 415             `ls -dr ../../tcl[[8-9]].[[0-9]] 2>/dev/null` \
 416             `ls -dr ../../tcl[[8-9]].[[0-9]]* 2>/dev/null` \
 417             ../../../tcl \
 418             `ls -dr ../../../tcl[[8-9]].[[0-9]].[[0-9]]* 2>/dev/null` \
 419             `ls -dr ../../../tcl[[8-9]].[[0-9]] 2>/dev/null` \
 420             `ls -dr ../../../tcl[[8-9]].[[0-9]]* 2>/dev/null`
 421       do
 422         if test -f "$i/unix/tclConfig.sh" ; then
 423           ac_cv_c_tclconfig=`(cd $i/unix; pwd)`
 424           break
 425         fi
 426       done
 427     fi
 428
 429     # check in a few common install locations
 430     if test x"${ac_cv_c_tclconfig}" = x ; then
 431       for i in \
 432             `ls -d ${libdir} 2>/dev/null` \
 433             `ls -d /usr/local/lib 2>/dev/null` \
 434             `ls -d /usr/contrib/lib 2>/dev/null` \
 435             `ls -d /usr/lib 2>/dev/null`
 436       do
 437         if test -f "$i/tclConfig.sh" ; then
 438            ac_cv_c_tclconfig=`(cd $i; pwd)`
 439            break
 440         fi
 441       done
 442     fi
 443
 444     # check in a few other private locations
 445     if test x"${ac_cv_c_tclconfig}" = x ; then
 446       for i in \
 447          ${srcdir}/../tcl \
 448          `ls -dr ${srcdir}/../tcl[[8-9]].[[0-9]].[[0-9]]* 2>/dev/null` \
 449          `ls -dr ${srcdir}/../tcl[[8-9]].[[0-9]] 2>/dev/null` \
 450          `ls -dr ${srcdir}/../tcl[[8-9]].[[0-9]]* 2>/dev/null`
 451       do
 452         if test -f "$i/unix/tclConfig.sh" ; then
 453           ac_cv_c_tclconfig=`(cd $i/unix; pwd)`
 454           break
 455         fi
 456       done
 457     fi
 458   ])
 459
 460   if test x"${ac_cv_c_tclconfig}" = x ; then
 461     use_tcl=no
 462     AC_MSG_WARN(Can't find Tcl configuration definitions)
 463     AC_MSG_WARN(*** Without Tcl the regression tests cannot be executed ***)
 464     AC_MSG_WARN(*** Consider using --with-tcl=... to define location of Tcl ***)
 465   else
 466     TCL_BIN_DIR=${ac_cv_c_tclconfig}
 467     AC_MSG_RESULT(found $TCL_BIN_DIR/tclConfig.sh)
 468
 469     AC_MSG_CHECKING([for existence of $TCL_BIN_DIR/tclConfig.sh])
 470     if test -f "$TCL_BIN_DIR/tclConfig.sh" ; then
 471       AC_MSG_RESULT([loading])
 472       . $TCL_BIN_DIR/tclConfig.sh
 473     else
 474       AC_MSG_RESULT([file not found])
 475     fi
 476
 477     #
 478     # If the TCL_BIN_DIR is the build directory (not the install directory),
 479     # then set the common variable name to the value of the build variables.
 480     # For example, the variable TCL_LIB_SPEC will be set to the value
 481     # of TCL_BUILD_LIB_SPEC. An extension should make use of TCL_LIB_SPEC
 482     # instead of TCL_BUILD_LIB_SPEC since it will work with both an
 483     # installed and uninstalled version of Tcl.
 484     #
 485
 486     if test -f $TCL_BIN_DIR/Makefile ; then
 487       TCL_LIB_SPEC=${TCL_BUILD_LIB_SPEC}
 488       TCL_STUB_LIB_SPEC=${TCL_BUILD_STUB_LIB_SPEC}
 489       TCL_STUB_LIB_PATH=${TCL_BUILD_STUB_LIB_PATH}
 490     fi
 491
 492     #
 493     # eval is required to do the TCL_DBGX substitution
 494     #
 495
 496     eval "TCL_LIB_FILE=\"${TCL_LIB_FILE}\""
 497     eval "TCL_LIB_FLAG=\"${TCL_LIB_FLAG}\""
 498     eval "TCL_LIB_SPEC=\"${TCL_LIB_SPEC}\""
 499
 500     eval "TCL_STUB_LIB_FILE=\"${TCL_STUB_LIB_FILE}\""
 501     eval "TCL_STUB_LIB_FLAG=\"${TCL_STUB_LIB_FLAG}\""
 502     eval "TCL_STUB_LIB_SPEC=\"${TCL_STUB_LIB_SPEC}\""
 503
 504     AC_SUBST(TCL_VERSION)
 505     AC_SUBST(TCL_BIN_DIR)
 506     AC_SUBST(TCL_SRC_DIR)
 507     AC_SUBST(TCL_INCLUDE_SPEC)
 508
 509     AC_SUBST(TCL_LIB_FILE)
 510     AC_SUBST(TCL_LIB_FLAG)
 511     AC_SUBST(TCL_LIB_SPEC)
 512
 513     AC_SUBST(TCL_STUB_LIB_FILE)
 514     AC_SUBST(TCL_STUB_LIB_FLAG)
 515     AC_SUBST(TCL_STUB_LIB_SPEC)
 516     AC_SUBST(TCL_SHLIB_SUFFIX)
 517   fi
 518 fi
 519 if test "${use_tcl}" = "no" ; then
 520   HAVE_TCL=""
 521 else
 522   HAVE_TCL=1
 523 fi
 524 AC_SUBST(HAVE_TCL)
 525
 526 ##########
 527 # Figure out what C libraries are required to compile programs
 528 # that use "readline()" library.
 529 #
 530 TARGET_READLINE_LIBS=""
 531 TARGET_READLINE_INC=""
 532 TARGET_HAVE_READLINE=0
 533 TARGET_HAVE_EDITLINE=0
 534 AC_ARG_ENABLE([editline],
 535         [AS_HELP_STRING([--enable-editline],[enable BSD editline support])],
 536         [with_editline=$enableval],
 537         [with_editline=auto])
 538 AC_ARG_ENABLE([readline],
 539         [AS_HELP_STRING([--disable-readline],[disable readline support])],
 540         [with_readline=$enableval],
 541         [with_readline=auto])
 542
 543 if test x"$with_editline" != xno; then
 544         sLIBS=$LIBS
 545         LIBS=""
 546         TARGET_HAVE_EDITLINE=1
 547         AC_SEARCH_LIBS(readline,edit,[with_readline=no],[TARGET_HAVE_EDITLINE=0])
 548         TARGET_READLINE_LIBS=$LIBS
 549         LIBS=$sLIBS
 550 fi
 551 if test x"$with_readline" != xno; then
 552         found="yes"
 553
 554         AC_ARG_WITH([readline-lib],
 555                 [AS_HELP_STRING([--with-readline-lib],[specify readline library])],
 556                 [with_readline_lib=$withval],
 557                 [with_readline_lib="auto"])
 558         if test "x$with_readline_lib" = xauto; then
 559                 save_LIBS="$LIBS"
 560                 LIBS=""
 561                 AC_SEARCH_LIBS(tgetent, [readline ncurses curses termcap], [term_LIBS="$LIBS"], [term_LIBS=""])
 562                 AC_CHECK_LIB([readline], [readline], [TARGET_READLINE_LIBS="-lreadline"], [found="no"])
 563                 TARGET_READLINE_LIBS="$TARGET_READLINE_LIBS $term_LIBS"
 564                 LIBS="$save_LIBS"
 565         else
 566                 TARGET_READLINE_LIBS="$with_readline_lib"
 567         fi
 568
 569         AC_ARG_WITH([readline-inc],
 570                 [AS_HELP_STRING([--with-readline-inc],[specify readline include paths])],
 571                 [with_readline_inc=$withval],
 572                 [with_readline_inc="auto"])
 573         if test "x$with_readline_inc" = xauto; then
 574                 AC_CHECK_HEADER(readline.h, [found="yes"], [
 575                         found="no"
 576                         if test "$cross_compiling" != yes; then
 577                                 for dir in /usr /usr/local /usr/local/readline /usr/contrib /mingw; do
 578                                         for subdir in include include/readline; do
 579                                                 AC_CHECK_FILE($dir/$subdir/readline.h, found=yes)
 580                                                 if test "$found" = "yes"; then
 581                                                         TARGET_READLINE_INC="-I$dir/$subdir"
 582                                                         break
 583                                                 fi
 584                                         done
 585                                         test "$found" = "yes" && break
 586                                 done
 587                         fi
 588                 ])
 589         else
 590                 TARGET_READLINE_INC="$with_readline_inc"
 591         fi
 592
 593         if test x"$found" = xno; then
 594                 TARGET_READLINE_LIBS=""
 595                 TARGET_READLINE_INC=""
 596                 TARGET_HAVE_READLINE=0
 597         else
 598                 TARGET_HAVE_READLINE=1
 599         fi
 600 fi
 601
 602 AC_SUBST(TARGET_READLINE_LIBS)
 603 AC_SUBST(TARGET_READLINE_INC)
 604 AC_SUBST(TARGET_HAVE_READLINE)
 605 AC_SUBST(TARGET_HAVE_EDITLINE)
 606
 607 ##########
 608 # Figure out what C libraries are required to compile programs
 609 # that use "fdatasync()" function.
 610 #
 611 AC_SEARCH_LIBS(fdatasync, [rt])
 612
 613 #########
 614 # check for debug enabled
 615 AC_ARG_ENABLE(debug, AS_HELP_STRING([--enable-debug],[enable debugging & verbose explain]))
 616 AC_MSG_CHECKING([build type])
 617 if test "${enable_debug}" = "yes" ; then
 618   TARGET_DEBUG="-DSQLITE_DEBUG=1 -DSQLITE_ENABLE_SELECTTRACE -DSQLITE_ENABLE_WHERETRACE -O0"
 619   AC_MSG_RESULT([debug])
 620 else
 621   TARGET_DEBUG="-DNDEBUG"
 622   AC_MSG_RESULT([release])
 623 fi
 624 AC_SUBST(TARGET_DEBUG)
 625
 626 #########
 627 # See whether we should use the amalgamation to build
 628
 629 AC_ARG_ENABLE(amalgamation, AS_HELP_STRING([--disable-amalgamation],
 630       [Disable the amalgamation and instead build all files separately]))
 631 if test "${enable_amalgamation}" = "no" ; then
 632   USE_AMALGAMATION=0
 633 fi
 634 AC_SUBST(USE_AMALGAMATION)
 635
 636 #########
 637 # Look for zlib.  Only needed by extensions and by the sqlite3.exe shell
 638 AC_CHECK_HEADERS(zlib.h)
 639 AC_SEARCH_LIBS(deflate, z, [HAVE_ZLIB="-DSQLITE_HAVE_ZLIB=1"], [HAVE_ZLIB=""])
 640 AC_SUBST(HAVE_ZLIB)
 641
 642 #########
 643 # See whether we should allow loadable extensions
 644 AC_ARG_ENABLE(load-extension, AS_HELP_STRING([--disable-load-extension],
 645       [Disable loading of external extensions]),,[enable_load_extension=yes])
 646 if test "${enable_load_extension}" = "yes" ; then
 647   OPT_FEATURE_FLAGS=""
 648   AC_SEARCH_LIBS(dlopen, dl)
 649 else
 650   OPT_FEATURE_FLAGS="-DSQLITE_OMIT_LOAD_EXTENSION=1"
 651 fi
 652
 653 ##########
 654 # Do we want to support math functions
 655 #
 656 AC_ARG_ENABLE(math,
 657 AS_HELP_STRING([--disable-math],[Disable math functions]))
 658 AC_MSG_CHECKING([whether to support math functions])
 659 if test "$enable_math" = "no"; then
 660   AC_MSG_RESULT([no])
 661 else
 662   AC_MSG_RESULT([yes])
 663   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_MATH_FUNCTIONS"
 664   AC_SEARCH_LIBS(ceil, m)
 665 fi
 666
 667 ##########
 668 # Do we want to support JSON functions
 669 #
 670 AC_ARG_ENABLE(json,
 671 AS_HELP_STRING([--disable-json],[Disable JSON functions]))
 672 AC_MSG_CHECKING([whether to support JSON functions])
 673 if test "$enable_json" = "no"; then
 674   AC_MSG_RESULT([no])
 675   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_OMIT_JSON"
 676 else
 677   AC_MSG_RESULT([yes])
 678 fi
 679
 680 ########
 681 # The --enable-all argument is short-hand to enable
 682 # multiple extensions.
 683 AC_ARG_ENABLE(all, AS_HELP_STRING([--enable-all],
 684       [Enable FTS4, FTS5, Geopoly, RTree, Sessions]))
 685
 686 ##########
 687 # Do we want to support memsys3 and/or memsys5
 688 #
 689 AC_ARG_ENABLE(memsys5,
 690   AS_HELP_STRING([--enable-memsys5],[Enable MEMSYS5]))
 691 AC_MSG_CHECKING([whether to support MEMSYS5])
 692 if test "${enable_memsys5}" = "yes"; then
 693   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_MEMSYS5"
 694   AC_MSG_RESULT([yes])
 695 else
 696   AC_MSG_RESULT([no])
 697 fi
 698 AC_ARG_ENABLE(memsys3,
 699   AS_HELP_STRING([--enable-memsys3],[Enable MEMSYS3]))
 700 AC_MSG_CHECKING([whether to support MEMSYS3])
 701 if test "${enable_memsys3}" = "yes" -a "${enable_memsys5}" = "no"; then
 702   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_MEMSYS3"
 703   AC_MSG_RESULT([yes])
 704 else
 705   AC_MSG_RESULT([no])
 706 fi
 707
 708 #########
 709 # See whether we should enable Full Text Search extensions
 710 AC_ARG_ENABLE(fts3, AS_HELP_STRING([--enable-fts3],
 711       [Enable the FTS3 extension]))
 712 AC_MSG_CHECKING([whether to support FTS3])
 713 if test "${enable_fts3}" = "yes" ; then
 714   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_FTS3"
 715   AC_MSG_RESULT([yes])
 716 else
 717   AC_MSG_RESULT([no])
 718 fi
 719 AC_ARG_ENABLE(fts4, AS_HELP_STRING([--enable-fts4],
 720       [Enable the FTS4 extension]))
 721 AC_MSG_CHECKING([whether to support FTS4])
 722 if test "${enable_fts4}" = "yes" -o "${enable_all}" = "yes" ; then
 723   AC_MSG_RESULT([yes])
 724   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_FTS4"
 725   AC_SEARCH_LIBS([log],[m])
 726 else
 727   AC_MSG_RESULT([no])
 728 fi
 729 AC_ARG_ENABLE(fts5, AS_HELP_STRING([--enable-fts5],
 730       [Enable the FTS5 extension]))
 731 AC_MSG_CHECKING([whether to support FTS5])
 732 if test "${enable_fts5}" = "yes" -o "${enable_all}" = "yes" ; then
 733   AC_MSG_RESULT([yes])
 734   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_FTS5"
 735   AC_SEARCH_LIBS([log],[m])
 736 else
 737   AC_MSG_RESULT([no])
 738 fi
 739
 740 #########
 741 # See whether we should enable the LIMIT clause on UPDATE and DELETE
 742 # statements.
 743 AC_ARG_ENABLE(update-limit, AS_HELP_STRING([--enable-update-limit],
 744       [Enable the UPDATE/DELETE LIMIT clause]))
 745 AC_MSG_CHECKING([whether to support LIMIT on UPDATE and DELETE statements])
 746 if test "${enable_update_limit}" = "yes" ; then
 747   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_UPDATE_DELETE_LIMIT"
 748   AC_MSG_RESULT([yes])
 749 else
 750   AC_MSG_RESULT([no])
 751 fi
 752
 753 #########
 754 # See whether we should enable GEOPOLY
 755 AC_ARG_ENABLE(geopoly, AS_HELP_STRING([--enable-geopoly],
 756       [Enable the GEOPOLY extension]),
 757       [enable_geopoly=yes],[enable_geopoly=no])
 758 AC_MSG_CHECKING([whether to support GEOPOLY])
 759 if test "${enable_geopoly}" = "yes" -o "${enable_all}" = "yes" ; then
 760   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_GEOPOLY"
 761   enable_rtree=yes
 762   AC_MSG_RESULT([yes])
 763 else
 764   AC_MSG_RESULT([no])
 765 fi
 766
 767 #########
 768 # See whether we should enable RTREE
 769 AC_ARG_ENABLE(rtree, AS_HELP_STRING([--enable-rtree],
 770       [Enable the RTREE extension]))
 771 AC_MSG_CHECKING([whether to support RTREE])
 772 if test "${enable_rtree}" = "yes" ; then
 773   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_RTREE"
 774   AC_MSG_RESULT([yes])
 775 else
 776   AC_MSG_RESULT([no])
 777 fi
 778
 779 #########
 780 # See whether we should enable the SESSION extension
 781 AC_ARG_ENABLE(session, AS_HELP_STRING([--enable-session],
 782       [Enable the SESSION extension]))
 783 AC_MSG_CHECKING([whether to support SESSION])
 784 if test "${enable_session}" = "yes" -o "${enable_all}" = "yes" ; then
 785   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_SESSION"
 786   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_PREUPDATE_HOOK"
 787   AC_MSG_RESULT([yes])
 788 else
 789   AC_MSG_RESULT([no])
 790 fi
 791
 792 #########
 793 # attempt to duplicate any OMITS and ENABLES into the ${OPT_FEATURE_FLAGS} parameter
 794 for option in $CFLAGS $CPPFLAGS
 795 do
 796   case $option in
 797     -DSQLITE_OMIT*) OPT_FEATURE_FLAGS="$OPT_FEATURE_FLAGS $option";;
 798     -DSQLITE_ENABLE*) OPT_FEATURE_FLAGS="$OPT_FEATURE_FLAGS $option";;
 799   esac
 800 done
 801 AC_SUBST(OPT_FEATURE_FLAGS)
 802
 803
 804 # attempt to remove any OMITS and ENABLES from the $(CFLAGS) parameter
 805 ac_temp_CFLAGS=""
 806 for option in $CFLAGS
 807 do
 808   case $option in
 809     -DSQLITE_OMIT*) ;;
 810     -DSQLITE_ENABLE*) ;;
 811     *) ac_temp_CFLAGS="$ac_temp_CFLAGS $option";;
 812   esac
 813 done
 814 CFLAGS=$ac_temp_CFLAGS
 815
 816
 817 # attempt to remove any OMITS and ENABLES from the $(CPPFLAGS) parameter
 818 ac_temp_CPPFLAGS=""
 819 for option in $CPPFLAGS
 820 do
 821   case $option in
 822     -DSQLITE_OMIT*) ;;
 823     -DSQLITE_ENABLE*) ;;
 824     *) ac_temp_CPPFLAGS="$ac_temp_CPPFLAGS $option";;
 825   esac
 826 done
 827 CPPFLAGS=$ac_temp_CPPFLAGS
 828
 829
 830 # attempt to remove any OMITS and ENABLES from the $(BUILD_CFLAGS) parameter
 831 ac_temp_BUILD_CFLAGS=""
 832 for option in $BUILD_CFLAGS
 833 do
 834   case $option in
 835     -DSQLITE_OMIT*) ;;
 836     -DSQLITE_ENABLE*) ;;
 837     *) ac_temp_BUILD_CFLAGS="$ac_temp_BUILD_CFLAGS $option";;
 838   esac
 839 done
 840 BUILD_CFLAGS=$ac_temp_BUILD_CFLAGS
 841
 842
 843 #########
 844 # See whether we should use GCOV
 845 AC_ARG_ENABLE(gcov, AS_HELP_STRING([--enable-gcov],
 846       [Enable coverage testing using gcov]))
 847 if test "${use_gcov}" = "yes" ; then
 848   USE_GCOV=1
 849 else
 850   USE_GCOV=0
 851 fi
 852 AC_SUBST(USE_GCOV)
 853
 854 #########
 855 # Enable/disabled amalagamation line macros
 856 ########
 857 AMALGAMATION_LINE_MACROS=--linemacros=0
 858 if test "${amalgamation_line_macros}" = "yes" ; then
 859   AMALGAMATION_LINE_MACROS=--linemacros=1
 860 fi
 861 if test "${amalgamation_line_macros}" = "no" ; then
 862   AMALGAMATION_LINE_MACROS=--linemacros=0
 863 fi
 864 AC_SUBST(AMALGAMATION_LINE_MACROS)
 865
 866 #########
 867 # Output the config header
 868 AC_CONFIG_HEADERS(sqlite_cfg.h)
 869
 870 #########
 871 # Generate the output files.
 872 #
 873 AC_SUBST(BUILD_CFLAGS)
 874 AC_CONFIG_FILES([
 875 Makefile
 876 sqlite3.pc
 877 ])
 878 AC_OUTPUT