configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.69])
   3
   4 AC_CONFIG_MACRO_DIRS([m4])
   5
   6 dnl Use 'VERSION' files to get version.
   7 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   8
   9 dnl Strip off newline characters.
  10 m4_define([SIPE_VERSION],
  11         m4_substr(SIPE_VERSION_DATA,
  12                   [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  13
  14 dnl homepage
  15 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  16
  17 dnl initialize package name, version, bugtracker & homepage
  18 AC_INIT([pidgin-sipe], SIPE_VERSION,
  19         [https://sourceforge.net/p/sipe/bugs/], [],
  20         SIPE_HOMEPAGE)
  21
  22 AC_DEFINE([SIPE_TRANSLATIONS_URL],
  23         ["https://www.transifex.com/stefanb/pidgin-sipe/"],
  24         [URL for submitting translations.])
  25
  26 dnl define optional git commit ID generated by autogen.sh
  27 m4_define([SIPE_GIT_COMMIT], m4_sinclude([GITVERSION]))
  28 AS_IF([test "x"SIPE_GIT_COMMIT != x],
  29         [AC_MSG_NOTICE([set git commit])
  30          AC_DEFINE(PACKAGE_GIT_COMMIT, "SIPE_GIT_COMMIT", [Define to the git commit for this package.])
  31 ])
  32
  33 dnl setup automake and require recent enough version
  34 AM_INIT_AUTOMAKE([1.16 dist-bzip2 dist-xz no-define tar-ustar])
  35
  36 AC_CANONICAL_HOST
  37
  38 dnl set PACKAGE_URL for autoconf < 2.64
  39 AS_IF([test "x${PACKAGE_URL}" = x],
  40         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  41          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  42 ])
  43
  44 dnl set programming language
  45 AC_LANG(C)
  46 AM_PROG_CC_C_O
  47 AM_PROG_LEX
  48 AC_HEADER_STDC
  49
  50 dnl setup shared library generation
  51 LT_INIT([disable-static])
  52
  53 dnl checks for tools
  54 IT_PROG_INTLTOOL([0.41.0])
  55 AC_PROG_INSTALL
  56
  57 dnl ******************************
  58 dnl Win32
  59 dnl ******************************
  60 AC_MSG_CHECKING([for Win32])
  61 AS_CASE(["$host"],
  62                 [*-mingw*], [os_win32=yes],
  63                 [os_win32=no])
  64 AC_MSG_RESULT([$os_win32])
  65 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  66
  67 dnl checks for header files
  68 AC_CHECK_HEADERS([])
  69
  70 dnl checks for library functions
  71 AC_CHECK_FUNCS([])
  72
  73 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  74 dnl as that is likely where libpurple will be found if it is not in the default
  75 dnl pkgconfig path
  76 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  77 export PKG_CONFIG_PATH
  78
  79 dnl debug mode
  80 AC_ARG_ENABLE(debug,
  81         [AS_HELP_STRING([--enable-debug],
  82                         [compile with debugging support @<:@default=no@:>@])],
  83         [],
  84         [enable_debug=no])
  85
  86 AS_IF([test "x$enable_debug" = xyes],
  87         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  88 AC_SUBST(DEBUG_CFLAGS)
  89
  90 dnl quality check mode
  91 dnl For people who are interested in finding bugs and not hiding them
  92 AC_ARG_ENABLE(quality-check,
  93         [AS_HELP_STRING([--enable-quality-check],
  94                         [compile with compiler checks enabled @<:@default=yes@:>@])],
  95         [],
  96         [enable_quality_check=yes])
  97
  98 AS_IF([test "x$enable_quality_check" = xyes],
  99         [dnl default quality configuration
 100          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
 101
 102          dnl enable warnings supported by the GCC on the build system
 103          dnl @TODO: not included in -Wall: "-Wwrite-strings" \
 104          for newflag in \
 105                         "-Wextra" \
 106                         "-Waggregate-return" \
 107                         "-Wcast-align" \
 108                         "-Wcast-function-type" \
 109                         "-Wdeclaration-after-statement" \
 110                         "-Wdeprecated-declarations" \
 111                         "-Wduplicate-decl-specifier" \
 112                         "-Winit-self" \
 113                         "-Wmaybe-uninitialized" \
 114                         "-Wmissing-declarations" \
 115                         "-Wmissing-prototypes" \
 116                         "-Wnested-externs" \
 117                         "-Wpointer-arith" \
 118                         "-Wundef" \
 119                         "-Wunused-but-set-variable" \
 120          ; do
 121                  ac_save_CFLAGS="$CFLAGS"
 122                  AC_MSG_CHECKING([if $CC supports $newflag])
 123                  CFLAGS="$CFLAGS $QUALITY_CFLAGS $newflag"
 124                  AC_COMPILE_IFELSE(
 125                         [AC_LANG_SOURCE([[]])],
 126                         [AC_MSG_RESULT(yes)
 127                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 128                         [AC_MSG_RESULT(no)]
 129                  )
 130                  CFLAGS="$ac_save_CFLAGS"
 131          done
 132         ])
 133 AC_SUBST(QUALITY_CFLAGS)
 134
 135 dnl check for availability of addition linker flags
 136 for newflag in \
 137         "-Wl,-Bsymbolic-functions" \
 138 ; do
 139         ac_save_LDFLAGS="$LDFLAGS"
 140         AC_MSG_CHECKING([if $CC supports $newflag])
 141         LDFLAGS="$LDFLAGS $ADDITIONAL_LDFLAGS $newflag"
 142         AC_LINK_IFELSE(
 143                 [AC_LANG_SOURCE([[
 144 int main(int argc, char *argv[])
 145 {
 146         return(0);
 147 }
 148                  ]])],
 149                 [AC_MSG_RESULT(yes)
 150                  ADDITIONAL_LDFLAGS="$ADDITIONAL_LDFLAGS $newflag"],
 151                 [AC_MSG_RESULT(no)]
 152         )
 153         LDFLAGS="$ac_save_LDFLAGS"
 154 done
 155 AC_SUBST(ADDITIONAL_LDFLAGS)
 156
 157 dnl Check for pkg-config before using it
 158 PKG_PROG_PKG_CONFIG
 159
 160 dnl check for valgrind (optional, only needed for debugging)
 161 PKG_CHECK_MODULES(VALGRIND, [valgrind],
 162         [AC_DEFINE(HAVE_VALGRIND, 1, [Define to 1 if you have the valgrind headers])],
 163         [AC_MSG_RESULT(no)])
 164
 165 dnl build option: with AppStream support
 166 AC_ARG_WITH(appstream,
 167         [AC_HELP_STRING([--with-appstream],
 168                 [install AppStream XML file @<:@default=yes@:>@])],
 169         [AS_IF([test "x$withval" = xno], [with_appstream=no])],
 170         [with_appstream=yes])
 171 AM_CONDITIONAL(SIPE_WITH_APPSTREAM, [test "x$with_appstream" != xno])
 172
 173 dnl build option: with voice & video support (for all backends)
 174 AC_ARG_WITH(vv,
 175         [AC_HELP_STRING([--with-vv],
 176                 [compile with voice and video support @<:@default=check@:>@])],
 177         [AS_IF([test "x$withval" = xyes], [with_vv=yes])],
 178         [with_vv=check])
 179
 180 dnl check for Kerberos 5 support
 181 AC_ARG_WITH([krb5],
 182         [AC_HELP_STRING([--with-krb5],
 183                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 184         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 185         [with_krb5=check])
 186
 187 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 188       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 189         [AC_MSG_CHECKING(if Kerberos 5 is available)
 190          AS_IF([AC_RUN_LOG([krb5-config --version])],
 191                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 192                  KRB5_LDFLAGS=""
 193
 194                  dnl same as AC_CHECK_LIB()
 195                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"],
 196                 [AC_MSG_RESULT(no)
 197                  with_krb5=no])],
 198       [                               dnl path specified by user
 199         KRB5_CFLAGS="-I${with_krb5}/include"
 200         KRB5_LDFLAGS="-L${with_krb5}/lib"
 201       ])
 202 AS_IF([test "x$with_krb5" != xno],
 203       [ac_save_CFLAGS="$CFLAGS"
 204        ac_save_LDFLAGS="$LDFLAGS"
 205        CFLAGS="$CFLAGS $KRB5_CFLAGS"
 206        LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 207        AC_CHECK_HEADERS([gssapi/gssapi.h gssapi/gssapi_krb5.h],
 208                         [],
 209                         [AC_ERROR([GSSAPI headers not found])])
 210        AC_CHECK_FUNC([gss_init_sec_context],
 211                      [],
 212                      [AC_ERROR([GSSAPI libraries not found])])
 213
 214        dnl older GSSAPI releases don't have gss_acquire_cred_with_passwd()
 215        AC_CHECK_HEADER([gssapi/gssapi_ext.h],
 216                        [AC_CHECK_FUNC([gss_acquire_cred_with_password],
 217                                       [AC_DEFINE(HAVE_GSSAPI_PASSWORD_SUPPORT, 1, [Define to 1 if gssapi has gss_acquire_cred_with_passwd()])],
 218                                       [AC_MSG_NOTICE([gss_acquire_cred_with_passwd() required: disabling GSSAPI non-SSO support])])],
 219                        [AC_MSG_NOTICE([gssapi/gssapi_ext.h required: disabling GSSAPI non-SSO support])])
 220
 221        CFLAGS="$ac_save_CFLAGS"
 222        LDFLAGS="$ac_save_LDFLAGS"
 223       ])
 224
 225 AM_CONDITIONAL(SIP_SEC_GSSAPI, [test "x$with_krb5" != xno])
 226 AC_SUBST(KRB5_CFLAGS)
 227 AC_SUBST(KRB5_LDFLAGS)
 228
 229 dnl check for DBUS support
 230 AC_ARG_WITH([dbus],
 231         [AC_HELP_STRING([--with-dbus],
 232                 [compile with D-BUS support @<:@default=check@:>@])],
 233         [AS_IF([test "x$withval" = xyes], [with_dbus=check])],
 234         [with_dbus=check])
 235
 236 AS_IF([test "x$with_dbus" = xno], [], dnl disabled by user
 237       [test "x$with_dbus" = xcheck],  dnl autodetect with pkg-config
 238         [PKG_CHECK_MODULES(DBUS, [dbus-1],
 239                 [with_dbus=yes],
 240                 [with_dbus=no])
 241         ])
 242 AM_CONDITIONAL(SIPE_DBUS, [test "x$with_dbus" = xyes])
 243 AS_IF([test "x$with_dbus" = xyes],
 244         [AC_DEFINE(HAVE_DBUS, 1, [Define if D-BUS should be used in sipe.])])
 245
 246 AC_ARG_ENABLE(gssapi_only,
 247         [AS_HELP_STRING([--enable-gssapi-only],
 248                         [disable all internal authentication code and only use
 249                          GSSAPI for authentication @<:@default=yes@:>@])],
 250         [],
 251         dnl requires Kerberos which provides GSSAPI
 252         [enable_gssapi_only=$with_krb5])
 253 AS_IF([test "x$enable_gssapi_only" != xno],
 254         [AC_CHECK_HEADER([gssapi/gssapi_ntlmssp.h],
 255                        [AC_DEFINE(HAVE_GSSAPI_ONLY, 1, [Define to 1 to enable GSSAPI-only mode])],
 256                        [AC_MSG_NOTICE([gssapi/gssapi_ntlm.h required: falling back to internal authentication implementation])
 257                         enable_gssapi_only=no])
 258         ])
 259 AM_CONDITIONAL(SIP_SEC_GSSAPI_ONLY, [test "x$enable_gssapi_only" != xno])
 260
 261 dnl
 262 dnl oldest supported LTS release vs. package versions
 263 dnl
 264 dnl last checked: Jun-2019
 265 dnl
 266 dnl package        | Debian  | RHEL    | SLES    | Ubuntu  | win32  |
 267 dnl                | 8.0     | 6.10    | 12 SP4  | 16.04   | 2.13.x |
 268 dnl            EOL | 07/2020 | 12/2020 | 11/2024 | 04/2021 |    N/A |
 269 dnl ---------------|---------|---------|---------|---------|--------|
 270 dnl glib-2.0       |  2.42.x |  2.28.x |  2.48.x |  2.48.x | 2.18.x |
 271 dnl gmime-2.6      |     YES |      NO |     YES |     YES |     NO |
 272 dnl gss-ntlmssp    |      NO |      NO |      NO |   0.7.x |    N/A |
 273 dnl intltool       |  0.50.2 |  0.41.0 |  0.51.0 |  0.51.0 | 0.40.4 |
 274 dnl nice           | TOO OLD | TOO OLD |  0.1.13 |  0.1.13 |    N/A |
 275 dnl purple         |  2.11.x |   2.7.x |  2.12.x |  2.10.x | 2.13.x |
 276 dnl telepathy-glib |  0.24.x |      NO |  0.24.x |  0.24.x |    N/A |
 277 dnl
 278
 279 dnl check for glib
 280 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.18.0])
 281 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.18.0])
 282
 283 dnl check for gmime
 284 PKG_CHECK_MODULES(GMIME, [gmime-3.0 >= 3.0.0],
 285         [ac_have_gmime=yes],
 286         [PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.6.0],
 287                 [ac_have_gmime=yes],
 288                 [ac_have_gmime=no])
 289         ])
 290 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 291 AS_IF([test "x$ac_have_gmime" = xyes],
 292         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 293
 294 dnl check for NSS
 295 AC_ARG_ENABLE(nss,
 296         [AS_HELP_STRING([--enable-nss],
 297                         [use NSS as crypto backend @<:@default=yes@:>@])],
 298         [],
 299         [enable_nss=yes])
 300 AS_IF([test "x$enable_nss" != xno],
 301         [PKG_CHECK_MODULES(NSS, [nss],
 302                 [],
 303                 [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 304                         [],
 305                         [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 306                                 [],
 307                                 [enable_nss=no])
 308                         ])
 309                 ])
 310         ])
 311
 312 dnl check for OpenSSL
 313 AC_ARG_ENABLE(openssl,
 314         [AS_HELP_STRING([--enable-openssl],
 315                         [use OpenSSL as crypto backend @<:@default=yes@:>@])],
 316         [],
 317         [enable_openssl=yes])
 318 AS_IF([test "x$enable_openssl" != xno],
 319         [PKG_CHECK_MODULES(OPENSSL, [libcrypto],
 320                    [],
 321                    [enable_openssl=no])
 322         ])
 323 AS_IF(
 324         [test "x$enable_nss" != xno],
 325                 [ dnl NSS has priority over OpenSSL
 326                   enable_openssl=no
 327                   AC_MSG_NOTICE([using NSS as crypto backend.])],
 328         [test "x$enable_openssl" != xno],
 329                 [AC_MSG_NOTICE([using OpenSSL as crypto backend.])],
 330         [AC_ERROR([nss, mozilla-nss, microb-engine-nss or libcrypto package is required])])
 331 AM_CONDITIONAL(SIPE_OPENSSL, [test "x$enable_openssl" != xno])
 332
 333 dnl check for libxml2
 334 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 335
 336 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 337 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 338 ac_save_CFLAGS="$CFLAGS"
 339 dnl NOTE: including $QUALITY_CFLAGS can lead to false negative configure checks!
 340 CFLAGS="$CFLAGS $GLIB_CFLAGS"
 341 dnl note the [[[ quoting: our code contains []!
 342 AC_RUN_IFELSE(
 343         [AC_LANG_PROGRAM(
 344                 [[
 345 #include <glib.h>
 346 #include <stdio.h>
 347
 348 /* Copied from uuid.c */
 349 typedef struct {
 350    guint32 time_low;
 351    guint16 time_mid;
 352    guint16 time_hi_and_version;
 353    guint8  clock_seq_hi_and_reserved;
 354    guint8  clock_seq_low;
 355    guint8  node[6];
 356 } uuid_t;
 357                 ]],
 358                 [[if (sizeof(uuid_t) == 16) {
 359                         return(0);
 360                  } else {
 361                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 362                         return(1);
 363                  }]])],
 364         [AC_MSG_RESULT(yes)],
 365         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 366
 367 Please notify the SIPE developers.
 368
 369 Copy & paste all lines starting with the line
 370
 371   checking that sizeof(uuid_t) is 16...
 372
 373 to the report and attach the file "config.log".
 374
 375 Compiler information:
 376
 377  host:     $host
 378  build:    $build
 379  compiler: $CC
 380 ])],
 381         [AC_MSG_WARN([cross compiling: not checking])])
 382 CFLAGS="$ac_save_CFLAGS"
 383
 384 dnl build option: OCS2005 client hack
 385 AC_ARG_ENABLE([ocs2005-message-hack],
 386         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
 387                                                           which causes "false" not delivered error messages
 388                                                           @<:@default=no@:>@])],
 389         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
 390                    [Define to 1 to disable SIP MESSAGE timeout feature.
 391                     OCS2005 clients don't seem to acknowledge MESSAGEs and
 392                     disabling the timeout suppresses "false" error messages])])
 393
 394 dnl build option: purple backend
 395 AC_ARG_ENABLE([purple],
 396         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 397         [],
 398         [enable_purple=yes])
 399 ac_have_appshare=no
 400 ac_have_appshare_server=no
 401 ac_have_xdata=no
 402 with_purple_vv=no
 403 AS_IF([test "x$enable_purple" != xno],
 404         [PKG_CHECK_MODULES(PURPLE, [purple-3],
 405                 [purple_pkgconfig=purple-3],
 406                 [PKG_CHECK_MODULES(PURPLE, [purple >= 2.7.0],
 407                         [purple_pkgconfig=purple],
 408                         [enable_purple=no])])
 409
 410          AS_IF([test "x$enable_purple" != xno],
 411                 [AC_MSG_NOTICE([using package "$purple_pkgconfig".])
 412
 413                  dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 414                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion $purple_pkgconfig | cut -d. -f 1`
 415                  AC_SUBST(PURPLE_MAJOR_VERSION)
 416
 417                  ac_save_CFLAGS="$CFLAGS"
 418                  ac_save_LIBS="$LIBS"
 419                  dnl NOTE: including $QUALITY_CFLAGS can lead to false negative configure checks!
 420                  CFLAGS="$CFLAGS $PURPLE_CFLAGS"
 421                  LIBS="$LIBS $PURPLE_LIBS"
 422
 423                  dnl check whether enable voice and video support
 424                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 425                        [AC_MSG_CHECKING(for purple voice and video support)
 426                         purple_has_media=no
 427                         AC_RUN_IFELSE(
 428                                 [AC_LANG_PROGRAM([[
 429 #include <media.h>
 430                                         ]],
 431                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]]
 432                                 )],
 433                                 [purple_has_media=yes
 434                                  AC_MSG_RESULT(ok)
 435                                 ],
 436                                 [AC_MSG_RESULT([no - your purple hasn't been compiled with voice and video support.])],
 437                                 [AS_IF([test "x$with_vv" = xyes],
 438                                        [purple_has_media=yes
 439                                         AC_MSG_RESULT([yes - enabling voice and video support for cross compiling on users' request.])],
 440                                        [AC_MSG_RESULT([no - disabled for cross compiling.])])
 441                                 ]
 442                         )
 443                         AS_IF([test "x$purple_has_media" = xyes],
 444                                 [PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
 445                                         dnl sipe-media.c uses g_slist_free_full()
 446                                         [PKG_CHECK_MODULES(_SIPE_MEDIA_RECHECK_PLEASE_IGNORE, [$purple_pkgconfig >= 2.8.0],
 447                                                 dnl check purple pkgconfig for gstreamer version
 448                                                 [gstreamer_pkgconfig=`$PKG_CONFIG --variable=gstreamer $purple_pkgconfig`
 449                                                 AS_IF([test "x$gstreamer_pkgconfig" == x],
 450                                                         [AS_IF([test "x$purple_pkgconfig" == xpurple-3],
 451                                                                 [gstreamer_pkgconfig=1.0])])
 452                                                 AS_IF([test "x$gstreamer_pkgconfig" == x1.0],
 453                                                         [gstreamer_pkgconfig="gstreamer-$gstreamer_pkgconfig gstreamer-rtp-$gstreamer_pkgconfig"
 454
 455                                                         AC_MSG_NOTICE([using packages "$gstreamer_pkgconfig".])
 456                                                         PKG_CHECK_MODULES(GSTREAMER, [$gstreamer_pkgconfig],
 457                                                                 [PKG_CHECK_MODULES(FARSTREAM, [farstream-0.2],
 458                                                                         [with_purple_vv=yes
 459
 460                                                                          AC_COMPILE_IFELSE(
 461                                                                                  [AC_LANG_PROGRAM([[
 462 #include <media.h>
 463                                                                                         ]],
 464                                                                                         [[return (PURPLE_MEDIA_NETWORK_PROTOCOL_TCP_PASSIVE);]]
 465                                                                                  )],
 466                                                                                  [AC_DEFINE(HAVE_PURPLE_NEW_TCP_ENUMS, 1, [Define if libpurple has new TCP enums in media backend.])]
 467                                                                         )],
 468                                                                         [AC_MSG_NOTICE(Farstream required: disabling purple voice and video support)])],
 469                                                                 [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 470                                                         [AC_MSG_NOTICE(your purple hasn't been compiled against GStreamer 1.0: disabling purple voice and video support)])],
 471                                                 [AC_MSG_NOTICE(libpurple >= 2.8.0 required: disabling purple voice and video support)])],
 472                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])
 473                                 ])
 474                        ])
 475
 476                  dnl SRTP and XDATA require media backend
 477                  AS_IF([test "x$with_purple_vv" != xno],
 478                         [AC_LINK_IFELSE(
 479                                 [AC_LANG_PROGRAM([[
 480 #include <media.h>
 481                                         ]],
 482                                         [[purple_media_set_encryption_parameters(NULL, "", "", "", "", 0);
 483                                           purple_media_set_decryption_parameters(NULL, "", "", "", "", "", 0);]]
 484                                  )],
 485                                  [AC_DEFINE(HAVE_SRTP, 1, [Define if we have SRTP support in media backend.])]
 486                          )
 487
 488                          AC_COMPILE_IFELSE(
 489                                 [AC_LANG_PROGRAM([[
 490 #include <media.h>
 491                                         ]],
 492                                         [[return (PURPLE_MEDIA_APPLICATION);]]
 493                                  )],
 494                                  [dnl libpurple supports raw data RTP connections
 495                                   ac_have_xdata=yes
 496
 497                                   dnl gio-2.0 is mandatory for application sharing support
 498                                   PKG_CHECK_MODULES(GIO, [gio-2.0],
 499                                         [ac_have_appshare=yes
 500
 501                                          dnl freerdp-shadow2 & winpr2 is mandatory for appshare server support
 502                                          PKG_CHECK_MODULES(FREERDP_SHADOW, [freerdp-shadow2 winpr2],
 503                                                 [ac_have_appshare_server=yes],
 504                                                 [ac_have_appshare_server=no])
 505                                    ])
 506                                  ]
 507                          )
 508                         ],
 509                         [AS_IF([test "x$with_vv" = xyes], dnl explicitly requested by user
 510                                 [AC_ERROR([Voice and video support explicitly requested, but not available])]
 511                          )]
 512                  )
 513
 514                  CFLAGS="$ac_save_CFLAGS"
 515                  LIBS="$ac_save_LIBS"])])
 516 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 517 AM_CONDITIONAL(SIPE_PURPLE3, [test "x$purple_pkgconfig" = xpurple-3])
 518
 519 dnl build option: telepathy backend
 520 AC_ARG_ENABLE([telepathy],
 521         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 522         [],
 523         [enable_telepathy=yes])
 524 AS_IF([test "x$enable_telepathy" != xno],
 525         [PKG_CHECK_MODULES(TELEPATHY_GLIB, [telepathy-glib >= 0.24.0],
 526                 [dnl GMIME is a build requirement
 527                  AS_IF([test "x$ac_have_gmime" = xyes],
 528                         [],
 529                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 530
 531                  dnl telepathy is based on GObject & D-Bus GLib
 532                  PKG_CHECK_MODULES(GOBJECT, [gobject-2.0])
 533                  PKG_CHECK_MODULES(DBUS_GLIB, [dbus-glib-1])
 534
 535                  dnl telepathy uses from gio:
 536                  dnl  - GIOStream      (>= 2.22.0)
 537                  dnl  - GResolver      (>= 2.22.0)
 538                  dnl  - GSocketClient  (>= 2.32.0)
 539                  dnl  - GTlsConnection (>= 2.28.0)
 540                  PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.32.0])
 541
 542                 ],
 543                 [enable_telepathy=no])])
 544 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 545
 546 dnl sanity check
 547 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
 548         [AC_ERROR(at least one plugin must be selected
 549
 550 If you didn't use a --enable option then please check that you have
 551 the headers for the packages "purple" or "telepathy-glib" installed.
 552 )],
 553         [])
 554
 555 dnl enable voice & video support if any backend supports it
 556 AS_IF([test "x$with_purple_vv" != xno],
 557         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 558 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 559
 560 dnl raw data RTP streams enable Lync file transfer
 561 AM_CONDITIONAL(SIPE_HAVE_XDATA, [test "x$ac_have_xdata" == xyes])
 562 AS_IF([test "x$ac_have_xdata" == xyes],
 563         [AC_DEFINE(HAVE_XDATA, 1, [Define if we have raw data RTP in media backend.])])
 564
 565 dnl enable appshare support
 566 AM_CONDITIONAL(SIPE_HAVE_APPSHARE, [test "x$ac_have_appshare" == xyes])
 567 AS_IF([test "x$ac_have_appshare" == xyes],
 568         [AC_DEFINE(HAVE_APPSHARE, 1, [Define to 1 if we have appshare support.])])
 569
 570 dnl RDP server for sharing local desktop
 571 AM_CONDITIONAL(SIPE_HAVE_APPSHARE_SERVER, [test "x$ac_have_appshare_server" = xyes])
 572 AS_IF([test "x$ac_have_appshare_server" == xyes],
 573         [AC_DEFINE(HAVE_APPSHARE_SERVER, 1, [Define if appshare server is enabled.])])
 574
 575 dnl libpurple API relies on GParameter (deprecated in glib-2.0 >= 2.62.0)
 576 AS_IF([test "x$enable_purple" != xno],
 577         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_60,
 578                    [We need GParameter for which no replacement is available])
 579         ])
 580 dnl telepathy code parts rely on interfaces that require GValueArray. This
 581 dnl type has been declared "deprectated" in glib-2.0 >= 2.32.0, but there
 582 dnl is no backward compatible replacement implementation possible
 583 dnl telepathy-glib API relies on GTimeVal (deprecated in glib-2.0 >= 2.62.0)
 584 AS_IF([test "x$enable_telepathy" != xno],
 585         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_30,
 586                    [We need GValueArray for which no replacement is available])
 587         ])
 588 dnl libpurple 2.x API relies on G_CONST_RETURN (deprecated in glib-2.0 >= 2.30.0)
 589 AS_IF([test "x$purple_pkgconfig" == xpurple],
 590         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_28,
 591                    [libpurple 2.x API uses G_CONST_RETURN])
 592         ])
 593
 594 dnl i18n
 595 AC_MSG_CHECKING([locale_CPPFLAGS])
 596 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 597 AC_SUBST([LOCALE_CPPFLAGS])
 598 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 599 AM_GNU_GETTEXT([external])
 600 AM_GNU_GETTEXT_VERSION([0.19.8])
 601 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 602
 603 dnl substitutions and generated files
 604 AC_CONFIG_HEADERS([config.h])
 605 AC_CONFIG_FILES([
 606         Makefile
 607         pixmaps/Makefile
 608         po/Makefile.in
 609         pixmaps/16/Makefile
 610         pixmaps/22/Makefile
 611         pixmaps/24/Makefile
 612         pixmaps/32/Makefile
 613         pixmaps/48/Makefile
 614         pixmaps/scalable/Makefile
 615         src/Makefile
 616         src/core/Makefile
 617         src/api/Makefile
 618         src/purple/Makefile
 619         src/telepathy/Makefile
 620         src/telepathy/data/Makefile
 621         ])
 622
 623 dnl generate files
 624 AC_OUTPUT()
 625
 626 dnl additional info for the user
 627 AS_ECHO()
 628 AS_IF([test "x$enable_purple" = xno],
 629         [AS_ECHO("Not building purple plugin")],
 630         [AS_ECHO("Build purple plugin")
 631          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 632          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 633          AS_ECHO_N("Voice and video: ")
 634          AS_IF([test "x$with_purple_vv" = xno],
 635           [AS_ECHO("disabled")],
 636           [AS_ECHO("enabled")])
 637         ])
 638 AS_ECHO()
 639 AS_IF([test "x$enable_telepathy" = xno],
 640         [AS_ECHO("Not building telepathy plugin")],
 641         [AS_ECHO("Build telepathy plugin")
 642          AS_ECHO("TELEPATHY_GLIB_CFLAGS: $TELEPATHY_GLIB_CFLAGS")
 643          AS_ECHO("TELEPATHY_GLIB_LIBS  : $TELEPATHY_GLIB_LIBS")])
 644 AS_ECHO()
 645 AS_IF([test "x$with_krb5" = xno],
 646         [AS_ECHO("Not building with Kerberos 5 support")],
 647         [AS_ECHO("Build with Kerberos 5 support")
 648          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 649          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 650 AS_ECHO()
 651 AS_IF([test "x$enable_gssapi_only" = xno],
 652         [AS_ECHO("Using internal authentication implementation")],
 653         [AS_ECHO("Using only GSSAPI for authentication")])
 654 AS_ECHO()
 655 AS_IF([test "x$enable_debug" = xno],
 656         [AS_ECHO("Debugging not enabled")],
 657         [AS_ECHO("Build with debugging enabled")
 658          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 659 AS_ECHO()
 660 AS_IF([test "x$QUALITY_CFLAGS" = x],
 661         [AS_ECHO("Compiler checks disabled")],
 662         [AS_ECHO("Build with compiler checks enabled")
 663          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 664 AS_ECHO()
 665 AS_ECHO("configure complete. Now run 'make'")
 666 AS_ECHO()
 667
 668 dnl The End.