configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 AC_CONFIG_MACRO_DIRS([m4])
   5
   6 dnl Use 'VERSION' files to get version.
   7 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   8
   9 dnl Strip off newline characters.
  10 m4_define([SIPE_VERSION],
  11         m4_substr(SIPE_VERSION_DATA,
  12                   [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  13
  14 dnl homepage
  15 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  16
  17 dnl initialize package name, version, bugtracker & homepage
  18 AC_INIT([pidgin-sipe], SIPE_VERSION,
  19         [https://sourceforge.net/p/sipe/bugs/], [],
  20         SIPE_HOMEPAGE)
  21
  22 AC_DEFINE([SIPE_TRANSLATIONS_URL],
  23         ["https://www.transifex.com/stefanb/pidgin-sipe/"],
  24         [URL for submitting translations.])
  25
  26 dnl define optional git commit ID generated by autogen.sh
  27 m4_define([SIPE_GIT_COMMIT], m4_sinclude([GITVERSION]))
  28 AS_IF([test "x"SIPE_GIT_COMMIT != x],
  29         [AC_MSG_NOTICE([set git commit])
  30          AC_DEFINE(PACKAGE_GIT_COMMIT, "SIPE_GIT_COMMIT", [Define to the git commit for this package.])
  31 ])
  32
  33 dnl setup automake and require recent enough version
  34 AM_INIT_AUTOMAKE([1.9 dist-bzip2 dist-xz no-define tar-ustar])
  35
  36 AC_CANONICAL_HOST
  37
  38 dnl set PACKAGE_URL for autoconf < 2.64
  39 AS_IF([test "x${PACKAGE_URL}" = x],
  40         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  41          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  42 ])
  43
  44 dnl set programming language
  45 AC_LANG(C)
  46 AM_PROG_CC_C_O
  47 AM_PROG_LEX
  48 AC_HEADER_STDC
  49
  50 dnl setup shared library generation
  51 LT_INIT([disable-static])
  52
  53 dnl checks for tools
  54 IT_PROG_INTLTOOL([0.35.0])
  55 AC_PROG_INSTALL
  56
  57 dnl ******************************
  58 dnl Win32
  59 dnl ******************************
  60 AC_MSG_CHECKING([for Win32])
  61 AS_CASE(["$host"],
  62                 [*-mingw*], [os_win32=yes],
  63                 [os_win32=no])
  64 AC_MSG_RESULT([$os_win32])
  65 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  66
  67 dnl checks for header files
  68 AC_CHECK_HEADERS([])
  69
  70 dnl checks for library functions
  71 AC_CHECK_FUNCS([])
  72
  73 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  74 dnl as that is likely where libpurple will be found if it is not in the default
  75 dnl pkgconfig path
  76 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  77 export PKG_CONFIG_PATH
  78
  79 dnl debug mode
  80 AC_ARG_ENABLE(debug,
  81         [AS_HELP_STRING([--enable-debug],
  82                         [compile with debugging support @<:@default=no@:>@])],
  83         [],
  84         [enable_debug=no])
  85
  86 AS_IF([test "x$enable_debug" = xyes],
  87         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  88 AC_SUBST(DEBUG_CFLAGS)
  89
  90 dnl quality check mode
  91 dnl For people who are interested in finding bugs and not hiding them
  92 AC_ARG_ENABLE(quality-check,
  93         [AS_HELP_STRING([--enable-quality-check],
  94                         [compile with compiler checks enabled @<:@default=yes@:>@])],
  95         [],
  96         [enable_quality_check=yes])
  97
  98 AS_IF([test "x$enable_quality_check" = xyes],
  99         [dnl default quality configuration
 100          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
 101
 102          dnl enable warnings supported by the GCC on the build system
 103          for newflag in \
 104                         "-Wextra" \
 105                         "-Waggregate-return" \
 106                         "-Wcast-align" \
 107                         "-Wcast-function-type" \
 108                         "-Wdeclaration-after-statement" \
 109                         "-Wdeprecated-declarations" \
 110                         "-Wduplicate-decl-specifier" \
 111                         "-Winit-self" \
 112                         "-Wmaybe-uninitialized" \
 113                         "-Wmissing-declarations" \
 114                         "-Wmissing-prototypes" \
 115                         "-Wnested-externs" \
 116                         "-Wpointer-arith" \
 117                         "-Wundef" \
 118                         "-Wunused-but-set-variable" \
 119          ; do
 120                  ac_save_CFLAGS="$CFLAGS"
 121                  AC_MSG_CHECKING([if $CC supports $newflag])
 122                  CFLAGS="$CFLAGS $QUALITY_CFLAGS $newflag"
 123                  AC_COMPILE_IFELSE(
 124                         [AC_LANG_SOURCE([[]])],
 125                         [AC_MSG_RESULT(yes)
 126                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 127                         [AC_MSG_RESULT(no)]
 128                  )
 129                  CFLAGS="$ac_save_CFLAGS"
 130          done
 131         ])
 132 AC_SUBST(QUALITY_CFLAGS)
 133
 134 dnl check for availability of addition linker flags
 135 for newflag in \
 136         "-Wl,-Bsymbolic-functions" \
 137 ; do
 138         ac_save_LDFLAGS="$LDFLAGS"
 139         AC_MSG_CHECKING([if $CC supports $newflag])
 140         LDFLAGS="$LDFLAGS $ADDITIONAL_LDFLAGS $newflag"
 141         AC_LINK_IFELSE(
 142                 [AC_LANG_SOURCE([[
 143 int main(int argc, char *argv[])
 144 {
 145         return(0);
 146 }
 147                  ]])],
 148                 [AC_MSG_RESULT(yes)
 149                  ADDITIONAL_LDFLAGS="$ADDITIONAL_LDFLAGS $newflag"],
 150                 [AC_MSG_RESULT(no)]
 151         )
 152         LDFLAGS="$ac_save_LDFLAGS"
 153 done
 154 AC_SUBST(ADDITIONAL_LDFLAGS)
 155
 156 dnl Check for pkg-config before using it
 157 PKG_PROG_PKG_CONFIG
 158
 159 dnl check for valgrind (optional, only needed for debugging)
 160 PKG_CHECK_MODULES(VALGRIND, [valgrind],
 161         [AC_DEFINE(HAVE_VALGRIND, 1, [Define to 1 if you have the valgrind headers])],
 162         [AC_MSG_RESULT(no)])
 163
 164 dnl build option: with AppStream support
 165 AC_ARG_WITH(appstream,
 166         [AC_HELP_STRING([--with-appstream],
 167                 [install AppStream XML file @<:@default=yes@:>@])],
 168         [AS_IF([test "x$withval" = xno], [with_appstream=no])],
 169         [with_appstream=yes])
 170 AM_CONDITIONAL(SIPE_WITH_APPSTREAM, [test "x$with_appstream" != xno])
 171
 172 dnl build option: with voice & video support (for all backends)
 173 AC_ARG_WITH(vv,
 174         [AC_HELP_STRING([--with-vv],
 175                 [compile with voice and video support @<:@default=check@:>@])],
 176         [AS_IF([test "x$withval" = xyes], [with_vv=yes])],
 177         [with_vv=check])
 178
 179 dnl check for Kerberos 5 support
 180 AC_ARG_WITH([krb5],
 181         [AC_HELP_STRING([--with-krb5],
 182                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 183         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 184         [with_krb5=check])
 185
 186 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 187       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 188         [AC_MSG_CHECKING(if Kerberos 5 is available)
 189          AS_IF([AC_RUN_LOG([krb5-config --version])],
 190                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 191                  KRB5_LDFLAGS=""
 192
 193                  dnl same as AC_CHECK_LIB()
 194                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"],
 195                 [AC_MSG_RESULT(no)
 196                  with_krb5=no])],
 197       [                               dnl path specified by user
 198         KRB5_CFLAGS="-I${with_krb5}/include"
 199         KRB5_LDFLAGS="-L${with_krb5}/lib"
 200       ])
 201 AS_IF([test "x$with_krb5" != xno],
 202       [ac_save_CFLAGS="$CFLAGS"
 203        ac_save_LDFLAGS="$LDFLAGS"
 204        CFLAGS="$CFLAGS $KRB5_CFLAGS"
 205        LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 206        AC_CHECK_HEADERS([gssapi/gssapi.h gssapi/gssapi_krb5.h],
 207                         [],
 208                         [AC_ERROR([GSSAPI headers not found])])
 209        AC_CHECK_FUNC([gss_init_sec_context],
 210                      [],
 211                      [AC_ERROR([GSSAPI libraries not found])])
 212
 213        dnl older GSSAPI releases don't have gss_acquire_cred_with_passwd()
 214        AC_CHECK_HEADER([gssapi/gssapi_ext.h],
 215                        [AC_CHECK_FUNC([gss_acquire_cred_with_password],
 216                                       [AC_DEFINE(HAVE_GSSAPI_PASSWORD_SUPPORT, 1, [Define to 1 if gssapi has gss_acquire_cred_with_passwd()])],
 217                                       [AC_MSG_NOTICE([gss_acquire_cred_with_passwd() required: disabling GSSAPI non-SSO support])])],
 218                        [AC_MSG_NOTICE([gssapi/gssapi_ext.h required: disabling GSSAPI non-SSO support])])
 219
 220        CFLAGS="$ac_save_CFLAGS"
 221        LDFLAGS="$ac_save_LDFLAGS"
 222       ])
 223
 224 AM_CONDITIONAL(SIP_SEC_GSSAPI, [test "x$with_krb5" != xno])
 225 AC_SUBST(KRB5_CFLAGS)
 226 AC_SUBST(KRB5_LDFLAGS)
 227
 228 dnl check for DBUS support
 229 AC_ARG_WITH([dbus],
 230         [AC_HELP_STRING([--with-dbus],
 231                 [compile with D-BUS support @<:@default=check@:>@])],
 232         [AS_IF([test "x$withval" = xyes], [with_dbus=check])],
 233         [with_dbus=check])
 234
 235 AS_IF([test "x$with_dbus" = xno], [], dnl disabled by user
 236       [test "x$with_dbus" = xcheck],  dnl autodetect with pkg-config
 237         [PKG_CHECK_MODULES(DBUS, [dbus-1],
 238                 [with_dbus=yes],
 239                 [with_dbus=no])
 240         ])
 241 AM_CONDITIONAL(SIPE_DBUS, [test "x$with_dbus" = xyes])
 242 AS_IF([test "x$with_dbus" = xyes],
 243         [AC_DEFINE(HAVE_DBUS, 1, [Define if D-BUS should be used in sipe.])])
 244
 245 AC_ARG_ENABLE(gssapi_only,
 246         [AS_HELP_STRING([--enable-gssapi-only],
 247                         [disable all internal authentication code and only use
 248                          GSSAPI for authentication @<:@default=yes@:>@])],
 249         [],
 250         dnl requires Kerberos which provides GSSAPI
 251         [enable_gssapi_only=$with_krb5])
 252 AS_IF([test "x$enable_gssapi_only" != xno],
 253         [AC_CHECK_HEADER([gssapi/gssapi_ntlmssp.h],
 254                        [AC_DEFINE(HAVE_GSSAPI_ONLY, 1, [Define to 1 to enable GSSAPI-only mode])],
 255                        [AC_MSG_NOTICE([gssapi/gssapi_ntlm.h required: falling back to internal authentication implementation])
 256                         enable_gssapi_only=no])
 257         ])
 258 AM_CONDITIONAL(SIP_SEC_GSSAPI_ONLY, [test "x$enable_gssapi_only" != xno])
 259
 260 dnl
 261 dnl oldest supported LTS release vs. package versions
 262 dnl
 263 dnl last checked: Jun-2019
 264 dnl
 265 dnl package        | Debian  | RHEL    | SLES    | Ubuntu  | win32  |
 266 dnl                | 8.0     | 6.10    | 12 SP4  | 16.04   | 2.13.x |
 267 dnl            EOL | 07/2020 | 12/2020 | 11/2024 | 04/2021 |    N/A |
 268 dnl ---------------|---------|---------|---------|---------|--------|
 269 dnl glib-2.0       |  2.42.x |  2.28.x |  2.48.x |  2.48.x | 2.18.x |
 270 dnl gmime-2.6      |     YES |      NO |     YES |     YES |     NO |
 271 dnl gss-ntlmssp    |      NO |      NO |      NO |   0.7.x |    N/A |
 272 dnl nice           | TOO OLD | TOO OLD |  0.1.13 |  0.1.13 |    N/A |
 273 dnl purple         |  2.11.x |   2.7.x |  2.12.x |  2.10.x | 2.13.x |
 274 dnl telepathy-glib |  0.24.x |      NO |  0.24.x |  0.24.x |    N/A |
 275 dnl
 276
 277 dnl check for glib
 278 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.18.0])
 279 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.18.0])
 280
 281 dnl check for gmime
 282 PKG_CHECK_MODULES(GMIME, [gmime-3.0 >= 3.0.0],
 283         [ac_have_gmime=yes],
 284         [PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.6.0],
 285                 [ac_have_gmime=yes],
 286                 [ac_have_gmime=no])
 287         ])
 288 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 289 AS_IF([test "x$ac_have_gmime" = xyes],
 290         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 291
 292 dnl check for NSS
 293 AC_ARG_ENABLE(nss,
 294         [AS_HELP_STRING([--enable-nss],
 295                         [use NSS as crypto backend @<:@default=yes@:>@])],
 296         [],
 297         [enable_nss=yes])
 298 AS_IF([test "x$enable_nss" != xno],
 299         [PKG_CHECK_MODULES(NSS, [nss],
 300                 [],
 301                 [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 302                         [],
 303                         [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 304                                 [],
 305                                 [enable_nss=no])
 306                         ])
 307                 ])
 308         ])
 309
 310 dnl check for OpenSSL
 311 AC_ARG_ENABLE(openssl,
 312         [AS_HELP_STRING([--enable-openssl],
 313                         [use OpenSSL as crypto backend @<:@default=yes@:>@])],
 314         [],
 315         [enable_openssl=yes])
 316 AS_IF([test "x$enable_openssl" != xno],
 317         [PKG_CHECK_MODULES(OPENSSL, [libcrypto],
 318                    [],
 319                    [enable_openssl=no])
 320         ])
 321 AS_IF(
 322         [test "x$enable_nss" != xno],
 323                 [ dnl NSS has priority over OpenSSL
 324                   enable_openssl=no
 325                   AC_MSG_NOTICE([using NSS as crypto backend.])],
 326         [test "x$enable_openssl" != xno],
 327                 [AC_MSG_NOTICE([using OpenSSL as crypto backend.])],
 328         [AC_ERROR([nss, mozilla-nss, microb-engine-nss or libcrypto package is required])])
 329 AM_CONDITIONAL(SIPE_OPENSSL, [test "x$enable_openssl" != xno])
 330
 331 dnl check for libxml2
 332 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 333
 334 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 335 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 336 ac_save_CFLAGS="$CFLAGS"
 337 CFLAGS="$CFLAGS $GLIB_CFLAGS $QUALITY_CFLAGS"
 338 dnl note the [[[ quoting: our code contains []!
 339 AC_RUN_IFELSE(
 340         [AC_LANG_PROGRAM(
 341                 [[
 342 #include <glib.h>
 343 #include <stdio.h>
 344
 345 /* Copied from uuid.c */
 346 typedef struct {
 347    guint32 time_low;
 348    guint16 time_mid;
 349    guint16 time_hi_and_version;
 350    guint8  clock_seq_hi_and_reserved;
 351    guint8  clock_seq_low;
 352    guint8  node[6];
 353 } uuid_t;
 354                 ]],
 355                 [[if (sizeof(uuid_t) == 16) {
 356                         return(0);
 357                  } else {
 358                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 359                         return(1);
 360                  }]])],
 361         [AC_MSG_RESULT(yes)],
 362         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 363
 364 Please notify the SIPE developers.
 365
 366 Copy & paste all lines starting with the line
 367
 368   checking that sizeof(uuid_t) is 16...
 369
 370 to the report and attach the file "config.log".
 371
 372 Compiler information:
 373
 374  host:     $host
 375  build:    $build
 376  compiler: $CC
 377 ])],
 378         [AC_MSG_WARN([cross compiling: not checking])])
 379 CFLAGS="$ac_save_CFLAGS"
 380
 381 dnl build option: OCS2005 client hack
 382 AC_ARG_ENABLE([ocs2005-message-hack],
 383         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
 384                                                           which causes "false" not delivered error messages
 385                                                           @<:@default=no@:>@])],
 386         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
 387                    [Define to 1 to disable SIP MESSAGE timeout feature.
 388                     OCS2005 clients don't seem to acknowledge MESSAGEs and
 389                     disabling the timeout suppresses "false" error messages])])
 390
 391 dnl build option: purple backend
 392 AC_ARG_ENABLE([purple],
 393         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 394         [],
 395         [enable_purple=yes])
 396 ac_have_appshare=no
 397 ac_have_appshare_server=no
 398 ac_have_xdata=no
 399 with_purple_vv=no
 400 AS_IF([test "x$enable_purple" != xno],
 401         [PKG_CHECK_MODULES(PURPLE, [purple-3],
 402                 [purple_pkgconfig=purple-3],
 403                 [PKG_CHECK_MODULES(PURPLE, [purple >= 2.7.0],
 404                         [purple_pkgconfig=purple],
 405                         [enable_purple=no])])
 406
 407          AS_IF([test "x$enable_purple" != xno],
 408                 [AC_MSG_NOTICE([using package "$purple_pkgconfig".])
 409
 410                  dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 411                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion $purple_pkgconfig | cut -d. -f 1`
 412                  AC_SUBST(PURPLE_MAJOR_VERSION)
 413
 414                  ac_save_CFLAGS="$CFLAGS"
 415                  ac_save_LIBS="$LIBS"
 416                  CFLAGS="$CFLAGS $PURPLE_CFLAGS $QUALITY_CFLAGS"
 417                  LIBS="$LIBS $PURPLE_LIBS"
 418
 419                  dnl check whether enable voice and video support
 420                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 421                        [AC_MSG_CHECKING(for purple voice and video support)
 422                         purple_has_media=no
 423                         AC_RUN_IFELSE(
 424                                 [AC_LANG_PROGRAM([[
 425 #include <media.h>
 426                                         ]],
 427                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]]
 428                                 )],
 429                                 [purple_has_media=yes
 430                                  AC_MSG_RESULT(ok)
 431                                 ],
 432                                 [AC_MSG_RESULT([no - your purple hasn't been compiled with voice and video support.])],
 433                                 [AS_IF([test "x$with_vv" = xyes],
 434                                        [purple_has_media=yes
 435                                         AC_MSG_RESULT([yes - enabling voice and video support for cross compiling on users' request.])],
 436                                        [AC_MSG_RESULT([no - disabled for cross compiling.])])
 437                                 ]
 438                         )
 439                         AS_IF([test "x$purple_has_media" = xyes],
 440                                 [PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
 441                                         dnl sipe-media.c uses g_slist_free_full()
 442                                         [PKG_CHECK_MODULES(_SIPE_MEDIA_RECHECK_PLEASE_IGNORE, [$purple_pkgconfig >= 2.8.0],
 443                                                 dnl check purple pkgconfig for gstreamer version
 444                                                 [gstreamer_pkgconfig=`$PKG_CONFIG --variable=gstreamer $purple_pkgconfig`
 445                                                 AS_IF([test "x$gstreamer_pkgconfig" == x],
 446                                                         [AS_IF([test "x$purple_pkgconfig" == xpurple-3],
 447                                                                 [gstreamer_pkgconfig=1.0])])
 448                                                 AS_IF([test "x$gstreamer_pkgconfig" == x1.0],
 449                                                         [gstreamer_pkgconfig="gstreamer-$gstreamer_pkgconfig gstreamer-rtp-$gstreamer_pkgconfig"
 450
 451                                                         AC_MSG_NOTICE([using packages "$gstreamer_pkgconfig".])
 452                                                         PKG_CHECK_MODULES(GSTREAMER, [$gstreamer_pkgconfig],
 453                                                                 [PKG_CHECK_MODULES(FARSTREAM, [farstream-0.2],
 454                                                                         [with_purple_vv=yes
 455
 456                                                                          AC_COMPILE_IFELSE(
 457                                                                                  [AC_LANG_PROGRAM([[
 458 #include <media.h>
 459                                                                                         ]],
 460                                                                                         [[return (PURPLE_MEDIA_NETWORK_PROTOCOL_TCP_PASSIVE);]]
 461                                                                                  )],
 462                                                                                  [AC_DEFINE(HAVE_PURPLE_NEW_TCP_ENUMS, 1, [Define if libpurple has new TCP enums in media backend.])]
 463                                                                         )],
 464                                                                         [AC_MSG_NOTICE(Farstream required: disabling purple voice and video support)])],
 465                                                                 [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 466                                                         [AC_MSG_NOTICE(your purple hasn't been compiled against GStreamer 1.0: disabling purple voice and video support)])],
 467                                                 [AC_MSG_NOTICE(libpurple >= 2.8.0 required: disabling purple voice and video support)])],
 468                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])
 469                                 ])
 470                        ])
 471
 472                  dnl SRTP and XDATA require media backend
 473                  AS_IF([test "x$with_purple_vv" != xno],
 474                         [AC_LINK_IFELSE(
 475                                 [AC_LANG_PROGRAM([[
 476 #include <media.h>
 477                                         ]],
 478                                         [[purple_media_set_encryption_parameters(NULL, "", "", "", "", 0);
 479                                           purple_media_set_decryption_parameters(NULL, "", "", "", "", "", 0);]]
 480                                  )],
 481                                  [AC_DEFINE(HAVE_SRTP, 1, [Define if we have SRTP support in media backend.])]
 482                          )
 483
 484                          AC_COMPILE_IFELSE(
 485                                 [AC_LANG_PROGRAM([[
 486 #include <media.h>
 487                                         ]],
 488                                         [[return (PURPLE_MEDIA_APPLICATION);]]
 489                                  )],
 490                                  [dnl libpurple supports raw data RTP connections
 491                                   ac_have_xdata=yes
 492
 493                                   dnl gio-2.0 is mandatory for application sharing support
 494                                   PKG_CHECK_MODULES(GIO, [gio-2.0],
 495                                         [ac_have_appshare=yes
 496
 497                                          dnl freerdp-shadow2 & winpr2 is mandatory for appshare server support
 498                                          PKG_CHECK_MODULES(FREERDP_SHADOW, [freerdp-shadow2 winpr2],
 499                                                 [ac_have_appshare_server=yes],
 500                                                 [ac_have_appshare_server=no])
 501                                    ])
 502                                  ]
 503                          )
 504                         ],
 505                         [AS_IF([test "x$with_vv" = xyes], dnl explicitly requested by user
 506                                 [AC_ERROR([Voice and video support explicitly requested, but not available])]
 507                          )]
 508                  )
 509
 510                  CFLAGS="$ac_save_CFLAGS"
 511                  LIBS="$ac_save_LIBS"])])
 512 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 513 AM_CONDITIONAL(SIPE_PURPLE3, [test "x$purple_pkgconfig" = xpurple-3])
 514
 515 dnl build option: telepathy backend
 516 AC_ARG_ENABLE([telepathy],
 517         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 518         [],
 519         [enable_telepathy=yes])
 520 AS_IF([test "x$enable_telepathy" != xno],
 521         [PKG_CHECK_MODULES(TELEPATHY_GLIB, [telepathy-glib >= 0.24.0],
 522                 [dnl GMIME is a build requirement
 523                  AS_IF([test "x$ac_have_gmime" = xyes],
 524                         [],
 525                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 526
 527                  dnl telepathy is based on GObject & D-Bus GLib
 528                  PKG_CHECK_MODULES(GOBJECT, [gobject-2.0])
 529                  PKG_CHECK_MODULES(DBUS_GLIB, [dbus-glib-1])
 530
 531                  dnl telepathy uses from gio:
 532                  dnl  - GIOStream      (>= 2.22.0)
 533                  dnl  - GResolver      (>= 2.22.0)
 534                  dnl  - GSocketClient  (>= 2.32.0)
 535                  dnl  - GTlsConnection (>= 2.28.0)
 536                  PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.32.0])
 537
 538                 ],
 539                 [enable_telepathy=no])])
 540 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 541
 542 dnl sanity check
 543 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
 544         [AC_ERROR(at least one plugin must be selected
 545
 546 If you didn't use a --enable option then please check that you have
 547 the headers for the packages "purple" or "telepathy-glib" installed.
 548 )],
 549         [])
 550
 551 dnl enable voice & video support if any backend supports it
 552 AS_IF([test "x$with_purple_vv" != xno],
 553         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 554 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 555
 556 dnl raw data RTP streams enable Lync file transfer
 557 AM_CONDITIONAL(SIPE_HAVE_XDATA, [test "x$ac_have_xdata" == xyes])
 558 AS_IF([test "x$ac_have_xdata" == xyes],
 559         [AC_DEFINE(HAVE_XDATA, 1, [Define if we have raw data RTP in media backend.])])
 560
 561 dnl enable appshare support
 562 AM_CONDITIONAL(SIPE_HAVE_APPSHARE, [test "x$ac_have_appshare" == xyes])
 563 AS_IF([test "x$ac_have_appshare" == xyes],
 564         [AC_DEFINE(HAVE_APPSHARE, 1, [Define to 1 if we have appshare support.])])
 565
 566 dnl RDP server for sharing local desktop
 567 AM_CONDITIONAL(SIPE_HAVE_APPSHARE_SERVER, [test "x$ac_have_appshare_server" = xyes])
 568 AS_IF([test "x$ac_have_appshare_server" == xyes],
 569         [AC_DEFINE(HAVE_APPSHARE_SERVER, 1, [Define if appshare server is enabled.])])
 570
 571 dnl libpurple API relies on GParameter (deprecated in glib-2.0 >= 2.62.0)
 572 AS_IF([test "x$enable_purple" != xno],
 573         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_60,
 574                    [We need GParameter for which no replacement is available])
 575         ])
 576 dnl telepathy code parts rely on interfaces that require GValueArray. This
 577 dnl type has been declared "deprectated" in glib-2.0 >= 2.32.0, but there
 578 dnl is no backward compatible replacement implementation possible
 579 dnl telepathy-glib API relies on GTimeVal (deprecated in glib-2.0 >= 2.62.0)
 580 AS_IF([test "x$enable_telepathy" != xno],
 581         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_30,
 582                    [We need GValueArray for which no replacement is available])
 583         ])
 584 dnl libpurple 2.x API relies on G_CONST_RETURN (deprecated in glib-2.0 >= 2.30.0)
 585 AS_IF([test "x$purple_pkgconfig" == xpurple],
 586         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_28,
 587                    [libpurple 2.x API uses G_CONST_RETURN])
 588         ])
 589
 590 dnl i18n
 591 AC_MSG_CHECKING([locale_CPPFLAGS])
 592 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 593 AC_SUBST([LOCALE_CPPFLAGS])
 594 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 595 AM_GNU_GETTEXT([external])
 596 AM_GNU_GETTEXT_VERSION([0.19.8])
 597 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 598
 599 dnl substitutions and generated files
 600 AC_CONFIG_HEADERS([config.h])
 601 AC_CONFIG_FILES([
 602         Makefile
 603         pixmaps/Makefile
 604         po/Makefile.in
 605         pixmaps/16/Makefile
 606         pixmaps/22/Makefile
 607         pixmaps/24/Makefile
 608         pixmaps/32/Makefile
 609         pixmaps/48/Makefile
 610         pixmaps/scalable/Makefile
 611         src/Makefile
 612         src/core/Makefile
 613         src/api/Makefile
 614         src/purple/Makefile
 615         src/telepathy/Makefile
 616         src/telepathy/data/Makefile
 617         ])
 618
 619 dnl generate files
 620 AC_OUTPUT()
 621
 622 dnl additional info for the user
 623 AS_ECHO()
 624 AS_IF([test "x$enable_purple" = xno],
 625         [AS_ECHO("Not building purple plugin")],
 626         [AS_ECHO("Build purple plugin")
 627          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 628          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 629          AS_ECHO_N("Voice and video: ")
 630          AS_IF([test "x$with_purple_vv" = xno],
 631           [AS_ECHO("disabled")],
 632           [AS_ECHO("enabled")])
 633         ])
 634 AS_ECHO()
 635 AS_IF([test "x$enable_telepathy" = xno],
 636         [AS_ECHO("Not building telepathy plugin")],
 637         [AS_ECHO("Build telepathy plugin")
 638          AS_ECHO("TELEPATHY_GLIB_CFLAGS: $TELEPATHY_GLIB_CFLAGS")
 639          AS_ECHO("TELEPATHY_GLIB_LIBS  : $TELEPATHY_GLIB_LIBS")])
 640 AS_ECHO()
 641 AS_IF([test "x$with_krb5" = xno],
 642         [AS_ECHO("Not building with Kerberos 5 support")],
 643         [AS_ECHO("Build with Kerberos 5 support")
 644          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 645          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 646 AS_ECHO()
 647 AS_IF([test "x$enable_gssapi_only" = xno],
 648         [AS_ECHO("Using internal authentication implementation")],
 649         [AS_ECHO("Using only GSSAPI for authentication")])
 650 AS_ECHO()
 651 AS_IF([test "x$enable_debug" = xno],
 652         [AS_ECHO("Debugging not enabled")],
 653         [AS_ECHO("Build with debugging enabled")
 654          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 655 AS_ECHO()
 656 AS_IF([test "x$QUALITY_CFLAGS" = x],
 657         [AS_ECHO("Compiler checks disabled")],
 658         [AS_ECHO("Build with compiler checks enabled")
 659          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 660 AS_ECHO()
 661 AS_ECHO("configure complete. Now run 'make'")
 662 AS_ECHO()
 663
 664 dnl The End.