test/uri.test

   1 # 2011 April 22
   2 #
   3 # The author disclaims copyright to this source code.  In place of
   4 # a legal notice, here is a blessing:
   5 #
   6 #    May you do good and not evil.
   7 #    May you find forgiveness for yourself and forgive others.
   8 #    May you share freely, never taking more than you give.
   9 #
  10 #***********************************************************************
  11 #
  12
  13 set testdir [file dirname $argv0]
  14 source $testdir/tester.tcl
  15
  16 # Test organization:
  17 #
  18 #   1.*: That file names are correctly extracted from URIs.
  19 #   2.*: That URI options (query parameters) are correctly extracted from URIs.
  20 #   3.*: That specifying an unknown VFS causes an error.
  21 #   4.*: Tests for specifying other options (other than "vfs").
  22 #   5.*: Test using a different VFS with an attached database.
  23 #   6.*: Test that authorities other than "" and localhost cause errors.
  24 #   7.*: Test that a read-write db can be attached to a read-only connection.
  25 #
  26
  27 set testprefix uri
  28 db close
  29 sqlite3_shutdown
  30 sqlite3_config_uri 1
  31
  32 #-------------------------------------------------------------------------
  33 # Test that file names are correctly extracted from URIs.
  34 #
  35 foreach {tn uri file} {
  36   1      test.db                              test.db
  37   2      file:test.db                         test.db
  38   3      file://PWD/test.db                   test.db
  39   4      file:PWD/test.db                     test.db
  40   5      file:test.db?mork=1                  test.db
  41   6      file:test.db?mork=1&tonglor=2        test.db
  42   7      file:test.db?mork=1#boris            test.db
  43   8      file:test.db#boris                   test.db
  44   9      test.db#boris                        test.db#boris
  45   10     file:test%2Edb                       test.db
  46   11     file                                 file
  47   12     http:test.db                         http:test.db
  48   13     file:test.db%00extra                 test.db
  49   14     file:testdb%00.db%00extra            testdb
  50
  51   15     test.db?mork=1#boris                 test.db?mork=1#boris
  52   16     file://localhostPWD/test.db%3Fhello  test.db?hello
  53 } {
  54
  55
  56   ifcapable !curdir { if {$tn==3} break }
  57
  58   ifcapable uri_00_error {
  59     if {[string first %00 $uri]>=0} continue
  60   }
  61
  62   if {$tcl_platform(platform)=="windows"} {
  63     #
  64     # NOTE: Due to limits on legal characters for file names imposed by
  65     #       Windows, we must skip the final two tests here (i.e. the
  66     #       question mark is illegal in a file name on Windows).
  67     #
  68     if {$tn>14} break
  69
  70     #
  71     # NOTE: When running on Tcl 8.6 (or higher?) on Windows, a colon within
  72     #       the file name no longer tries to access an alternate data stream
  73     #       (ADS) named "test.db" for the "http" file, causing some spurious
  74     #       failures of this test.
  75     #
  76     if {$tn==12 && $::tcl_version>=8.6} continue
  77
  78     #
  79     # NOTE: On Windows, we need to account for the fact that the current
  80     #       directory does not start with a forward slash.
  81     #
  82     set uri  [string map [list PWD/ /[test_pwd /]] $uri]
  83   } else {
  84     set uri  [string map [list PWD/ [test_pwd /]] $uri]
  85   }
  86
  87   if {[file isdir $file]} {error "$file is a directory"}
  88   forcedelete $file
  89   do_test 1.$tn.1 { file exists $file } 0
  90   set DB [sqlite3_open $uri]
  91   do_test 1.$tn.2 { file exists $file } 1
  92   sqlite3_close $DB
  93   forcedelete $file
  94
  95   do_test 1.$tn.3 { file exists $file } 0
  96   sqlite3 db xxx.db
  97   catchsql { ATTACH $uri AS aux }
  98   do_test 1.$tn.4 { file exists $file } 1
  99   db close
 100 }
 101
 102 #-------------------------------------------------------------------------
 103 # Test that URI query parameters are passed through to the VFS layer
 104 # correctly.
 105 #
 106 testvfs tvfs2
 107 testvfs tvfs -default 1
 108 tvfs filter xOpen
 109 tvfs script open_method
 110 proc open_method {method file arglist} {
 111   set ::arglist $arglist
 112 }
 113 foreach {tn uri kvlist} {
 114   1      file:test.db?hello=world                     {hello world}
 115   2      file:test.db?hello&world                     {hello {} world {}}
 116   3      file:test.db?hello=1&world=2&vfs=tvfs        {hello 1 world 2 vfs tvfs}
 117   4      file:test.db?hello=1&world=2&vfs=tvfs2        {}
 118   5      file:test.db?%68%65%6C%6C%6F=%77%6F%72%6C%64 {hello world}
 119   6      file:testdb%00.db?hello%00extra=world%00ex   {hello world}
 120   7      file:testdb%00.db?hello%00=world%00          {hello world}
 121   8      file:testdb%00.db?=world&xyz=abc             {xyz abc}
 122   9      file:test.db?%00hello=world&xyz=abc          {xyz abc}
 123   10     file:test.db?hello=%00world&xyz=             {hello {} xyz {}}
 124   11     file:test.db?=#ravada                        {}
 125   12     file:test.db?&&&&&&&&hello=world&&&&&&&      {hello world}
 126
 127   13     test.db?&&&&&&&&hello=world&&&&&&&           {}
 128   14     http:test.db?hello&world                     {}
 129 } {
 130
 131   ifcapable uri_00_error {
 132     if {[string first %00 $uri]>=0} continue
 133   }
 134
 135   if {$tcl_platform(platform) == "windows" && $tn>12} {
 136     continue
 137   }
 138
 139   set ::arglist ""
 140   set DB [sqlite3_open $uri]
 141   do_test 2.$tn.1 { set ::arglist } $kvlist
 142   sqlite3_close $DB
 143
 144   sqlite3 db xxx.db
 145   set ::arglist ""
 146   execsql { ATTACH $uri AS aux }
 147   do_test 2.$tn.2 { set ::arglist } $kvlist
 148   db close
 149 }
 150 tvfs delete
 151 tvfs2 delete
 152
 153 #-------------------------------------------------------------------------
 154 # Test that specifying a non-existent VFS raises an error.
 155 #
 156 do_test 3.1 {
 157   list [catch { sqlite3 db "file:test.db?vfs=nosuchvfs" } msg] $msg
 158 } {1 {no such vfs: nosuchvfs}}
 159
 160 #-------------------------------------------------------------------------
 161 # Test some of the other options (other than "vfs").
 162 #
 163 foreach {tn mode create_ok write_ok readonly_ok} {
 164   1    ro    0   0   1
 165   2    rw    0   1   0
 166   3    rwc   1   1   0
 167 } {
 168   catch { db close }
 169   forcedelete test.db
 170
 171   set A(1) {0 {}}
 172   set A(0) {1 {unable to open database file}}
 173   do_test 4.1.$tn.1 {
 174     list [catch {sqlite3 db "file:test.db?mode=$mode"} msg] $msg
 175   } $A($create_ok)
 176
 177   catch { db close }
 178   forcedelete test.db
 179   sqlite3 db test.db
 180   db eval { CREATE TABLE t1(a, b) }
 181   db close
 182
 183   set A(1) {0 {}}
 184   set A(0) {1 {attempt to write a readonly database}}
 185   do_test 4.1.$tn.2 {
 186     sqlite3 db "file:test.db?mode=$mode"
 187     catchsql { INSERT INTO t1 VALUES(1, 2) }
 188   } $A($write_ok)
 189
 190   set A(1) {0 {}}
 191   set A(0) [list 1 "access mode not allowed: $mode"]
 192   do_test 4.1.$tn.3 {
 193     list [catch {sqlite3 db "file:test.db?mode=$mode" -readonly 1} msg] $msg
 194   } $A($readonly_ok)
 195 }
 196
 197 set orig [sqlite3_enable_shared_cache]
 198 foreach {tn options sc_default is_shared} {
 199   1    ""                1   1
 200   2    "cache=private"   1   0
 201   3    "cache=shared"    1   1
 202   4    ""                0   0
 203   5    "cache=private"   0   0
 204   6    "cache=shared"    0   1
 205 } {
 206   catch { db close }
 207   forcedelete test.db
 208
 209   sqlite3_enable_shared_cache 1
 210   sqlite3 db2 test.db
 211   db2 eval {CREATE TABLE t1(a, b)}
 212
 213   sqlite3_enable_shared_cache $sc_default
 214   sqlite3 db "file:test.db?$options"
 215   db eval {SELECT * FROM t1}
 216
 217   set A(1) {1 {database table is locked: t1}}
 218   set A(0) {0 {}}
 219   do_test 4.2.$tn {
 220     db2 eval {BEGIN; INSERT INTO t1 VALUES(1, 2);}
 221     catchsql { SELECT * FROM t1 }
 222   } $A($is_shared)
 223
 224   db2 close
 225 }
 226
 227 do_test 4.3.1 {
 228   list [catch {sqlite3 db "file:test.db?mode=rc"} msg] $msg
 229 } {1 {no such access mode: rc}}
 230 do_test 4.3.2 {
 231   list [catch {sqlite3 db "file:test.db?cache=public"} msg] $msg
 232 } {1 {no such cache mode: public}}
 233
 234 #-------------------------------------------------------------------------
 235 # Test that things work if an ATTACHed database uses a different VFS than
 236 # the main database. The important point is that for all operations
 237 # involving the ATTACHed database, the correct versions of the following
 238 # VFS are used for all operations involving the attached database.
 239 #
 240 #     xOpen
 241 #     xDelete
 242 #     xAccess
 243 #     xFullPathname
 244 #
 245
 246 # This block of code creates two VFS - "tvfs1" and "tvfs2". Each time one
 247 # of the above methods is called using "tvfs1", global variable ::T1(X) is
 248 # set, where X is the file-name the method is called on. Calls to the above
 249 # methods using "tvfs2" set entries in the global T2 array.
 250 #
 251 ifcapable wal {
 252   testvfs tvfs1
 253   tvfs1 filter {xOpen xDelete xAccess xFullPathname}
 254   tvfs1 script tvfs1_callback
 255   proc tvfs1_callback {method filename args} {
 256     set ::T1([file tail $filename]) 1
 257     return SQLITE_OK
 258   }
 259   testvfs tvfs2
 260   tvfs2 filter {xOpen xDelete xAccess xFullPathname}
 261   tvfs2 script tvfs2_callback
 262   proc tvfs2_callback {method filename args} {
 263     set ::T2([file tail $filename]) 1
 264     return SQLITE_OK
 265   }
 266
 267   catch {db close}
 268   eval forcedelete [glob test.db*]
 269   do_test 5.1.1 {
 270     sqlite3 db file:test.db1?vfs=tvfs1
 271     execsql {
 272       ATTACH 'file:test.db2?vfs=tvfs2' AS aux;
 273       PRAGMA main.journal_mode = PERSIST;
 274       PRAGMA aux.journal_mode = PERSIST;
 275       CREATE TABLE t1(a, b);
 276       CREATE TABLE aux.t2(a, b);
 277       PRAGMA main.journal_mode = WAL;
 278       PRAGMA aux.journal_mode = WAL;
 279       INSERT INTO t1 VALUES('x', 'y');
 280       INSERT INTO t2 VALUES('x', 'y');
 281     }
 282     lsort [array names ::T1]
 283   } {test.db1 test.db1-journal test.db1-wal}
 284
 285   do_test 5.1.2 {
 286     lsort [array names ::T2]
 287   } {test.db2 test.db2-journal test.db2-wal}
 288   db close
 289
 290   tvfs1 delete
 291   tvfs2 delete
 292 }
 293
 294 #-------------------------------------------------------------------------
 295 # Check that only "" and "localhost" are acceptable as authorities.
 296 #
 297 catch {db close}
 298 foreach {tn uri res} {
 299   1     "file://localhost/PWD/test.db"   {not an error}
 300   2     "file:///PWD/test.db"            {not an error}
 301   3     "file:/PWD/test.db"              {not an error}
 302   4     "file://l%6Fcalhost/PWD/test.db" {invalid uri authority: l%6Fcalhost}
 303   5     "file://lbcalhost/PWD/test.db"   {invalid uri authority: lbcalhost}
 304   6     "file://x/PWD/test.db"           {invalid uri authority: x}
 305 } {
 306
 307   if {$tcl_platform(platform)=="windows"} {
 308     set uri  [string map [list PWD [string range [get_pwd] 3 end]] $uri]
 309   } else {
 310     set uri  [string map [list PWD [string range [get_pwd] 1 end]] $uri]
 311   }
 312
 313   do_test 6.$tn {
 314     set DB [sqlite3_open $uri]
 315     sqlite3_errmsg $DB
 316   } $res
 317   catch { sqlite3_close $DB }
 318 }
 319
 320 forcedelete test.db test.db2
 321 do_test 7.1 {
 322   sqlite3 db test.db
 323   execsql {
 324     CREATE TABLE t1(a, b);
 325     INSERT INTO t1 VALUES(1, 2);
 326     ATTACH 'test.db2' AS aux;
 327     CREATE TABLE aux.t2(a, b);
 328     INSERT INTO t1 VALUES('a', 'b');
 329   }
 330   db close
 331 } {}
 332 do_test 7.2 {
 333   sqlite3 db file:test.db?mode=ro
 334   execsql { ATTACH 'file:test.db2?mode=rw' AS aux }
 335 } {}
 336 do_execsql_test  7.3 {
 337   INSERT INTO t2 VALUES('c', 'd')
 338 } {}
 339 do_catchsql_test 7.4 {
 340   INSERT INTO t1 VALUES(3, 4)
 341 } {1 {attempt to write a readonly database}}
 342
 343 finish_test