sloppygui.pro

   1 SLOPPYGUI_VERSION = unknown
   2
   3 # Check if the version file exists.
   4 exists(version) {
   5
   6         # If the version file exists, use its contents as the version number
   7         SLOPPYGUI_VERSION = $$system(cat version)
   8 } else {
   9
  10         # If the version file doesn't exist, check if we have
  11         # .git directory
  12         exists(.git) {
  13
  14                 # Check if we can describe this commit
  15                 system(git describe > /dev/null 2> /dev/null) {
  16
  17                         # If we can, describe it
  18                         SLOPPYGUI_VERSION = $$system(git describe)
  19                 } else {
  20
  21                         # If we can't describe it, parse the sha id and use that
  22                         SLOPPYGUI_VERSION = git-$$system(git rev-parse --short HEAD)
  23                 }
  24         }
  25 }
  26
  27 DEFINES += SLOPPYGUI_VERSION='\'"$$SLOPPYGUI_VERSION"\''
  28
  29 CONFIG += qt debug
  30 QT += svg
  31
  32 win32:debug {
  33         CONFIG += console
  34 }
  35
  36 HEADERS = src/graphicschessboardsquareitem.h \
  37           src/graphicschessboarditem.h \
  38           src/graphicschesspiece.h \
  39           src/chessboardview.h \
  40           src/manager.h \
  41           src/logmanager.h \
  42           src/stdoutlogger.h \
  43           src/guilogger.h \
  44           src/loggerbase.h \
  45           src/mainwindow.h \
  46           src/symbols.h \
  47           src/promotiondlg.h \
  48           src/chessgame.h \
  49           src/timecontrol.h \
  50           src/chessplayer.h \
  51           src/chessengine.h \
  52           src/xboardengine.h \
  53           src/uciengine.h \
  54           src/chessboard/chessboard.h \
  55           src/chessboard/chessmove.h \
  56           src/chessboard/magicmoves.h \
  57           src/chessboard/movegen.h \
  58           src/chessboard/notation.h \
  59           src/chessboard/util.h \
  60           src/chessboard/zobrist.h
  61
  62 SOURCES = src/graphicschessboardsquareitem.cpp \
  63           src/graphicschessboarditem.cpp \
  64           src/graphicschesspiece.cpp \
  65           src/chessboardview.cpp \
  66           src/manager.cpp \
  67           src/logmanager.cpp \
  68           src/stdoutlogger.cpp \
  69           src/guilogger.cpp \
  70           src/mainwindow.cpp \
  71           src/symbols.cpp \
  72           src/promotiondlg.cpp \
  73           src/main.cpp \
  74           src/chessgame.cpp \
  75           src/timecontrol.cpp \
  76           src/chessplayer.cpp \
  77           src/chessengine.cpp \
  78           src/xboardengine.cpp \
  79           src/uciengine.cpp \
  80           src/chessboard/chessboard.cpp \
  81           src/chessboard/chessmove.cpp \
  82           src/chessboard/magicmoves.cpp \
  83           src/chessboard/makemove.cpp \
  84           src/chessboard/movegen.cpp \
  85           src/chessboard/notation.cpp \
  86           src/chessboard/util.cpp \
  87           src/chessboard/zobrist.cpp
  88
  89 RESOURCES = res/chessboard/chessboard.qrc
  90
  91 OBJECTS_DIR = .obj/
  92 MOC_DIR = .moc/
  93 RCC_DIR = .rcc/
  94
  95 # API documentation (Doxygen)
  96 doc-api.commands = doxygen docs/api/api.doxygen
  97 QMAKE_EXTRA_TARGETS += doc-api
  98
  99 # man documentation
 100 unix:doc-man.commands = a2x -f manpage docs/man/sloppygui.6.txt
 101 unix:QMAKE_EXTRA_TARGETS += doc-man
 102