configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use `VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9           m4_substr(SIPE_VERSION_DATA,
  10                     [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/tracker/?atid=949931&group_id=194563], [],
  18         SIPE_HOMEPAGE)
  19
  20 AC_DEFINE([SIPE_TRANSLATIONS_URL],
  21         ["https://www.transifex.net/projects/p/pidgin-sipe/r/mob/"],
  22         [URL for submitting translations.])
  23
  24 dnl setup automake and require recent enough version
  25 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-define tar-ustar])
  26
  27 AC_CANONICAL_HOST
  28
  29 dnl set PACKAGE_URL for autoconf < 2.64
  30 AS_IF([test "x${PACKAGE_URL}" = x],
  31         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  32          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  33 ])
  34
  35 dnl set programming language
  36 AC_LANG(C)
  37 AM_PROG_CC_C_O
  38 AC_HEADER_STDC
  39
  40 dnl setup shared library generation
  41 LT_INIT([disable-static])
  42
  43 dnl checks for tools
  44 IT_PROG_INTLTOOL([0.35.0])
  45 AC_PROG_INSTALL
  46 AC_PROG_RANLIB
  47
  48 dnl ******************************
  49 dnl Win32
  50 dnl ******************************
  51 AC_MSG_CHECKING([for Win32])
  52 AS_CASE(["$host"],
  53                 [*-mingw*], [os_win32=yes],
  54                 [os_win32=no])
  55 AC_MSG_RESULT([$os_win32])
  56 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  57
  58 dnl checks for header files
  59 AC_CHECK_HEADERS([sys/sockio.h])
  60
  61 dnl checks for library functions
  62 AC_CHECK_FUNCS([])
  63
  64 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  65 dnl as that is likely where libpurple will be found if it is not in the default
  66 dnl pkgconfig path
  67 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  68 export PKG_CONFIG_PATH
  69
  70 dnl debug mode
  71 AC_ARG_ENABLE(debug,
  72         [AS_HELP_STRING([--enable-debug],
  73                         [compile with debugging support [default=no]])],
  74         [],
  75         [enable_debug=no])
  76
  77 AS_IF([test "x$enable_debug" = xyes],
  78         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  79 AC_SUBST(DEBUG_CFLAGS)
  80
  81 dnl quality check mode
  82 dnl For people who are interested in finding bugs and not hiding them
  83 AC_ARG_ENABLE(quality-check,
  84         [AS_HELP_STRING([--enable-quality-check],
  85                         [compile with compiler checks enabled [default=yes]])],
  86         [],
  87         [enable_quality_check=yes])
  88
  89 AS_IF([test "x$enable_quality_check" = xyes],
  90         [dnl default quality configuration
  91          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  92
  93          dnl enable warnings supported by the GCC on the build system
  94          for newflag in \
  95                         "-Wextra" \
  96                         "-Waggregate-return" \
  97                         "-Wcast-align" \
  98                         "-Wdeclaration-after-statement" \
  99                         "-Wdeprecated-declarations" \
 100                         "-Winit-self" \
 101                         "-Wmissing-declarations" \
 102                         "-Wmissing-prototypes" \
 103                         "-Wnested-externs" \
 104                         "-Wpointer-arith" \
 105                         "-Wundef" \
 106                         "-Wunused-but-set-variable" \
 107          ; do
 108                  ac_save_CFLAGS=$CFLAGS
 109                  AC_MSG_CHECKING([if $CC supports $newflag])
 110                  CFLAGS="$QUALITY_CFLAGS $newflag"
 111                  AC_COMPILE_IFELSE(
 112                         [AC_LANG_SOURCE([[]])],
 113                         [AC_MSG_RESULT(yes)
 114                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 115                         [AC_MSG_RESULT(no)]
 116                  )
 117                  CFLAGS=$ac_save_CFLAGS
 118          done
 119         ])
 120 AC_SUBST(QUALITY_CFLAGS)
 121
 122 dnl Check for pkg-config before using it
 123 PKG_PROG_PKG_CONFIG
 124
 125 dnl check for valgrind (optional, only needed for debugging)
 126 PKG_CHECK_MODULES(VALGRIND, [valgrind],
 127         [AC_DEFINE(HAVE_VALGRIND, 1, [Define to 1 if you have the valgrind headers])],
 128         [AC_MSG_RESULT(no)])
 129
 130 dnl build option: with voice & video support (for all backends)
 131 AC_ARG_WITH(vv,
 132         [AC_HELP_STRING([--with-vv],
 133                 [compile with voice and video support @<:@default=check@:>@])],
 134         [AS_IF([test "x$withval" = xyes], [with_vv=check])],
 135         [with_vv=check])
 136
 137 dnl check for Kerberos 5 support
 138 AC_ARG_WITH([krb5],
 139         [AC_HELP_STRING([--with-krb5],
 140                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 141         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 142         [with_krb5=check])
 143
 144 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 145       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 146         [AC_MSG_CHECKING(if Kerberos 5 is available)
 147          AS_IF([AC_RUN_LOG([krb5-config --version])],
 148                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 149                  KRB5_LDFLAGS=""
 150
 151                  dnl same as AC_CHECK_LIB()
 152                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"
 153                  AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5)])],
 154                 [AC_MSG_RESULT(no)
 155                  with_krb5=no])],
 156       [                               dnl path specified by user
 157         KRB5_CFLAGS="-I${with_krb5}/include"
 158         KRB5_LDFLAGS="-L${with_krb5}/lib"
 159         ac_save_LDFLAGS="$LDLAGS"
 160         LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 161         AC_CHECK_LIB(krb5, krb5_rd_req,          [],
 162                 [AC_CHECK_LIB(krb5, krb5_rd_req, [],
 163                         [AC_ERROR(Kerberos 5 libraries not found)])])
 164         AC_CHECK_LIB(gssapi_krb5, gss_krb5_export_lucid_sec_context, [],
 165                         [AC_ERROR(GSSAPI Kerberos 5 libraries not found)])
 166         LDFLAGS="$ac_save_LDFLAGS"])
 167 AM_CONDITIONAL(SIP_SEC_KRB5, [test "x$with_krb5" != xno])
 168 AC_SUBST(KRB5_CFLAGS)
 169 AC_SUBST(KRB5_LDFLAGS)
 170
 171 dnl check for glib
 172 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.12.0])
 173 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.12.0])
 174
 175 dnl check for gmime
 176 dnl See also: https://bugzilla.gnome.org/show_bug.cgi?id=613653#c8
 177 PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.5.2],
 178         [ac_have_gmime=yes],
 179         [PKG_CHECK_MODULES(GMIME, [gmime-2.4 >= 2.4.16],
 180                 [ac_have_gmime=yes],
 181                 [ac_have_gmime=no])
 182 ])
 183 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 184 AS_IF([test "x$ac_have_gmime" = xyes],
 185         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 186
 187 dnl check for NSS
 188 PKG_CHECK_MODULES(NSS, [nss],
 189         [],
 190         [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 191                 [],
 192                 [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 193                         [],
 194                         [AC_ERROR([nss, mozilla-nss or microb-engine-nss package is required])])
 195         ])
 196 ])
 197
 198 dnl check for libxml2
 199 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 200
 201 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 202 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 203 ac_save_CFLAGS=$CFLAGS
 204 CFLAGS="$GLIB_CFLAGS $QUALITY_CFLAGS"
 205 dnl note the [[[ quoting: our code contains []!
 206 AC_RUN_IFELSE(
 207         [AC_LANG_PROGRAM(
 208                 [[
 209 #include <glib.h>
 210 #include <stdio.h>
 211
 212 /* Copied from uuid.c */
 213 typedef struct {
 214    guint32 time_low;
 215    guint16 time_mid;
 216    guint16 time_hi_and_version;
 217    guint8  clock_seq_hi_and_reserved;
 218    guint8  clock_seq_low;
 219    guint8  node[6];
 220 } uuid_t;
 221                 ]],
 222                 [[if (sizeof(uuid_t) == 16) {
 223                         return(0);
 224                  } else {
 225                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 226                         return(1);
 227                  }]])],
 228         [AC_MSG_RESULT(yes)],
 229         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 230
 231 Please notify the SIPE developers.
 232
 233 Copy & paste all lines starting with the line
 234
 235   checking that sizeof(uuid_t) is 16...
 236
 237 to the report and attach the file "config.log".
 238
 239 Compiler information:
 240
 241  host:     $host
 242  build:    $build
 243  compiler: $CC
 244 ])],
 245         [AC_MSG_WARN([cross compiling: not checking])])
 246 CFLAGS=$ac_save_CFLAGS
 247
 248 dnl build option: OCS2005 client hack
 249 AC_ARG_ENABLE([ocs2005-message-hack],
 250         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
 251                                                           which causes "false" not delivered error messages
 252                                                           @<:@default=no@:>@])],
 253         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
 254                    [Define to 1 to disable SIP MESSAGE timeout feature.
 255                     OCS2005 clients don't seem to acknowledge MESSAGEs and
 256                     disabling the timeout suppresses "false" error messages])])
 257
 258 dnl build option: purple backend
 259 AC_ARG_ENABLE([purple],
 260         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 261         [],
 262         [enable_purple=yes])
 263 with_purple_vv=no
 264 AS_IF([test "x$enable_purple" != xno],
 265         [PKG_CHECK_MODULES(PURPLE, [purple >= 2.4.0],
 266                 [dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 267                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion purple | cut -d. -f 1`
 268                  AC_SUBST(PURPLE_MAJOR_VERSION)
 269
 270                  dnl let user now if he has a 32- and 64-bit header conflict...
 271                  AC_MSG_CHECKING([for 32- and 64-bit header conflicts])
 272                  ac_save_CFLAGS=$CFLAGS
 273                  CFLAGS="$PURPLE_CFLAGS $QUALITY_CFLAGS"
 274                  AC_COMPILE_IFELSE(
 275                         [AC_LANG_PROGRAM([[
 276 #include <glib.h>
 277 #include <cipher.h>
 278
 279 /* Compile some code that has caused trouble in the past */
 280 static void testfunc(unsigned long len)
 281 {
 282   PurpleCipherContext *rc4 = NULL;
 283   guchar *plaintext = NULL;
 284   gsize plaintext_length = 0;
 285   guchar *encrypted_text = NULL;
 286   gsize dummy;
 287   purple_cipher_context_set_option(rc4, "key_len", GUINT_TO_POINTER(len));
 288   purple_cipher_context_encrypt(rc4, plaintext, plaintext_length,
 289                                 encrypted_text, &dummy);
 290 }
 291                                         ]],
 292                                         [[testfunc(16);]])],
 293                         [AC_MSG_RESULT(none)],
 294                         [AC_MSG_FAILURE([conflicts found.
 295
 296 Check that you have the correct glib/libpurple headers installed for
 297 your architecture or set GLIB_CFLAGS/PURPLE_CFLAGS to override the
 298 system defaults.
 299 ])
 300                         ])
 301
 302                  dnl on windows
 303                  dnl test program needs to be in the same location as libpurple
 304                  dnl installation for latter to load ssl plugin referenced by
 305                  dnl RELATIVE path.
 306                  AS_IF([test "x${os_win32}" != xyes],
 307                         [dnl purple SSL support is mandatory
 308                          AC_MSG_CHECKING([for purple SSL support])
 309                          ac_save_LIBS=$LIBS
 310                          LIBS="$PURPLE_LIBS"
 311                          AC_RUN_IFELSE(
 312                                 [AC_LANG_PROGRAM([[
 313 #include <glib.h>
 314 #include <plugin.h>
 315 #include <sslconn.h>
 316                                                 ]],
 317                                                 [[
 318         purple_plugins_init();
 319         purple_plugins_probe(G_MODULE_SUFFIX);
 320         purple_ssl_init();
 321         return(purple_ssl_is_supported()?0:1);
 322                                                 ]])],
 323                                 [AC_MSG_RESULT(ok)],
 324                                 [AC_MSG_FAILURE([your purple hasn't been compiled with SSL support.
 325 ])
 326                                 ],
 327                                 [AC_MSG_WARN([cross compiling: not checking])])
 328                  ])
 329
 330                  dnl check whether enable voice and video support
 331                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 332                        [test "x$with_vv" = xcheck],  dnl autodetect
 333                          [AC_MSG_CHECKING(for purple voice and video support)
 334                           AC_RUN_IFELSE(
 335                                 [AC_LANG_PROGRAM([[
 336 #include <media.h>
 337                                         ]],
 338                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]]
 339                                 )],
 340                                 [AC_MSG_RESULT(ok)
 341                                  PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
 342                                         dnl sipe-media.c uses g_slist_free_full()
 343                                         [PKG_CHECK_MODULES(_SIPE_MEDIA_RECHECK_PLEASE_IGNORE, [purple >= 2.8.0 glib-2.0 >= 2.28.0],
 344                                                 [PKG_CHECK_MODULES(GSTREAMER, [gstreamer-0.10],
 345                                                         [with_purple_vv=yes],
 346                                                         [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 347                                                 [AC_MSG_NOTICE(libpurple >= 2.8.0 glib2 >= 2.28.0 required: disabling purple voice and video support)])],
 348                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])],
 349                                 [AC_MSG_RESULT(no - your purple hasn't been compiled with voice and video support.)],
 350                                 [AC_MSG_WARN([cross compiling: not checking])])
 351                          ])
 352
 353                  dnl check if we have TCP media transport patches in libpurple
 354                  AS_IF([test "x$with_purple_vv" != xno],
 355                         [
 356                          AC_MSG_CHECKING(for TCP media transport)
 357                          AC_COMPILE_IFELSE(
 358                                 [AC_LANG_PROGRAM([[#include <media.h>]],[[return PURPLE_MEDIA_NETWORK_PROTOCOL_TCP_ACTIVE]])],
 359                                 [
 360                                  with_purple_tcp=yes
 361                                  AC_DEFINE(HAVE_ICE_TCP, 1, [Define if we have support for TCP media transport.])
 362                                  AC_MSG_RESULT(yes)
 363                                 ],
 364                                 [AC_MSG_RESULT(no)]
 365                          )
 366                         ])
 367
 368                  CFLAGS=$ac_save_CFLAGS
 369                  LIBS=$ac_save_LIBS],
 370                 [enable_purple=no])])
 371 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 372
 373 dnl build option: telepathy backend
 374 AC_ARG_ENABLE([telepathy],
 375         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 376         [],
 377         [enable_telepathy=yes])
 378 AS_IF([test "x$enable_telepathy" != xno],
 379         [PKG_CHECK_MODULES(TELEPATHY, [telepathy-glib],
 380                 [dnl GMIME is a build requirement
 381                  AS_IF([test "x$ac_have_gmime" = xyes],
 382                         [],
 383                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 384
 385                  dnl NOTHING IMPLEMENTED YET!!!
 386                 ],
 387                 [enable_telepathy=no])])
 388 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 389
 390 dnl sanity check
 391 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
 392         [AC_ERROR(at least one plugin must be selected
 393
 394 If you didn't use a --enable option then please check that you have
 395 the headers for the packages "purple" or "telepathy-glib" installed.
 396 )],
 397         [])
 398
 399 dnl enable voice & video support if any backend supports it
 400 AS_IF([test "x$with_purple_vv" != xno],
 401         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 402 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 403
 404 dnl i18n
 405 AC_MSG_CHECKING([locale_CPPFLAGS])
 406 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 407 AC_SUBST([LOCALE_CPPFLAGS])
 408 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 409 AM_GLIB_GNU_GETTEXT
 410 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 411
 412 dnl codeset
 413 AM_LANGINFO_CODESET
 414
 415 dnl substitutions and generated files
 416 AC_CONFIG_HEADERS([config.h])
 417 AC_CONFIG_FILES([
 418         Makefile
 419         pixmaps/Makefile
 420         m4macros/Makefile
 421         po/Makefile.in
 422         pixmaps/16/Makefile
 423         pixmaps/22/Makefile
 424         pixmaps/48/Makefile
 425         pixmaps/scalable/Makefile
 426         src/Makefile
 427         src/core/Makefile
 428         src/api/Makefile
 429         src/purple/Makefile
 430         src/telepathy/Makefile
 431         ])
 432
 433 dnl generate files
 434 AC_OUTPUT()
 435
 436 dnl additional info for the user
 437 AS_ECHO()
 438 AS_IF([test "x$enable_purple" = xno],
 439         [AS_ECHO("Not building purple plugin")],
 440         [AS_ECHO("Build purple plugin")
 441          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 442          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 443          AS_ECHO_N("Voice and video: ")
 444          AS_IF([test "x$with_purple_vv" = xno],
 445           [AS_ECHO("disabled")],
 446           [
 447            AS_ECHO_N("enabled")
 448            AS_IF([test "x$with_purple_tcp" = xyes], [AS_ECHO_N(" with TCP transport")])
 449            AS_ECHO()
 450           ])
 451         ])
 452 AS_ECHO()
 453 AS_IF([test "x$enable_telepathy" = xno],
 454         [AS_ECHO("Not building telepathy plugin")],
 455         [AS_ECHO("Build telepathy plugin")
 456          AS_ECHO()
 457          AS_ECHO("NOTHING IMPLEMENTED YET!!!")
 458          AS_ECHO()
 459          AS_ECHO("TELEPATHY_CFLAGS: $TELEPATHY_CFLAGS")
 460          AS_ECHO("TELEPATHY_LIBS  : $TELEPATHY_LIBS")])
 461 AS_ECHO()
 462 AS_IF([test "x$with_krb5" = xno],
 463         [AS_ECHO("Not building with Kerberos 5 support")],
 464         [AS_ECHO("Build with Kerberos 5 support")
 465          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 466          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 467 AS_ECHO()
 468 AS_IF([test "x$enable_debug" = xno],
 469         [AS_ECHO("Debugging not enabled")],
 470         [AS_ECHO("Build with debugging enabled")
 471          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 472 AS_ECHO()
 473 AS_IF([test "x$QUALITY_CFLAGS" = x],
 474         [AS_ECHO("Compiler checks disabled")],
 475         [AS_ECHO("Build with compiler checks enabled")
 476          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 477 AS_ECHO()
 478 AS_ECHO("configure complete. Now run 'make'")
 479 AS_ECHO()
 480
 481 dnl The End.