configure.ac

   1 #
   2 # The build process allows for using a cross-compiler.  But the default
   3 # action is to target the same platform that we are running on.  The
   4 # configure script needs to discover the following properties of the
   5 # build and target systems:
   6 #
   7 #    srcdir
   8 #
   9 #        The is the name of the directory that contains the
  10 #        "configure" shell script.  All source files are
  11 #        located relative to this directory.
  12 #
  13 #    bindir
  14 #
  15 #        The name of the directory where executables should be
  16 #        written by the "install" target of the makefile.
  17 #
  18 #    program_prefix
  19 #
  20 #        Add this prefix to the names of all executables that run
  21 #        on the target machine.  Default: ""
  22 #
  23 #    ENABLE_SHARED
  24 #
  25 #        True if shared libraries should be generated.
  26 #
  27 #    BUILD_CC
  28 #
  29 #        The name of a command that is used to convert C
  30 #        source files into executables that run on the build
  31 #        platform.
  32 #
  33 #    BUILD_CFLAGS
  34 #
  35 #        Switches that the build compiler needs in order to construct
  36 #        command-line programs.
  37 #
  38 #    BUILD_LIBS
  39 #
  40 #        Libraries that the build compiler needs in order to construct
  41 #        command-line programs.
  42 #
  43 #    BUILD_EXEEXT
  44 #
  45 #        The filename extension for executables on the build
  46 #        platform.  "" for Unix and ".exe" for Windows.
  47 #
  48 #    TCL_*
  49 #
  50 #        Lots of values are read in from the tclConfig.sh script,
  51 #        if that script is available.  This values are used for
  52 #        constructing and installing the TCL extension.
  53 #
  54 #    TARGET_READLINE_LIBS
  55 #
  56 #        This is the library directives passed to the target linker
  57 #        that cause the executable to link against the readline library.
  58 #        This might be a switch like "-lreadline" or pathnames of library
  59 #        file like "../../src/libreadline.a".
  60 #
  61 #    TARGET_READLINE_INC
  62 #
  63 #        This variables define the directory that contain header
  64 #        files for the readline library.  If the compiler is able
  65 #        to find <readline.h> on its own, then this can be blank.
  66 #
  67 #    TARGET_EXEEXT
  68 #
  69 #        The filename extension for executables on the
  70 #        target platform.  "" for Unix and ".exe" for windows.
  71 #
  72 # This configure.in file is easy to reuse on other projects.  Just
  73 # change the argument to AC_INIT().  And disable any features that
  74 # you don't need (for example BLT) by erasing or commenting out
  75 # the corresponding code.
  76 #
  77 AC_INIT(sqlcipher, m4_esyscmd([cat VERSION | tr -d '\n']))
  78
  79 dnl Make sure the local VERSION file matches this configure script
  80 sqlite_version_sanity_check=`cat $srcdir/VERSION | tr -d '\n'`
  81 if test "$PACKAGE_VERSION" != "$sqlite_version_sanity_check" ; then
  82 AC_MSG_ERROR([configure script is out of date:
  83  configure \$PACKAGE_VERSION = $PACKAGE_VERSION
  84  top level VERSION file     = $sqlite_version_sanity_check
  85 please regen with autoconf])
  86 fi
  87
  88 #########
  89 # Programs needed
  90 #
  91 AC_PROG_LIBTOOL
  92 AC_PROG_INSTALL
  93 AC_PROG_AWK
  94
  95 #########
  96 # Enable large file support (if special flags are necessary)
  97 #
  98 AC_SYS_LARGEFILE
  99
 100 #########
 101 # Check for needed/wanted data types
 102 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, intptr_t, uint8_t,
 103                 uint16_t, uint32_t, uint64_t, uintptr_t])
 104
 105 #########
 106 # Check for needed/wanted headers
 107 AC_CHECK_HEADERS([sys/types.h stdlib.h stdint.h inttypes.h malloc.h])
 108
 109 #########
 110 # Figure out whether or not we have these functions
 111 #
 112 AC_CHECK_FUNCS([fdatasync gmtime_r isnan localtime_r localtime_s malloc_usable_size strchrnul usleep utime])
 113
 114 #########
 115 # By default, we use the amalgamation (this may be changed below...)
 116 #
 117 USE_AMALGAMATION=1
 118
 119 #########
 120 # See whether we can run specific tclsh versions known to work well;
 121 # if not, then we fall back to plain tclsh.
 122 # TODO: try other versions before falling back?
 123 #
 124 AC_CHECK_PROGS(TCLSH_CMD, [tclsh8.6 tclsh8.5 tclsh], none)
 125 if test "$TCLSH_CMD" = "none"; then
 126   # If we can't find a local tclsh, then building the amalgamation will fail.
 127   # We act as though --disable-amalgamation has been used.
 128   echo "Warning: can't find tclsh - defaulting to non-amalgamation build."
 129   USE_AMALGAMATION=0
 130   TCLSH_CMD="tclsh"
 131 fi
 132 AC_SUBST(TCLSH_CMD)
 133
 134 AC_ARG_VAR([TCLLIBDIR], [Where to install tcl plugin])
 135 if test "x${TCLLIBDIR+set}" != "xset" ; then
 136   TCLLIBDIR='$(libdir)'
 137   for i in `echo 'puts stdout $auto_path' | ${TCLSH_CMD}` ; do
 138     TCLLIBDIR=$i
 139     break
 140   done
 141   TCLLIBDIR="${TCLLIBDIR}/sqlite3"
 142 fi
 143
 144 #########
 145 # Set up an appropriate program prefix
 146 #
 147 if test "$program_prefix" = "NONE"; then
 148   program_prefix=""
 149 fi
 150 AC_SUBST(program_prefix)
 151
 152 VERSION=[`cat $srcdir/VERSION | sed 's/^\([0-9]*\.*[0-9]*\).*/\1/'`]
 153 AC_MSG_NOTICE(Version set to $VERSION)
 154 AC_SUBST(VERSION)
 155 RELEASE=`cat $srcdir/VERSION`
 156 AC_MSG_NOTICE(Release set to $RELEASE)
 157 AC_SUBST(RELEASE)
 158 VERSION_NUMBER=[`cat $srcdir/VERSION \
 159                            | sed 's/[^0-9]/ /g' \
 160                 | awk '{printf "%d%03d%03d",$1,$2,$3}'`]
 161 AC_MSG_NOTICE(Version number set to $VERSION_NUMBER)
 162 AC_SUBST(VERSION_NUMBER)
 163
 164 #########
 165 # Locate a compiler for the build machine.  This compiler should
 166 # generate command-line programs that run on the build machine.
 167 #
 168 if test x"$cross_compiling" = xno; then
 169         BUILD_CC=$CC
 170         BUILD_CFLAGS=$CFLAGS
 171 else
 172         if test "${BUILD_CC+set}" != set; then
 173                 AC_CHECK_PROGS(BUILD_CC, gcc cc cl)
 174         fi
 175         if test "${BUILD_CFLAGS+set}" != set; then
 176                 BUILD_CFLAGS="-g"
 177         fi
 178 fi
 179 AC_SUBST(BUILD_CC)
 180
 181 ##########
 182 # Do we want to support multithreaded use of sqlite
 183 #
 184 AC_ARG_ENABLE(threadsafe,
 185 AC_HELP_STRING([--disable-threadsafe],[Disable mutexing]),,enable_threadsafe=yes)
 186 AC_MSG_CHECKING([whether to support threadsafe operation])
 187 if test "$enable_threadsafe" = "no"; then
 188   SQLITE_THREADSAFE=0
 189   AC_MSG_RESULT([no])
 190 else
 191   SQLITE_THREADSAFE=1
 192   AC_MSG_RESULT([yes])
 193 fi
 194 AC_SUBST(SQLITE_THREADSAFE)
 195
 196 if test "$SQLITE_THREADSAFE" = "1"; then
 197   AC_SEARCH_LIBS(pthread_create, pthread)
 198 fi
 199
 200 ##########
 201 # Which crypto library do we use
 202 #
 203 AC_ARG_WITH([crypto-lib],
 204 AC_HELP_STRING([--with-crypto-lib],[Specify which crypto library to use]),
 205 crypto_lib=$withval)
 206 AC_MSG_CHECKING([for crypto library to use])
 207 if test "$crypto_lib" = "none"; then
 208   AC_MSG_RESULT([none])
 209 else
 210   if test "$crypto_lib" = "commoncrypto"; then
 211     CFLAGS+=" -DSQLCIPHER_CRYPTO_CC"
 212     BUILD_CFLAGS+=" -DSQLCIPHER_CRYPTO_CC"
 213           AC_MSG_RESULT([commoncrypto])
 214   else
 215     if test "$crypto_lib" = "libtomcrypt"; then
 216       CFLAGS+=" -DSQLCIPHER_CRYPTO_LIBTOMCRYPT"
 217       BUILD_CFLAGS+=" -DSQLCIPHER_CRYPTO_LIBTOMCRYPT"
 218       AC_MSG_RESULT([libtomcrypt])
 219       AC_CHECK_LIB([tomcrypt], [register_cipher], ,
 220                    AC_MSG_ERROR([Library crypto not found. Install libtomcrypt!"]))
 221     else
 222         CFLAGS+=" -DSQLCIPHER_CRYPTO_OPENSSL"
 223         BUILD_CFLAGS+=" -DSQLCIPHER_CRYPTO_OPENSSL"
 224               AC_MSG_RESULT([openssl])
 225         AC_CHECK_LIB([crypto], [HMAC_Init_ex], ,
 226                      AC_MSG_ERROR([Library crypto not found. Install openssl!"]))
 227     fi
 228   fi
 229 fi
 230
 231 ##########
 232 # Do we want to allow a connection created in one thread to be used
 233 # in another thread.  This does not work on many Linux systems (ex: RedHat 9)
 234 # due to bugs in the threading implementations.  This is thus off by default.
 235 #
 236 AC_ARG_ENABLE(cross-thread-connections,
 237 AC_HELP_STRING([--enable-cross-thread-connections],[Allow connection sharing across threads]),,enable_xthreadconnect=no)
 238 AC_MSG_CHECKING([whether to allow connections to be shared across threads])
 239 if test "$enable_xthreadconnect" = "no"; then
 240   XTHREADCONNECT=''
 241   AC_MSG_RESULT([no])
 242 else
 243   XTHREADCONNECT='-DSQLITE_ALLOW_XTHREAD_CONNECT=1'
 244   AC_MSG_RESULT([yes])
 245 fi
 246 AC_SUBST(XTHREADCONNECT)
 247
 248 ##########
 249 # Do we want to support release
 250 #
 251 AC_ARG_ENABLE(releasemode,
 252 AC_HELP_STRING([--enable-releasemode],[Support libtool link to release mode]),,enable_releasemode=no)
 253 AC_MSG_CHECKING([whether to support shared library linked as release mode or not])
 254 if test "$enable_releasemode" = "no"; then
 255   ALLOWRELEASE=""
 256   AC_MSG_RESULT([no])
 257 else
 258   ALLOWRELEASE="-release `cat $srcdir/VERSION`"
 259   AC_MSG_RESULT([yes])
 260 fi
 261 AC_SUBST(ALLOWRELEASE)
 262
 263 ##########
 264 # Do we want temporary databases in memory
 265 #
 266 AC_ARG_ENABLE(tempstore,
 267 AC_HELP_STRING([--enable-tempstore],[Use an in-ram database for temporary tables (never,no,yes,always)]),,enable_tempstore=no)
 268 AC_MSG_CHECKING([whether to use an in-ram database for temporary tables])
 269 case "$enable_tempstore" in
 270   never )
 271     TEMP_STORE=0
 272     AC_MSG_RESULT([never])
 273   ;;
 274   no )
 275     TEMP_STORE=1
 276     AC_MSG_RESULT([no])
 277   ;;
 278   yes )
 279      TEMP_STORE=2
 280     AC_MSG_RESULT([yes])
 281   ;;
 282   always )
 283      TEMP_STORE=3
 284     AC_MSG_RESULT([always])
 285   ;;
 286   * )
 287     TEMP_STORE=1
 288     AC_MSG_RESULT([no])
 289   ;;
 290 esac
 291
 292 AC_SUBST(TEMP_STORE)
 293
 294 ###########
 295 # Lots of things are different if we are compiling for Windows using
 296 # the CYGWIN environment.  So check for that special case and handle
 297 # things accordingly.
 298 #
 299 AC_MSG_CHECKING([if executables have the .exe suffix])
 300 if test "$config_BUILD_EXEEXT" = ".exe"; then
 301   CYGWIN=yes
 302   AC_MSG_RESULT(yes)
 303 else
 304   AC_MSG_RESULT(unknown)
 305 fi
 306 if test "$CYGWIN" != "yes"; then
 307   AC_CYGWIN
 308 fi
 309 if test "$CYGWIN" = "yes"; then
 310   BUILD_EXEEXT=.exe
 311 else
 312   BUILD_EXEEXT=$EXEEXT
 313 fi
 314 if test x"$cross_compiling" = xno; then
 315   TARGET_EXEEXT=$BUILD_EXEEXT
 316 else
 317   TARGET_EXEEXT=$config_TARGET_EXEEXT
 318 fi
 319 if test "$TARGET_EXEEXT" = ".exe"; then
 320   SQLITE_OS_UNIX=0
 321   SQLITE_OS_WIN=1
 322   CFLAGS="$CFLAGS -DSQLITE_OS_WIN=1"
 323 else
 324   SQLITE_OS_UNIX=1
 325   SQLITE_OS_WIN=0
 326   CFLAGS="$CFLAGS -DSQLITE_OS_UNIX=1"
 327 fi
 328
 329 AC_SUBST(BUILD_EXEEXT)
 330 AC_SUBST(SQLITE_OS_UNIX)
 331 AC_SUBST(SQLITE_OS_WIN)
 332 AC_SUBST(TARGET_EXEEXT)
 333
 334 ##########
 335 # Figure out all the parameters needed to compile against Tcl.
 336 #
 337 # This code is derived from the SC_PATH_TCLCONFIG and SC_LOAD_TCLCONFIG
 338 # macros in the in the tcl.m4 file of the standard TCL distribution.
 339 # Those macros could not be used directly since we have to make some
 340 # minor changes to accomodate systems that do not have TCL installed.
 341 #
 342 AC_ARG_ENABLE(tcl, AC_HELP_STRING([--disable-tcl],[do not build TCL extension]),
 343       [use_tcl=$enableval],[use_tcl=yes])
 344 if test "${use_tcl}" = "yes" ; then
 345   AC_ARG_WITH(tcl, AC_HELP_STRING([--with-tcl=DIR],[directory containing tcl configuration (tclConfig.sh)]), with_tclconfig=${withval})
 346   AC_MSG_CHECKING([for Tcl configuration])
 347   AC_CACHE_VAL(ac_cv_c_tclconfig,[
 348     # First check to see if --with-tcl was specified.
 349     if test x"${with_tclconfig}" != x ; then
 350       if test -f "${with_tclconfig}/tclConfig.sh" ; then
 351         ac_cv_c_tclconfig=`(cd ${with_tclconfig}; pwd)`
 352       else
 353         AC_MSG_ERROR([${with_tclconfig} directory doesn't contain tclConfig.sh])
 354       fi
 355     fi
 356
 357     # Start autosearch by asking tclsh
 358     if test x"${ac_cv_c_tclconfig}" = x ; then
 359       if test x"$cross_compiling" = xno; then
 360         for i in `echo 'puts stdout $auto_path' | ${TCLSH_CMD}`
 361         do
 362           if test -f "$i/tclConfig.sh" ; then
 363             ac_cv_c_tclconfig="$i"
 364             break
 365           fi
 366         done
 367       fi
 368     fi
 369
 370     # then check for a private Tcl installation
 371     if test x"${ac_cv_c_tclconfig}" = x ; then
 372       for i in \
 373             ../tcl \
 374             `ls -dr ../tcl[[8-9]].[[0-9]].[[0-9]]* 2>/dev/null` \
 375             `ls -dr ../tcl[[8-9]].[[0-9]] 2>/dev/null` \
 376             `ls -dr ../tcl[[8-9]].[[0-9]]* 2>/dev/null` \
 377             ../../tcl \
 378             `ls -dr ../../tcl[[8-9]].[[0-9]].[[0-9]]* 2>/dev/null` \
 379             `ls -dr ../../tcl[[8-9]].[[0-9]] 2>/dev/null` \
 380             `ls -dr ../../tcl[[8-9]].[[0-9]]* 2>/dev/null` \
 381             ../../../tcl \
 382             `ls -dr ../../../tcl[[8-9]].[[0-9]].[[0-9]]* 2>/dev/null` \
 383             `ls -dr ../../../tcl[[8-9]].[[0-9]] 2>/dev/null` \
 384             `ls -dr ../../../tcl[[8-9]].[[0-9]]* 2>/dev/null`
 385       do
 386         if test -f "$i/unix/tclConfig.sh" ; then
 387           ac_cv_c_tclconfig=`(cd $i/unix; pwd)`
 388           break
 389         fi
 390       done
 391     fi
 392
 393     # check in a few common install locations
 394     if test x"${ac_cv_c_tclconfig}" = x ; then
 395       for i in \
 396             `ls -d ${libdir} 2>/dev/null` \
 397             `ls -d /usr/local/lib 2>/dev/null` \
 398             `ls -d /usr/contrib/lib 2>/dev/null` \
 399             `ls -d /usr/lib 2>/dev/null`
 400       do
 401         if test -f "$i/tclConfig.sh" ; then
 402            ac_cv_c_tclconfig=`(cd $i; pwd)`
 403            break
 404         fi
 405       done
 406     fi
 407
 408     # check in a few other private locations
 409     if test x"${ac_cv_c_tclconfig}" = x ; then
 410       for i in \
 411          ${srcdir}/../tcl \
 412          `ls -dr ${srcdir}/../tcl[[8-9]].[[0-9]].[[0-9]]* 2>/dev/null` \
 413          `ls -dr ${srcdir}/../tcl[[8-9]].[[0-9]] 2>/dev/null` \
 414          `ls -dr ${srcdir}/../tcl[[8-9]].[[0-9]]* 2>/dev/null`
 415       do
 416         if test -f "$i/unix/tclConfig.sh" ; then
 417           ac_cv_c_tclconfig=`(cd $i/unix; pwd)`
 418           break
 419         fi
 420       done
 421     fi
 422   ])
 423
 424   if test x"${ac_cv_c_tclconfig}" = x ; then
 425     use_tcl=no
 426     AC_MSG_WARN(Can't find Tcl configuration definitions)
 427     AC_MSG_WARN(*** Without Tcl the regression tests cannot be executed ***)
 428     AC_MSG_WARN(*** Consider using --with-tcl=... to define location of Tcl ***)
 429   else
 430     TCL_BIN_DIR=${ac_cv_c_tclconfig}
 431     AC_MSG_RESULT(found $TCL_BIN_DIR/tclConfig.sh)
 432
 433     AC_MSG_CHECKING([for existence of $TCL_BIN_DIR/tclConfig.sh])
 434     if test -f "$TCL_BIN_DIR/tclConfig.sh" ; then
 435       AC_MSG_RESULT([loading])
 436       . $TCL_BIN_DIR/tclConfig.sh
 437     else
 438       AC_MSG_RESULT([file not found])
 439     fi
 440
 441     #
 442     # If the TCL_BIN_DIR is the build directory (not the install directory),
 443     # then set the common variable name to the value of the build variables.
 444     # For example, the variable TCL_LIB_SPEC will be set to the value
 445     # of TCL_BUILD_LIB_SPEC. An extension should make use of TCL_LIB_SPEC
 446     # instead of TCL_BUILD_LIB_SPEC since it will work with both an
 447     # installed and uninstalled version of Tcl.
 448     #
 449
 450     if test -f $TCL_BIN_DIR/Makefile ; then
 451       TCL_LIB_SPEC=${TCL_BUILD_LIB_SPEC}
 452       TCL_STUB_LIB_SPEC=${TCL_BUILD_STUB_LIB_SPEC}
 453       TCL_STUB_LIB_PATH=${TCL_BUILD_STUB_LIB_PATH}
 454     fi
 455
 456     #
 457     # eval is required to do the TCL_DBGX substitution
 458     #
 459
 460     eval "TCL_LIB_FILE=\"${TCL_LIB_FILE}\""
 461     eval "TCL_LIB_FLAG=\"${TCL_LIB_FLAG}\""
 462     eval "TCL_LIB_SPEC=\"${TCL_LIB_SPEC}\""
 463
 464     eval "TCL_STUB_LIB_FILE=\"${TCL_STUB_LIB_FILE}\""
 465     eval "TCL_STUB_LIB_FLAG=\"${TCL_STUB_LIB_FLAG}\""
 466     eval "TCL_STUB_LIB_SPEC=\"${TCL_STUB_LIB_SPEC}\""
 467
 468     AC_SUBST(TCL_VERSION)
 469     AC_SUBST(TCL_BIN_DIR)
 470     AC_SUBST(TCL_SRC_DIR)
 471     AC_SUBST(TCL_INCLUDE_SPEC)
 472
 473     AC_SUBST(TCL_LIB_FILE)
 474     AC_SUBST(TCL_LIB_FLAG)
 475     AC_SUBST(TCL_LIB_SPEC)
 476
 477     AC_SUBST(TCL_STUB_LIB_FILE)
 478     AC_SUBST(TCL_STUB_LIB_FLAG)
 479     AC_SUBST(TCL_STUB_LIB_SPEC)
 480   fi
 481 fi
 482 if test "${use_tcl}" = "no" ; then
 483   HAVE_TCL=""
 484 else
 485   HAVE_TCL=1
 486 fi
 487 AC_SUBST(HAVE_TCL)
 488
 489 ##########
 490 # Figure out what C libraries are required to compile programs
 491 # that use "readline()" library.
 492 #
 493 TARGET_READLINE_LIBS=""
 494 TARGET_READLINE_INC=""
 495 TARGET_HAVE_READLINE=0
 496 AC_ARG_ENABLE([readline],
 497         [AC_HELP_STRING([--disable-readline],[disable readline support [default=detect]])],
 498         [with_readline=$enableval],
 499         [with_readline=auto])
 500
 501 if test x"$with_readline" != xno; then
 502         found="yes"
 503
 504         AC_ARG_WITH([readline-lib],
 505                 [AC_HELP_STRING([--with-readline-lib],[specify readline library])],
 506                 [with_readline_lib=$withval],
 507                 [with_readline_lib="auto"])
 508         if test "x$with_readline_lib" = xauto; then
 509                 save_LIBS="$LIBS"
 510                 LIBS=""
 511                 AC_SEARCH_LIBS(tgetent, [readline ncurses curses termcap], [term_LIBS="$LIBS"], [term_LIBS=""])
 512                 AC_CHECK_LIB([readline], [readline], [TARGET_READLINE_LIBS="-lreadline"], [found="no"])
 513                 TARGET_READLINE_LIBS="$TARGET_READLINE_LIBS $term_LIBS"
 514                 LIBS="$save_LIBS"
 515         else
 516                 TARGET_READLINE_LIBS="$with_readline_lib"
 517         fi
 518
 519         AC_ARG_WITH([readline-inc],
 520                 [AC_HELP_STRING([--with-readline-inc],[specify readline include paths])],
 521                 [with_readline_inc=$withval],
 522                 [with_readline_inc="auto"])
 523         if test "x$with_readline_inc" = xauto; then
 524                 AC_CHECK_HEADER(readline.h, [found="yes"], [
 525                         found="no"
 526                         if test "$cross_compiling" != yes; then
 527                                 for dir in /usr /usr/local /usr/local/readline /usr/contrib /mingw; do
 528                                         for subdir in include include/readline; do
 529                                                 AC_CHECK_FILE($dir/$subdir/readline.h, found=yes)
 530                                                 if test "$found" = "yes"; then
 531                                                         TARGET_READLINE_INC="-I$dir/$subdir"
 532                                                         break
 533                                                 fi
 534                                         done
 535                                         test "$found" = "yes" && break
 536                                 done
 537                         fi
 538                 ])
 539         else
 540                 TARGET_READLINE_INC="$with_readline_inc"
 541         fi
 542
 543         if test x"$found" = xno; then
 544                 TARGET_READLINE_LIBS=""
 545                 TARGET_READLINE_INC=""
 546                 TARGET_HAVE_READLINE=0
 547         else
 548                 TARGET_HAVE_READLINE=1
 549         fi
 550 fi
 551
 552 AC_SUBST(TARGET_READLINE_LIBS)
 553 AC_SUBST(TARGET_READLINE_INC)
 554 AC_SUBST(TARGET_HAVE_READLINE)
 555
 556 ##########
 557 # Figure out what C libraries are required to compile programs
 558 # that use "fdatasync()" function.
 559 #
 560 AC_SEARCH_LIBS(fdatasync, [rt])
 561
 562 #########
 563 # check for debug enabled
 564 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug],[enable debugging & verbose explain]),
 565       [use_debug=$enableval],[use_debug=no])
 566 if test "${use_debug}" = "yes" ; then
 567   TARGET_DEBUG="-DSQLITE_DEBUG=1"
 568 else
 569   TARGET_DEBUG="-DNDEBUG"
 570 fi
 571 AC_SUBST(TARGET_DEBUG)
 572
 573 #########
 574 # See whether we should use the amalgamation to build
 575 AC_ARG_ENABLE(amalgamation, AC_HELP_STRING([--disable-amalgamation],
 576       [Disable the amalgamation and instead build all files separately]),
 577       [use_amalgamation=$enableval],[use_amalgamation=yes])
 578 if test "${use_amalgamation}" != "yes" ; then
 579   USE_AMALGAMATION=0
 580 fi
 581 AC_SUBST(USE_AMALGAMATION)
 582
 583 #########
 584 # See whether we should allow loadable extensions
 585 AC_ARG_ENABLE(load-extension, AC_HELP_STRING([--disable-load-extension],
 586       [Disable loading of external extensions]),
 587       [use_loadextension=$enableval],[use_loadextension=yes])
 588 if test "${use_loadextension}" = "yes" ; then
 589   OPT_FEATURE_FLAGS=""
 590   AC_SEARCH_LIBS(dlopen, dl)
 591 else
 592   OPT_FEATURE_FLAGS="-DSQLITE_OMIT_LOAD_EXTENSION=1"
 593 fi
 594
 595 #########
 596 # attempt to duplicate any OMITS and ENABLES into the $(OPT_FEATURE_FLAGS) parameter
 597 for option in $CFLAGS $CPPFLAGS
 598 do
 599   case $option in
 600     -DSQLITE_OMIT*) OPT_FEATURE_FLAGS="$OPT_FEATURE_FLAGS $option";;
 601     -DSQLITE_ENABLE*) OPT_FEATURE_FLAGS="$OPT_FEATURE_FLAGS $option";;
 602   esac
 603 done
 604 AC_SUBST(OPT_FEATURE_FLAGS)
 605
 606
 607 # attempt to remove any OMITS and ENABLES from the $(CFLAGS) parameter
 608 ac_temp_CFLAGS=""
 609 for option in $CFLAGS
 610 do
 611   case $option in
 612     -DSQLITE_OMIT*) ;;
 613     -DSQLITE_ENABLE*) ;;
 614     *) ac_temp_CFLAGS="$ac_temp_CFLAGS $option";;
 615   esac
 616 done
 617 CFLAGS=$ac_temp_CFLAGS
 618
 619
 620 # attempt to remove any OMITS and ENABLES from the $(CPPFLAGS) parameter
 621 ac_temp_CPPFLAGS=""
 622 for option in $CPPFLAGS
 623 do
 624   case $option in
 625     -DSQLITE_OMIT*) ;;
 626     -DSQLITE_ENABLE*) ;;
 627     *) ac_temp_CPPFLAGS="$ac_temp_CPPFLAGS $option";;
 628   esac
 629 done
 630 CPPFLAGS=$ac_temp_CPPFLAGS
 631
 632
 633 # attempt to remove any OMITS and ENABLES from the $(BUILD_CFLAGS) parameter
 634 ac_temp_BUILD_CFLAGS=""
 635 for option in $BUILD_CFLAGS
 636 do
 637   case $option in
 638     -DSQLITE_OMIT*) ;;
 639     -DSQLITE_ENABLE*) ;;
 640     *) ac_temp_BUILD_CFLAGS="$ac_temp_BUILD_CFLAGS $option";;
 641   esac
 642 done
 643 BUILD_CFLAGS=$ac_temp_BUILD_CFLAGS
 644
 645
 646 #########
 647 # See whether we should use GCOV
 648 AC_ARG_ENABLE(gcov, AC_HELP_STRING([--enable-gcov],
 649       [Enable coverage testing using gcov]),
 650       [use_gcov=$enableval],[use_gcov=no])
 651 if test "${use_gcov}" = "yes" ; then
 652   USE_GCOV=1
 653 else
 654   USE_GCOV=0
 655 fi
 656 AC_SUBST(USE_GCOV)
 657
 658
 659 #########
 660 # Output the config header
 661 AC_CONFIG_HEADERS(config.h)
 662
 663 #########
 664 # Generate the output files.
 665 #
 666 AC_SUBST(BUILD_CFLAGS)
 667 AC_OUTPUT([
 668 Makefile
 669 sqlcipher.pc
 670 ])