configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use `VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9           m4_substr(SIPE_VERSION_DATA,
  10                     [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/tracker/?atid=949931&group_id=194563], [],
  18         SIPE_HOMEPAGE)
  19
  20 AC_DEFINE([SIPE_TRANSLATIONS_URL],
  21         ["https://www.transifex.net/projects/p/pidgin-sipe/r/mob/"],
  22         [URL for submitting translations.])
  23
  24 dnl setup automake and require recent enough version
  25 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-define tar-ustar])
  26
  27 AC_CANONICAL_HOST
  28
  29 dnl set PACKAGE_URL for autoconf < 2.64
  30 AS_IF([test "x${PACKAGE_URL}" = x],
  31         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  32          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  33 ])
  34
  35 dnl set programming language
  36 AC_LANG(C)
  37 AM_PROG_CC_C_O
  38 AC_HEADER_STDC
  39
  40 dnl setup shared library generation
  41 LT_INIT([disable-static])
  42
  43 dnl checks for tools
  44 IT_PROG_INTLTOOL([0.35.0])
  45 AC_PROG_INSTALL
  46 AC_PROG_RANLIB
  47
  48 dnl ******************************
  49 dnl Win32
  50 dnl ******************************
  51 AC_MSG_CHECKING([for Win32])
  52 AS_CASE(["$host"],
  53                 [*-mingw*], [os_win32=yes],
  54                 [os_win32=no])
  55 AC_MSG_RESULT([$os_win32])
  56 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  57
  58 dnl checks for header files
  59 AC_CHECK_HEADERS([sys/sockio.h])
  60
  61 dnl checks for library functions
  62 AC_CHECK_FUNCS([])
  63
  64 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  65 dnl as that is likely where libpurple will be found if it is not in the default
  66 dnl pkgconfig path
  67 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  68 export PKG_CONFIG_PATH
  69
  70 dnl debug mode
  71 AC_ARG_ENABLE(debug,
  72         [AS_HELP_STRING([--enable-debug],
  73                         [compile with debugging support [default=no]])],
  74         [],
  75         [enable_debug=no])
  76
  77 AS_IF([test "x$enable_debug" = xyes],
  78         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  79 AC_SUBST(DEBUG_CFLAGS)
  80
  81 dnl quality check mode
  82 dnl For people who are interested in finding bugs and not hiding them
  83 AC_ARG_ENABLE(quality-check,
  84         [AS_HELP_STRING([--enable-quality-check],
  85                         [compile with compiler checks enabled [default=yes]])],
  86         [],
  87         [enable_quality_check=yes])
  88
  89 AS_IF([test "x$enable_quality_check" = xyes],
  90         [dnl default quality configuration
  91          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  92
  93          dnl enable warnings supported by the GCC on the build system
  94          for newflag in \
  95                         "-Wextra" \
  96                         "-Waggregate-return" \
  97                         "-Wcast-align" \
  98                         "-Wdeclaration-after-statement" \
  99                         "-Winit-self" \
 100                         "-Wmissing-declarations" \
 101                         "-Wmissing-prototypes" \
 102                         "-Wnested-externs" \
 103                         "-Wpointer-arith" \
 104                         "-Wundef" \
 105                         "-Wunused-but-set-variable" \
 106          ; do
 107                  ac_save_CFLAGS=$CFLAGS
 108                  AC_MSG_CHECKING([if $CC supports $newflag])
 109                  CFLAGS="$QUALITY_CFLAGS $newflag"
 110                  AC_COMPILE_IFELSE(
 111                         [AC_LANG_SOURCE([[]])],
 112                         [AC_MSG_RESULT(yes)
 113                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 114                         [AC_MSG_RESULT(no)]
 115                  )
 116                  CFLAGS=$ac_save_CFLAGS
 117          done
 118         ])
 119 AC_SUBST(QUALITY_CFLAGS)
 120
 121 dnl Check for pkg-config before using it
 122 PKG_PROG_PKG_CONFIG
 123
 124 dnl build option: with voice & video support (for all backends)
 125 AC_ARG_WITH(vv,
 126         [AC_HELP_STRING([--with-vv],
 127                 [compile with voice and video support @<:@default=check@:>@])],
 128         [AS_IF([test "x$withval" = xyes], [with_vv=check])],
 129         [with_vv=check])
 130
 131 dnl check for Kerberos 5 support
 132 AC_ARG_WITH([krb5],
 133         [AC_HELP_STRING([--with-krb5],
 134                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 135         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 136         [with_krb5=check])
 137
 138 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 139       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 140         [AC_MSG_CHECKING(if Kerberos 5 is available)
 141          AS_IF([AC_RUN_LOG([krb5-config --version])],
 142                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 143                  KRB5_LDFLAGS=""
 144
 145                  dnl same as AC_CHECK_LIB()
 146                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"
 147                  AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5)])],
 148                 [AC_MSG_RESULT(no)
 149                  with_krb5=no])],
 150       [                               dnl path specified by user
 151         KRB5_CFLAGS="-I${with_krb5}/include"
 152         KRB5_LDFLAGS="-L${with_krb5}/lib"
 153         ac_save_LDFLAGS="$LDLAGS"
 154         LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 155         AC_CHECK_LIB(krb5, krb5_rd_req,          [],
 156                 [AC_CHECK_LIB(krb5, krb5_rd_req, [],
 157                         [AC_ERROR(Kerberos 5 libraries not found)])])
 158         AC_CHECK_LIB(gssapi_krb5, gss_krb5_export_lucid_sec_context, [],
 159                         [AC_ERROR(GSSAPI Kerberos 5 libraries not found)])
 160         LDFLAGS="$ac_save_LDFLAGS"])
 161 AM_CONDITIONAL(SIP_SEC_KRB5, [test "x$with_krb5" != xno])
 162 AC_SUBST(KRB5_CFLAGS)
 163 AC_SUBST(KRB5_LDFLAGS)
 164
 165 dnl check for glib
 166 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.12.0])
 167 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.12.0])
 168
 169 dnl check for gmime
 170 dnl See also: https://bugzilla.gnome.org/show_bug.cgi?id=613653#c8
 171 PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.5.2],
 172         [ac_have_gmime=yes],
 173         [PKG_CHECK_MODULES(GMIME, [gmime-2.4 >= 2.4.16],
 174                 [ac_have_gmime=yes],
 175                 [ac_have_gmime=no])
 176 ])
 177 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 178 AS_IF([test "x$ac_have_gmime" = xyes],
 179         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 180
 181 dnl check for NSS
 182 PKG_CHECK_MODULES(NSS, [nss],
 183         [ac_have_nss=yes],
 184         [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 185                 [ac_have_nss=yes],
 186                 [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 187                         [ac_have_nss=yes],
 188                         [ac_have_nss=no])
 189         ])
 190 ])
 191 AM_CONDITIONAL(SIPE_CRYPTO_NSS, [test "x$ac_have_nss" = xyes])
 192 AS_IF([test "x$ac_have_nss" = xyes],
 193         [AC_DEFINE(HAVE_NSS, 1, [Define if nss should be used in sipe.])])
 194
 195 dnl check for libxml2
 196 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 197
 198 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 199 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 200 ac_save_CFLAGS=$CFLAGS
 201 CFLAGS="$GLIB_CFLAGS $QUALITY_CFLAGS"
 202 dnl note the [[[ quoting: our code contains []!
 203 AC_RUN_IFELSE(
 204         [AC_LANG_PROGRAM(
 205                 [[
 206 #include <glib.h>
 207 #include <stdio.h>
 208
 209 /* Copied from uuid.c */
 210 typedef struct {
 211    guint32 time_low;
 212    guint16 time_mid;
 213    guint16 time_hi_and_version;
 214    guint8  clock_seq_hi_and_reserved;
 215    guint8  clock_seq_low;
 216    guint8  node[6];
 217 } uuid_t;
 218                 ]],
 219                 [[if (sizeof(uuid_t) == 16) {
 220                         return(0);
 221                  } else {
 222                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 223                         return(1);
 224                  }]])],
 225         [AC_MSG_RESULT(yes)],
 226         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 227
 228 Please notify the SIPE developers.
 229
 230 Copy & paste all lines starting with the line
 231
 232   checking that sizeof(uuid_t) is 16...
 233
 234 to the report and attach the file "config.log".
 235
 236 Compiler information:
 237
 238  host:     $host
 239  build:    $build
 240  compiler: $CC
 241 ])],
 242         [AC_MSG_WARN([cross compiling: not checking])])
 243 CFLAGS=$ac_save_CFLAGS
 244
 245 dnl build option: OCS2005 client hack
 246 AC_ARG_ENABLE([ocs2005-message-hack],
 247         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
 248                                                           which causes "false" not delivered error messages
 249                                                           @<:@default=no@:>@])],
 250         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
 251                    [Define to 1 to disable SIP MESSAGE timeout feature.
 252                     OCS2005 clients don't seem to acknowledge MESSAGEs and
 253                     disabling the timeout suppresses "false" error messages])])
 254
 255 dnl build option: purple backend
 256 AC_ARG_ENABLE([purple],
 257         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 258         [],
 259         [enable_purple=yes])
 260 with_purple_vv=no
 261 AS_IF([test "x$enable_purple" != xno],
 262         [PKG_CHECK_MODULES(PURPLE, [purple >= 2.4.0],
 263                 [dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 264                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion purple | cut -d. -f 1`
 265                  AC_SUBST(PURPLE_MAJOR_VERSION)
 266
 267                  dnl let user now if he has a 32- and 64-bit header conflict...
 268                  AC_MSG_CHECKING([for 32- and 64-bit header conflicts])
 269                  ac_save_CFLAGS=$CFLAGS
 270                  CFLAGS="$PURPLE_CFLAGS $QUALITY_CFLAGS"
 271                  AC_COMPILE_IFELSE(
 272                         [AC_LANG_PROGRAM([[
 273 #include <glib.h>
 274 #include <cipher.h>
 275
 276 /* Compile some code that has caused trouble in the past */
 277 static void testfunc(unsigned long len)
 278 {
 279   PurpleCipherContext *rc4 = NULL;
 280   guchar *plaintext = NULL;
 281   gsize plaintext_length = 0;
 282   guchar *encrypted_text = NULL;
 283   gsize dummy;
 284   purple_cipher_context_set_option(rc4, "key_len", GUINT_TO_POINTER(len));
 285   purple_cipher_context_encrypt(rc4, plaintext, plaintext_length,
 286                                 encrypted_text, &dummy);
 287 }
 288                                         ]],
 289                                         [[testfunc(16);]])],
 290                         [AC_MSG_RESULT(none)],
 291                         [AC_MSG_FAILURE([conflicts found.
 292
 293 Check that you have the correct glib/libpurple headers installed for
 294 your architecture or set GLIB_CFLAGS/PURPLE_CFLAGS to override the
 295 system defaults.
 296 ])
 297                         ])
 298
 299                  dnl on windows
 300                  dnl test program needs to be in the same location as libpurple
 301                  dnl installation for latter to load ssl plugin referenced by
 302                  dnl RELATIVE path.
 303                  AS_IF([test "x${os_win32}" != xyes],
 304                         [dnl purple SSL support is mandatory
 305                          AC_MSG_CHECKING([for purple SSL support])
 306                          ac_save_LIBS=$LIBS
 307                          LIBS="$PURPLE_LIBS"
 308                          AC_RUN_IFELSE(
 309                                 [AC_LANG_PROGRAM([[
 310 #include <glib.h>
 311 #include <plugin.h>
 312 #include <sslconn.h>
 313                                                 ]],
 314                                                 [[
 315         purple_plugins_init();
 316         purple_plugins_probe(G_MODULE_SUFFIX);
 317         purple_ssl_init();
 318         return(purple_ssl_is_supported()?0:1);
 319                                                 ]])],
 320                                 [AC_MSG_RESULT(ok)],
 321                                 [AC_MSG_FAILURE([your purple hasn't been compiled with SSL support.
 322 ])
 323                                 ],
 324                                 [AC_MSG_WARN([cross compiling: not checking])])
 325                  ])
 326
 327                  dnl check whether enable voice and video support
 328                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 329                        [test "x$with_vv" = xcheck],  dnl autodetect
 330                          [AC_MSG_CHECKING(for purple voice and video support)
 331                           AC_RUN_IFELSE(
 332                                 [AC_LANG_PROGRAM([[
 333 #include <media.h>
 334                                         ]],
 335                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]]
 336                                 )],
 337                                 [AC_MSG_RESULT(ok)
 338                                  PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
 339                                         dnl sipe-media.c uses g_slist_free_full()
 340                                         [PKG_CHECK_MODULES(_SIPE_MEDIA_RECHECK_PLEASE_IGNORE, [purple >= 2.8.0 glib-2.0 >= 2.28.0],
 341                                                 [PKG_CHECK_MODULES(GSTREAMER, [gstreamer-0.10],
 342                                                         [with_purple_vv=yes],
 343                                                         [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 344                                                 [AC_MSG_NOTICE(libpurple >= 2.8.0 glib2 >= 2.28.0 required: disabling purple voice and video support)])],
 345                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])],
 346                                 [AC_MSG_RESULT(no - your purple hasn't been compiled with voice and video support.)],
 347                                 [AC_MSG_WARN([cross compiling: not checking])])
 348                          ])
 349
 350                  dnl check if we have TCP media transport patches in libpurple
 351                  AS_IF([test "x$with_purple_vv" != xno],
 352                         [
 353                          AC_MSG_CHECKING(for TCP media transport)
 354                          AC_COMPILE_IFELSE(
 355                                 [AC_LANG_PROGRAM([[#include <media.h>]],[[return PURPLE_MEDIA_NETWORK_PROTOCOL_TCP_ACTIVE]])],
 356                                 [
 357                                  with_purple_tcp=yes
 358                                  AC_DEFINE(HAVE_ICE_TCP, 1, [Define if we have support for TCP media transport.])
 359                                  AC_MSG_RESULT(yes)
 360                                 ],
 361                                 [AC_MSG_RESULT(no)]
 362                          )
 363                         ])
 364
 365                  CFLAGS=$ac_save_CFLAGS
 366                  LIBS=$ac_save_LIBS],
 367                 [enable_purple=no])])
 368 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 369
 370 dnl build option: telepathy backend
 371 AC_ARG_ENABLE([telepathy],
 372         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 373         [],
 374         [enable_telepathy=yes])
 375 AS_IF([test "x$enable_telepathy" != xno],
 376         [PKG_CHECK_MODULES(TELEPATHY, [telepathy-glib],
 377                 [dnl GMIME is a build requirement
 378                  AS_IF([test "x$ac_have_gmime" = xyes],
 379                         [],
 380                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 381
 382                  dnl NSS is a build requirement
 383                  AS_IF([test "x$ac_have_nss" = xyes],
 384                         [],
 385                         [AC_ERROR(NSS package is required for telepathy plugin)])
 386
 387                  dnl NOTHING IMPLEMENTED YET!!!
 388                 ],
 389                 [enable_telepathy=no])])
 390 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 391
 392 dnl build option: kopete backend
 393 AC_ARG_ENABLE([kopete],
 394         [AC_HELP_STRING([--enable-kopete], [build kopete plugin @<:@default=no@:>@])],
 395         [],
 396         [enable_kopete=no])
 397 AS_IF([test "x$enable_kopete" != xno],
 398         [dnl GMIME is a build requirement
 399          AS_IF([test "x$ac_have_gmime" = xyes],
 400                 [],
 401                 [AC_ERROR(GMIME package is required for kopete plugin)])
 402
 403          dnl NSS is a build requirement
 404          AS_IF([test "x$ac_have_nss" = xyes],
 405                 [],
 406                 [AC_ERROR(NSS package is required for kopete plugin)])
 407
 408          dnl NOTHING IMPLEMENTED YET!!!
 409         ],
 410         [enable_kopete=no])
 411 AM_CONDITIONAL(SIPE_INCLUDE_KOPETE, [test "x$enable_kopete" != xno])
 412
 413 dnl sanity check
 414 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno -a "x$enable_kopete" = xno],
 415         [AC_ERROR(at least one plugin must be selected
 416
 417 If you didn't use a --enable option then please check that you have
 418 the headers for the packages "purple" or "telepathy-glib" installed.
 419 )],
 420         [])
 421
 422 dnl enable voice & video support if any backend supports it
 423 AS_IF([test "x$with_purple_vv" != xno],
 424         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 425 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 426
 427 dnl i18n
 428 AC_MSG_CHECKING([locale_CPPFLAGS])
 429 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 430 AC_SUBST([LOCALE_CPPFLAGS])
 431 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 432 AM_GLIB_GNU_GETTEXT
 433 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 434
 435 dnl codeset
 436 AM_LANGINFO_CODESET
 437
 438 dnl substitutions and generated files
 439 AC_CONFIG_HEADERS([config.h])
 440 AC_CONFIG_FILES([
 441         Makefile
 442         pixmaps/Makefile
 443         m4macros/Makefile
 444         po/Makefile.in
 445         pixmaps/16/Makefile
 446         pixmaps/22/Makefile
 447         pixmaps/48/Makefile
 448         pixmaps/scalable/Makefile
 449         src/Makefile
 450         src/core/Makefile
 451         src/api/Makefile
 452         src/purple/Makefile
 453         src/telepathy/Makefile
 454         src/kopete/Makefile
 455         ])
 456
 457 dnl generate files
 458 AC_OUTPUT()
 459
 460 dnl additional info for the user
 461 AS_ECHO()
 462 AS_IF([test "x$enable_purple" = xno],
 463         [AS_ECHO("Not building purple plugin")],
 464         [AS_ECHO("Build purple plugin")
 465          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 466          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 467          AS_ECHO_N("Voice and video: ")
 468          AS_IF([test "x$with_purple_vv" = xno],
 469           [AS_ECHO("disabled")],
 470           [
 471            AS_ECHO_N("enabled")
 472            AS_IF([test "x$with_purple_tcp" = xyes], [AS_ECHO_N(" with TCP transport")])
 473            AS_ECHO()
 474           ])
 475         ])
 476 AS_ECHO()
 477 AS_IF([test "x$enable_telepathy" = xno],
 478         [AS_ECHO("Not building telepathy plugin")],
 479         [AS_ECHO("Build telepathy plugin")
 480          AS_ECHO()
 481          AS_ECHO("NOTHING IMPLEMENTED YET!!!")
 482          AS_ECHO()
 483          AS_ECHO("TELEPATHY_CFLAGS: $TELEPATHY_CFLAGS")
 484          AS_ECHO("TELEPATHY_LIBS  : $TELEPATHY_LIBS")])
 485 AS_ECHO()
 486 AS_IF([test "x$enable_kopete" = xno],
 487         [AS_ECHO("Not building kopete plugin")],
 488         [AS_ECHO("Build kopete plugin")
 489          AS_ECHO()
 490          AS_ECHO("NOTHING IMPLEMENTED YET!!!")
 491          AS_ECHO()])
 492 AS_ECHO()
 493 AS_IF([test "x$with_krb5" = xno],
 494         [AS_ECHO("Not building with Kerberos 5 support")],
 495         [AS_ECHO("Build with Kerberos 5 support")
 496          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 497          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 498 AS_ECHO()
 499 AS_IF([test "x$enable_debug" = xno],
 500         [AS_ECHO("Debugging not enabled")],
 501         [AS_ECHO("Build with debugging enabled")
 502          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 503 AS_ECHO()
 504 AS_IF([test "x$QUALITY_CFLAGS" = x],
 505         [AS_ECHO("Compiler checks disabled")],
 506         [AS_ECHO("Build with compiler checks enabled")
 507          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 508 AS_ECHO()
 509 AS_ECHO("configure complete. Now run 'make'")
 510 AS_ECHO()
 511
 512 dnl The End.