configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use `VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9           m4_substr(SIPE_VERSION_DATA,
  10                     [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/tracker/?atid=949931&group_id=194563], [],
  18         SIPE_HOMEPAGE)
  19
  20 dnl setup automake and require recent enough version
  21 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-define tar-ustar])
  22
  23 dnl set PACKAGE_URL for autoconf < 2.64
  24 AS_IF([test "x${PACKAGE_URL}" = x],
  25         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  26          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  27 ])
  28
  29 dnl set programming language
  30 AC_LANG(C)
  31 AM_PROG_CC_C_O
  32 AC_HEADER_STDC
  33
  34 dnl setup shared library generation
  35 LT_INIT([disable-static])
  36
  37 dnl checks for tools
  38 IT_PROG_INTLTOOL([0.35.0])
  39 AC_PROG_INSTALL
  40 AC_PROG_RANLIB
  41
  42 dnl checks for header files
  43 AC_CHECK_HEADERS([sys/sockio.h])
  44
  45 dnl checks for library functions
  46 AC_CHECK_FUNCS([])
  47
  48 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  49 dnl as that is likely where libpurple will be found if it is not in the default
  50 dnl pkgconfig path
  51 PREFIX=$ac_default_prefix
  52 AS_IF([test "x$prefix" != xNONE],
  53         [PREFIX=$prefix])
  54
  55 PKG_CONFIG_PATH="$PKG_CONFIG_PATH":"$PREFIX/lib/pkgconfig"
  56 export PKG_CONFIG_PATH
  57
  58 dnl debug mode
  59 AC_ARG_ENABLE(debug,
  60         [AS_HELP_STRING([--enable-debug],
  61                         [compile with debugging support [default=no]])],
  62         [],
  63         [enable_debug=no])
  64
  65 AS_IF([test "x$enable_debug" = xyes],
  66         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  67 AC_SUBST(DEBUG_CFLAGS)
  68
  69 dnl quality check mode
  70 dnl For people who are interested in finding bugs and not hiding them
  71 AC_ARG_ENABLE(quality-check,
  72         [AS_HELP_STRING([--enable-quality-check],
  73                         [compile with compiler checks enabled [default=yes]])],
  74         [],
  75         [enable_quality_check=yes])
  76
  77 AS_IF([test "x$enable_quality_check" = xyes],
  78         [QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  79          ac_save_CFLAGS=$CFLAGS
  80
  81          dnl GCC >= 3.4
  82          AC_MSG_CHECKING([if $CC supports -Wextra])
  83          CFLAGS="$QUALITY_CFLAGS -Wextra"
  84          AC_COMPILE_IFELSE(
  85                 AC_LANG_PROGRAM(),
  86                 [AC_MSG_RESULT(yes)
  87                  QUALITY_CFLAGS="$QUALITY_CFLAGS -Wextra"],
  88                 [AC_MSG_RESULT(no)]
  89          )
  90
  91          dnl declaration-after-statement (ISO C90 behaviour, as on Windows & GCC < 3)
  92          AC_MSG_CHECKING([if $CC supports -Werror=declaration-after-statement])
  93          CFLAGS="$QUALITY_CFLAGS -Werror=declaration-after-statement"
  94          AC_COMPILE_IFELSE(
  95                 AC_LANG_PROGRAM(),
  96                 [AC_MSG_RESULT(yes)
  97                  QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror=declaration-after-statement"],
  98                 [AC_MSG_RESULT(no)]
  99          )
 100          CFLAGS=$ac_save_CFLAGS])
 101 AC_SUBST(QUALITY_CFLAGS)
 102
 103 dnl Check for pkg-config before using it
 104 PKG_PROG_PKG_CONFIG
 105
 106 dnl check for Kerberos 5 support
 107 AC_ARG_WITH([krb5],
 108         [AC_HELP_STRING([--with-krb5],
 109                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 110         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 111         [with_krb5=check])
 112
 113 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 114       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 115         [AC_MSG_CHECKING(if Kerberos 5 is available)
 116          AS_IF([AC_RUN_LOG([krb5-config --version])],
 117                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 118                  KRB5_LDFLAGS=""
 119
 120                  dnl same as AC_CHECK_LIB()
 121                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"
 122                  AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5)])],
 123                 [AC_MSG_RESULT(no)
 124                  with_krb5=no])],
 125       [                               dnl path specified by user
 126         KRB5_CFLAGS="-I${with_krb5}/include"
 127         KRB5_LDFLAGS="-L${with_krb5}/lib"
 128         ac_save_LDFLAGS="$LDLAGS"
 129         LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 130         AC_CHECK_LIB(krb5, krb5_rd_req,          [],
 131                 [AC_CHECK_LIB(krb5, krb5_rd_req, [],
 132                         [AC_ERROR(Kerberos 5 libraries not found)])])
 133         AC_CHECK_LIB(gssapi_krb5, gss_krb5_export_lucid_sec_context, [],
 134                         [AC_ERROR(GSSAPI Kerberos 5 libraries not found)])
 135         LDFLAGS="$ac_save_LDFLAGS"])
 136 AM_CONDITIONAL(SIP_SEC_KRB5, [test "x$with_krb5" != xno])
 137 AC_SUBST(KRB5_CFLAGS)
 138 AC_SUBST(KRB5_LDFLAGS)
 139
 140 dnl check for glib
 141 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.12.0])
 142
 143 dnl check for gmime
 144 dnl See also: https://bugzilla.gnome.org/show_bug.cgi?id=613653#c8
 145 PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.5.2],
 146         [ac_have_gmime=yes],
 147         [PKG_CHECK_MODULES(GMIME, [gmime-2.4 >= 2.4.16],
 148                 [ac_have_gmime=yes],
 149                 [ac_have_gmime=no])
 150 ])
 151 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 152 AM_COND_IF(SIPE_MIME_GMIME,
 153         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 154
 155 dnl check for libxml2
 156 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 157
 158 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 159 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 160 ac_save_CFLAGS=$CFLAGS
 161 CFLAGS="$GLIB_CFLAGS $QUALITY_CFLAGS"
 162 dnl note the [[[ quoting: our code contains []!
 163 AC_RUN_IFELSE(
 164         AC_LANG_PROGRAM(
 165                 [[[
 166 #include <glib.h>
 167 #include <stdio.h>
 168
 169 /* Copied from uuid.c */
 170 typedef struct {
 171    guint32 time_low;
 172    guint16 time_mid;
 173    guint16 time_hi_and_version;
 174    guint8  clock_seq_hi_and_reserved;
 175    guint8  clock_seq_low;
 176    guint8  node[6];
 177 } uuid_t;
 178                 ]]],
 179                 [return(sizeof(uuid_t) == 16 ? 0 : 1);]),
 180         [AC_MSG_RESULT(yes)],
 181         [AC_MSG_RESULT(failed)
 182          AC_ERROR(sizeof(uuid_t) is not 16
 183
 184 Please notify the SIPE developers and provide the following information:
 185
 186  host:     $host
 187  build:    $build
 188  compiler: $CC
 189 )])
 190 CFLAGS=$ac_save_CFLAGS
 191
 192 dnl build option: purple backend
 193 AC_ARG_ENABLE([purple],
 194         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 195         [],
 196         [enable_purple=yes])
 197 AS_IF([test "x$enable_purple" != xno],
 198         [PKG_CHECK_MODULES(PURPLE, [purple >= 2.4.0],
 199                 [dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 200                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion purple | cut -d. -f 1`
 201                  AC_SUBST(PURPLE_MAJOR_VERSION)
 202
 203                  dnl let user now if he has a 32- and 64-bit header conflict...
 204                  AC_MSG_CHECKING([for 32- and 64-bit header conflicts])
 205                  ac_save_CFLAGS=$CFLAGS
 206                  CFLAGS="$PURPLE_CFLAGS $QUALITY_CFLAGS"
 207                  AC_COMPILE_IFELSE(
 208                         AC_LANG_PROGRAM([
 209 #include <glib.h>
 210 #include <cipher.h>
 211
 212 /* Compile some code that has caused trouble in the past */
 213 void testfunc(unsigned long len)
 214 {
 215   PurpleCipherContext *rc4 = NULL;
 216   purple_cipher_context_set_option(rc4, "key_len", GUINT_TO_POINTER(len));
 217 }
 218                                         ],
 219                                         [testfunc(16);]),
 220                         [AC_MSG_RESULT(none)],
 221                         [AC_MSG_RESULT(failed)
 222                          AC_ERROR([conflicts found.
 223
 224 Check that you have the correct glib/libpurple headers installed for
 225 your architecture or set PURPLE_CFLAGS to override the system defaults.
 226 ])
 227                         ])
 228                  CFLAGS=$ac_save_CFLAGS],
 229                 [enable_purple=no])])
 230 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 231
 232 dnl build option: telepathy backend
 233 AC_ARG_ENABLE([telepathy],
 234         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 235         [],
 236         [enable_telepathy=yes])
 237 AS_IF([test "x$enable_telepathy" != xno],
 238         [PKG_CHECK_MODULES(TELEPATHY, [telepathy-glib],
 239                 [dnl GMIME is a build requirement
 240                  AM_COND_IF(SIPE_MIME_GMIME,
 241                         [],
 242                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 243
 244                  dnl NOTHING IMPLEMENTED YET!!!
 245                 ],
 246                 [enable_telepathy=no])])
 247 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 248
 249 dnl sanity check
 250 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
 251         [AC_ERROR(at least one plugin must be selected
 252
 253 If you didn't use a --enable option then please check that you have
 254 the headers for the packages "purple" or "telepathy-glib" installed.
 255 )],
 256         [])
 257
 258 dnl i18n
 259 AC_MSG_CHECKING([locale_CPPFLAGS])
 260 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(prefix)/$(DATADIRNAME)/locale\"'
 261 AC_SUBST([LOCALE_CPPFLAGS])
 262 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 263 AM_GLIB_GNU_GETTEXT
 264 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 265
 266 dnl codeset
 267 AM_LANGINFO_CODESET
 268
 269 dnl substitutions and generated files
 270 AC_CONFIG_HEADERS([config.h])
 271 AC_CONFIG_FILES([
 272         Makefile
 273         pixmaps/Makefile
 274         m4macros/Makefile
 275         po/Makefile.in
 276         pixmaps/16/Makefile
 277         pixmaps/22/Makefile
 278         pixmaps/48/Makefile
 279         pixmaps/scalable/Makefile
 280         src/Makefile
 281         src/core/Makefile
 282         src/api/Makefile
 283         src/purple/Makefile
 284         src/telepathy/Makefile
 285         ])
 286
 287 dnl generate files
 288 AC_OUTPUT()
 289
 290 dnl additional info for the user
 291 AS_ECHO()
 292 AS_IF([test "x$enable_purple" = xno],
 293         [AS_ECHO("Not building purple plugin")],
 294         [AS_ECHO("Build purple plugin")
 295          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 296          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")])
 297 AS_ECHO()
 298 AS_IF([test "x$enable_telepathy" = xno],
 299         [AS_ECHO("Not building telepathy plugin")],
 300         [AS_ECHO("Build telepathy plugin")
 301          AS_ECHO()
 302          AS_ECHO("NOTHING IMPLEMENTED YET!!!")
 303          AS_ECHO()
 304          AS_ECHO("TELEPATHY_CFLAGS: $TELEPATHY_CFLAGS")
 305          AS_ECHO("TELEPATHY_LIBS  : $TELEPATHY_LIBS")])
 306 AS_ECHO()
 307 AS_IF([test "x$with_krb5" = xno],
 308         [AS_ECHO("Not building with Kerberos 5 support")],
 309         [AS_ECHO("Build with Kerberos 5 support")
 310          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 311          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 312 AS_ECHO()
 313 AS_IF([test "x$enable_debug" = xno],
 314         [AS_ECHO("Debugging not enabled")],
 315         [AS_ECHO("Build with debugging enabled")
 316          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 317 AS_ECHO()
 318 AS_IF([test "x$QUALITY_CFLAGS" = x],
 319         [AS_ECHO("Compiler checks disabled")],
 320         [AS_ECHO("Build with compiler checks enabled")
 321          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 322 AS_ECHO()
 323 AS_ECHO("configure complete. Now run 'make'")
 324 AS_ECHO()
 325
 326 dnl The End.