sloppygui.pro

   1 SLOPPYGUI_VERSION = unknown
   2
   3 # Check if the version file exists.
   4 exists(version) {
   5
   6         # If the version file exists, use its contents as the version number
   7         SLOPPYGUI_VERSION = $$system(cat version)
   8 } else {
   9
  10         # If the version file doesn't exist, check if we have
  11         # .git directory
  12         exists(.git) {
  13
  14                 # Check if we can describe this commit
  15                 system(git describe > /dev/null 2> /dev/null) {
  16
  17                         # If we can, describe it
  18                         SLOPPYGUI_VERSION = $$system(git describe)
  19                 } else {
  20
  21                         # If we can't describe it, parse the sha id and use that
  22                         SLOPPYGUI_VERSION = git-$$system(git rev-parse --short HEAD)
  23                 }
  24         }
  25 }
  26
  27 DEFINES += SLOPPYGUI_VERSION='\'"$$SLOPPYGUI_VERSION"\''
  28
  29 CONFIG += qt debug
  30 QT += svg
  31
  32 win32:debug {
  33         CONFIG += console
  34 }
  35
  36 HEADERS = src/graphicschessboardsquareitem.h \
  37           src/graphicschessboarditem.h \
  38           src/graphicschesspiece.h \
  39           src/chessboardview.h \
  40           src/manager.h \
  41           src/logmanager.h \
  42           src/newgamedlg.h \
  43           src/stdoutlogger.h \
  44           src/guilogger.h \
  45           src/loggerbase.h \
  46           src/mainwindow.h \
  47           src/symbols.h \
  48           src/promotiondlg.h \
  49           src/chessgame.h \
  50           src/timecontrol.h \
  51           src/chessplayer.h \
  52           src/chessengine.h \
  53           src/engineconfiguration.h \
  54           src/engineconfigurationmodel.h \
  55           src/xboardengine.h \
  56           src/uciengine.h \
  57           src/chessboard/chessboard.h \
  58           src/chessboard/chessmove.h \
  59           src/chessboard/magicmoves.h \
  60           src/chessboard/movegen.h \
  61           src/chessboard/notation.h \
  62           src/chessboard/util.h \
  63           src/chessboard/zobrist.h
  64
  65 SOURCES = src/graphicschessboardsquareitem.cpp \
  66           src/graphicschessboarditem.cpp \
  67           src/graphicschesspiece.cpp \
  68           src/chessboardview.cpp \
  69           src/manager.cpp \
  70           src/logmanager.cpp \
  71           src/stdoutlogger.cpp \
  72           src/guilogger.cpp \
  73           src/mainwindow.cpp \
  74           src/symbols.cpp \
  75           src/promotiondlg.cpp \
  76           src/main.cpp \
  77           src/chessgame.cpp \
  78           src/timecontrol.cpp \
  79           src/chessplayer.cpp \
  80           src/chessengine.cpp \
  81           src/engineconfiguration.cpp \
  82           src/engineconfigurationmodel.cpp \
  83           src/xboardengine.cpp \
  84           src/uciengine.cpp \
  85           src/newgamedlg.cpp \
  86           src/chessboard/chessboard.cpp \
  87           src/chessboard/chessmove.cpp \
  88           src/chessboard/magicmoves.cpp \
  89           src/chessboard/makemove.cpp \
  90           src/chessboard/movegen.cpp \
  91           src/chessboard/notation.cpp \
  92           src/chessboard/util.cpp \
  93           src/chessboard/zobrist.cpp
  94
  95 FORMS = ui/newgamedlg.ui
  96 UI_HEADERS_DIR = src
  97
  98 RESOURCES = res/chessboard/chessboard.qrc
  99
 100 OBJECTS_DIR = .obj/
 101 MOC_DIR = .moc/
 102 RCC_DIR = .rcc/
 103
 104 # API documentation (Doxygen)
 105 doc-api.commands = doxygen docs/api/api.doxygen
 106 QMAKE_EXTRA_TARGETS += doc-api
 107
 108 # man documentation
 109 unix:doc-man.commands = a2x -f manpage docs/man/sloppygui.6.txt
 110 unix:QMAKE_EXTRA_TARGETS += doc-man
 111