configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 # Copyright (C) 2002, 2003 Simon Josefsson.
   3 #
   4 # This file is part of Shishi.
   5 #
   6 # Shishi is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10 #
  11 # Shishi is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Shishi; see the file COPYING.  If not, write to
  18 # the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  19 # Boston, MA 02111-1307, USA.
  20
  21 AC_PREREQ(2.50)
  22 AC_INIT(shishi, 0.0.0, bug-shishi@josefsson.org)
  23
  24 # Interfaces removed:    CURRENT++, AGE=0, REVISION=0
  25 # Interfaces added:      CURRENT++, AGE++, REVISION=0
  26 # No interfaces changed:                   REVISION++
  27 LT_CURRENT=0
  28 LT_AGE=0
  29 LT_REVISION=0
  30 AC_SUBST(LT_CURRENT)
  31 AC_SUBST(LT_AGE)
  32 AC_SUBST(LT_REVISION)
  33
  34 AM_INIT_AUTOMAKE(gnits)
  35 AM_CONFIG_HEADER(config.h)
  36
  37 # Checks for header files.
  38 AC_PROG_CC
  39 AC_GNU_SOURCE
  40 AC_HEADER_STDC
  41 AC_CHECK_HEADERS([stdlib.h memory.h string.h strings.h sys/socket.h unistd.h])
  42 AC_CHECK_HEADERS(getopt.h unistd.h strings.h netdb.h time.h sys/poll.h \
  43         sys/time.h sys/types.h sys/select.h sys/socket.h sys/stat.h stdint.h \
  44         termios.h signal.h pwd.h errno.h syslog.h)
  45 AC_CHECK_HEADERS(netinet/in.h netinet/in6.h arpa/inet.h)
  46
  47 # Checks for programs.
  48 AC_PROG_LIBTOOL
  49 AM_GNU_GETTEXT(use-libtool, need-ngettext)
  50 AM_GNU_GETTEXT_VERSION(0.12.1)
  51 AM_MISSING_PROG(PERL, perl, $missing_dir)
  52 AM_MISSING_PROG(HELP2MAN, help2man, $missing_dir)
  53 AM_MISSING_PROG(TEXI2PDF, texi2pdf, $missing_dir)
  54 AM_MISSING_PROG(DOCBOOK2TXT, docbook2txt, $missing_dir)
  55 AM_MISSING_PROG(DOCBOOK2HTML, docbook2html, $missing_dir)
  56 AM_MISSING_PROG(DOCBOOK2PS, docbook2ps, $missing_dir)
  57 AM_MISSING_PROG(DOCBOOK2PDF, docbook2pdf, $missing_dir)
  58 AM_MISSING_PROG(ASN1PARSER, asn1Parser, $missing_dir)
  59 AM_WITH_DMALLOC
  60
  61 # Checks for typedefs, structures, and compiler characteristics.
  62 AC_C_CONST
  63 AC_TYPE_SIZE_T
  64 AC_TYPE_UID_T
  65 AC_TYPE_SIGNAL
  66 AC_HEADER_TIME
  67 AC_CHECK_DECLS(h_errno)
  68 AC_CHECK_TYPE([socklen_t],, [AC_DEFINE([socklen_t], [size_t],
  69               [Define to `size_t' if `socklen_t' is missing.])], [
  70 #ifdef HAVE_SYS_TYPES_H
  71 #include <sys/types.h>
  72 #endif
  73 #ifdef HAVE_SYS_SOCKET_H
  74 #include <sys/socket.h>
  75 #endif
  76 #ifdef HAVE_NETDB_H
  77 #include <netdb.h>
  78 #endif
  79 ])
  80
  81 # Check for PAM
  82 AC_ARG_ENABLE(pam,
  83   AC_HELP_STRING([--disable-pam], [Don't use PAM even if available]))
  84 if test "$enable_pam" != "no"; then
  85         AC_CHECK_HEADERS(security/pam_appl.h)
  86         AC_CHECK_HEADERS(security/pam_modules.h, [], [],
  87         [
  88 #if HAVE_SECURITY_PAM_APPL_H
  89 #include <security/pam_appl.h>
  90 #endif
  91 ])
  92   AC_CHECK_HEADERS(security/_pam_macros.h)
  93   enable_pam=$ac_cv_header_security_pam_modules_h
  94 fi
  95 if test "$enable_pam" != "no"; then
  96         PAM_SHISHI=pam_shishi
  97 else
  98         AC_MSG_WARN([[The Shishi PAM module will not be built.]])
  99 fi
 100 AC_SUBST(PAM_SHISHI)
 101 AC_MSG_CHECKING([if PAM should be used])
 102 AC_MSG_RESULT($enable_pam)
 103
 104 # Check for IPv6
 105 AC_ARG_ENABLE(ipv6,
 106   AC_HELP_STRING([--disable-ipv6], [Don't use IPv6 even if available]))
 107 if test "$enable_ipv6" != "no"; then
 108   enable_ipv6=yes
 109   AC_CHECK_DECLS([AF_INET6, IN6ADDR_ANY_INIT],,enable_ipv6=no,[
 110   #ifdef HAVE_SYS_TYPES_H
 111   #include <sys/types.h>
 112   #endif
 113   #ifdef HAVE_SYS_SOCKET_H
 114   #include <sys/socket.h>
 115   #endif
 116   #ifdef HAVE_NETINET_IN_H
 117   #include <netinet/in.h>
 118   #endif
 119   #ifdef HAVE_NETINET_IN6_H
 120   #include <netinet/in6.h>
 121   #endif
 122   ])
 123   AC_CHECK_TYPE(struct sockaddr_in6,,enable_ipv6=no,[
 124   #ifdef HAVE_SYS_TYPES_H
 125   #include <sys/types.h>
 126   #endif
 127   #ifdef HAVE_SYS_SOCKET_H
 128   #include <sys/socket.h>
 129   #endif
 130   #ifdef HAVE_NETINET_IN_H
 131   #include <netinet/in.h>
 132   #endif
 133   #ifdef HAVE_NETINET_IN6_H
 134   #include <netinet/in6.h>
 135   #endif
 136   ])
 137 fi
 138 if test "$enable_ipv6" != "no"; then
 139   AC_DEFINE(WITH_IPV6, 1, [Define to 1 if you want IPv6.])
 140 else
 141   AC_MSG_WARN([[IPv6 support is disabled.]])
 142 fi
 143 AC_MSG_CHECKING([if IPv6 should be used])
 144 AC_MSG_RESULT($enable_ipv6)
 145
 146 # Check gdbm
 147 #AC_ARG_WITH(system-gdbm,
 148 #  AC_HELP_STRING([--without-system-gdbm], [Don't use the system's gdbm]))
 149 #if test "$with_system_gdbm" != "no" ; then
 150 #  AC_CHECK_LIB(gdbm, gdbm_open,,with_system_gdbm=no)
 151 #fi
 152 #LIBGDBM=""
 153 #if test "$with_system_gdbm" = "no" ; then
 154 #  LIBGDBM="\$(top_builddir)/gdbm/libgdbm.a"
 155 #  CFLAGS="$CFLAGS -I\$(top_srcdir)/gdbm"
 156 #  GDBM=gdbm
 157 #  AC_SUBST(GDBM)
 158 #fi
 159 #AC_SUBST(LIBGDBM)
 160
 161 # Check for idn
 162 AC_ARG_WITH(system-idn,
 163   AC_HELP_STRING([--without-system-idn],
 164                 [don't use the system's libidn]))
 165 if test "$with_system_idn" != "no" ; then
 166         PKG_CHECK_MODULES(LIBIDN, libidn >= 0.1.0,
 167                 with_system_idn=yes,
 168                 with_system_idn=no)
 169 fi
 170 if test "$with_system_idn" = "no"; then
 171         AC_MSG_WARN([[
 172
 173 The system's libidn 0.1.0 or later not used.  Using copy distributed
 174 with Shishi instead.  See <http://www.gnu.org/software/libidn/>.
 175
 176 ]])
 177         LIBIDN_CFLAGS="-I\$(top_srcdir)/libstringprep"
 178         LIBIDN_LIBS="\$(top_builddir)/libstringprep/libidn.la"
 179         LIBIDN=libstringprep
 180 fi
 181 AC_SUBST(LIBIDN_CFLAGS)
 182 AC_SUBST(LIBIDN_LIBS)
 183 AC_SUBST(LIBIDN)
 184 AC_MSG_CHECKING([if system's libidn should be used])
 185 AC_MSG_RESULT($with_system_idn)
 186 AC_CONFIG_SUBDIRS(libstringprep)
 187
 188 # Check for libtasn1
 189 AC_ARG_WITH(system-libtasn1,
 190   AC_HELP_STRING([--without-system-libtasn1],
 191                 [don't use the system's libtasn1]))
 192 if test "$with_system_libtasn1" != "no" ; then
 193         AC_CHECK_LIB(tasn1, asn1_read_tag, [
 194                 LIBTASN1_LIBS="-ltasn1"
 195                 LIBTASN1_CFLAGS=""
 196                 with_system_libtasn1=yes
 197         ], [
 198                 with_system_libtasn1=no
 199         ])
 200 fi
 201 if test "$with_system_libtasn1" = "no"; then
 202         AC_MSG_WARN([[
 203
 204 The system's libtasn1 0.2.0 or later not used.  Using copy distributed
 205 with Shishi instead.  See <http://www.gnu.org/software/gnutls/>.
 206
 207 ]])
 208         LIBTASN1_CFLAGS="-I\$(top_srcdir)/asn1/lib"
 209         LIBTASN1_LIBS="\$(top_builddir)/asn1/lib/libtasn1.la"
 210         ASN1=asn1
 211 fi
 212 AC_SUBST(LIBTASN1_CFLAGS)
 213 AC_SUBST(LIBTASN1_LIBS)
 214 AC_SUBST(ASN1)
 215 AC_MSG_CHECKING([if system's libtasn1 should be used])
 216 AC_MSG_RESULT($with_system_libtasn1)
 217 AC_CONFIG_SUBDIRS(asn1)
 218
 219 # Check for libgcrypt
 220 AC_ARG_WITH(system-libgcrypt,
 221   AC_HELP_STRING([--without-system-libgcrypt],
 222                 [don't use the system's libgcrypt]))
 223 if test "$with_system_libgcrypt" != "no" ; then
 224         AM_PATH_LIBGCRYPT(1.1.13, [
 225                 with_system_libgcrypt=yes
 226         ], [
 227                 with_system_libgcrypt=no
 228         ])
 229 fi
 230 if test "$with_system_libgcrypt" = "no"; then
 231         AC_MSG_WARN([[
 232
 233 The system's libgcrypt 1.1.13 or later not used.  Using copy distributed
 234 with shishi instead. See <ftp://ftp.gnupg.org/pub/gcrypt/alpha/libgcrypt/>.
 235
 236 ]])
 237         LIBGCRYPT_CFLAGS="-I\$(top_srcdir)/crypto/src"
 238         LIBGCRYPT_LIBS="\$(top_builddir)/crypto/src/libgcrypt.la"
 239         CRYPTO=crypto
 240 fi
 241 AC_SUBST(LIBGCRYPT_CFLAGS)
 242 AC_SUBST(LIBGCRYPT_LIBS)
 243 AC_SUBST(CRYPTO)
 244 AC_MSG_CHECKING([if system's libgcrypt should be used])
 245 AC_MSG_RESULT($with_system_libgcrypt)
 246 AC_CONFIG_SUBDIRS(crypto)
 247
 248 # For gnulib stuff in gl/.
 249 gl_FUNC_ALLOCA
 250 gl_ARGP
 251 gl_ERROR
 252 gl_FUNC_GETHOSTNAME
 253 gl_GETOPT
 254 jm_FUNC_MALLOC
 255 gl_FUNC_MEMMOVE
 256 gl_FUNC_MEMSET
 257 jm_FUNC_REALLOC
 258 gt_FUNC_SETENV
 259 gl_STRCASE
 260 gl_FUNC_STRCHRNUL
 261 gl_FUNC_STRDUP
 262 gl_FUNC_STRERROR
 263 gl_SYSEXITS
 264 jm_FUNC_GLIBC_UNLOCKED_IO
 265 gl_FUNC_VASNPRINTF
 266 gl_FUNC_VASPRINTF
 267 gl_XALLOC
 268
 269 # Checks for library functions.
 270 AC_FUNC_STRFTIME
 271 AC_CHECK_FUNCS(signal select ngettext gethostbyname)
 272
 273 # Configure extra tools
 274 enable_ftpd=no; export enable_ftpd
 275 enable_inetd=no; export enable_inetd
 276 enable_rexecd=no; export enable_rexecd
 277 enable_rlogind=no; export enable_rlogind
 278 enable_rshd=no; export enable_rshd
 279 enable_syslogd=no; export enable_syslogd
 280 enable_talkd=no; export enable_talkd
 281 enable_telnetd=yes; export enable_telnetd
 282 enable_tftpd=no; export enable_tftpd
 283 enable_uucpd=no; export enable_uucpd
 284 enable_ftp=no; export enable_ftp
 285 enable_ping=no; export enable_ping
 286 enable_rcp=no; export enable_rcp
 287 enable_rlogin=no; export enable_rlogin
 288 enable_rsh=yes; export enable_rsh
 289 enable_logger=no; export enable_logger
 290 enable_talk=no; export enable_talk
 291 enable_telnet=yes; export enable_telnet
 292 enable_tftp=no; export enable_tftp
 293 enable_whois=no; export enable_whois
 294 enable_ifconfig=no; export enable_ifconfig
 295 enable_authentication=yes; export enable_authentication
 296 enable_encryption=yes; export enable_encryption
 297 with_shishi=yes; export with_shishi
 298 AC_CONFIG_SUBDIRS(extra/inetutils)
 299
 300 # Check for gtk-doc.
 301 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH path to installed docs ])
 302 if test "x$with_html_dir" = "x" ; then
 303   HTML_DIR='${datadir}/gtk-doc/html'
 304 else
 305   HTML_DIR=$with_html_dir
 306 fi
 307 AC_SUBST(HTML_DIR)
 308 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
 309 gtk_doc_min_version=0.6
 310 if $GTKDOC ; then
 311     gtk_doc_version=`gtkdoc-mkdb --version`
 312     AC_MSG_CHECKING([gtk-doc version ($gtk_doc_version) >= $gtk_doc_min_version])
 313     if perl <<EOF ; then
 314       exit (("$gtk_doc_version" =~ /^[[0-9]]+\.[[0-9]]+$/) &&
 315             ("$gtk_doc_version" >= "$gtk_doc_min_version") ? 0 : 1);
 316 EOF
 317       AC_MSG_RESULT(yes)
 318    else
 319       AC_MSG_RESULT(no)
 320       GTKDOC=false
 321    fi
 322 fi
 323
 324 # Let people disable the gtk-doc stuff.
 325 AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc  Use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
 326 if test x$enable_gtk_doc = xauto ; then
 327   if test x$GTKDOC = xtrue ; then
 328     enable_gtk_doc=yes
 329   else
 330     enable_gtk_doc=no
 331   fi
 332 fi
 333 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
 334
 335 AC_CONFIG_FILES(Makefile intl/Makefile po/Makefile.in m4/Makefile \
 336         lib/Makefile lib/shishi.h src/Makefile tests/Makefile doc/Makefile \
 337         doc/reference/Makefile extra/Makefile extra/pam_shishi/Makefile \
 338         gl/Makefile shishi.pc shishi.conf shishi.skel)
 339
 340 # We are done
 341 AC_OUTPUT