sloppygui.pro

   1 SLOPPYGUI_VERSION = unknown
   2
   3 # Check if the version file exists.
   4 exists(version) {
   5
   6         # If the version file exists, use its contents as the version number
   7         SLOPPYGUI_VERSION = $$system(cat version)
   8 } else {
   9
  10         # If the version file doesn't exist, check if we have
  11         # .git directory
  12         exists(.git) {
  13
  14                 # Check if we can describe this commit
  15                 system(git describe > /dev/null 2> /dev/null) {
  16
  17                         # If we can, describe it
  18                         SLOPPYGUI_VERSION = $$system(git describe)
  19                 } else {
  20
  21                         # If we can't describe it, parse the sha id and use that
  22                         SLOPPYGUI_VERSION = git-$$system(git rev-parse --short HEAD)
  23                 }
  24         }
  25 }
  26
  27 macx-xcode {
  28         DEFINES += SLOPPYGUI_VERSION=\"$$SLOPPYGUI_VERSION\"
  29 } else {
  30         DEFINES += SLOPPYGUI_VERSION=\\\"$$SLOPPYGUI_VERSION\\\"
  31 }
  32
  33 CONFIG += qt debug
  34 QT += svg
  35
  36 win32:debug {
  37         CONFIG += console
  38 }
  39
  40 HEADERS = src/graphicschessboardsquareitem.h \
  41           src/graphicschessboarditem.h \
  42           src/graphicschesspiece.h \
  43           src/chessboardview.h \
  44           src/chessclock.h \
  45           src/manager.h \
  46           src/logmanager.h \
  47           src/newgamedlg.h \
  48           src/stdoutlogger.h \
  49           src/guilogger.h \
  50           src/loggerbase.h \
  51           src/mainwindow.h \
  52           src/symbols.h \
  53           src/promotiondlg.h \
  54           src/chessgame.h \
  55           src/timecontrol.h \
  56           src/chessplayer.h \
  57           src/chessengine.h \
  58           src/engineconfiguration.h \
  59           src/engineconfigurationmodel.h \
  60           src/xboardengine.h \
  61           src/uciengine.h \
  62           src/chessboard/chessboard.h \
  63           src/chessboard/chessmove.h \
  64           src/chessboard/magicmoves.h \
  65           src/chessboard/movegen.h \
  66           src/chessboard/notation.h \
  67           src/chessboard/util.h \
  68           src/chessboard/zobrist.h
  69
  70 SOURCES = src/main.cpp \
  71           src/graphicschessboardsquareitem.cpp \
  72           src/graphicschessboarditem.cpp \
  73           src/graphicschesspiece.cpp \
  74           src/chessboardview.cpp \
  75           src/chessclock.cpp \
  76           src/manager.cpp \
  77           src/logmanager.cpp \
  78           src/stdoutlogger.cpp \
  79           src/guilogger.cpp \
  80           src/mainwindow.cpp \
  81           src/symbols.cpp \
  82           src/promotiondlg.cpp \
  83           src/chessgame.cpp \
  84           src/timecontrol.cpp \
  85           src/chessplayer.cpp \
  86           src/chessengine.cpp \
  87           src/engineconfiguration.cpp \
  88           src/engineconfigurationmodel.cpp \
  89           src/xboardengine.cpp \
  90           src/uciengine.cpp \
  91           src/newgamedlg.cpp \
  92           src/chessboard/chessboard.cpp \
  93           src/chessboard/chessmove.cpp \
  94           src/chessboard/magicmoves.cpp \
  95           src/chessboard/makemove.cpp \
  96           src/chessboard/movegen.cpp \
  97           src/chessboard/notation.cpp \
  98           src/chessboard/util.cpp \
  99           src/chessboard/zobrist.cpp
 100
 101 FORMS = ui/newgamedlg.ui
 102 UI_HEADERS_DIR = src
 103
 104 RESOURCES = res/chessboard/chessboard.qrc
 105
 106 !macx-xcode {
 107         OBJECTS_DIR = .obj/
 108         MOC_DIR = .moc/
 109         RCC_DIR = .rcc/
 110 }
 111
 112 # API documentation (Doxygen)
 113 doc-api.commands = doxygen docs/api/api.doxygen
 114 QMAKE_EXTRA_TARGETS += doc-api
 115
 116 # man documentation
 117 unix:doc-man.commands = a2x -f manpage docs/man/sloppygui.6.txt
 118 unix:QMAKE_EXTRA_TARGETS += doc-man
 119