configure.ac

   1
   2 AC_PREREQ(2.59c)
   3
   4 dnl releases only do -Wall, cvs and prerelease does -Werror too
   5 dnl use a three digit version number for releases, and four for cvs/prerelease
   6 AC_INIT(libnice, 0.1.2.1)
   7 LIBNICE_RELEASE="no"
   8
   9 AC_CANONICAL_SYSTEM
  10
  11 AC_CONFIG_SRCDIR([agent/agent.c])
  12 AC_CONFIG_HEADER([config.h])
  13 AM_INIT_AUTOMAKE([-Wall])
  14
  15 AC_CONFIG_FILES([
  16         Makefile
  17         agent/Makefile
  18         stun/Makefile
  19         stun/tests/Makefile
  20         stun/tools/Makefile
  21         socket/Makefile
  22         nice/Makefile
  23         nice/nice.pc
  24         random/Makefile
  25         gst/Makefile
  26         docs/Makefile
  27         docs/reference/Makefile
  28         docs/reference/libnice/Makefile
  29         tests/Makefile
  30         ])
  31
  32 # Set the libtool C/A/R version info
  33 #    If the source code was changed, but there were no interface changes:
  34 #      Increment REVISION.
  35 #    If there was a compatible interface change:
  36 #      Increment CURRENT and AGE. Set REVISION to 0
  37 #    If there was an incompatible interface change:
  38 #      Increment CURRENT. Set AGE and REVISION to 0
  39 LIBNICE_CURRENT=10
  40 LIBNICE_REVISION=2
  41 LIBNICE_AGE=0
  42 LIBNICE_LIBVERSION=${LIBNICE_CURRENT}:${LIBNICE_REVISION}:${LIBNICE_AGE}
  43 LIBNICE_LT_LDFLAGS="-version-info ${LIBNICE_LIBVERSION} -no-undefined"
  44 AC_SUBST(LIBNICE_LT_LDFLAGS)
  45
  46
  47 dnl use pretty build output with automake >= 1.11
  48 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  49   [AM_DEFAULT_VERBOSITY=1
  50    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  51
  52
  53 # Checks for programs.
  54
  55 AC_PROG_CC
  56 AC_USE_SYSTEM_EXTENSIONS
  57 AC_PROG_LIBTOOL
  58
  59 # Check Operating System
  60 AC_MSG_CHECKING([operating system])
  61 case "$host" in
  62         *-*-*mingw*|*-*-*cygwin*)
  63                 platform=win32
  64                 AC_MSG_RESULT($platform)
  65                 ;;
  66         *)
  67                 platform=linux/other
  68                 AC_MSG_RESULT($platform)
  69                 ;;
  70 esac
  71
  72 AM_CONDITIONAL([WINDOWS], [test "$platform" = "win32"])
  73
  74 # Checks for compiler features
  75
  76 AC_C_RESTRICT
  77 AC_C_VARARRAYS
  78 AC_HEADER_ASSERT
  79 AC_HEADER_STDBOOL
  80 AH_VERBATIM([_FORTIFY_SOURCE],
  81 [/* Define to `2' to get GNU/libc warnings. */
  82 /* Only define if -O1 or more is enabled */
  83 #if defined __OPTIMIZE__ && __OPTIMIZE__ > 0
  84 # define _FORTIFY_SOURCE 2
  85 #endif])
  86 AC_DEFINE([NICEAPI_EXPORT], [ ], [Public library function implementation])
  87 AC_CHECK_HEADERS([arpa/inet.h net/in.h])
  88 AC_CHECK_HEADERS([ifaddrs.h], \
  89                       [AC_DEFINE(HAVE_GETIFADDRS, [1], \
  90                        [Whether getifaddrs() is available on the system])])
  91
  92 LIBNICE_CFLAGS="-Wall"
  93 dnl if asked for, add -Werror if supported
  94 if test "x$LIBNICE_RELEASE" != "xyes"; then
  95   LIBNICE_CFLAGS="$LIBNICE_CFLAGS -Werror"
  96 fi
  97
  98 AC_SUBST(LIBNICE_CFLAGS)
  99 AC_MSG_NOTICE([set LIBNICE_CFLAGS to $LIBNICE_CFLAGS])
 100
 101 # Checks for libraries.
 102 AC_CHECK_LIB(rt, clock_gettime, [LIBRT="-lrt"], [LIBRT=""])
 103 AC_CHECK_FUNCS([poll])
 104 AC_SUBST(LIBRT)
 105
 106 PKG_CHECK_MODULES(GLIB, [dnl
 107         glib-2.0 >= 2.13 dnl
 108         gobject-2.0 >= 2.13 dnl
 109         gthread-2.0 >= 2.13 dnl
 110         gio-2.0 >= 2.13 dnl
 111         ])
 112
 113 AC_ARG_WITH(gstreamer,
 114         AC_HELP_STRING([--with-gstreamer], [use GStreamer]),
 115         [with_gstreamer=${withval}],
 116         [with_gstreamer=auto])
 117
 118 AS_IF([test "$with_gstreamer" != no], [
 119
 120         PKG_CHECK_MODULES(GST, [
 121                 gstreamer-0.11 >= 0.11.1
 122                 gstreamer-base-0.11 >= 0.11.1
 123                 ],
 124                 [
 125                 with_gstreamer=yes
 126                 GST_MAJORMINOR=0.11
 127                 gstplugindir="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 128                 ],
 129                 [
 130                 AS_IF([test "$with_gstreamer" = yes], [
 131                         AC_MSG_ERROR([GStreamer support was requested but GStreamer libraries are not available])
 132                 ])
 133
 134                 with_gstreamer=no
 135                 ])
 136 ])
 137
 138 AC_SUBST(gstplugindir)
 139
 140 AM_CONDITIONAL(WITH_GSTREAMER, test "$with_gstreamer" = yes)
 141
 142 GUPNP_IGD_REQUIRED=0.1.2
 143
 144 AC_ARG_ENABLE([gupnp],
 145         AC_HELP_STRING([--disable-gupnp], [Disable GUPnP IGD support]),
 146         [case "${enableval}" in
 147             yes) WANT_GUPNP=yes ;;
 148             no)  WANT_GUPNP=no ;;
 149             *) AC_MSG_ERROR(bad value ${enableval} for --enable-gupnp) ;;
 150         esac],
 151         WANT_GUPNP=test)
 152
 153 HAVE_GUPNP=no
 154 if test "x$WANT_GUPNP" != "xno"; then
 155    PKG_CHECK_MODULES(GUPNP, gupnp-igd-1.0 >= $GUPNP_IGD_REQUIRED,
 156     [ HAVE_GUPNP=yes ],
 157     [ HAVE_GUPNP=no ])
 158 fi
 159 if test "x$WANT_GUPNP" = "xyes" && test "x$HAVE_GUPNP" = "xno"; then
 160    AC_ERROR([Requested GUPnP IGD, but it is not available])
 161 fi
 162
 163 if test "x$HAVE_GUPNP" = "xyes"; then
 164    AC_DEFINE(HAVE_GUPNP,,[Have the GUPnP IGD library])
 165 fi
 166
 167 AC_SUBST(HAVE_GUPNP)
 168
 169 dnl Test coverage
 170 AC_ARG_ENABLE([coverage],
 171         [AS_HELP_STRING([--enable-coverage],
 172                 [build for test coverage (default disabled)])],,
 173         [enable_coverage="no"])
 174 AS_IF([test "${enable_coverage}" != "no"], [
 175         CFLAGS="${CFLAGS} -g -O0 -fprofile-arcs -ftest-coverage"
 176         LDFLAGS="-lgcov"
 177         CCACHE_DISABLE=1
 178 ])
 179 AC_SUBST(CCACHE_DISABLE)
 180
 181 case $host_os in
 182   solaris*)
 183     LDFLAGS="$LDFLAGS -lsocket -lnls"
 184     ;;
 185   *)
 186     ;;
 187 esac
 188
 189 # check for gtk-doc
 190 m4_ifdef([GTK_DOC_CHECK], [
 191 GTK_DOC_CHECK(1.9)
 192 ],[
 193 AM_CONDITIONAL([ENABLE_GTK_DOC], false)
 194 ])
 195 AC_CONFIG_MACRO_DIR(m4)
 196
 197 AC_OUTPUT
 198