configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use `VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9           m4_substr(SIPE_VERSION_DATA,
  10                     [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/tracker/?atid=949931&group_id=194563], [],
  18         SIPE_HOMEPAGE)
  19
  20 AC_DEFINE([SIPE_TRANSLATIONS_URL],
  21         ["https://www.transifex.net/projects/p/pidgin-sipe/r/mob/"],
  22         [URL for submitting translations.])
  23
  24 dnl setup automake and require recent enough version
  25 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-define tar-ustar])
  26
  27 AC_CANONICAL_HOST
  28
  29 dnl set PACKAGE_URL for autoconf < 2.64
  30 AS_IF([test "x${PACKAGE_URL}" = x],
  31         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  32          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  33 ])
  34
  35 dnl set programming language
  36 AC_LANG(C)
  37 AM_PROG_CC_C_O
  38 AC_HEADER_STDC
  39
  40 dnl setup shared library generation
  41 LT_INIT([disable-static])
  42
  43 dnl checks for tools
  44 IT_PROG_INTLTOOL([0.35.0])
  45 AC_PROG_INSTALL
  46 AC_PROG_RANLIB
  47
  48 dnl ******************************
  49 dnl Win32
  50 dnl ******************************
  51 AC_MSG_CHECKING([for Win32])
  52 AS_CASE(["$host"],
  53                 [*-mingw*], [os_win32=yes],
  54                 [os_win32=no])
  55 AC_MSG_RESULT([$os_win32])
  56 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  57
  58 dnl checks for header files
  59 AC_CHECK_HEADERS([sys/sockio.h])
  60
  61 dnl checks for library functions
  62 AC_CHECK_FUNCS([])
  63
  64 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  65 dnl as that is likely where libpurple will be found if it is not in the default
  66 dnl pkgconfig path
  67 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  68 export PKG_CONFIG_PATH
  69
  70 dnl debug mode
  71 AC_ARG_ENABLE(debug,
  72         [AS_HELP_STRING([--enable-debug],
  73                         [compile with debugging support [default=no]])],
  74         [],
  75         [enable_debug=no])
  76
  77 AS_IF([test "x$enable_debug" = xyes],
  78         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  79 AC_SUBST(DEBUG_CFLAGS)
  80
  81 dnl quality check mode
  82 dnl For people who are interested in finding bugs and not hiding them
  83 AC_ARG_ENABLE(quality-check,
  84         [AS_HELP_STRING([--enable-quality-check],
  85                         [compile with compiler checks enabled [default=yes]])],
  86         [],
  87         [enable_quality_check=yes])
  88
  89 AS_IF([test "x$enable_quality_check" = xyes],
  90         [dnl default quality configuration
  91          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  92
  93          dnl enable warnings supported by the GCC on the build system
  94          for newflag in \
  95                         "-Wextra" \
  96                         "-Waggregate-return" \
  97                         "-Wcast-align" \
  98                         "-Wdeclaration-after-statement" \
  99                         "-Winit-self" \
 100                         "-Wmissing-declarations" \
 101                         "-Wmissing-prototypes" \
 102                         "-Wnested-externs" \
 103                         "-Wpointer-arith" \
 104                         "-Wundef" \
 105                         "-Wunused-but-set-variable" \
 106          ; do
 107                  ac_save_CFLAGS=$CFLAGS
 108                  AC_MSG_CHECKING([if $CC supports $newflag])
 109                  CFLAGS="$QUALITY_CFLAGS $newflag"
 110                  AC_COMPILE_IFELSE(
 111                         [AC_LANG_SOURCE([[]])],
 112                         [AC_MSG_RESULT(yes)
 113                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 114                         [AC_MSG_RESULT(no)]
 115                  )
 116                  CFLAGS=$ac_save_CFLAGS
 117          done
 118         ])
 119 AC_SUBST(QUALITY_CFLAGS)
 120
 121 dnl Check for pkg-config before using it
 122 PKG_PROG_PKG_CONFIG
 123
 124 dnl build option: with voice & video support (for all backends)
 125 AC_ARG_WITH(vv,
 126         [AC_HELP_STRING([--with-vv],
 127                 [compile with voice and video support @<:@default=check@:>@])],
 128         [AS_IF([test "x$withval" = xyes], [with_vv=check])],
 129         [with_vv=check])
 130
 131 dnl check for Kerberos 5 support
 132 AC_ARG_WITH([krb5],
 133         [AC_HELP_STRING([--with-krb5],
 134                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 135         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 136         [with_krb5=check])
 137
 138 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 139       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 140         [AC_MSG_CHECKING(if Kerberos 5 is available)
 141          AS_IF([AC_RUN_LOG([krb5-config --version])],
 142                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 143                  KRB5_LDFLAGS=""
 144
 145                  dnl same as AC_CHECK_LIB()
 146                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"
 147                  AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5)])],
 148                 [AC_MSG_RESULT(no)
 149                  with_krb5=no])],
 150       [                               dnl path specified by user
 151         KRB5_CFLAGS="-I${with_krb5}/include"
 152         KRB5_LDFLAGS="-L${with_krb5}/lib"
 153         ac_save_LDFLAGS="$LDLAGS"
 154         LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 155         AC_CHECK_LIB(krb5, krb5_rd_req,          [],
 156                 [AC_CHECK_LIB(krb5, krb5_rd_req, [],
 157                         [AC_ERROR(Kerberos 5 libraries not found)])])
 158         AC_CHECK_LIB(gssapi_krb5, gss_krb5_export_lucid_sec_context, [],
 159                         [AC_ERROR(GSSAPI Kerberos 5 libraries not found)])
 160         LDFLAGS="$ac_save_LDFLAGS"])
 161 AM_CONDITIONAL(SIP_SEC_KRB5, [test "x$with_krb5" != xno])
 162 AC_SUBST(KRB5_CFLAGS)
 163 AC_SUBST(KRB5_LDFLAGS)
 164
 165 dnl check for glib
 166 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.12.0])
 167 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.12.0])
 168
 169 dnl check for gmime
 170 dnl See also: https://bugzilla.gnome.org/show_bug.cgi?id=613653#c8
 171 PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.5.2],
 172         [ac_have_gmime=yes],
 173         [PKG_CHECK_MODULES(GMIME, [gmime-2.4 >= 2.4.16],
 174                 [ac_have_gmime=yes],
 175                 [ac_have_gmime=no])
 176 ])
 177 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 178 AS_IF([test "x$ac_have_gmime" = xyes],
 179         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 180
 181 dnl check for NSS
 182 PKG_CHECK_MODULES(NSS, [nss],
 183         [],
 184         [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 185                 [],
 186                 [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 187                         [],
 188                         [AC_ERROR([nss, mozilla-nss or microb-engine-nss package is required])])
 189         ])
 190 ])
 191
 192 dnl check for libxml2
 193 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 194
 195 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 196 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 197 ac_save_CFLAGS=$CFLAGS
 198 CFLAGS="$GLIB_CFLAGS $QUALITY_CFLAGS"
 199 dnl note the [[[ quoting: our code contains []!
 200 AC_RUN_IFELSE(
 201         [AC_LANG_PROGRAM(
 202                 [[
 203 #include <glib.h>
 204 #include <stdio.h>
 205
 206 /* Copied from uuid.c */
 207 typedef struct {
 208    guint32 time_low;
 209    guint16 time_mid;
 210    guint16 time_hi_and_version;
 211    guint8  clock_seq_hi_and_reserved;
 212    guint8  clock_seq_low;
 213    guint8  node[6];
 214 } uuid_t;
 215                 ]],
 216                 [[if (sizeof(uuid_t) == 16) {
 217                         return(0);
 218                  } else {
 219                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 220                         return(1);
 221                  }]])],
 222         [AC_MSG_RESULT(yes)],
 223         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 224
 225 Please notify the SIPE developers.
 226
 227 Copy & paste all lines starting with the line
 228
 229   checking that sizeof(uuid_t) is 16...
 230
 231 to the report and attach the file "config.log".
 232
 233 Compiler information:
 234
 235  host:     $host
 236  build:    $build
 237  compiler: $CC
 238 ])],
 239         [AC_MSG_WARN([cross compiling: not checking])])
 240 CFLAGS=$ac_save_CFLAGS
 241
 242 dnl build option: OCS2005 client hack
 243 AC_ARG_ENABLE([ocs2005-message-hack],
 244         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
 245                                                           which causes "false" not delivered error messages
 246                                                           @<:@default=no@:>@])],
 247         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
 248                    [Define to 1 to disable SIP MESSAGE timeout feature.
 249                     OCS2005 clients don't seem to acknowledge MESSAGEs and
 250                     disabling the timeout suppresses "false" error messages])])
 251
 252 dnl build option: purple backend
 253 AC_ARG_ENABLE([purple],
 254         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 255         [],
 256         [enable_purple=yes])
 257 with_purple_vv=no
 258 AS_IF([test "x$enable_purple" != xno],
 259         [PKG_CHECK_MODULES(PURPLE, [purple >= 2.4.0],
 260                 [dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 261                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion purple | cut -d. -f 1`
 262                  AC_SUBST(PURPLE_MAJOR_VERSION)
 263
 264                  dnl let user now if he has a 32- and 64-bit header conflict...
 265                  AC_MSG_CHECKING([for 32- and 64-bit header conflicts])
 266                  ac_save_CFLAGS=$CFLAGS
 267                  CFLAGS="$PURPLE_CFLAGS $QUALITY_CFLAGS"
 268                  AC_COMPILE_IFELSE(
 269                         [AC_LANG_PROGRAM([[
 270 #include <glib.h>
 271 #include <cipher.h>
 272
 273 /* Compile some code that has caused trouble in the past */
 274 static void testfunc(unsigned long len)
 275 {
 276   PurpleCipherContext *rc4 = NULL;
 277   guchar *plaintext = NULL;
 278   gsize plaintext_length = 0;
 279   guchar *encrypted_text = NULL;
 280   gsize dummy;
 281   purple_cipher_context_set_option(rc4, "key_len", GUINT_TO_POINTER(len));
 282   purple_cipher_context_encrypt(rc4, plaintext, plaintext_length,
 283                                 encrypted_text, &dummy);
 284 }
 285                                         ]],
 286                                         [[testfunc(16);]])],
 287                         [AC_MSG_RESULT(none)],
 288                         [AC_MSG_FAILURE([conflicts found.
 289
 290 Check that you have the correct glib/libpurple headers installed for
 291 your architecture or set GLIB_CFLAGS/PURPLE_CFLAGS to override the
 292 system defaults.
 293 ])
 294                         ])
 295
 296                  dnl on windows
 297                  dnl test program needs to be in the same location as libpurple
 298                  dnl installation for latter to load ssl plugin referenced by
 299                  dnl RELATIVE path.
 300                  AS_IF([test "x${os_win32}" != xyes],
 301                         [dnl purple SSL support is mandatory
 302                          AC_MSG_CHECKING([for purple SSL support])
 303                          ac_save_LIBS=$LIBS
 304                          LIBS="$PURPLE_LIBS"
 305                          AC_RUN_IFELSE(
 306                                 [AC_LANG_PROGRAM([[
 307 #include <glib.h>
 308 #include <plugin.h>
 309 #include <sslconn.h>
 310                                                 ]],
 311                                                 [[
 312         purple_plugins_init();
 313         purple_plugins_probe(G_MODULE_SUFFIX);
 314         purple_ssl_init();
 315         return(purple_ssl_is_supported()?0:1);
 316                                                 ]])],
 317                                 [AC_MSG_RESULT(ok)],
 318                                 [AC_MSG_FAILURE([your purple hasn't been compiled with SSL support.
 319 ])
 320                                 ],
 321                                 [AC_MSG_WARN([cross compiling: not checking])])
 322                  ])
 323
 324                  dnl check whether enable voice and video support
 325                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 326                        [test "x$with_vv" = xcheck],  dnl autodetect
 327                          [AC_MSG_CHECKING(for purple voice and video support)
 328                           AC_RUN_IFELSE(
 329                                 [AC_LANG_PROGRAM([[
 330 #include <media.h>
 331                                         ]],
 332                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]]
 333                                 )],
 334                                 [AC_MSG_RESULT(ok)
 335                                  PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
 336                                         dnl sipe-media.c uses g_slist_free_full()
 337                                         [PKG_CHECK_MODULES(_SIPE_MEDIA_RECHECK_PLEASE_IGNORE, [purple >= 2.8.0 glib-2.0 >= 2.28.0],
 338                                                 [PKG_CHECK_MODULES(GSTREAMER, [gstreamer-0.10],
 339                                                         [with_purple_vv=yes],
 340                                                         [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 341                                                 [AC_MSG_NOTICE(libpurple >= 2.8.0 glib2 >= 2.28.0 required: disabling purple voice and video support)])],
 342                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])],
 343                                 [AC_MSG_RESULT(no - your purple hasn't been compiled with voice and video support.)],
 344                                 [AC_MSG_WARN([cross compiling: not checking])])
 345                          ])
 346
 347                  dnl check if we have TCP media transport patches in libpurple
 348                  AS_IF([test "x$with_purple_vv" != xno],
 349                         [
 350                          AC_MSG_CHECKING(for TCP media transport)
 351                          AC_COMPILE_IFELSE(
 352                                 [AC_LANG_PROGRAM([[#include <media.h>]],[[return PURPLE_MEDIA_NETWORK_PROTOCOL_TCP_ACTIVE]])],
 353                                 [
 354                                  with_purple_tcp=yes
 355                                  AC_DEFINE(HAVE_ICE_TCP, 1, [Define if we have support for TCP media transport.])
 356                                  AC_MSG_RESULT(yes)
 357                                 ],
 358                                 [AC_MSG_RESULT(no)]
 359                          )
 360                         ])
 361
 362                  CFLAGS=$ac_save_CFLAGS
 363                  LIBS=$ac_save_LIBS],
 364                 [enable_purple=no])])
 365 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 366
 367 dnl build option: telepathy backend
 368 AC_ARG_ENABLE([telepathy],
 369         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 370         [],
 371         [enable_telepathy=yes])
 372 AS_IF([test "x$enable_telepathy" != xno],
 373         [PKG_CHECK_MODULES(TELEPATHY, [telepathy-glib],
 374                 [dnl GMIME is a build requirement
 375                  AS_IF([test "x$ac_have_gmime" = xyes],
 376                         [],
 377                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 378
 379                  dnl NOTHING IMPLEMENTED YET!!!
 380                 ],
 381                 [enable_telepathy=no])])
 382 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 383
 384 dnl sanity check
 385 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
 386         [AC_ERROR(at least one plugin must be selected
 387
 388 If you didn't use a --enable option then please check that you have
 389 the headers for the packages "purple" or "telepathy-glib" installed.
 390 )],
 391         [])
 392
 393 dnl enable voice & video support if any backend supports it
 394 AS_IF([test "x$with_purple_vv" != xno],
 395         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 396 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 397
 398 dnl i18n
 399 AC_MSG_CHECKING([locale_CPPFLAGS])
 400 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 401 AC_SUBST([LOCALE_CPPFLAGS])
 402 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 403 AM_GLIB_GNU_GETTEXT
 404 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 405
 406 dnl codeset
 407 AM_LANGINFO_CODESET
 408
 409 dnl substitutions and generated files
 410 AC_CONFIG_HEADERS([config.h])
 411 AC_CONFIG_FILES([
 412         Makefile
 413         pixmaps/Makefile
 414         m4macros/Makefile
 415         po/Makefile.in
 416         pixmaps/16/Makefile
 417         pixmaps/22/Makefile
 418         pixmaps/48/Makefile
 419         pixmaps/scalable/Makefile
 420         src/Makefile
 421         src/core/Makefile
 422         src/api/Makefile
 423         src/purple/Makefile
 424         src/telepathy/Makefile
 425         ])
 426
 427 dnl generate files
 428 AC_OUTPUT()
 429
 430 dnl additional info for the user
 431 AS_ECHO()
 432 AS_IF([test "x$enable_purple" = xno],
 433         [AS_ECHO("Not building purple plugin")],
 434         [AS_ECHO("Build purple plugin")
 435          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 436          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 437          AS_ECHO_N("Voice and video: ")
 438          AS_IF([test "x$with_purple_vv" = xno],
 439           [AS_ECHO("disabled")],
 440           [
 441            AS_ECHO_N("enabled")
 442            AS_IF([test "x$with_purple_tcp" = xyes], [AS_ECHO_N(" with TCP transport")])
 443            AS_ECHO()
 444           ])
 445         ])
 446 AS_ECHO()
 447 AS_IF([test "x$enable_telepathy" = xno],
 448         [AS_ECHO("Not building telepathy plugin")],
 449         [AS_ECHO("Build telepathy plugin")
 450          AS_ECHO()
 451          AS_ECHO("NOTHING IMPLEMENTED YET!!!")
 452          AS_ECHO()
 453          AS_ECHO("TELEPATHY_CFLAGS: $TELEPATHY_CFLAGS")
 454          AS_ECHO("TELEPATHY_LIBS  : $TELEPATHY_LIBS")])
 455 AS_ECHO()
 456 AS_IF([test "x$with_krb5" = xno],
 457         [AS_ECHO("Not building with Kerberos 5 support")],
 458         [AS_ECHO("Build with Kerberos 5 support")
 459          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 460          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 461 AS_ECHO()
 462 AS_IF([test "x$enable_debug" = xno],
 463         [AS_ECHO("Debugging not enabled")],
 464         [AS_ECHO("Build with debugging enabled")
 465          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 466 AS_ECHO()
 467 AS_IF([test "x$QUALITY_CFLAGS" = x],
 468         [AS_ECHO("Compiler checks disabled")],
 469         [AS_ECHO("Build with compiler checks enabled")
 470          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 471 AS_ECHO()
 472 AS_ECHO("configure complete. Now run 'make'")
 473 AS_ECHO()
 474
 475 dnl The End.