ext/rbu/rbu10.test

   1 # 2014 August 30
   2 #
   3 # The author disclaims copyright to this source code.  In place of
   4 # a legal notice, here is a blessing:
   5 #
   6 #    May you do good and not evil.
   7 #    May you find forgiveness for yourself and forgive others.
   8 #    May you share freely, never taking more than you give.
   9 #
  10 #***********************************************************************
  11 #
  12
  13 source [file join [file dirname [info script]] rbu_common.tcl]
  14 if_no_rbu_support { finish_test ; return }
  15 set ::testprefix rbu10
  16
  17 #--------------------------------------------------------------------
  18 # Test that UPDATE commands work even if the input columns are in a
  19 # different order to the output columns.
  20 #
  21 do_execsql_test 1.0 {
  22   CREATE TABLE t1(a INTEGER PRIMARY KEY, b, c);
  23   INSERT INTO t1 VALUES(1, 'b', 'c');
  24 }
  25
  26 proc apply_rbu {sql} {
  27   forcedelete rbu.db
  28   sqlite3 db2 rbu.db
  29   db2 eval $sql
  30   db2 close
  31   sqlite3rbu rbu test.db rbu.db
  32   while { [rbu step]=="SQLITE_OK" } {}
  33   rbu close
  34 }
  35
  36 do_test 1.1 {
  37   apply_rbu {
  38     CREATE TABLE data_t1(a, c, b, rbu_control);
  39     INSERT INTO data_t1 VALUES(1, 'xxx', NULL, '.x.');
  40   }
  41   db eval { SELECT * FROM t1 }
  42 } {1 b xxx}
  43
  44 #--------------------------------------------------------------------
  45 # Test that the hidden languageid column of an fts4 table can be
  46 # written.
  47 #
  48 ifcapable fts3 {
  49   do_execsql_test 2.0 {
  50     create virtual TABLE ft USING fts4(a, b, languageid='langid');
  51   }
  52   do_test 2.1 {
  53     apply_rbu {
  54       CREATE TABLE data_ft(a, b, rbu_rowid, langid, rbu_control);
  55       INSERT INTO data_ft VALUES('a', 'b', 22, 1, 0);    -- insert
  56       INSERT INTO data_ft VALUES('a', 'b', 23, 10, 0);   -- insert
  57       INSERT INTO data_ft VALUES('a', 'b', 24, 100, 0);  -- insert
  58     }
  59     db eval { SELECT a, b, rowid, langid FROM ft }
  60   } [list {*}{
  61     a b 22 1
  62     a b 23 10
  63     a b 24 100
  64   }]
  65
  66   # Or not - this data_xxx table has no langid column, so langid
  67   # defaults to 0.
  68   #
  69   do_test 2.2 {
  70     apply_rbu {
  71       CREATE TABLE data_ft(a, b, rbu_rowid, rbu_control);
  72       INSERT INTO data_ft VALUES('a', 'b', 25, 0);    -- insert
  73     }
  74     db eval { SELECT a, b, rowid, langid FROM ft }
  75   } [list {*}{
  76     a b 22 1
  77     a b 23 10
  78     a b 24 100
  79     a b 25 0
  80   }]
  81
  82   # Update langid.
  83   #
  84   do_test 2.3 {
  85     apply_rbu {
  86       CREATE TABLE data_ft(a, b, rbu_rowid, langid, rbu_control);
  87       INSERT INTO data_ft VALUES(NULL, NULL, 23, 50, '..x');
  88       INSERT INTO data_ft VALUES(NULL, NULL, 25, 500, '..x');
  89     }
  90     db eval { SELECT a, b, rowid, langid FROM ft }
  91   } [list {*}{
  92     a b 22 1
  93     a b 23 50
  94     a b 24 100
  95     a b 25 500
  96   }]
  97 }
  98
  99 #--------------------------------------------------------------------
 100 # Test that if writing a hidden virtual table column is an error,
 101 # attempting to do so via rbu is also an error.
 102 #
 103 ifcapable fts3 {
 104   do_execsql_test 3.0 {
 105     CREATE VIRTUAL TABLE xt USING fts4(a);
 106   }
 107   do_test 3.1 {
 108     list [catch {
 109       apply_rbu {
 110         CREATE TABLE data_xt(a, xt, rbu_rowid, rbu_control);
 111         INSERT INTO data_xt VALUES('a', 'b', 1, 0);
 112       }
 113     } msg] $msg
 114   } {1 {SQLITE_ERROR - SQL logic error}}
 115 }
 116
 117 #--------------------------------------------------------------------
 118 # Test that it is not possible to violate a NOT NULL constraint by
 119 # applying an RBU update.
 120 #
 121 do_execsql_test 4.1 {
 122   CREATE TABLE t2(a INTEGER NOT NULL, b TEXT NOT NULL, c PRIMARY KEY);
 123   CREATE TABLE t3(a INTEGER NOT NULL, b TEXT NOT NULL, c INTEGER PRIMARY KEY);
 124   CREATE TABLE t4(a, b, PRIMARY KEY(a, b)) WITHOUT ROWID;
 125
 126   INSERT INTO t2 VALUES(10, 10, 10);
 127   INSERT INTO t3 VALUES(10, 10, 10);
 128   INSERT INTO t4 VALUES(10, 10);
 129 }
 130
 131 foreach {tn error rbu} {
 132   2 {SQLITE_CONSTRAINT - NOT NULL constraint failed: t2.a} {
 133     INSERT INTO data_t2 VALUES(NULL, 'abc', 1, 0);
 134   }
 135   3 {SQLITE_CONSTRAINT - NOT NULL constraint failed: t2.b} {
 136     INSERT INTO data_t2 VALUES(2, NULL, 1, 0);
 137   }
 138   4 {SQLITE_CONSTRAINT - NOT NULL constraint failed: t2.c} {
 139     INSERT INTO data_t2 VALUES(1, 'abc', NULL, 0);
 140   }
 141
 142   5 {SQLITE_MISMATCH - datatype mismatch} {
 143     INSERT INTO data_t3 VALUES(1, 'abc', NULL, 0);
 144   }
 145
 146   6 {SQLITE_CONSTRAINT - NOT NULL constraint failed: t4.b} {
 147     INSERT INTO data_t4 VALUES('a', NULL, 0);
 148   }
 149   7 {SQLITE_CONSTRAINT - NOT NULL constraint failed: t4.a} {
 150     INSERT INTO data_t4 VALUES(NULL, 'a', 0);
 151   }
 152   8  {SQLITE_CONSTRAINT - NOT NULL constraint failed: t2.a} {
 153     INSERT INTO data_t2 VALUES(NULL, 0, 10, 'x..');
 154   }
 155   9  {SQLITE_CONSTRAINT - NOT NULL constraint failed: t3.b} {
 156     INSERT INTO data_t3 VALUES(10, NULL, 10, '.x.');
 157   }
 158
 159   10 {SQLITE_MISMATCH - datatype mismatch} {
 160     INSERT INTO data_t3 VALUES(1, 'abc', 'text', 0);
 161   }
 162 } {
 163   set rbu "
 164     CREATE TABLE data_t2(a, b, c, rbu_control);
 165     CREATE TABLE data_t3(a, b, c, rbu_control);
 166     CREATE TABLE data_t4(a, b, rbu_control);
 167     $rbu
 168   "
 169   do_test 4.2.$tn {
 170     list [catch { apply_rbu $rbu } msg] $msg
 171   } [list 1 $error]
 172 }
 173
 174 do_test 4.3 {
 175   set rbu {
 176     CREATE TABLE data_t3(a, b, c, rbu_control);
 177     INSERT INTO data_t3 VALUES(1, 'abc', '5', 0);
 178     INSERT INTO data_t3 VALUES(1, 'abc', '-6.0', 0);
 179   }
 180   list [catch { apply_rbu $rbu } msg] $msg
 181 } {0 SQLITE_DONE}
 182
 183
 184 finish_test