configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use 'VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9         m4_substr(SIPE_VERSION_DATA,
  10                   [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/p/sipe/bugs/], [],
  18         SIPE_HOMEPAGE)
  19
  20 AC_DEFINE([SIPE_TRANSLATIONS_URL],
  21         ["https://www.transifex.com/projects/p/pidgin-sipe/r/mob/"],
  22         [URL for submitting translations.])
  23
  24 dnl define optional git commit ID generated by autogen.sh
  25 m4_define([SIPE_GIT_COMMIT], m4_sinclude([GITVERSION]))
  26 AS_IF([test "x"SIPE_GIT_COMMIT != x],
  27         [AC_MSG_NOTICE([set git commit])
  28          AC_DEFINE(PACKAGE_GIT_COMMIT, "SIPE_GIT_COMMIT", [Define to the git commit for this package.])
  29 ])
  30
  31 dnl setup automake and require recent enough version
  32 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-define tar-ustar])
  33
  34 AC_CANONICAL_HOST
  35
  36 dnl set PACKAGE_URL for autoconf < 2.64
  37 AS_IF([test "x${PACKAGE_URL}" = x],
  38         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  39          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  40 ])
  41
  42 dnl set programming language
  43 AC_LANG(C)
  44 AM_PROG_CC_C_O
  45 AC_HEADER_STDC
  46
  47 dnl setup shared library generation
  48 LT_INIT([disable-static])
  49
  50 dnl checks for tools
  51 IT_PROG_INTLTOOL([0.35.0])
  52 AC_PROG_INSTALL
  53 AC_PROG_RANLIB
  54
  55 dnl ******************************
  56 dnl Win32
  57 dnl ******************************
  58 AC_MSG_CHECKING([for Win32])
  59 AS_CASE(["$host"],
  60                 [*-mingw*], [os_win32=yes],
  61                 [os_win32=no])
  62 AC_MSG_RESULT([$os_win32])
  63 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  64
  65 dnl checks for header files
  66 AC_CHECK_HEADERS([sys/sockio.h])
  67
  68 dnl checks for library functions
  69 AC_CHECK_FUNCS([])
  70
  71 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  72 dnl as that is likely where libpurple will be found if it is not in the default
  73 dnl pkgconfig path
  74 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  75 export PKG_CONFIG_PATH
  76
  77 dnl debug mode
  78 AC_ARG_ENABLE(debug,
  79         [AS_HELP_STRING([--enable-debug],
  80                         [compile with debugging support [default=no]])],
  81         [],
  82         [enable_debug=no])
  83
  84 AS_IF([test "x$enable_debug" = xyes],
  85         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  86 AC_SUBST(DEBUG_CFLAGS)
  87
  88 dnl quality check mode
  89 dnl For people who are interested in finding bugs and not hiding them
  90 AC_ARG_ENABLE(quality-check,
  91         [AS_HELP_STRING([--enable-quality-check],
  92                         [compile with compiler checks enabled [default=yes]])],
  93         [],
  94         [enable_quality_check=yes])
  95
  96 AS_IF([test "x$enable_quality_check" = xyes],
  97         [dnl default quality configuration
  98          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  99
 100          dnl enable warnings supported by the GCC on the build system
 101          for newflag in \
 102                         "-Wextra" \
 103                         "-Waggregate-return" \
 104                         "-Wcast-align" \
 105                         "-Wdeclaration-after-statement" \
 106                         "-Wdeprecated-declarations" \
 107                         "-Winit-self" \
 108                         "-Wmaybe-uninitialized" \
 109                         "-Wmissing-declarations" \
 110                         "-Wmissing-prototypes" \
 111                         "-Wnested-externs" \
 112                         "-Wpointer-arith" \
 113                         "-Wundef" \
 114                         "-Wunused-but-set-variable" \
 115          ; do
 116                  ac_save_CFLAGS=$CFLAGS
 117                  AC_MSG_CHECKING([if $CC supports $newflag])
 118                  CFLAGS="$QUALITY_CFLAGS $newflag"
 119                  AC_COMPILE_IFELSE(
 120                         [AC_LANG_SOURCE([[]])],
 121                         [AC_MSG_RESULT(yes)
 122                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 123                         [AC_MSG_RESULT(no)]
 124                  )
 125                  CFLAGS=$ac_save_CFLAGS
 126          done
 127         ])
 128 AC_SUBST(QUALITY_CFLAGS)
 129
 130 dnl Check for pkg-config before using it
 131 PKG_PROG_PKG_CONFIG
 132
 133 dnl check for valgrind (optional, only needed for debugging)
 134 PKG_CHECK_MODULES(VALGRIND, [valgrind],
 135         [AC_DEFINE(HAVE_VALGRIND, 1, [Define to 1 if you have the valgrind headers])],
 136         [AC_MSG_RESULT(no)])
 137
 138 dnl build option: with voice & video support (for all backends)
 139 AC_ARG_WITH(vv,
 140         [AC_HELP_STRING([--with-vv],
 141                 [compile with voice and video support @<:@default=check@:>@])],
 142         [AS_IF([test "x$withval" = xyes], [with_vv=check])],
 143         [with_vv=check])
 144
 145 dnl check for Kerberos 5 support
 146 AC_ARG_WITH([krb5],
 147         [AC_HELP_STRING([--with-krb5],
 148                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 149         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 150         [with_krb5=check])
 151
 152 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 153       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 154         [AC_MSG_CHECKING(if Kerberos 5 is available)
 155          AS_IF([AC_RUN_LOG([krb5-config --version])],
 156                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 157                  KRB5_LDFLAGS=""
 158
 159                  dnl same as AC_CHECK_LIB()
 160                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"],
 161                 [AC_MSG_RESULT(no)
 162                  with_krb5=no])],
 163       [                               dnl path specified by user
 164         KRB5_CFLAGS="-I${with_krb5}/include"
 165         KRB5_LDFLAGS="-L${with_krb5}/lib"
 166       ])
 167 AS_IF([test "x$with_krb5" != xno],
 168       [ac_save_CFLAGS="$CFLAGS"
 169        ac_save_LDFLAGS="$LDLAGS"
 170        CFLAGS="$CFLAGS $KRB5_CFLAGS"
 171        LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 172        AC_CHECK_HEADERS([gssapi/gssapi.h gssapi/gssapi_krb5.h],
 173                         ,
 174                         [AC_ERROR([GSSAPI headers not found])])
 175        AC_CHECK_FUNC([gss_init_sec_context],
 176                      ,
 177                      [AC_ERROR([GSSAPI libraries not found])])
 178        AC_CHECK_HEADER([gssapi/gssapi_ext.h],
 179                         AC_CHECK_FUNC([gss_acquire_cred_with_password],
 180                                       [AC_DEFINE(HAVE_GSSAPI_PASSWORD_SUPPORT, 1, [Define to 1 if gssapi has gss_acquire_cred_with_passwd()])],
 181                                       [AC_MSG_NOTICE([gss_acquire_cred_with_passwd() required: disabling GSSAPI non-SSO support])]))
 182        CFLAGS="$ac_save_CFLAGS"
 183        LDFLAGS="$ac_save_LDFLAGS"
 184       ])
 185
 186 AM_CONDITIONAL(SIP_SEC_KRB5, [test "x$with_krb5" != xno])
 187 AC_SUBST(KRB5_CFLAGS)
 188 AC_SUBST(KRB5_LDFLAGS)
 189
 190 dnl check for glib
 191 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.12.0])
 192 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.12.0])
 193
 194 dnl check for gmime
 195 dnl See also: https://bugzilla.gnome.org/show_bug.cgi?id=613653#c8
 196 PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.5.2],
 197         [ac_have_gmime=yes],
 198         [PKG_CHECK_MODULES(GMIME, [gmime-2.4 >= 2.4.16],
 199                 [ac_have_gmime=yes],
 200                 [ac_have_gmime=no])
 201 ])
 202 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 203 AS_IF([test "x$ac_have_gmime" = xyes],
 204         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 205
 206 dnl check for NSS
 207 PKG_CHECK_MODULES(NSS, [nss],
 208         [],
 209         [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 210                 [],
 211                 [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 212                         [],
 213                         [AC_ERROR([nss, mozilla-nss or microb-engine-nss package is required])])
 214         ])
 215 ])
 216
 217 dnl check for libxml2
 218 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 219
 220 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 221 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 222 ac_save_CFLAGS=$CFLAGS
 223 CFLAGS="$GLIB_CFLAGS $QUALITY_CFLAGS"
 224 dnl note the [[[ quoting: our code contains []!
 225 AC_RUN_IFELSE(
 226         [AC_LANG_PROGRAM(
 227                 [[
 228 #include <glib.h>
 229 #include <stdio.h>
 230
 231 /* Copied from uuid.c */
 232 typedef struct {
 233    guint32 time_low;
 234    guint16 time_mid;
 235    guint16 time_hi_and_version;
 236    guint8  clock_seq_hi_and_reserved;
 237    guint8  clock_seq_low;
 238    guint8  node[6];
 239 } uuid_t;
 240                 ]],
 241                 [[if (sizeof(uuid_t) == 16) {
 242                         return(0);
 243                  } else {
 244                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 245                         return(1);
 246                  }]])],
 247         [AC_MSG_RESULT(yes)],
 248         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 249
 250 Please notify the SIPE developers.
 251
 252 Copy & paste all lines starting with the line
 253
 254   checking that sizeof(uuid_t) is 16...
 255
 256 to the report and attach the file "config.log".
 257
 258 Compiler information:
 259
 260  host:     $host
 261  build:    $build
 262  compiler: $CC
 263 ])],
 264         [AC_MSG_WARN([cross compiling: not checking])])
 265 CFLAGS=$ac_save_CFLAGS
 266
 267 dnl build option: OCS2005 client hack
 268 AC_ARG_ENABLE([ocs2005-message-hack],
 269         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
 270                                                           which causes "false" not delivered error messages
 271                                                           @<:@default=no@:>@])],
 272         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
 273                    [Define to 1 to disable SIP MESSAGE timeout feature.
 274                     OCS2005 clients don't seem to acknowledge MESSAGEs and
 275                     disabling the timeout suppresses "false" error messages])])
 276
 277 dnl build option: purple backend
 278 AC_ARG_ENABLE([purple],
 279         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 280         [],
 281         [enable_purple=yes])
 282 with_purple_vv=no
 283 AS_IF([test "x$enable_purple" != xno],
 284         [PKG_CHECK_MODULES(PURPLE, [purple >= 2.4.0],
 285                 [dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 286                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion purple | cut -d. -f 1`
 287                  AC_SUBST(PURPLE_MAJOR_VERSION)
 288
 289                  dnl let user now if he has a 32- and 64-bit header conflict...
 290                  AC_MSG_CHECKING([for 32- and 64-bit header conflicts])
 291                  ac_save_CFLAGS=$CFLAGS
 292                  CFLAGS="$PURPLE_CFLAGS $QUALITY_CFLAGS"
 293                  AC_COMPILE_IFELSE(
 294                         [AC_LANG_PROGRAM([[
 295 #include <unistd.h>
 296 #include <glib.h>
 297 #include <cipher.h>
 298 #include <version.h>
 299
 300 /* Compile some code that has caused trouble in the past */
 301 static void testfunc(unsigned long len)
 302 {
 303   PurpleCipherContext *rc4 = NULL;
 304   guchar *plaintext = NULL;
 305   gsize plaintext_length = 0;
 306   guchar *encrypted_text = NULL;
 307   gsize dummy = 0;
 308   purple_cipher_context_set_option(rc4, "key_len", GUINT_TO_POINTER(len));
 309   purple_cipher_context_encrypt(rc4, plaintext, plaintext_length,
 310                                 encrypted_text,
 311 #if PURPLE_VERSION_CHECK(3,0,0)
 312                                 dummy);
 313 #else
 314                                 &dummy);
 315 #endif
 316 }
 317                                         ]],
 318                                         [[testfunc(16);]])],
 319                         [AC_MSG_RESULT(none)],
 320                         [AC_MSG_FAILURE([conflicts found.
 321
 322 Check that you have the correct glib/libpurple headers installed for
 323 your architecture or set GLIB_CFLAGS/PURPLE_CFLAGS to override the
 324 system defaults.
 325 ])
 326                         ])
 327
 328                  dnl on windows
 329                  dnl test program needs to be in the same location as libpurple
 330                  dnl installation for latter to load ssl plugin referenced by
 331                  dnl RELATIVE path.
 332                  AS_IF([test "x${os_win32}" != xyes],
 333                         [dnl purple SSL support is mandatory
 334                          AC_MSG_CHECKING([for purple SSL support])
 335                          ac_save_LIBS=$LIBS
 336                          LIBS="$PURPLE_LIBS"
 337                          AC_RUN_IFELSE(
 338                                 [AC_LANG_PROGRAM([[
 339 #include <glib.h>
 340 #include <plugin.h>
 341 #include <sslconn.h>
 342                                                 ]],
 343                                                 [[
 344         purple_plugins_init();
 345         purple_plugins_probe(G_MODULE_SUFFIX);
 346         purple_ssl_init();
 347         return(purple_ssl_is_supported()?0:1);
 348                                                 ]])],
 349                                 [AC_MSG_RESULT(ok)],
 350                                 [AC_MSG_FAILURE([your purple hasn't been compiled with SSL support.
 351 ])
 352                                 ],
 353                                 [AC_MSG_WARN([cross compiling: not checking])])
 354                  ])
 355
 356                  dnl check whether enable voice and video support
 357                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 358                        [test "x$with_vv" = xcheck],  dnl autodetect
 359                          [AC_MSG_CHECKING(for purple voice and video support)
 360                           AC_RUN_IFELSE(
 361                                 [AC_LANG_PROGRAM([[
 362 #include <media.h>
 363                                         ]],
 364                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]]
 365                                 )],
 366                                 [AC_MSG_RESULT(ok)
 367                                  PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
 368                                         dnl sipe-media.c uses g_slist_free_full()
 369                                         [PKG_CHECK_MODULES(_SIPE_MEDIA_RECHECK_PLEASE_IGNORE, [purple >= 2.8.0],
 370                                                 [PKG_CHECK_MODULES(GSTREAMER, [gstreamer-0.10],
 371                                                         [with_purple_vv=yes],
 372                                                         [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 373                                                 [AC_MSG_NOTICE(libpurple >= 2.8.0 required: disabling purple voice and video support)])],
 374                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])],
 375                                 [AC_MSG_RESULT(no - your purple hasn't been compiled with voice and video support.)],
 376                                 [AC_MSG_WARN([cross compiling: not checking])])
 377                          ])
 378
 379                  dnl check if we have TCP media transport patches in libpurple
 380                  AS_IF([test "x$with_purple_vv" != xno],
 381                         [
 382                          AC_MSG_CHECKING(for TCP media transport)
 383                          AC_COMPILE_IFELSE(
 384                                 [AC_LANG_PROGRAM([[#include <media.h>]],[[return PURPLE_MEDIA_NETWORK_PROTOCOL_TCP_ACTIVE]])],
 385                                 [
 386                                  with_purple_tcp=yes
 387                                  AC_DEFINE(HAVE_ICE_TCP, 1, [Define if we have support for TCP media transport.])
 388                                  AC_MSG_RESULT(yes)
 389                                 ],
 390                                 [AC_MSG_RESULT(no)]
 391                          )
 392                         ])
 393
 394                  CFLAGS=$ac_save_CFLAGS
 395                  LIBS=$ac_save_LIBS],
 396                 [enable_purple=no])])
 397 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 398
 399 dnl build option: telepathy backend
 400 AC_ARG_ENABLE([telepathy],
 401         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 402         [],
 403         [enable_telepathy=yes])
 404 AS_IF([test "x$enable_telepathy" != xno],
 405         [PKG_CHECK_MODULES(TELEPATHY_GLIB, [telepathy-glib >= 0.18.0],
 406                 [dnl GMIME is a build requirement
 407                  AS_IF([test "x$ac_have_gmime" = xyes],
 408                         [],
 409                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 410
 411                  dnl telepathy is based on GObject & D-Bus GLib
 412                  PKG_CHECK_MODULES(GOBJECT, [gobject-2.0])
 413                  PKG_CHECK_MODULES(DBUS_GLIB, [dbus-glib-1])
 414
 415                  dnl telepathy uses from gio:
 416                  dnl  - GIOStream      (>= 2.22.0)
 417                  dnl  - GResolver      (>= 2.22.0)
 418                  dnl  - GSocketClient  (>= 2.32.0)
 419                  dnl  - GTlsConnection (>= 2.28.0)
 420                  PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.32.0])
 421
 422                 ],
 423                 [enable_telepathy=no])])
 424 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 425
 426 dnl sanity check
 427 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
 428         [AC_ERROR(at least one plugin must be selected
 429
 430 If you didn't use a --enable option then please check that you have
 431 the headers for the packages "purple" or "telepathy-glib" installed.
 432 )],
 433         [])
 434
 435 dnl enable voice & video support if any backend supports it
 436 AS_IF([test "x$with_purple_vv" != xno],
 437         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 438 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 439
 440 dnl these code parts rely on interfaces that require GValueArray. This
 441 dnl type has been declared "deprectated" in glib-2.0 >= 2.32.0, but there
 442 dnl is no backward compatible replacement implementation possible
 443 AS_IF([test "x$with_purple_vv" != xno -o "x$enable_telepathy" != xno],
 444         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_28,
 445                    [We need GValueArray for which no replacement is available])])
 446
 447 dnl i18n
 448 AC_MSG_CHECKING([locale_CPPFLAGS])
 449 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 450 AC_SUBST([LOCALE_CPPFLAGS])
 451 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 452 AM_GLIB_GNU_GETTEXT
 453 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 454
 455 dnl codeset
 456 AM_LANGINFO_CODESET
 457
 458 dnl substitutions and generated files
 459 AC_CONFIG_HEADERS([config.h])
 460 AC_CONFIG_FILES([
 461         Makefile
 462         pixmaps/Makefile
 463         m4macros/Makefile
 464         po/Makefile.in
 465         pixmaps/16/Makefile
 466         pixmaps/22/Makefile
 467         pixmaps/24/Makefile
 468         pixmaps/32/Makefile
 469         pixmaps/48/Makefile
 470         pixmaps/scalable/Makefile
 471         src/Makefile
 472         src/core/Makefile
 473         src/api/Makefile
 474         src/purple/Makefile
 475         src/telepathy/Makefile
 476         src/telepathy/data/Makefile
 477         ])
 478
 479 dnl generate files
 480 AC_OUTPUT()
 481
 482 dnl additional info for the user
 483 AS_ECHO()
 484 AS_IF([test "x$enable_purple" = xno],
 485         [AS_ECHO("Not building purple plugin")],
 486         [AS_ECHO("Build purple plugin")
 487          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 488          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 489          AS_ECHO_N("Voice and video: ")
 490          AS_IF([test "x$with_purple_vv" = xno],
 491           [AS_ECHO("disabled")],
 492           [
 493            AS_ECHO_N("enabled")
 494            AS_IF([test "x$with_purple_tcp" = xyes], [AS_ECHO_N(" with TCP transport")])
 495            AS_ECHO()
 496           ])
 497         ])
 498 AS_ECHO()
 499 AS_IF([test "x$enable_telepathy" = xno],
 500         [AS_ECHO("Not building telepathy plugin")],
 501         [AS_ECHO("Build telepathy plugin")
 502          AS_ECHO("TELEPATHY_GLIB_CFLAGS: $TELEPATHY_GLIB_CFLAGS")
 503          AS_ECHO("TELEPATHY_GLIB_LIBS  : $TELEPATHY_GLIB_LIBS")])
 504 AS_ECHO()
 505 AS_IF([test "x$with_krb5" = xno],
 506         [AS_ECHO("Not building with Kerberos 5 support")],
 507         [AS_ECHO("Build with Kerberos 5 support")
 508          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 509          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 510 AS_ECHO()
 511 AS_IF([test "x$enable_debug" = xno],
 512         [AS_ECHO("Debugging not enabled")],
 513         [AS_ECHO("Build with debugging enabled")
 514          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 515 AS_ECHO()
 516 AS_IF([test "x$QUALITY_CFLAGS" = x],
 517         [AS_ECHO("Compiler checks disabled")],
 518         [AS_ECHO("Build with compiler checks enabled")
 519          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 520 AS_ECHO()
 521 AS_ECHO("configure complete. Now run 'make'")
 522 AS_ECHO()
 523
 524 dnl The End.