configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use `VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9           m4_substr(SIPE_VERSION_DATA,
  10                     [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/tracker/?atid=949931&group_id=194563], [],
  18         SIPE_HOMEPAGE)
  19
  20 dnl setup automake and require recent enough version
  21 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-define tar-ustar])
  22
  23 dnl set PACKAGE_URL for autoconf < 2.64
  24 AS_IF([test "x${PACKAGE_URL}" = x],
  25         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  26          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  27 ])
  28
  29 dnl set programming language
  30 AC_LANG(C)
  31 AM_PROG_CC_C_O
  32 AC_HEADER_STDC
  33
  34 dnl setup shared library generation
  35 LT_INIT([disable-static])
  36
  37 dnl checks for tools
  38 IT_PROG_INTLTOOL([0.35.0])
  39 AC_PROG_INSTALL
  40 AC_PROG_RANLIB
  41
  42 dnl checks for header files
  43 AC_CHECK_HEADERS([sys/sockio.h])
  44
  45 dnl checks for library functions
  46 AC_CHECK_FUNCS([])
  47
  48 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  49 dnl as that is likely where libpurple will be found if it is not in the default
  50 dnl pkgconfig path
  51 PREFIX=$ac_default_prefix
  52 AS_IF([test "x$prefix" != xNONE],
  53         [PREFIX=$prefix])
  54
  55 PKG_CONFIG_PATH="$PKG_CONFIG_PATH":"$PREFIX/lib/pkgconfig"
  56 export PKG_CONFIG_PATH
  57
  58 dnl debug mode
  59 AC_ARG_ENABLE(debug,
  60         [AS_HELP_STRING([--enable-debug],
  61                         [compile with debugging support [default=no]])],
  62         [],
  63         [enable_debug=no])
  64
  65 AS_IF([test "x$enable_debug" = xyes],
  66         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  67 AC_SUBST(DEBUG_CFLAGS)
  68
  69 dnl quality check mode
  70 dnl For people who are interested in finding bugs and not hiding them
  71 AC_ARG_ENABLE(quality-check,
  72         [AS_HELP_STRING([--enable-quality-check],
  73                         [compile with compiler checks enabled [default=yes]])],
  74         [],
  75         [enable_quality_check=yes])
  76
  77 AS_IF([test "x$enable_quality_check" = xyes],
  78         [QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  79          ac_save_CFLAGS=$CFLAGS
  80
  81          dnl GCC >= 3.4
  82          AC_MSG_CHECKING([if $CC supports -Wextra])
  83          CFLAGS="$QUALITY_CFLAGS -Wextra"
  84          AC_COMPILE_IFELSE(
  85                 AC_LANG_PROGRAM(),
  86                 [AC_MSG_RESULT(yes)
  87                  QUALITY_CFLAGS="$QUALITY_CFLAGS -Wextra"],
  88                 [AC_MSG_RESULT(no)]
  89          )
  90
  91          dnl declaration-after-statement (ISO C90 behaviour, as on Windows & GCC < 3)
  92          AC_MSG_CHECKING([if $CC supports -Werror=declaration-after-statement])
  93          CFLAGS="$QUALITY_CFLAGS -Werror=declaration-after-statement"
  94          AC_COMPILE_IFELSE(
  95                 AC_LANG_PROGRAM(),
  96                 [AC_MSG_RESULT(yes)
  97                  QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror=declaration-after-statement"],
  98                 [AC_MSG_RESULT(no)]
  99          )
 100          CFLAGS=$ac_save_CFLAGS])
 101 AC_SUBST(QUALITY_CFLAGS)
 102
 103 dnl Check for pkg-config before using it
 104 PKG_PROG_PKG_CONFIG
 105
 106 dnl check for Kerberos 5 support
 107 AC_ARG_WITH([krb5],
 108         [AC_HELP_STRING([--with-krb5],
 109                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 110         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 111         [with_krb5=check])
 112
 113 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 114       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 115         [AC_MSG_CHECKING(if Kerberos 5 is available)
 116          AS_IF([AC_RUN_LOG([krb5-config --version])],
 117                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 118                  KRB5_LDFLAGS=""
 119
 120                  dnl same as AC_CHECK_LIB()
 121                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"
 122                  AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5)])],
 123                 [AC_MSG_RESULT(no)
 124                  with_krb5=no])],
 125       [                               dnl path specified by user
 126         KRB5_CFLAGS="-I${with_krb5}/include"
 127         KRB5_LDFLAGS="-L${with_krb5}/lib"
 128         ac_save_LDFLAGS="$LDLAGS"
 129         LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 130         AC_CHECK_LIB(krb5, krb5_rd_req,          [],
 131                 [AC_CHECK_LIB(krb5, krb5_rd_req, [],
 132                         [AC_ERROR(Kerberos 5 libraries not found)])])
 133         AC_CHECK_LIB(gssapi_krb5, gss_krb5_export_lucid_sec_context, [],
 134                         [AC_ERROR(GSSAPI Kerberos 5 libraries not found)])
 135         LDFLAGS="$ac_save_LDFLAGS"])
 136 AM_CONDITIONAL(SIP_SEC_KRB5, [test "x$with_krb5" != xno])
 137 AC_SUBST(KRB5_CFLAGS)
 138 AC_SUBST(KRB5_LDFLAGS)
 139
 140 dnl check for glib
 141 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.12.0])
 142 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.12.0])
 143
 144 dnl check for gmime
 145 dnl See also: https://bugzilla.gnome.org/show_bug.cgi?id=613653#c8
 146 PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.5.2],
 147         [ac_have_gmime=yes],
 148         [PKG_CHECK_MODULES(GMIME, [gmime-2.4 >= 2.4.16],
 149                 [ac_have_gmime=yes],
 150                 [ac_have_gmime=no])
 151 ])
 152 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 153 AS_IF([test "x$ac_have_gmime" = xyes],
 154         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 155
 156 dnl check for NSS
 157 PKG_CHECK_MODULES(NSS, [nss],
 158         [ac_have_nss=yes],
 159         [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 160                 [ac_have_nss=yes],
 161                 [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 162                         [ac_have_nss=yes],
 163                         [ac_have_nss=no])
 164         ])
 165 ])
 166 AM_CONDITIONAL(SIPE_CRYPTO_NSS, [test "x$ac_have_nss" = xyes])
 167 AS_IF([test "x$ac_have_nss" = xyes],
 168         [AC_DEFINE(HAVE_NSS, 1, [Define if nss should be used in sipe.])])
 169
 170 dnl check for libxml2
 171 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 172
 173 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 174 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 175 ac_save_CFLAGS=$CFLAGS
 176 CFLAGS="$GLIB_CFLAGS $QUALITY_CFLAGS"
 177 dnl note the [[[ quoting: our code contains []!
 178 AC_RUN_IFELSE(
 179         AC_LANG_PROGRAM(
 180                 [[[
 181 #include <glib.h>
 182 #include <stdio.h>
 183
 184 /* Copied from uuid.c */
 185 typedef struct {
 186    guint32 time_low;
 187    guint16 time_mid;
 188    guint16 time_hi_and_version;
 189    guint8  clock_seq_hi_and_reserved;
 190    guint8  clock_seq_low;
 191    guint8  node[6];
 192 } uuid_t;
 193                 ]]],
 194                 [return(sizeof(uuid_t) == 16 ? 0 : 1);]),
 195         [AC_MSG_RESULT(yes)],
 196         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 197
 198 Please notify the SIPE developers and provide the following information:
 199
 200  host:     $host
 201  build:    $build
 202  compiler: $CC
 203 ])])
 204 CFLAGS=$ac_save_CFLAGS
 205
 206 dnl build option: purple backend
 207 AC_ARG_ENABLE([purple],
 208         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 209         [],
 210         [enable_purple=yes])
 211 AS_IF([test "x$enable_purple" != xno],
 212         [PKG_CHECK_MODULES(PURPLE, [purple >= 2.4.0],
 213                 [dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 214                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion purple | cut -d. -f 1`
 215                  AC_SUBST(PURPLE_MAJOR_VERSION)
 216
 217                  dnl let user now if he has a 32- and 64-bit header conflict...
 218                  AC_MSG_CHECKING([for 32- and 64-bit header conflicts])
 219                  ac_save_CFLAGS=$CFLAGS
 220                  CFLAGS="$PURPLE_CFLAGS $QUALITY_CFLAGS"
 221                  AC_COMPILE_IFELSE(
 222                         AC_LANG_PROGRAM([
 223 #include <glib.h>
 224 #include <cipher.h>
 225
 226 /* Compile some code that has caused trouble in the past */
 227 void testfunc(unsigned long len)
 228 {
 229   PurpleCipherContext *rc4 = NULL;
 230   purple_cipher_context_set_option(rc4, "key_len", GUINT_TO_POINTER(len));
 231 }
 232                                         ],
 233                                         [testfunc(16);]),
 234                         [AC_MSG_RESULT(none)],
 235                         [AC_MSG_FAILURE([conflicts found.
 236
 237 Check that you have the correct glib/libpurple headers installed for
 238 your architecture or set PURPLE_CFLAGS to override the system defaults.
 239 ])
 240                         ])
 241
 242                  dnl purple SSL support is mandatory
 243                  AC_MSG_CHECKING([for purple SSL support])
 244                  ac_save_LIBS=$LIBS
 245                  LIBS="$PURPLE_LIBS"
 246                  AC_RUN_IFELSE(
 247                         AC_LANG_PROGRAM([
 248 #include <glib.h>
 249 #include <plugin.h>
 250 #include <sslconn.h>
 251 ],
 252                                         [
 253         purple_plugins_init();
 254         purple_plugins_probe(G_MODULE_SUFFIX);
 255         purple_ssl_init();
 256         return(purple_ssl_is_supported()?0:1);
 257                                         ]),
 258                         [AC_MSG_RESULT(ok)],
 259                         [AC_MSG_FAILURE([your purple hasn't been compiled with SSL support.
 260 ])
 261                         ])
 262                  CFLAGS=$ac_save_CFLAGS
 263                  LIBS=$ac_save_LIBS],
 264                 [enable_purple=no])])
 265 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 266
 267 dnl check whether enable voice and video support
 268 AS_IF([test "x$enable_purple" = xno], [with_vv=no],
 269         [AC_ARG_WITH(vv,
 270                 [AC_HELP_STRING([--with-vv],
 271                         [compile with voice and video support @<:@default=check@:>@])],
 272                 [AS_IF([test "x$withval" = xyes], [with_vv=check])],
 273                 [with_vv=check])
 274         ])
 275
 276 AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 277       [test "x$with_vv" = xcheck],  dnl autodetect
 278         [AC_MSG_CHECKING(for purple voice and video support)
 279           ac_save_CFLAGS=$CFLAGS
 280           ac_save_LDFLAGS=$LDFLAGS
 281           CFLAGS="$PURPLE_CFLAGS $QUALITY_CFLAGS"
 282           LDFLAGS="$PURPLE_LDFLAGS $PURPLE_LIBS"
 283           AC_RUN_IFELSE(
 284             AC_LANG_PROGRAM(
 285                   [[[
 286 #include <libpurple/media.h>
 287                   ]]],
 288                   [return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]
 289                 ),
 290             [AC_MSG_RESULT(ok)
 291              AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])],
 292             [AC_MSG_RESULT(no)
 293              AC_ERROR(your purple hasn't been compiled with voice and video support.)
 294              with_vv=no]
 295           )
 296           CFLAGS=$ac_save_CFLAGS
 297           LDFLAGS=$ac_save_LDFLAGS
 298         ]
 299 )
 300 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_vv" != xno])
 301
 302 dnl build option: telepathy backend
 303 AC_ARG_ENABLE([telepathy],
 304         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 305         [],
 306         [enable_telepathy=yes])
 307 AS_IF([test "x$enable_telepathy" != xno],
 308         [PKG_CHECK_MODULES(TELEPATHY, [telepathy-glib],
 309                 [dnl GMIME is a build requirement
 310                  AS_IF([test "x$ac_have_gmime" = xyes],
 311                         [],
 312                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 313
 314                  dnl NSS is a build requirement
 315                  AS_IF([test "x$ac_have_nss" = xyes],
 316                         [],
 317                         [AC_ERROR(NSS package is required for telepathy plugin)])
 318
 319                  dnl NOTHING IMPLEMENTED YET!!!
 320                 ],
 321                 [enable_telepathy=no])])
 322 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 323
 324 dnl build option: kopete backend
 325 AC_ARG_ENABLE([kopete],
 326         [AC_HELP_STRING([--enable-kopete], [build kopete plugin @<:@default=no@:>@])],
 327         [],
 328         [enable_kopete=no])
 329 AS_IF([test "x$enable_kopete" != xno],
 330         [dnl GMIME is a build requirement
 331          AS_IF([test "x$ac_have_gmime" = xyes],
 332                 [],
 333                 [AC_ERROR(GMIME package is required for kopete plugin)])
 334
 335          dnl NSS is a build requirement
 336          AS_IF([test "x$ac_have_nss" = xyes],
 337                 [],
 338                 [AC_ERROR(NSS package is required for kopete plugin)])
 339
 340          dnl NOTHING IMPLEMENTED YET!!!
 341         ],
 342         [enable_kopete=no])
 343 AM_CONDITIONAL(SIPE_INCLUDE_KOPETE, [test "x$enable_kopete" != xno])
 344
 345 dnl sanity check
 346 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno -a "x$enable_kopete" = xno],
 347         [AC_ERROR(at least one plugin must be selected
 348
 349 If you didn't use a --enable option then please check that you have
 350 the headers for the packages "purple" or "telepathy-glib" installed.
 351 )],
 352         [])
 353
 354 dnl i18n
 355 AC_MSG_CHECKING([locale_CPPFLAGS])
 356 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(prefix)/$(DATADIRNAME)/locale\"'
 357 AC_SUBST([LOCALE_CPPFLAGS])
 358 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 359 AM_GLIB_GNU_GETTEXT
 360 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 361
 362 dnl codeset
 363 AM_LANGINFO_CODESET
 364
 365 dnl substitutions and generated files
 366 AC_CONFIG_HEADERS([config.h])
 367 AC_CONFIG_FILES([
 368         Makefile
 369         pixmaps/Makefile
 370         m4macros/Makefile
 371         po/Makefile.in
 372         pixmaps/16/Makefile
 373         pixmaps/22/Makefile
 374         pixmaps/48/Makefile
 375         pixmaps/scalable/Makefile
 376         src/Makefile
 377         src/core/Makefile
 378         src/api/Makefile
 379         src/purple/Makefile
 380         src/telepathy/Makefile
 381         src/kopete/Makefile
 382         ])
 383
 384 dnl generate files
 385 AC_OUTPUT()
 386
 387 dnl additional info for the user
 388 AS_ECHO()
 389 AS_IF([test "x$enable_purple" = xno],
 390         [AS_ECHO("Not building purple plugin")],
 391         [AS_ECHO("Build purple plugin")
 392          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 393          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 394          AS_IF([test "x$with_vv" = xno],
 395           [AS_ECHO("Voice and video: disabled")],
 396           [AS_ECHO("Voice and video: enabled")])
 397         ])
 398 AS_ECHO()
 399 AS_IF([test "x$enable_telepathy" = xno],
 400         [AS_ECHO("Not building telepathy plugin")],
 401         [AS_ECHO("Build telepathy plugin")
 402          AS_ECHO()
 403          AS_ECHO("NOTHING IMPLEMENTED YET!!!")
 404          AS_ECHO()
 405          AS_ECHO("TELEPATHY_CFLAGS: $TELEPATHY_CFLAGS")
 406          AS_ECHO("TELEPATHY_LIBS  : $TELEPATHY_LIBS")])
 407 AS_ECHO()
 408 AS_IF([test "x$enable_kopete" = xno],
 409         [AS_ECHO("Not building kopete plugin")],
 410         [AS_ECHO("Build kopete plugin")
 411          AS_ECHO()
 412          AS_ECHO("NOTHING IMPLEMENTED YET!!!")
 413          AS_ECHO()])
 414 AS_ECHO()
 415 AS_IF([test "x$with_krb5" = xno],
 416         [AS_ECHO("Not building with Kerberos 5 support")],
 417         [AS_ECHO("Build with Kerberos 5 support")
 418          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 419          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 420 AS_ECHO()
 421 AS_IF([test "x$enable_debug" = xno],
 422         [AS_ECHO("Debugging not enabled")],
 423         [AS_ECHO("Build with debugging enabled")
 424          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 425 AS_ECHO()
 426 AS_IF([test "x$QUALITY_CFLAGS" = x],
 427         [AS_ECHO("Compiler checks disabled")],
 428         [AS_ECHO("Build with compiler checks enabled")
 429          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 430 AS_ECHO()
 431 AS_ECHO("configure complete. Now run 'make'")
 432 AS_ECHO()
 433
 434 dnl The End.