configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use 'VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9         m4_substr(SIPE_VERSION_DATA,
  10                   [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/p/sipe/bugs/], [],
  18         SIPE_HOMEPAGE)
  19
  20 AC_DEFINE([SIPE_TRANSLATIONS_URL],
  21         ["https://www.transifex.com/projects/p/pidgin-sipe/r/mob/"],
  22         [URL for submitting translations.])
  23
  24 dnl define optional git commit ID generated by autogen.sh
  25 m4_define([SIPE_GIT_COMMIT], m4_sinclude([GITVERSION]))
  26 AS_IF([test "x"SIPE_GIT_COMMIT != x],
  27         [AC_MSG_NOTICE([set git commit])
  28          AC_DEFINE(PACKAGE_GIT_COMMIT, "SIPE_GIT_COMMIT", [Define to the git commit for this package.])
  29 ])
  30
  31 dnl setup automake and require recent enough version
  32 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-define tar-ustar])
  33
  34 AC_CANONICAL_HOST
  35
  36 dnl set PACKAGE_URL for autoconf < 2.64
  37 AS_IF([test "x${PACKAGE_URL}" = x],
  38         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  39          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  40 ])
  41
  42 dnl set programming language
  43 AC_LANG(C)
  44 AM_PROG_CC_C_O
  45 AC_HEADER_STDC
  46
  47 dnl setup shared library generation
  48 LT_INIT([disable-static])
  49
  50 dnl checks for tools
  51 IT_PROG_INTLTOOL([0.35.0])
  52 AC_PROG_INSTALL
  53 AC_PROG_RANLIB
  54
  55 dnl ******************************
  56 dnl Win32
  57 dnl ******************************
  58 AC_MSG_CHECKING([for Win32])
  59 AS_CASE(["$host"],
  60                 [*-mingw*], [os_win32=yes],
  61                 [os_win32=no])
  62 AC_MSG_RESULT([$os_win32])
  63 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  64
  65 dnl checks for header files
  66 AC_CHECK_HEADERS([sys/sockio.h])
  67
  68 dnl checks for library functions
  69 AC_CHECK_FUNCS([])
  70
  71 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  72 dnl as that is likely where libpurple will be found if it is not in the default
  73 dnl pkgconfig path
  74 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  75 export PKG_CONFIG_PATH
  76
  77 dnl debug mode
  78 AC_ARG_ENABLE(debug,
  79         [AS_HELP_STRING([--enable-debug],
  80                         [compile with debugging support @<:@default=no@:>@])],
  81         [],
  82         [enable_debug=no])
  83
  84 AS_IF([test "x$enable_debug" = xyes],
  85         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  86 AC_SUBST(DEBUG_CFLAGS)
  87
  88 dnl quality check mode
  89 dnl For people who are interested in finding bugs and not hiding them
  90 AC_ARG_ENABLE(quality-check,
  91         [AS_HELP_STRING([--enable-quality-check],
  92                         [compile with compiler checks enabled @<:@default=yes@:>@])],
  93         [],
  94         [enable_quality_check=yes])
  95
  96 AS_IF([test "x$enable_quality_check" = xyes],
  97         [dnl default quality configuration
  98          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  99
 100          dnl enable warnings supported by the GCC on the build system
 101          for newflag in \
 102                         "-Wextra" \
 103                         "-Waggregate-return" \
 104                         "-Wcast-align" \
 105                         "-Wdeclaration-after-statement" \
 106                         "-Wdeprecated-declarations" \
 107                         "-Winit-self" \
 108                         "-Wmaybe-uninitialized" \
 109                         "-Wmissing-declarations" \
 110                         "-Wmissing-prototypes" \
 111                         "-Wnested-externs" \
 112                         "-Wpointer-arith" \
 113                         "-Wundef" \
 114                         "-Wunused-but-set-variable" \
 115          ; do
 116                  ac_save_CFLAGS=$CFLAGS
 117                  AC_MSG_CHECKING([if $CC supports $newflag])
 118                  CFLAGS="$QUALITY_CFLAGS $newflag"
 119                  AC_COMPILE_IFELSE(
 120                         [AC_LANG_SOURCE([[]])],
 121                         [AC_MSG_RESULT(yes)
 122                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 123                         [AC_MSG_RESULT(no)]
 124                  )
 125                  CFLAGS=$ac_save_CFLAGS
 126          done
 127         ])
 128 AC_SUBST(QUALITY_CFLAGS)
 129
 130 dnl Check for pkg-config before using it
 131 PKG_PROG_PKG_CONFIG
 132
 133 dnl check for valgrind (optional, only needed for debugging)
 134 PKG_CHECK_MODULES(VALGRIND, [valgrind],
 135         [AC_DEFINE(HAVE_VALGRIND, 1, [Define to 1 if you have the valgrind headers])],
 136         [AC_MSG_RESULT(no)])
 137
 138 dnl build option: with voice & video support (for all backends)
 139 AC_ARG_WITH(vv,
 140         [AC_HELP_STRING([--with-vv],
 141                 [compile with voice and video support @<:@default=check@:>@])],
 142         [AS_IF([test "x$withval" = xyes], [with_vv=check])],
 143         [with_vv=check])
 144
 145 dnl check for Kerberos 5 support
 146 AC_ARG_WITH([krb5],
 147         [AC_HELP_STRING([--with-krb5],
 148                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 149         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 150         [with_krb5=check])
 151
 152 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 153       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 154         [AC_MSG_CHECKING(if Kerberos 5 is available)
 155          AS_IF([AC_RUN_LOG([krb5-config --version])],
 156                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 157                  KRB5_LDFLAGS=""
 158
 159                  dnl same as AC_CHECK_LIB()
 160                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"],
 161                 [AC_MSG_RESULT(no)
 162                  with_krb5=no])],
 163       [                               dnl path specified by user
 164         KRB5_CFLAGS="-I${with_krb5}/include"
 165         KRB5_LDFLAGS="-L${with_krb5}/lib"
 166       ])
 167 AS_IF([test "x$with_krb5" != xno],
 168       [ac_save_CFLAGS="$CFLAGS"
 169        ac_save_LDFLAGS="$LDLAGS"
 170        CFLAGS="$CFLAGS $KRB5_CFLAGS"
 171        LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 172        AC_CHECK_HEADERS([gssapi/gssapi.h gssapi/gssapi_krb5.h],
 173                         [],
 174                         [AC_ERROR([GSSAPI headers not found])])
 175        AC_CHECK_FUNC([gss_init_sec_context],
 176                      [],
 177                      [AC_ERROR([GSSAPI libraries not found])])
 178
 179        dnl older GSSAPI releases don't have gss_acquire_cred_with_passwd()
 180        AC_CHECK_HEADER([gssapi/gssapi_ext.h],
 181                        [AC_CHECK_FUNC([gss_acquire_cred_with_password],
 182                                       [AC_DEFINE(HAVE_GSSAPI_PASSWORD_SUPPORT, 1, [Define to 1 if gssapi has gss_acquire_cred_with_passwd()])],
 183                                       [AC_MSG_NOTICE([gss_acquire_cred_with_passwd() required: disabling GSSAPI non-SSO support])])],
 184                        [AC_MSG_NOTICE([gssapi/gssapi_ext.h required: disabling GSSAPI non-SSO support])])
 185
 186        CFLAGS="$ac_save_CFLAGS"
 187        LDFLAGS="$ac_save_LDFLAGS"
 188       ])
 189
 190 AM_CONDITIONAL(SIP_SEC_GSSAPI, [test "x$with_krb5" != xno])
 191 AC_SUBST(KRB5_CFLAGS)
 192 AC_SUBST(KRB5_LDFLAGS)
 193
 194 AC_ARG_ENABLE(gssapi_only,
 195         [AS_HELP_STRING([--enable-gssapi-only],
 196                         [disable all internal authentication code and only use
 197                          GSSAPI for authentication @<:@default=yes@:>@])],
 198         [],
 199         dnl requires Kerberos which provides GSSAPI
 200         [enable_gssapi_only=$with_krb5])
 201 AS_IF([test "x$enable_gssapi_only" != xno],
 202         [AC_CHECK_HEADER([gssapi/gssapi_ntlmssp.h],
 203                        [AC_DEFINE(HAVE_GSSAPI_ONLY, 1, [Define to 1 to enable GSSAPI-only mode])],
 204                        [AC_MSG_NOTICE([gssapi/gssapi_ntlm.h required: falling back to internal authentication implementation])
 205                         enable_gssapi_only=no])
 206         ])
 207 AM_CONDITIONAL(SIP_SEC_GSSAPI_ONLY, [test "x$enable_gssapi_only" != xno])
 208
 209 dnl check for glib
 210 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.12.0])
 211 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.12.0])
 212
 213 dnl check for gmime
 214 dnl See also: https://bugzilla.gnome.org/show_bug.cgi?id=613653#c8
 215 PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.5.2],
 216         [ac_have_gmime=yes],
 217         [PKG_CHECK_MODULES(GMIME, [gmime-2.4 >= 2.4.16],
 218                 [ac_have_gmime=yes],
 219                 [ac_have_gmime=no])
 220 ])
 221 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 222 AS_IF([test "x$ac_have_gmime" = xyes],
 223         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 224
 225 dnl check for NSS
 226 PKG_CHECK_MODULES(NSS, [nss],
 227         [],
 228         [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 229                 [],
 230                 [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 231                         [],
 232                         [AC_ERROR([nss, mozilla-nss or microb-engine-nss package is required])])
 233         ])
 234 ])
 235
 236 dnl check for OpenSSL - TEMPORARY for development
 237 PKG_CHECK_MODULES(OPENSSL, [libcrypto],
 238         [ac_have_openssl=yes],
 239         [ac_have_openssl=no])
 240 AM_CONDITIONAL(SIPE_OPENSSL, [test "x$ac_have_openssl" = xyes])
 241
 242 dnl check for libxml2
 243 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 244
 245 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 246 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 247 ac_save_CFLAGS=$CFLAGS
 248 CFLAGS="$GLIB_CFLAGS $QUALITY_CFLAGS"
 249 dnl note the [[[ quoting: our code contains []!
 250 AC_RUN_IFELSE(
 251         [AC_LANG_PROGRAM(
 252                 [[
 253 #include <glib.h>
 254 #include <stdio.h>
 255
 256 /* Copied from uuid.c */
 257 typedef struct {
 258    guint32 time_low;
 259    guint16 time_mid;
 260    guint16 time_hi_and_version;
 261    guint8  clock_seq_hi_and_reserved;
 262    guint8  clock_seq_low;
 263    guint8  node[6];
 264 } uuid_t;
 265                 ]],
 266                 [[if (sizeof(uuid_t) == 16) {
 267                         return(0);
 268                  } else {
 269                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 270                         return(1);
 271                  }]])],
 272         [AC_MSG_RESULT(yes)],
 273         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 274
 275 Please notify the SIPE developers.
 276
 277 Copy & paste all lines starting with the line
 278
 279   checking that sizeof(uuid_t) is 16...
 280
 281 to the report and attach the file "config.log".
 282
 283 Compiler information:
 284
 285  host:     $host
 286  build:    $build
 287  compiler: $CC
 288 ])],
 289         [AC_MSG_WARN([cross compiling: not checking])])
 290 CFLAGS=$ac_save_CFLAGS
 291
 292 dnl build option: OCS2005 client hack
 293 AC_ARG_ENABLE([ocs2005-message-hack],
 294         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
 295                                                           which causes "false" not delivered error messages
 296                                                           @<:@default=no@:>@])],
 297         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
 298                    [Define to 1 to disable SIP MESSAGE timeout feature.
 299                     OCS2005 clients don't seem to acknowledge MESSAGEs and
 300                     disabling the timeout suppresses "false" error messages])])
 301
 302 dnl build option: purple backend
 303 AC_ARG_ENABLE([purple],
 304         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 305         [],
 306         [enable_purple=yes])
 307 with_purple_vv=no
 308 AS_IF([test "x$enable_purple" != xno],
 309         [PKG_CHECK_MODULES(PURPLE, [purple >= 2.4.0],
 310                 [dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 311                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion purple | cut -d. -f 1`
 312                  AC_SUBST(PURPLE_MAJOR_VERSION)
 313
 314                  dnl let user now if he has a 32- and 64-bit header conflict...
 315                  AC_MSG_CHECKING([for 32- and 64-bit header conflicts])
 316                  ac_save_CFLAGS=$CFLAGS
 317                  CFLAGS="$PURPLE_CFLAGS $QUALITY_CFLAGS"
 318                  AC_COMPILE_IFELSE(
 319                         [AC_LANG_PROGRAM([[
 320 #include <unistd.h>
 321 #include <glib.h>
 322 #include <cipher.h>
 323 #include <version.h>
 324
 325 /* Compile some code that has caused trouble in the past */
 326 static void testfunc(unsigned long len)
 327 {
 328   PurpleCipherContext *rc4 = NULL;
 329   guchar *plaintext = NULL;
 330   gsize plaintext_length = 0;
 331   guchar *encrypted_text = NULL;
 332   gsize dummy = 0;
 333   purple_cipher_context_set_option(rc4, "key_len", GUINT_TO_POINTER(len));
 334   purple_cipher_context_encrypt(rc4, plaintext, plaintext_length,
 335                                 encrypted_text,
 336 #if PURPLE_VERSION_CHECK(3,0,0)
 337                                 dummy);
 338 #else
 339                                 &dummy);
 340 #endif
 341 }
 342                                         ]],
 343                                         [[testfunc(16);]])],
 344                         [AC_MSG_RESULT(none)],
 345                         [AC_MSG_FAILURE([conflicts found.
 346
 347 Check that you have the correct glib/libpurple headers installed for
 348 your architecture or set GLIB_CFLAGS/PURPLE_CFLAGS to override the
 349 system defaults.
 350 ])
 351                         ])
 352
 353                  dnl on windows
 354                  dnl test program needs to be in the same location as libpurple
 355                  dnl installation for latter to load ssl plugin referenced by
 356                  dnl RELATIVE path.
 357                  AS_IF([test "x${os_win32}" != xyes],
 358                         [dnl purple SSL support is mandatory
 359                          AC_MSG_CHECKING([for purple SSL support])
 360                          ac_save_LIBS=$LIBS
 361                          LIBS="$PURPLE_LIBS"
 362                          AC_RUN_IFELSE(
 363                                 [AC_LANG_PROGRAM([[
 364 #include <glib.h>
 365 #include <plugin.h>
 366 #include <sslconn.h>
 367                                                 ]],
 368                                                 [[
 369         purple_plugins_init();
 370         purple_plugins_probe(G_MODULE_SUFFIX);
 371         purple_ssl_init();
 372         return(purple_ssl_is_supported()?0:1);
 373                                                 ]])],
 374                                 [AC_MSG_RESULT(ok)],
 375                                 [AC_MSG_FAILURE([your purple hasn't been compiled with SSL support.
 376 ])
 377                                 ],
 378                                 [AC_MSG_WARN([cross compiling: not checking])])
 379                  ])
 380
 381                  dnl check whether enable voice and video support
 382                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 383                        [test "x$with_vv" = xcheck],  dnl autodetect
 384                          [AC_MSG_CHECKING(for purple voice and video support)
 385                           AC_RUN_IFELSE(
 386                                 [AC_LANG_PROGRAM([[
 387 #include <media.h>
 388                                         ]],
 389                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]]
 390                                 )],
 391                                 [AC_MSG_RESULT(ok)
 392                                  PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
 393                                         dnl sipe-media.c uses g_slist_free_full()
 394                                         [PKG_CHECK_MODULES(_SIPE_MEDIA_RECHECK_PLEASE_IGNORE, [purple >= 2.8.0],
 395                                                 [PKG_CHECK_MODULES(GSTREAMER, [gstreamer-0.10],
 396                                                         [with_purple_vv=yes],
 397                                                         [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 398                                                 [AC_MSG_NOTICE(libpurple >= 2.8.0 required: disabling purple voice and video support)])],
 399                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])],
 400                                 [AC_MSG_RESULT(no - your purple hasn't been compiled with voice and video support.)],
 401                                 [AC_MSG_WARN([cross compiling: not checking])])
 402                          ])
 403
 404                  dnl check if we have TCP media transport patches in libpurple
 405                  AS_IF([test "x$with_purple_vv" != xno],
 406                         [
 407                          AC_MSG_CHECKING(for TCP media transport)
 408                          AC_COMPILE_IFELSE(
 409                                 [AC_LANG_PROGRAM([[#include <media.h>]],[[return PURPLE_MEDIA_NETWORK_PROTOCOL_TCP_ACTIVE]])],
 410                                 [
 411                                  with_purple_tcp=yes
 412                                  AC_DEFINE(HAVE_ICE_TCP, 1, [Define if we have support for TCP media transport.])
 413                                  AC_MSG_RESULT(yes)
 414                                 ],
 415                                 [AC_MSG_RESULT(no)]
 416                          )
 417                         ])
 418
 419                  CFLAGS=$ac_save_CFLAGS
 420                  LIBS=$ac_save_LIBS],
 421                 [enable_purple=no])])
 422 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 423
 424 dnl build option: telepathy backend
 425 AC_ARG_ENABLE([telepathy],
 426         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 427         [],
 428         [enable_telepathy=yes])
 429 AS_IF([test "x$enable_telepathy" != xno],
 430         [PKG_CHECK_MODULES(TELEPATHY_GLIB, [telepathy-glib >= 0.18.0],
 431                 [dnl GMIME is a build requirement
 432                  AS_IF([test "x$ac_have_gmime" = xyes],
 433                         [],
 434                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 435
 436                  dnl telepathy is based on GObject & D-Bus GLib
 437                  PKG_CHECK_MODULES(GOBJECT, [gobject-2.0])
 438                  PKG_CHECK_MODULES(DBUS_GLIB, [dbus-glib-1])
 439
 440                  dnl telepathy uses from gio:
 441                  dnl  - GIOStream      (>= 2.22.0)
 442                  dnl  - GResolver      (>= 2.22.0)
 443                  dnl  - GSocketClient  (>= 2.32.0)
 444                  dnl  - GTlsConnection (>= 2.28.0)
 445                  PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.32.0])
 446
 447                 ],
 448                 [enable_telepathy=no])])
 449 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 450
 451 dnl sanity check
 452 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
 453         [AC_ERROR(at least one plugin must be selected
 454
 455 If you didn't use a --enable option then please check that you have
 456 the headers for the packages "purple" or "telepathy-glib" installed.
 457 )],
 458         [])
 459
 460 dnl enable voice & video support if any backend supports it
 461 AS_IF([test "x$with_purple_vv" != xno],
 462         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 463 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 464
 465 dnl these code parts rely on interfaces that require GValueArray. This
 466 dnl type has been declared "deprectated" in glib-2.0 >= 2.32.0, but there
 467 dnl is no backward compatible replacement implementation possible
 468 AS_IF([test "x$with_purple_vv" != xno -o "x$enable_telepathy" != xno],
 469         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_28,
 470                    [We need GValueArray for which no replacement is available])])
 471
 472 dnl i18n
 473 AC_MSG_CHECKING([locale_CPPFLAGS])
 474 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 475 AC_SUBST([LOCALE_CPPFLAGS])
 476 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 477 AM_GLIB_GNU_GETTEXT
 478 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 479
 480 dnl codeset
 481 AM_LANGINFO_CODESET
 482
 483 dnl substitutions and generated files
 484 AC_CONFIG_HEADERS([config.h])
 485 AC_CONFIG_FILES([
 486         Makefile
 487         pixmaps/Makefile
 488         m4macros/Makefile
 489         po/Makefile.in
 490         pixmaps/16/Makefile
 491         pixmaps/22/Makefile
 492         pixmaps/24/Makefile
 493         pixmaps/32/Makefile
 494         pixmaps/48/Makefile
 495         pixmaps/scalable/Makefile
 496         src/Makefile
 497         src/core/Makefile
 498         src/api/Makefile
 499         src/purple/Makefile
 500         src/telepathy/Makefile
 501         src/telepathy/data/Makefile
 502         ])
 503
 504 dnl generate files
 505 AC_OUTPUT()
 506
 507 dnl additional info for the user
 508 AS_ECHO()
 509 AS_IF([test "x$enable_purple" = xno],
 510         [AS_ECHO("Not building purple plugin")],
 511         [AS_ECHO("Build purple plugin")
 512          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 513          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 514          AS_ECHO_N("Voice and video: ")
 515          AS_IF([test "x$with_purple_vv" = xno],
 516           [AS_ECHO("disabled")],
 517           [
 518            AS_ECHO_N("enabled")
 519            AS_IF([test "x$with_purple_tcp" = xyes], [AS_ECHO_N(" with TCP transport")])
 520            AS_ECHO()
 521           ])
 522         ])
 523 AS_ECHO()
 524 AS_IF([test "x$enable_telepathy" = xno],
 525         [AS_ECHO("Not building telepathy plugin")],
 526         [AS_ECHO("Build telepathy plugin")
 527          AS_ECHO("TELEPATHY_GLIB_CFLAGS: $TELEPATHY_GLIB_CFLAGS")
 528          AS_ECHO("TELEPATHY_GLIB_LIBS  : $TELEPATHY_GLIB_LIBS")])
 529 AS_ECHO()
 530 AS_IF([test "x$with_krb5" = xno],
 531         [AS_ECHO("Not building with Kerberos 5 support")],
 532         [AS_ECHO("Build with Kerberos 5 support")
 533          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 534          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 535 AS_ECHO()
 536 AS_IF([test "x$enable_gssapi_only" = xno],
 537         [AS_ECHO("Using internal authentication implementation")],
 538         [AS_ECHO("Using only GSSAPI for authentication")])
 539 AS_ECHO()
 540 AS_IF([test "x$enable_debug" = xno],
 541         [AS_ECHO("Debugging not enabled")],
 542         [AS_ECHO("Build with debugging enabled")
 543          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 544 AS_ECHO()
 545 AS_IF([test "x$QUALITY_CFLAGS" = x],
 546         [AS_ECHO("Compiler checks disabled")],
 547         [AS_ECHO("Build with compiler checks enabled")
 548          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 549 AS_ECHO()
 550 AS_ECHO("configure complete. Now run 'make'")
 551 AS_ECHO()
 552
 553 dnl The End.