tool/mksqlite3h.tcl

   1 #!/usr/bin/tclsh
   2 #
   3 # This script constructs the "sqlite3.h" header file from the following
   4 # sources:
   5 #
   6 #   1) The src/sqlite.h.in source file.  This is the template for sqlite3.h.
   7 #   2) The VERSION file containing the current SQLite version number.
   8 #   3) The manifest file from the fossil SCM.  This gives use the date.
   9 #   4) The manifest.uuid file from the fossil SCM.  This gives the SHA1 hash.
  10 #
  11 # Run this script by specifying the root directory of the source tree
  12 # on the command-line.
  13 #
  14 # This script performs processing on src/sqlite.h.in. It:
  15 #
  16 #   1) Adds SQLITE_EXTERN in front of the declaration of global variables,
  17 #   2) Adds SQLITE_API in front of the declaration of API functions,
  18 #   3) Replaces the string --VERS-- with the current library version,
  19 #      formatted as a string (e.g. "3.6.17"), and
  20 #   4) Replaces the string --VERSION-NUMBER-- with current library version,
  21 #      formatted as an integer (e.g. "3006017").
  22 #   5) Replaces the string --SOURCE-ID-- with the date and time and sha1
  23 #      hash of the fossil-scm manifest for the source tree.
  24 #   6) Adds the SQLITE_CALLBACK calling convention macro in front of all
  25 #      callback declarations.
  26 #
  27 # This script outputs to stdout.
  28 #
  29 # Example usage:
  30 #
  31 #   tclsh mksqlite3h.tcl ../sqlite >sqlite3.h
  32 #
  33
  34
  35 # Get the source tree root directory from the command-line
  36 #
  37 set TOP [lindex $argv 0]
  38
  39 # Enable use of SQLITE_APICALL macros at the right points?
  40 #
  41 set useapicall 0
  42
  43 if {[lsearch -regexp [lrange $argv 1 end] {^-+useapicall}] != -1} {
  44   set useapicall 1
  45 }
  46
  47 # Get the SQLite version number (ex: 3.6.18) from the $TOP/VERSION file.
  48 #
  49 set in [open $TOP/VERSION]
  50 set zVersion [string trim [read $in]]
  51 close $in
  52 set nVersion [eval format "%d%03d%03d" [split $zVersion .]]
  53
  54 # Get the fossil-scm version number from $TOP/manifest.uuid.
  55 #
  56 set in [open $TOP/manifest.uuid]
  57 set zUuid [string trim [read $in]]
  58 close $in
  59
  60 # Get the fossil-scm check-in date from the "D" card of $TOP/manifest.
  61 #
  62 set in [open $TOP/manifest]
  63 set zDate {}
  64 while {![eof $in]} {
  65   set line [gets $in]
  66   if {[regexp {^D (2[-0-9T:]+)} $line all date]} {
  67     set zDate [string map {T { }} $date]
  68     break
  69   }
  70 }
  71 close $in
  72
  73 # Set up patterns for recognizing API declarations.
  74 #
  75 set varpattern {^[a-zA-Z][a-zA-Z_0-9 *]+sqlite3_[_a-zA-Z0-9]+(\[|;| =)}
  76 set declpattern1 {^ *([a-zA-Z][a-zA-Z_0-9 ]+ \**)(sqlite3_[_a-zA-Z0-9]+)(\(.*)$}
  77
  78 set declpattern2 \
  79     {^ *([a-zA-Z][a-zA-Z_0-9 ]+ \**)(sqlite3session_[_a-zA-Z0-9]+)(\(.*)$}
  80
  81 set declpattern3 \
  82     {^ *([a-zA-Z][a-zA-Z_0-9 ]+ \**)(sqlite3changeset_[_a-zA-Z0-9]+)(\(.*)$}
  83
  84 set declpattern4 \
  85     {^ *([a-zA-Z][a-zA-Z_0-9 ]+ \**)(sqlite3changegroup_[_a-zA-Z0-9]+)(\(.*)$}
  86
  87 # Force the output to use unix line endings, even on Windows.
  88 fconfigure stdout -translation lf
  89
  90 set filelist [subst {
  91   $TOP/src/sqlite.h.in
  92   $TOP/ext/rtree/sqlite3rtree.h
  93   $TOP/ext/session/sqlite3session.h
  94   $TOP/ext/fts5/fts5.h
  95 }]
  96
  97 # These are the functions that accept a variable number of arguments.  They
  98 # always need to use the "cdecl" calling convention even when another calling
  99 # convention (e.g. "stcall") is being used for the rest of the library.
 100 set cdecllist {
 101   sqlite3_config
 102   sqlite3_db_config
 103   sqlite3_log
 104   sqlite3_mprintf
 105   sqlite3_snprintf
 106   sqlite3_test_control
 107   sqlite3_vtab_config
 108 }
 109
 110 # Process the source files.
 111 #
 112 foreach file $filelist {
 113   set in [open $file]
 114   if {![regexp {sqlite\.h\.in} $file]} {
 115     puts "/******** Begin file [file tail $file] *********/"
 116   }
 117   while {![eof $in]} {
 118
 119     set line [gets $in]
 120
 121     # File sqlite3rtree.h contains a line "#include <sqlite3.h>". Omit this
 122     # line when copying sqlite3rtree.h into sqlite3.h.
 123     #
 124     if {[string match {*#include*[<"]sqlite3.h[>"]*} $line]} continue
 125
 126     regsub -- --VERS--           $line $zVersion line
 127     regsub -- --VERSION-NUMBER-- $line $nVersion line
 128     regsub -- --SOURCE-ID--      $line "$zDate $zUuid" line
 129
 130     if {[regexp $varpattern $line] && ![regexp {^ *typedef} $line]} {
 131       set line "SQLITE_API $line"
 132     } else {
 133       if {[regexp $declpattern1 $line all rettype funcname rest] || \
 134           [regexp $declpattern2 $line all rettype funcname rest] || \
 135           [regexp $declpattern3 $line all rettype funcname rest] || \
 136           [regexp $declpattern4 $line all rettype funcname rest]} {
 137         set line SQLITE_API
 138         append line " " [string trim $rettype]
 139         if {[string index $rettype end] ne "*"} {
 140           append line " "
 141         }
 142         if {$useapicall} {
 143           if {[lsearch -exact $cdecllist $funcname] >= 0} {
 144             append line SQLITE_CDECL " "
 145           } else {
 146             append line SQLITE_APICALL " "
 147           }
 148         }
 149         append line $funcname $rest
 150       }
 151     }
 152     if {$useapicall} {
 153       set line [string map [list (*sqlite3_syscall_ptr) \
 154           "(SQLITE_SYSAPI *sqlite3_syscall_ptr)"] $line]
 155       regsub {\(\*} $line {(SQLITE_CALLBACK *} line
 156     }
 157     puts $line
 158   }
 159   close $in
 160   if {![regexp {sqlite\.h\.in} $file]} {
 161     puts "/******** End of [file tail $file] *********/"
 162   }
 163 }