configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use `VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9           m4_substr(SIPE_VERSION_DATA,
  10                     [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/tracker/?atid=949931&group_id=194563], [],
  18         SIPE_HOMEPAGE)
  19
  20 AC_DEFINE([SIPE_TRANSLATIONS_URL],
  21         ["https://www.transifex.net/projects/p/pidgin-sipe/r/mob/"],
  22         [URL for submitting translations.])
  23
  24 dnl setup automake and require recent enough version
  25 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-define tar-ustar])
  26
  27 AC_CANONICAL_HOST
  28
  29 dnl set PACKAGE_URL for autoconf < 2.64
  30 AS_IF([test "x${PACKAGE_URL}" = x],
  31         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  32          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  33 ])
  34
  35 dnl set programming language
  36 AC_LANG(C)
  37 AM_PROG_CC_C_O
  38 AC_HEADER_STDC
  39
  40 dnl setup shared library generation
  41 LT_INIT([disable-static])
  42
  43 dnl checks for tools
  44 IT_PROG_INTLTOOL([0.35.0])
  45 AC_PROG_INSTALL
  46 AC_PROG_RANLIB
  47
  48 dnl ******************************
  49 dnl Win32
  50 dnl ******************************
  51 AC_MSG_CHECKING([for Win32])
  52 AS_CASE(["$host"],
  53                 [*-mingw*], [os_win32=yes],
  54                 [os_win32=no])
  55 AC_MSG_RESULT([$os_win32])
  56 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  57
  58 dnl checks for header files
  59 AC_CHECK_HEADERS([sys/sockio.h])
  60
  61 dnl checks for library functions
  62 AC_CHECK_FUNCS([])
  63
  64 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  65 dnl as that is likely where libpurple will be found if it is not in the default
  66 dnl pkgconfig path
  67 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  68 export PKG_CONFIG_PATH
  69
  70 dnl debug mode
  71 AC_ARG_ENABLE(debug,
  72         [AS_HELP_STRING([--enable-debug],
  73                         [compile with debugging support [default=no]])],
  74         [],
  75         [enable_debug=no])
  76
  77 AS_IF([test "x$enable_debug" = xyes],
  78         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  79 AC_SUBST(DEBUG_CFLAGS)
  80
  81 dnl quality check mode
  82 dnl For people who are interested in finding bugs and not hiding them
  83 AC_ARG_ENABLE(quality-check,
  84         [AS_HELP_STRING([--enable-quality-check],
  85                         [compile with compiler checks enabled [default=yes]])],
  86         [],
  87         [enable_quality_check=yes])
  88
  89 AS_IF([test "x$enable_quality_check" = xyes],
  90         [dnl default quality configuration
  91          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  92
  93          dnl enable warnings supported by the GCC on the build system
  94          for newflag in \
  95                         "-Wextra" \
  96                         "-Waggregate-return" \
  97                         "-Wcast-align" \
  98                         "-Wdeclaration-after-statement" \
  99                         "-Winit-self" \
 100                         "-Wmissing-declarations" \
 101                         "-Wmissing-prototypes" \
 102                         "-Wnested-externs" \
 103                         "-Wpointer-arith" \
 104                         "-Wundef" \
 105                         "-Wunused-but-set-variable" \
 106          ; do
 107                  ac_save_CFLAGS=$CFLAGS
 108                  AC_MSG_CHECKING([if $CC supports $newflag])
 109                  CFLAGS="$QUALITY_CFLAGS $newflag"
 110                  AC_COMPILE_IFELSE(
 111                         [AC_LANG_SOURCE([[]])],
 112                         [AC_MSG_RESULT(yes)
 113                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 114                         [AC_MSG_RESULT(no)]
 115                  )
 116                  CFLAGS=$ac_save_CFLAGS
 117          done
 118         ])
 119 AC_SUBST(QUALITY_CFLAGS)
 120
 121 dnl Check for pkg-config before using it
 122 PKG_PROG_PKG_CONFIG
 123
 124 dnl check for valgrind (optional, only needed for debugging)
 125 PKG_CHECK_MODULES(VALGRIND, [valgrind],
 126         [AC_DEFINE(HAVE_VALGRIND, 1, [Define to 1 if you have the valgrind headers])],
 127         [AC_MSG_RESULT(no)])
 128
 129 dnl build option: with voice & video support (for all backends)
 130 AC_ARG_WITH(vv,
 131         [AC_HELP_STRING([--with-vv],
 132                 [compile with voice and video support @<:@default=check@:>@])],
 133         [AS_IF([test "x$withval" = xyes], [with_vv=check])],
 134         [with_vv=check])
 135
 136 dnl check for Kerberos 5 support
 137 AC_ARG_WITH([krb5],
 138         [AC_HELP_STRING([--with-krb5],
 139                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 140         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 141         [with_krb5=check])
 142
 143 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 144       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 145         [AC_MSG_CHECKING(if Kerberos 5 is available)
 146          AS_IF([AC_RUN_LOG([krb5-config --version])],
 147                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 148                  KRB5_LDFLAGS=""
 149
 150                  dnl same as AC_CHECK_LIB()
 151                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"
 152                  AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5)])],
 153                 [AC_MSG_RESULT(no)
 154                  with_krb5=no])],
 155       [                               dnl path specified by user
 156         KRB5_CFLAGS="-I${with_krb5}/include"
 157         KRB5_LDFLAGS="-L${with_krb5}/lib"
 158         ac_save_LDFLAGS="$LDLAGS"
 159         LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 160         AC_CHECK_LIB(krb5, krb5_rd_req,          [],
 161                 [AC_CHECK_LIB(krb5, krb5_rd_req, [],
 162                         [AC_ERROR(Kerberos 5 libraries not found)])])
 163         AC_CHECK_LIB(gssapi_krb5, gss_krb5_export_lucid_sec_context, [],
 164                         [AC_ERROR(GSSAPI Kerberos 5 libraries not found)])
 165         LDFLAGS="$ac_save_LDFLAGS"])
 166 AM_CONDITIONAL(SIP_SEC_KRB5, [test "x$with_krb5" != xno])
 167 AC_SUBST(KRB5_CFLAGS)
 168 AC_SUBST(KRB5_LDFLAGS)
 169
 170 dnl check for glib
 171 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.12.0])
 172 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.12.0])
 173
 174 dnl check for gmime
 175 dnl See also: https://bugzilla.gnome.org/show_bug.cgi?id=613653#c8
 176 PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.5.2],
 177         [ac_have_gmime=yes],
 178         [PKG_CHECK_MODULES(GMIME, [gmime-2.4 >= 2.4.16],
 179                 [ac_have_gmime=yes],
 180                 [ac_have_gmime=no])
 181 ])
 182 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 183 AS_IF([test "x$ac_have_gmime" = xyes],
 184         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 185
 186 dnl check for NSS
 187 PKG_CHECK_MODULES(NSS, [nss],
 188         [],
 189         [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 190                 [],
 191                 [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 192                         [],
 193                         [AC_ERROR([nss, mozilla-nss or microb-engine-nss package is required])])
 194         ])
 195 ])
 196
 197 dnl check for libxml2
 198 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 199
 200 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 201 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 202 ac_save_CFLAGS=$CFLAGS
 203 CFLAGS="$GLIB_CFLAGS $QUALITY_CFLAGS"
 204 dnl note the [[[ quoting: our code contains []!
 205 AC_RUN_IFELSE(
 206         [AC_LANG_PROGRAM(
 207                 [[
 208 #include <glib.h>
 209 #include <stdio.h>
 210
 211 /* Copied from uuid.c */
 212 typedef struct {
 213    guint32 time_low;
 214    guint16 time_mid;
 215    guint16 time_hi_and_version;
 216    guint8  clock_seq_hi_and_reserved;
 217    guint8  clock_seq_low;
 218    guint8  node[6];
 219 } uuid_t;
 220                 ]],
 221                 [[if (sizeof(uuid_t) == 16) {
 222                         return(0);
 223                  } else {
 224                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 225                         return(1);
 226                  }]])],
 227         [AC_MSG_RESULT(yes)],
 228         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 229
 230 Please notify the SIPE developers.
 231
 232 Copy & paste all lines starting with the line
 233
 234   checking that sizeof(uuid_t) is 16...
 235
 236 to the report and attach the file "config.log".
 237
 238 Compiler information:
 239
 240  host:     $host
 241  build:    $build
 242  compiler: $CC
 243 ])],
 244         [AC_MSG_WARN([cross compiling: not checking])])
 245 CFLAGS=$ac_save_CFLAGS
 246
 247 dnl build option: OCS2005 client hack
 248 AC_ARG_ENABLE([ocs2005-message-hack],
 249         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
 250                                                           which causes "false" not delivered error messages
 251                                                           @<:@default=no@:>@])],
 252         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
 253                    [Define to 1 to disable SIP MESSAGE timeout feature.
 254                     OCS2005 clients don't seem to acknowledge MESSAGEs and
 255                     disabling the timeout suppresses "false" error messages])])
 256
 257 dnl build option: purple backend
 258 AC_ARG_ENABLE([purple],
 259         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 260         [],
 261         [enable_purple=yes])
 262 with_purple_vv=no
 263 AS_IF([test "x$enable_purple" != xno],
 264         [PKG_CHECK_MODULES(PURPLE, [purple >= 2.4.0],
 265                 [dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 266                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion purple | cut -d. -f 1`
 267                  AC_SUBST(PURPLE_MAJOR_VERSION)
 268
 269                  dnl let user now if he has a 32- and 64-bit header conflict...
 270                  AC_MSG_CHECKING([for 32- and 64-bit header conflicts])
 271                  ac_save_CFLAGS=$CFLAGS
 272                  CFLAGS="$PURPLE_CFLAGS $QUALITY_CFLAGS"
 273                  AC_COMPILE_IFELSE(
 274                         [AC_LANG_PROGRAM([[
 275 #include <glib.h>
 276 #include <cipher.h>
 277
 278 /* Compile some code that has caused trouble in the past */
 279 static void testfunc(unsigned long len)
 280 {
 281   PurpleCipherContext *rc4 = NULL;
 282   guchar *plaintext = NULL;
 283   gsize plaintext_length = 0;
 284   guchar *encrypted_text = NULL;
 285   gsize dummy;
 286   purple_cipher_context_set_option(rc4, "key_len", GUINT_TO_POINTER(len));
 287   purple_cipher_context_encrypt(rc4, plaintext, plaintext_length,
 288                                 encrypted_text, &dummy);
 289 }
 290                                         ]],
 291                                         [[testfunc(16);]])],
 292                         [AC_MSG_RESULT(none)],
 293                         [AC_MSG_FAILURE([conflicts found.
 294
 295 Check that you have the correct glib/libpurple headers installed for
 296 your architecture or set GLIB_CFLAGS/PURPLE_CFLAGS to override the
 297 system defaults.
 298 ])
 299                         ])
 300
 301                  dnl on windows
 302                  dnl test program needs to be in the same location as libpurple
 303                  dnl installation for latter to load ssl plugin referenced by
 304                  dnl RELATIVE path.
 305                  AS_IF([test "x${os_win32}" != xyes],
 306                         [dnl purple SSL support is mandatory
 307                          AC_MSG_CHECKING([for purple SSL support])
 308                          ac_save_LIBS=$LIBS
 309                          LIBS="$PURPLE_LIBS"
 310                          AC_RUN_IFELSE(
 311                                 [AC_LANG_PROGRAM([[
 312 #include <glib.h>
 313 #include <plugin.h>
 314 #include <sslconn.h>
 315                                                 ]],
 316                                                 [[
 317         purple_plugins_init();
 318         purple_plugins_probe(G_MODULE_SUFFIX);
 319         purple_ssl_init();
 320         return(purple_ssl_is_supported()?0:1);
 321                                                 ]])],
 322                                 [AC_MSG_RESULT(ok)],
 323                                 [AC_MSG_FAILURE([your purple hasn't been compiled with SSL support.
 324 ])
 325                                 ],
 326                                 [AC_MSG_WARN([cross compiling: not checking])])
 327                  ])
 328
 329                  dnl check whether enable voice and video support
 330                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 331                        [test "x$with_vv" = xcheck],  dnl autodetect
 332                          [AC_MSG_CHECKING(for purple voice and video support)
 333                           AC_RUN_IFELSE(
 334                                 [AC_LANG_PROGRAM([[
 335 #include <media.h>
 336                                         ]],
 337                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]]
 338                                 )],
 339                                 [AC_MSG_RESULT(ok)
 340                                  PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
 341                                         dnl sipe-media.c uses g_slist_free_full()
 342                                         [PKG_CHECK_MODULES(_SIPE_MEDIA_RECHECK_PLEASE_IGNORE, [purple >= 2.8.0 glib-2.0 >= 2.28.0],
 343                                                 [PKG_CHECK_MODULES(GSTREAMER, [gstreamer-0.10],
 344                                                         [with_purple_vv=yes],
 345                                                         [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 346                                                 [AC_MSG_NOTICE(libpurple >= 2.8.0 glib2 >= 2.28.0 required: disabling purple voice and video support)])],
 347                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])],
 348                                 [AC_MSG_RESULT(no - your purple hasn't been compiled with voice and video support.)],
 349                                 [AC_MSG_WARN([cross compiling: not checking])])
 350                          ])
 351
 352                  dnl check if we have TCP media transport patches in libpurple
 353                  AS_IF([test "x$with_purple_vv" != xno],
 354                         [
 355                          AC_MSG_CHECKING(for TCP media transport)
 356                          AC_COMPILE_IFELSE(
 357                                 [AC_LANG_PROGRAM([[#include <media.h>]],[[return PURPLE_MEDIA_NETWORK_PROTOCOL_TCP_ACTIVE]])],
 358                                 [
 359                                  with_purple_tcp=yes
 360                                  AC_DEFINE(HAVE_ICE_TCP, 1, [Define if we have support for TCP media transport.])
 361                                  AC_MSG_RESULT(yes)
 362                                 ],
 363                                 [AC_MSG_RESULT(no)]
 364                          )
 365                         ])
 366
 367                  CFLAGS=$ac_save_CFLAGS
 368                  LIBS=$ac_save_LIBS],
 369                 [enable_purple=no])])
 370 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 371
 372 dnl build option: telepathy backend
 373 AC_ARG_ENABLE([telepathy],
 374         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 375         [],
 376         [enable_telepathy=yes])
 377 AS_IF([test "x$enable_telepathy" != xno],
 378         [PKG_CHECK_MODULES(TELEPATHY, [telepathy-glib],
 379                 [dnl GMIME is a build requirement
 380                  AS_IF([test "x$ac_have_gmime" = xyes],
 381                         [],
 382                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 383
 384                  dnl NOTHING IMPLEMENTED YET!!!
 385                 ],
 386                 [enable_telepathy=no])])
 387 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 388
 389 dnl sanity check
 390 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
 391         [AC_ERROR(at least one plugin must be selected
 392
 393 If you didn't use a --enable option then please check that you have
 394 the headers for the packages "purple" or "telepathy-glib" installed.
 395 )],
 396         [])
 397
 398 dnl enable voice & video support if any backend supports it
 399 AS_IF([test "x$with_purple_vv" != xno],
 400         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 401 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 402
 403 dnl i18n
 404 AC_MSG_CHECKING([locale_CPPFLAGS])
 405 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 406 AC_SUBST([LOCALE_CPPFLAGS])
 407 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 408 AM_GLIB_GNU_GETTEXT
 409 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 410
 411 dnl codeset
 412 AM_LANGINFO_CODESET
 413
 414 dnl substitutions and generated files
 415 AC_CONFIG_HEADERS([config.h])
 416 AC_CONFIG_FILES([
 417         Makefile
 418         pixmaps/Makefile
 419         m4macros/Makefile
 420         po/Makefile.in
 421         pixmaps/16/Makefile
 422         pixmaps/22/Makefile
 423         pixmaps/48/Makefile
 424         pixmaps/scalable/Makefile
 425         src/Makefile
 426         src/core/Makefile
 427         src/api/Makefile
 428         src/purple/Makefile
 429         src/telepathy/Makefile
 430         ])
 431
 432 dnl generate files
 433 AC_OUTPUT()
 434
 435 dnl additional info for the user
 436 AS_ECHO()
 437 AS_IF([test "x$enable_purple" = xno],
 438         [AS_ECHO("Not building purple plugin")],
 439         [AS_ECHO("Build purple plugin")
 440          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 441          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 442          AS_ECHO_N("Voice and video: ")
 443          AS_IF([test "x$with_purple_vv" = xno],
 444           [AS_ECHO("disabled")],
 445           [
 446            AS_ECHO_N("enabled")
 447            AS_IF([test "x$with_purple_tcp" = xyes], [AS_ECHO_N(" with TCP transport")])
 448            AS_ECHO()
 449           ])
 450         ])
 451 AS_ECHO()
 452 AS_IF([test "x$enable_telepathy" = xno],
 453         [AS_ECHO("Not building telepathy plugin")],
 454         [AS_ECHO("Build telepathy plugin")
 455          AS_ECHO()
 456          AS_ECHO("NOTHING IMPLEMENTED YET!!!")
 457          AS_ECHO()
 458          AS_ECHO("TELEPATHY_CFLAGS: $TELEPATHY_CFLAGS")
 459          AS_ECHO("TELEPATHY_LIBS  : $TELEPATHY_LIBS")])
 460 AS_ECHO()
 461 AS_IF([test "x$with_krb5" = xno],
 462         [AS_ECHO("Not building with Kerberos 5 support")],
 463         [AS_ECHO("Build with Kerberos 5 support")
 464          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 465          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 466 AS_ECHO()
 467 AS_IF([test "x$enable_debug" = xno],
 468         [AS_ECHO("Debugging not enabled")],
 469         [AS_ECHO("Build with debugging enabled")
 470          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 471 AS_ECHO()
 472 AS_IF([test "x$QUALITY_CFLAGS" = x],
 473         [AS_ECHO("Compiler checks disabled")],
 474         [AS_ECHO("Build with compiler checks enabled")
 475          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 476 AS_ECHO()
 477 AS_ECHO("configure complete. Now run 'make'")
 478 AS_ECHO()
 479
 480 dnl The End.