test/fts4check.test

   1 # 2012 March 26
   2 #
   3 # The author disclaims copyright to this source code.  In place of
   4 # a legal notice, here is a blessing:
   5 #
   6 #    May you do good and not evil.
   7 #    May you find forgiveness for yourself and forgive others.
   8 #    May you share freely, never taking more than you give.
   9 #
  10 #*************************************************************************
  11 # This file implements regression tests for SQLite library. The
  12 # focus of this script is testing the FTS 'integrity-check' function,
  13 # used to check if the current FTS index accurately reflects the content
  14 # of the table.
  15 #
  16
  17 set testdir [file dirname $argv0]
  18 source $testdir/tester.tcl
  19 source $testdir/fts3_common.tcl
  20 set ::testprefix fts4check
  21
  22 # If SQLITE_ENABLE_FTS3 is defined, omit this file.
  23 ifcapable !fts3 {
  24   finish_test
  25   return
  26 }
  27
  28 # Run the integrity-check on FTS table $tbl using database handle $db. If
  29 # the integrity-check passes, return "ok". Otherwise, throw an exception.
  30 #
  31 proc fts_integrity {db tbl} {
  32   $db eval "INSERT INTO $tbl ($tbl) VALUES('integrity-check')"
  33   return "ok"
  34 }
  35
  36 #-------------------------------------------------------------------------
  37 # Test cases 1.*
  38 #
  39 #   1.0: Build a reasonably sized FTS table (5000 rows).
  40 #
  41 #   1.1: Run the integrity check code to check it passes.
  42 #
  43 #   1.2: Make a series of minor changes to the underlying FTS data structures
  44 #        (e.g. delete or insert a row from the %_content table). Check that
  45 #        this causes the integrity-check code to fail.
  46 #
  47
  48 # Build an FTS table and check the integrity-check passes.
  49 #
  50 do_test 1.0 { fts3_build_db_1 5000 } {}
  51 do_test 1.1 { fts_integrity db t1 } {ok}
  52
  53 # Mess around with the underlying tables. Check that this causes the
  54 # integrity-check test to fail.
  55 #
  56 foreach {tn disruption} {
  57   1 {
  58     INSERT INTO t1_content(docid, c0x, c1y) VALUES(NULL, 'a', 'b');
  59   }
  60   2 {
  61     DELETE FROM t1_content WHERE docid = (SELECT max(docid) FROM t1_content);
  62   }
  63   3 {
  64     DELETE FROM t1_segdir WHERE level=0 AND idx=(
  65       SELECT max(idx) FROM t1_segdir WHERE level=0
  66     );
  67   }
  68 } {
  69   sqlite3_db_config db DEFENSIVE 0
  70   do_execsql_test  1.2.1.$tn "BEGIN; $disruption"
  71   do_catchsql_test 1.2.2.$tn {
  72     INSERT INTO t1 (t1) VALUES('integrity-check')
  73   } {1 {database disk image is malformed}}
  74   do_execsql_test  1.2.3.$tn "ROLLBACK"
  75 }
  76
  77 do_test 1.3 { fts_integrity db t1 } {ok}
  78
  79 #-------------------------------------------------------------------------
  80 # Test cases 2.*
  81 #
  82 #   2.0: Build a reasonably sized FTS table (20000 rows) that includes
  83 #        prefix indexes.
  84 #
  85 #   2.1: Run the integrity check code to check it passes.
  86 #
  87 #   2.2: Make a series of minor changes to the underlying FTS data structures
  88 #        (e.g. delete or insert a row from the %_content table). Check that
  89 #        this causes the integrity-check code to fail.
  90 #
  91
  92 do_test 2.0 { fts3_build_db_2 -extra {prefix="3,1"} 20000 } {}
  93 do_test 2.1 { fts_integrity db t2 } {ok}
  94 foreach {tn disruption} {
  95   1 {
  96     INSERT INTO t2_content VALUES(NULL, 'xyz')
  97   }
  98   3 {
  99     DELETE FROM t2_segdir WHERE level=0 AND idx=(
 100       SELECT max(idx) FROM t2_segdir WHERE level=1024
 101     );
 102   }
 103 } {
 104   sqlite3_db_config db DEFENSIVE 0
 105   do_execsql_test  2.2.1.$tn "BEGIN; $disruption"
 106   do_catchsql_test 2.2.2.$tn {
 107     INSERT INTO t2 (t2) VALUES('integrity-check')
 108   } {1 {database disk image is malformed}}
 109   do_execsql_test  2.2.3.$tn "ROLLBACK"
 110 }
 111
 112
 113 #-------------------------------------------------------------------------
 114 # Test cases 3.*
 115 #
 116 #   3.0: Build a reasonably sized FTS table (5000 rows) that includes
 117 #        prefix indexes and uses the languageid= feature.
 118 #
 119 #   3.1: Run the integrity check code to check it passes.
 120 #
 121 #   3.2: Make a series of minor changes to the underlying FTS data structures
 122 #        (e.g. delete or insert a row from the %_content table). Check that
 123 #        this causes the integrity-check code to fail.
 124 #
 125 do_test 3.0 {
 126   reset_db
 127   fts3_build_db_1 5000
 128   execsql {
 129     CREATE VIRTUAL TABLE t3 USING fts4(x, y, prefix="2,3", languageid=langid);
 130   }
 131   foreach docid [execsql {SELECT docid FROM t1 ORDER BY 1 ASC}] {
 132     execsql {
 133       INSERT INTO t3(x, y, langid)
 134       SELECT x, y, (docid%9)*4 FROM t1 WHERE docid=$docid;
 135     }
 136   }
 137 } {}
 138 do_test 3.1 { fts_integrity db t3 } {ok}
 139
 140 foreach {tn disruption} {
 141   1 {
 142     INSERT INTO t3_content(c0x, c1y, langid) VALUES(NULL, 'a', 0);
 143   }
 144   2 {
 145     UPDATE t3_content SET langid=langid+1 WHERE rowid = (
 146       SELECT max(rowid) FROM t3_content
 147     )
 148   }
 149 } {
 150   sqlite3_db_config db DEFENSIVE 0
 151   do_execsql_test  3.2.1.$tn "BEGIN; $disruption"
 152   do_catchsql_test 3.2.2.$tn {
 153     INSERT INTO t3 (t3) VALUES('integrity-check')
 154   } {1 {database disk image is malformed}}
 155   do_execsql_test  3.2.3.$tn "ROLLBACK"
 156 }
 157
 158 #--------------------------------------------------------------------------
 159 # Test case 4.*
 160 #
 161 # Test that the integrity-check works if there are "notindexed" columns.
 162 #
 163 do_execsql_test 4.0 {
 164   CREATE VIRTUAL TABLE t4 USING fts4(a, b, c, notindexed=b);
 165   INSERT INTO t4 VALUES('text one', 'text two', 'text three');
 166   INSERT INTO t4(t4) VALUES('integrity-check');
 167 }
 168
 169 sqlite3_db_config db DEFENSIVE 0
 170 do_execsql_test 4.1 {
 171   PRAGMA writable_schema = 1;
 172   UPDATE sqlite_master
 173     SET sql = 'CREATE VIRTUAL TABLE t4 USING fts4(a, b, c)'
 174     WHERE name = 't4';
 175 }
 176
 177 do_test 4.2 {
 178   db close
 179   sqlite3 db test.db
 180   catchsql {
 181     INSERT INTO t4(t4) VALUES('integrity-check');
 182   }
 183 } {1 {database disk image is malformed}}
 184 reset_db
 185
 186 #--------------------------------------------------------------------------
 187 # Test case 5.*
 188 #
 189 # Test that the integrity-check works if there is uncommitted data.
 190 #
 191 do_execsql_test 5.0 {
 192   BEGIN;
 193   CREATE VIRTUAL TABLE t5 USING fts4(a, prefix="1,2,3");
 194   INSERT INTO t5 VALUES('And down by Kosiosko, where the reed-banks sweep');
 195   INSERT INTO t5 VALUES('and sway, and the rolling plains are wide, the');
 196   INSERT INTO t5 VALUES('man from snowy river is a household name today,');
 197   INSERT INTO t5 VALUES('and the stockmen tell the story of his ride');
 198 }
 199
 200 do_execsql_test 5.1 {
 201   INSERT INTO t5(t5) VALUES('integrity-check');
 202 } {}
 203
 204 sqlite3_db_config db DEFENSIVE 0
 205 do_catchsql_test 5.2 {
 206   INSERT INTO t5_content VALUES(5, 'his hardy mountain pony');
 207   INSERT INTO t5(t5) VALUES('integrity-check');
 208 } {1 {database disk image is malformed}}
 209
 210 do_execsql_test 5.3 ROLLBACK
 211
 212 do_execsql_test 5.4 {
 213   CREATE VIRTUAL TABLE t5 USING fts4(a, prefix="1,2,3");
 214   INSERT INTO t5(t5) VALUES('integrity-check');
 215 } {}
 216
 217 finish_test