contrib/debug/parse_log.pl

   1 #!/usr/bin/perl -w
   2 use 5.010;
   3 use strict;
   4 use warnings;
   5
   6 use File::Spec;
   7 use Getopt::Long;
   8 use Pod::Usage;
   9
  10 # Command line option
  11 my %Options = (
  12                directory => ".",
  13               );
  14 GetOptions(\%Options,
  15            "directory=s",
  16            "callid",
  17            "from",
  18            "method",
  19            "transport",
  20            "filter",
  21            "help|h|?")
  22   or pod2usage(2);
  23 pod2usage(-verbose => 2) if $Options{help};
  24
  25 ###############################################################################
  26 #
  27 # Message parsing
  28 #
  29 ###############################################################################
  30 my %callid;
  31 my %from;
  32 my %method;
  33 my %transport;
  34 sub AddMessage($$$$@)
  35 {
  36   my($direction, $type, $transport, $time, @message) = @_;
  37
  38   # extract additional information from SIP messages
  39   if ($type eq "SIP") {
  40     my($index, $callid, $from, $method);
  41     foreach my $line (@message) {
  42       next if $index++ < 1;
  43       last if $line =~ /^\s+$/;
  44
  45       next unless my($keyword, $value) = $line =~ /^([^:]+):\s+(.+)/;
  46       $callid   = $value                     if $keyword =~ /^call-id$/i;
  47       ($from)   = $value =~ /^<sip:([^;>]+)/ if $keyword =~ /^from$/i;
  48       ($method) = $value =~ /^\d+\s+(\S+)/   if $keyword =~ /^cseq$/i;
  49     }
  50     push(@{$callid{$callid}},     \@message) if $Options{callid} && defined $callid;
  51     push(@{$from{lc($from)}},     \@message) if $Options{from}   && defined $from;
  52     push(@{$method{uc($method)}}, \@message) if $Options{method} && defined $method;
  53   }
  54
  55   # information available for all message types
  56   push(@{$transport{$transport}}, \@message) if $Options{transport};
  57 }
  58
  59 sub DumpMessages()
  60 {
  61   foreach my $callid (keys %callid) {
  62     if (open(my $fh, ">",
  63              File::Spec->catfile($Options{directory}, "callid-${callid}.txt"))) {
  64       print $fh @{$_} foreach (@{$callid{$callid}});
  65       close($fh);
  66     }
  67   }
  68   foreach my $from (keys %from) {
  69     if (open(my $fh, ">",
  70              File::Spec->catfile($Options{directory}, "from-${from}.txt"))) {
  71       print $fh @{$_} foreach (@{$from{$from}});
  72       close($fh);
  73     }
  74   }
  75   foreach my $method (keys %method) {
  76     if (open(my $fh, ">",
  77              File::Spec->catfile($Options{directory}, "method-${method}.txt"))) {
  78       print $fh @{$_} foreach (@{$method{$method}});
  79       close($fh);
  80     }
  81   }
  82   foreach my $transport (keys %transport) {
  83     if (open(my $fh, ">",
  84              File::Spec->catfile($Options{directory}, "transport-${transport}.txt"))) {
  85       print $fh @{$_} foreach (@{$transport{$transport}});
  86       close($fh);
  87     }
  88   }
  89 }
  90
  91 ###############################################################################
  92 #
  93 # Main program
  94 #
  95 ###############################################################################
  96
  97 # For all lines from command line files or STDIN
  98 my @message;
  99 my $counter;
 100 while (<>) {
 101
 102   # Start of message?
 103   if (my ($direction, $type, $transport, $time) =
 104       /^MESSAGE START\s+([<>]+)\s+([^(]+)\((0x[\da-f]+)\)\s+-\s+(.+)/) {
 105     push(@message,
 106          "------------- NEXT MESSAGE: " .
 107          (($direction =~ /^>/) ? "outgoing" : "incoming") .
 108          " $type($transport) at $time\n");
 109
 110   # End of message?
 111   } elsif (($direction, $type, $transport, $time) =
 112            /^MESSAGE END\s+([<>]+)\s+([^(]+)\((0x[\da-f]+)\)\s+-\s+(.+)/) {
 113
 114     if ($Options{filter}) {
 115       print @message;
 116     } else {
 117       print STDERR "." if (++$counter % 10 == 0);
 118       AddMessage($direction, $type, $transport, $time, @message);
 119     }
 120
 121     # Done with the current message
 122     undef @message;
 123
 124   # All other lines
 125   } else {
 126
 127     # Collect message information
 128     push(@message, $_) if @message;
 129   }
 130 }
 131
 132 unless ($Options{filter}) {
 133   print STDERR "\n" unless $Options{filter};
 134   DumpMessages();
 135 }
 136
 137 # That's all folks...
 138 exit 0;
 139
 140 __END__
 141
 142 =head1 NAME
 143
 144 parse_log.pl - parse pidgin-sipe debug log
 145
 146 =head1 SYNOPSIS
 147
 148 [perl} parse_log.pl --help|-h|-?
 149
 150 [perl} parse_log.pl --filter
 151                     [file ...]
 152
 153 [perl} parse_log.pl [--directory <dir>]
 154                     [--callid]
 155                     [--from]
 156                     [--method]
 157                     [--transport]
 158                     [file ...]
 159
 160 =head1 OPTIONS
 161
 162 =over 8
 163
 164 =item B<--callid>
 165
 166 Dump all SIP messages belonging to one Call-ID to the same file.
 167
 168 =item B<--directory>
 169
 170 Directory for output files. Default is the current directory.
 171
 172 =item B<--filter>
 173
 174 Enable filter mode. Messages are simply printed to stdout.
 175
 176 =item B<--from>
 177
 178 Dump all SIP messages sent from the same SIP URI to the same file.
 179
 180 =item B<--help>
 181
 182 =item B<--h>
 183
 184 =item B<--?>
 185
 186 Print a brief help message and exits.
 187
 188 =item B<--method>
 189
 190 Dump all SIP messages with the same method to the same file.
 191
 192 =item B<--transport>
 193
 194 Dump all messages from one transport to the same file.
 195
 196 =back
 197
 198 =head1 DESCRIPTION
 199
 200 B<This program> extracts SIP/HTTP messages from pidgin-sipe debug logs. If
 201 no file is specified then it reads from STDIN.
 202
 203 =cut