doc/parts/formats/html.xsl

   1 <?xml version="1.0" encoding="UTF-8"?>
   2
   3 <!-- This file is part of Shapes.                                           -->
   4 <!--                                                                        -->
   5 <!-- Shapes is free software: you can redistribute it and/or modify         -->
   6 <!-- it under the terms of the GNU General Public License as published by   -->
   7 <!-- the Free Software Foundation, either version 3 of the License, or      -->
   8 <!-- any later version.                                                     -->
   9 <!--                                                                        -->
  10 <!-- Shapes is distributed in the hope that it will be useful,              -->
  11 <!-- but WITHOUT ANY WARRANTY; without even the implied warranty of         -->
  12 <!-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the          -->
  13 <!-- GNU General Public License for more details.                           -->
  14 <!--                                                                        -->
  15 <!-- You should have received a copy of the GNU General Public License      -->
  16 <!-- along with Shapes.  If not, see <http://www.gnu.org/licenses/>.        -->
  17 <!--                                                                        -->
  18 <!-- Copyright 2008, 2009, 2010, 2014 Henrik Tidefelt                       -->
  19
  20 <xsl:stylesheet
  21   version="2.0"
  22   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  23   xmlns="http://www.w3.org/1999/xhtml"
  24 >
  25
  26 <xsl:template match="str-PDF"><span class="medium-caps">pdf</span></xsl:template>
  27 <xsl:template match="str-HTML"><span class="medium-caps">html</span></xsl:template>
  28 <xsl:template match="str-XML"><span class="medium-caps">xml</span></xsl:template>
  29 <xsl:template match="str-SVG"><span class="medium-caps">svg</span></xsl:template>
  30 <xsl:template match="str-PNG"><span class="medium-caps">png</span></xsl:template>
  31 <xsl:template match="str-JPEG"><span class="medium-caps">jpeg</span></xsl:template>
  32 <xsl:template match="str-PostScript">PostScript</xsl:template>
  33 <xsl:template match="str-Shapes">Shapes</xsl:template>
  34 <xsl:template match="str-shapes-mode"><em>shapes-mode</em></xsl:template>
  35 <xsl:template match="str-TeX"><span class="tex">T<sub>e</sub>X</span></xsl:template>
  36 <xsl:template match="str-LaTeX"><span class="latex">L<sup>a</sup>T<sub>e</sub>X</span></xsl:template>
  37 <xsl:template match="str-pdfLaTeX"><span class="latex">pdfL<sup>a</sup>T<sub>e</sub>X</span></xsl:template>
  38 <xsl:template match="str-MetaPost">MetaPost</xsl:template>
  39 <xsl:template match="str-C-plus-plus"><span class="medium-caps">c</span>++</xsl:template>
  40 <xsl:template match="str-UTF-8"><span class="medium-caps">utf</span>-8</xsl:template>
  41 <xsl:template match="str-2D">2<span class="medium-caps"><sup>d</sup></span></xsl:template>
  42 <xsl:template match="str-3D">3<span class="medium-caps"><sup>d</sup></span></xsl:template>
  43
  44 <xsl:template name="str-Google" match="str-Google"><span class="Google"><span class="blue">G</span><span class="red">o</span><span class="yellow">o</span><span class="blue">g</span><span class="green">l</span><span class="red">e</span><span class="black">™</span></span></xsl:template>
  45
  46 <xsl:template match="abbr-etc">&amp;c</xsl:template>
  47
  48 <xsl:template match="char-cdot">*</xsl:template>
  49 <xsl:template match="char-bullet">•</xsl:template>
  50 <xsl:template match="char-str-open">`</xsl:template>
  51 <xsl:template match="char-str-close">´</xsl:template>
  52
  53 <xsl:template match="const-false"><span class="rm">false</span></xsl:template>
  54 <xsl:template match="const-true"><span class="rm">true</span></xsl:template>
  55
  56 <xsl:template match="x-hat"><b>x</b></xsl:template>
  57 <xsl:template match="y-hat"><b>y</b></xsl:template>
  58 <xsl:template match="z-hat"><b>z</b></xsl:template>
  59
  60 <xsl:template match="physical"><span class="nowrap"><xsl:apply-templates select="scalar" /><span class="xx-small"> </span><xsl:apply-templates select="unit" /></span></xsl:template>
  61 <xsl:template match="sci-fmt[@mantissa,@exp]"><span class="nowrap"><xsl:value-of select="@mantissa" /><span class="small-caps">e</span><xsl:value-of select="@exp" /></span></xsl:template>
  62 <xsl:template match="quote">“<xsl:apply-templates />”</xsl:template>
  63
  64 <xsl:template match="p[not(@class)]">
  65   <div class="p"><xsl:apply-templates/></div>
  66 </xsl:template>
  67 <xsl:template match="p[@class='center']">
  68   <div class="p" style="text-align:center;"><xsl:apply-templates/></div>
  69 </xsl:template>
  70 <xsl:template match="p[@class='todo']">
  71   <div class="p todo"><xsl:apply-templates/></div>
  72 </xsl:template>
  73
  74 <xsl:template match="ol">
  75   <ol><xsl:apply-templates/></ol>
  76 </xsl:template>
  77 <xsl:template match="ol/li">
  78   <li><xsl:apply-templates/></li>
  79 </xsl:template>
  80
  81 <xsl:template match="ul">
  82   <ul><xsl:apply-templates/></ul>
  83 </xsl:template>
  84 <xsl:template match="ul/li">
  85   <li><xsl:apply-templates/></li>
  86 </xsl:template>
  87
  88 <xsl:template match="pre">
  89 <pre>
  90 <xsl:apply-templates/>
  91 </pre>
  92 </xsl:template>
  93 <xsl:template match="pre[@class]">
  94 <xsl:element name="pre">
  95 <xsl:attribute name="class"><xsl:value-of select="@class" /></xsl:attribute>
  96 <xsl:apply-templates/>
  97 </xsl:element>
  98 </xsl:template>
  99
 100 <xsl:template match="note">
 101   <table class="note">
 102     <tr><td><xsl:apply-templates/></td></tr>
 103   </table>
 104 </xsl:template>
 105
 106 <xsl:template match="see-also">
 107   <div class="p">
 108     <b>See also:</b>
 109     <xsl:for-each select="*">
 110       <xsl:text> </xsl:text>
 111       <span class="horizontal-item">
 112         <xsl:apply-templates select="."/>
 113       </span>
 114     </xsl:for-each>
 115   </div>
 116 </xsl:template>
 117
 118 <xsl:template name="version-header">
 119         <div class="version-header"><xsl:text>For version </xsl:text>
 120                 <xsl:choose>
 121                         <xsl:when test="/book/shapes-version"><xsl:value-of select="/book/shapes-version/@number" /></xsl:when>
 122                         <xsl:when test="/man/manhead/shapes-version"><xsl:value-of select="/man/manhead/shapes-version/@number" /></xsl:when>
 123                 </xsl:choose>
 124                 <xsl:text>.</xsl:text>
 125         </div>
 126 </xsl:template>
 127
 128 <xsl:template name="head-navigation" >
 129         <xsl:call-template name="version-header" />
 130         <div class="p">
 131                 <xsl:element name="a"><xsl:attribute name="href"><xsl:value-of select="/book/base/@href" />index.html</xsl:attribute><xsl:text>To top.</xsl:text></xsl:element>
 132                 <xsl:if test="/book/up-link">
 133                         <xsl:text>  Up: </xsl:text><xsl:apply-templates select="/book/up-link" />
 134                 </xsl:if>
 135         </div>
 136 </xsl:template>
 137
 138 <xsl:template name="part-to-href">
 139         <xsl:param name="name" />
 140         <xsl:value-of select="/book/base/@href" /><xsl:choose>
 141                 <xsl:when test="$name='structure'">structure.html</xsl:when>
 142                 <xsl:when test="$name='syntax'">syntax.html</xsl:when>
 143                 <xsl:when test="$name='bindings'">bindings.html</xsl:when>
 144                 <xsl:when test="$name='states'">states.html</xsl:when>
 145                 <xsl:when test="$name='dynamic'">dynamic.html</xsl:when>
 146                 <xsl:when test="$name='types'">types.html</xsl:when>
 147                 <xsl:when test="$name='state-types'">state-types.html</xsl:when>
 148                 <xsl:when test="$name='algo-tol'">algo-tol.html</xsl:when>
 149                 <xsl:when test="$name='man'">man.html</xsl:when>
 150                 <xsl:when test="$name='tutorial'">tutorial.html</xsl:when>
 151                 <xsl:when test="$name='extensions'">extensions/index.html</xsl:when>
 152                 <xsl:when test="$name='install'">install.html</xsl:when>
 153                 <xsl:when test="$name='interactive'">interactive.html</xsl:when>
 154                 <xsl:when test="$name='edit'">edit.html</xsl:when>
 155                 <xsl:when test="$name='namespace-index'">namespace-index.html</xsl:when>
 156         </xsl:choose>
 157 </xsl:template>
 158 <xsl:template name="extension-to-href">
 159   <xsl:param name="namespace" />
 160   <xsl:param name="name" />
 161   <xsl:choose>
 162     <xsl:when test="$namespace">
 163       <xsl:value-of select="/book/base/@href" /><xsl:text>extensions/</xsl:text><xsl:value-of select="replace(replace($namespace, '^\.\.', ''), '\.\.', '-')" />-<xsl:value-of select="$name" /><xsl:text>.html</xsl:text>
 164     </xsl:when>
 165     <xsl:otherwise>
 166       <xsl:value-of select="/book/base/@href" /><xsl:text>extensions/</xsl:text><xsl:value-of select="$name" /><xsl:text>.html</xsl:text>
 167     </xsl:otherwise>
 168   </xsl:choose>
 169 </xsl:template>
 170 <xsl:template name="id-to-anchor-name">
 171         <xsl:param name="id" />
 172         <xsl:value-of select="replace(replace(concat('secid:', $id), '-', '--'), '/', '-.')" />
 173 </xsl:template>
 174 <xsl:template name="env-var-to-anchor-name">
 175         <xsl:param name="id" />
 176         <xsl:value-of select="replace(replace(concat('env:', $id), '-', '--'), '/', '-.')" />
 177 </xsl:template>
 178
 179 <xsl:template match="env-var[@name]">
 180         <xsl:element name="a">
 181                 <xsl:attribute name="class">discrete</xsl:attribute>
 182                 <xsl:attribute name="href">
 183                         <xsl:call-template name="part-to-href">
 184                                 <xsl:with-param name="name">man</xsl:with-param>
 185                         </xsl:call-template>#<xsl:call-template name="env-var-to-anchor-name">
 186                                 <xsl:with-param name="id"><xsl:value-of select="@name" /></xsl:with-param>
 187                         </xsl:call-template>
 188                 </xsl:attribute>
 189                 <xsl:value-of select="@name" />
 190         </xsl:element>
 191 </xsl:template>
 192
 193 <xsl:template match="part-href[@name]">
 194   <xsl:call-template name="part-to-href">
 195     <xsl:with-param name="name"><xsl:value-of select="@name" /></xsl:with-param>
 196   </xsl:call-template>
 197 </xsl:template>
 198 <xsl:template match="extension-href[@name]">
 199   <xsl:call-template name="extension-to-href">
 200     <xsl:with-param name="name"><xsl:value-of select="@name" /></xsl:with-param>
 201   </xsl:call-template>
 202 </xsl:template>
 203 <xsl:template name="name-to-linked-extension">
 204   <xsl:param name="placed" />
 205   <xsl:param name="namespace" />
 206   <xsl:param name="name" />
 207   <xsl:element name="a">
 208     <xsl:attribute name="class">discrete</xsl:attribute>
 209     <xsl:attribute name="href">
 210       <xsl:call-template name="extension-to-href">
 211         <xsl:with-param name="namespace"><xsl:value-of select="$namespace" /></xsl:with-param>
 212         <xsl:with-param name="name"><xsl:value-of select="$name" /></xsl:with-param>
 213       </xsl:call-template>
 214     </xsl:attribute>
 215     <xsl:choose>
 216       <xsl:when test="$placed">
 217         <span class="filename"><xsl:value-of select="$name" /></span>
 218       </xsl:when>
 219       <xsl:otherwise>
 220         <xsl:call-template name="format-namespace-name">
 221           <xsl:with-param name="name"><xsl:value-of select="$namespace" /></xsl:with-param>
 222         </xsl:call-template>
 223         <xsl:text> / </xsl:text>
 224         <span class="filename"><xsl:value-of select="$name" /></span>
 225       </xsl:otherwise>
 226     </xsl:choose>
 227   </xsl:element>
 228 </xsl:template>
 229 <xsl:template match="extension[@path]">
 230   <xsl:variable name="namespace"><xsl:value-of select="replace(@path, '/.*$', '')" /></xsl:variable>
 231   <xsl:variable name="name"><xsl:value-of select="replace(@path, '^.*/', '')" /></xsl:variable>
 232   <xsl:call-template name="name-to-linked-extension">
 233     <xsl:with-param name="namespace"><xsl:value-of select="$namespace" /></xsl:with-param>
 234     <xsl:with-param name="name"><xsl:value-of select="$name" /></xsl:with-param>
 235   </xsl:call-template>
 236 </xsl:template>
 237
 238 <xsl:template match="a[(@part or @id) and not(@extension)]">
 239         <xsl:element name="a">
 240                 <xsl:attribute name="href">
 241                         <xsl:if test="@part">
 242                                 <xsl:call-template name="part-to-href">
 243                                         <xsl:with-param name="name"><xsl:value-of select="@part" /></xsl:with-param>
 244                                 </xsl:call-template>
 245                         </xsl:if>
 246                         <xsl:if test="@id">
 247                                 <xsl:text>#</xsl:text>
 248                                 <xsl:call-template name="id-to-anchor-name"><xsl:with-param name="id"><xsl:value-of select="@id" /></xsl:with-param></xsl:call-template>
 249                         </xsl:if>
 250                 </xsl:attribute>
 251                 <xsl:choose>
 252                         <xsl:when test="node()">
 253                                 <xsl:apply-templates />
 254                         </xsl:when>
 255                         <xsl:when test="@part">
 256                                 <span class="filename">
 257                                         <xsl:call-template name="part-to-href">
 258                                                 <xsl:with-param name="name"><xsl:value-of select="@part" /></xsl:with-param>
 259                                         </xsl:call-template>
 260                                 </span>
 261                         </xsl:when>
 262                         <xsl:otherwise>
 263                                 <xsl:variable name="dstid">
 264                                         <xsl:value-of select="@id" />
 265                                 </xsl:variable>
 266                                 <xsl:apply-templates select="//section[@id=$dstid]/title" />
 267                                 <xsl:apply-templates select="//example-with-output[@id=$dstid]/@title" />
 268                         </xsl:otherwise>
 269                 </xsl:choose>
 270         </xsl:element>
 271 </xsl:template>
 272 <xsl:template match="a[@id]/title">
 273   <xsl:variable name="dstid">
 274     <xsl:value-of select="../@id" />
 275   </xsl:variable>
 276   <xsl:apply-templates select="//section[@id=$dstid]/title" />
 277 </xsl:template>
 278 <xsl:template match="a[@extension]">
 279         <xsl:element name="a">
 280                 <xsl:attribute name="href">
 281                         <xsl:call-template name="extension-to-href">
 282                                 <xsl:with-param name="name"><xsl:value-of select="@extension" /></xsl:with-param>
 283                         </xsl:call-template>
 284                         <xsl:if test="@id">
 285                                 <xsl:text>#</xsl:text>
 286                                 <xsl:call-template name="id-to-anchor-name"><xsl:with-param name="id"><xsl:value-of select="@id" /></xsl:with-param></xsl:call-template>
 287                         </xsl:if>
 288                 </xsl:attribute>
 289                 <span class="filename"><xsl:value-of select="@extension" /></span>
 290         </xsl:element>
 291 </xsl:template>
 292
 293 <xsl:template match='a[@method="google-lucky" and @query]'>
 294         <xsl:element name="a">
 295                 <xsl:attribute name="href">http://www.google.com/search?btnI=I%27m%20Feeling%20Lucky&amp;q=<xsl:value-of select="encode-for-uri(@query)" /></xsl:attribute>
 296                 <xsl:choose>
 297                         <xsl:when test="node()">
 298                                 <xsl:apply-templates />
 299                         </xsl:when>
 300                         <xsl:otherwise>
 301                                 <xsl:text>[</xsl:text><xsl:call-template name="str-Google" /><xsl:text>_lucky `</xsl:text><xsl:value-of select="@query" /><xsl:text>´]</xsl:text>
 302                         </xsl:otherwise>
 303                 </xsl:choose>
 304         </xsl:element>
 305 </xsl:template>
 306 <xsl:template match='a[@method="google" and @query]'>
 307         <xsl:element name="a">
 308                 <xsl:attribute name="href">http://www.google.com/search?q=<xsl:value-of select="encode-for-uri(@query)" /></xsl:attribute>
 309                 <xsl:choose>
 310                         <xsl:when test="node()">
 311                                 <xsl:apply-templates />
 312                         </xsl:when>
 313                         <xsl:otherwise>
 314                                 <xsl:text>[</xsl:text><xsl:call-template name="str-Google" /><xsl:text> `</xsl:text><xsl:value-of select="@query" /><xsl:text>´]</xsl:text>
 315                         </xsl:otherwise>
 316                 </xsl:choose>
 317         </xsl:element>
 318 </xsl:template>
 319 <xsl:template match="a[@query]/query">
 320   <xsl:value-of select="../@query" />
 321 </xsl:template>
 322
 323 <xsl:template name="name-to-linked-type">
 324   <xsl:param name="name" />
 325   <xsl:element name="a">
 326     <xsl:attribute name="class">discrete</xsl:attribute>
 327     <xsl:attribute name="href"><xsl:call-template name="part-to-href"><xsl:with-param name="name">types</xsl:with-param></xsl:call-template>#type:<xsl:value-of select="$name" /></xsl:attribute>
 328     <xsl:call-template name="format-type-name">
 329       <xsl:with-param name="name"><xsl:value-of select="$name" /></xsl:with-param>
 330     </xsl:call-template>
 331   </xsl:element>
 332 </xsl:template>
 333 <xsl:template name="name-to-linked-statetype">
 334   <xsl:param name="name" />
 335   <xsl:element name="a">
 336     <xsl:attribute name="class">discrete</xsl:attribute>
 337     <xsl:attribute name="href"><xsl:call-template name="part-to-href"><xsl:with-param name="name">stete-types</xsl:with-param></xsl:call-template>#statetype:<xsl:value-of select="$name" /></xsl:attribute>
 338     <xsl:call-template name="format-type-name">
 339       <xsl:with-param name="name"><xsl:value-of select="$name" /></xsl:with-param>
 340     </xsl:call-template>
 341   </xsl:element>
 342 </xsl:template>
 343
 344 <xsl:template match="named-type[@name and not(@link)]">
 345   <xsl:call-template name="name-to-linked-type">
 346     <xsl:with-param name="name"><xsl:value-of select="@name" /></xsl:with-param>
 347   </xsl:call-template>
 348 </xsl:template>
 349 <xsl:template match="named-type[@name and @link='no']">
 350   <xsl:call-template name="format-type-name">
 351     <xsl:with-param name="name"><xsl:value-of select="@name" /></xsl:with-param>
 352   </xsl:call-template>
 353 </xsl:template>
 354
 355 <xsl:template match="named-statetype[@name and not(@link)]">
 356   <xsl:call-template name="name-to-linked-statetype">
 357     <xsl:with-param name="name"><xsl:value-of select="@name" /></xsl:with-param>
 358   </xsl:call-template>
 359 </xsl:template>
 360 <xsl:template match="named-statetype[@name and @link='no']">
 361   <xsl:call-template name="format-statetype-name">
 362     <xsl:with-param name="name"><xsl:value-of select="@name" /></xsl:with-param>
 363   </xsl:call-template>
 364 </xsl:template>
 365
 366 <xsl:template name="format-template-type-name">
 367   <xsl:param name="name" />
 368   <span class="typename template">§<xsl:value-of select="$name" /></span>
 369 </xsl:template>
 370 <xsl:template name="format-template-statetype-name">
 371   <xsl:param name="name" />
 372   <span class="typename template">§•<xsl:value-of select="$name" /></span>
 373 </xsl:template>
 374
 375 <xsl:template match="template-type[@name]">
 376   <xsl:call-template name="format-template-type-name">
 377     <xsl:with-param name="name"><xsl:value-of select="@name" /></xsl:with-param>
 378   </xsl:call-template>
 379 </xsl:template>
 380 <xsl:template match="template-statetype[@name]">
 381   <xsl:call-template name="format-template-statetype-name">
 382     <xsl:with-param name="name"><xsl:value-of select="@name" /></xsl:with-param>
 383   </xsl:call-template>
 384 </xsl:template>
 385
 386 <xsl:template name="format-mutator-name">
 387         <xsl:param name="name" />
 388         <span class="varname"><xsl:value-of select="$name" /></span>
 389 </xsl:template>
 390 <xsl:template name="name-to-linked-mutator">
 391         <xsl:param name="extension" />
 392         <xsl:param name="extension-href" />
 393         <xsl:param name="type" />
 394         <xsl:param name="name" />
 395         <xsl:element name="a">
 396                 <xsl:attribute name="class">discrete</xsl:attribute>
 397                 <xsl:attribute name="href">
 398                         <xsl:choose>
 399                                 <xsl:when test="$extension">
 400                                         <xsl:call-template name="extension-to-href"><xsl:with-param name="name"><xsl:value-of select="$extension" /></xsl:with-param></xsl:call-template>#mutator:<xsl:value-of select="$type" />:<xsl:value-of select="$name" />
 401                                 </xsl:when>
 402                                 <xsl:when test="$extension-href">
 403                                         <xsl:value-of select="$extension-href" />#mutator:<xsl:value-of select="$type" />:<xsl:value-of select="$name" />
 404                                 </xsl:when>
 405                                 <xsl:otherwise>
 406                                         <xsl:call-template name="part-to-href"><xsl:with-param name="name">statetypes</xsl:with-param></xsl:call-template>#mutator:<xsl:value-of select="$type" />:<xsl:value-of select="$name" />
 407                                 </xsl:otherwise>
 408                         </xsl:choose>
 409                 </xsl:attribute>
 410                 <xsl:call-template name="format-statetype-name">
 411                         <xsl:with-param name="name"><xsl:value-of select="$type" /></xsl:with-param>
 412                 </xsl:call-template>
 413                 <span class="inline">/</span>
 414                 <xsl:call-template name="format-mutator-name">
 415                         <xsl:with-param name="name"><xsl:value-of select="$name" /></xsl:with-param>
 416                 </xsl:call-template>
 417         </xsl:element>
 418 </xsl:template>
 419 <xsl:template match="mutator[@type and @name and not(@extension)]">
 420         <xsl:call-template name="name-to-linked-mutator">
 421                 <xsl:with-param name="type"><xsl:value-of select="@type" /></xsl:with-param>
 422                 <xsl:with-param name="name"><xsl:value-of select="@name" /></xsl:with-param>
 423         </xsl:call-template>
 424 </xsl:template>
 425 <xsl:template match="mutator[@type and @name and @extension]">
 426         <xsl:call-template name="name-to-linked-mutator">
 427                 <xsl:with-param name="extension"><xsl:value-of select="@extension" /></xsl:with-param>
 428                 <xsl:with-param name="type"><xsl:value-of select="@type" /></xsl:with-param>
 429                 <xsl:with-param name="name"><xsl:value-of select="@name" /></xsl:with-param>
 430         </xsl:call-template>
 431 </xsl:template>
 432
 433 <xsl:template name="name-to-tol-param">
 434         <xsl:param name="name" />
 435         <span class="tolparam"><xsl:value-of select="@name" /></span>
 436 </xsl:template>
 437 <xsl:template match="tol-param[@name and @link='no']">
 438         <xsl:call-template name="name-to-operator">
 439                 <xsl:with-param name="name"><xsl:value-of select="@name" /></xsl:with-param>
 440         </xsl:call-template>
 441 </xsl:template>
 442 <xsl:template match="tol-param[@name and not(@link)]">
 443         <xsl:element name="a">
 444                 <xsl:attribute name="class">discrete</xsl:attribute>
 445                 <xsl:attribute name="href"><xsl:call-template name="part-to-href"><xsl:with-param name="name">algo-tol</xsl:with-param></xsl:call-template>#tol-<xsl:value-of select="@name" /></xsl:attribute>
 446                 <xsl:call-template name="name-to-operator">
 447                         <xsl:with-param name="name"><xsl:value-of select="@name" /></xsl:with-param>
 448                 </xsl:call-template>
 449         </xsl:element>
 450 </xsl:template>
 451
 452 <xsl:template name="name-to-operator">
 453         <xsl:param name="name" />
 454         <span class="inline"><xsl:value-of select="$name" /></span>
 455 </xsl:template>
 456 <xsl:template match="operator[@name]">
 457         <xsl:call-template name="name-to-operator">
 458                 <xsl:with-param name="name"><xsl:value-of select="@name" /></xsl:with-param>
 459         </xsl:call-template>
 460 </xsl:template>
 461 <xsl:template name="name-to-operator-unary-prefix">
 462         <xsl:param name="name" />
 463         <span class="inline"><xsl:value-of select="$name" /></span>
 464 </xsl:template>
 465 <xsl:template match="operator-unary-prefix[@name]">
 466         <xsl:call-template name="name-to-operator-unary-prefix">
 467                 <xsl:with-param name="name"><xsl:value-of select="@name" /></xsl:with-param>
 468         </xsl:call-template>
 469 </xsl:template>
 470
 471 <xsl:template name="format-namespace-name">
 472   <xsl:param name="name" />
 473   <span class="inline"><xsl:value-of select="$name" /></span>
 474 </xsl:template>
 475 <xsl:template name="name-to-linked-namespace">
 476   <xsl:param name="name" />
 477   <xsl:element name="a">
 478     <xsl:attribute name="class">discrete</xsl:attribute>
 479     <xsl:attribute name="href">
 480       <xsl:call-template name="namespace-to-href"><xsl:with-param name="name"><xsl:value-of select="$name" /></xsl:with-param></xsl:call-template>
 481     </xsl:attribute>
 482     <xsl:call-template name="format-namespace-name">
 483       <xsl:with-param name="name"><xsl:value-of select="$name" /></xsl:with-param>
 484     </xsl:call-template>
 485   </xsl:element>
 486 </xsl:template>
 487 <xsl:template match="user-namespace[@name]">
 488   <xsl:call-template name="format-namespace-name">
 489     <xsl:with-param name="name"><xsl:value-of select="@name" /></xsl:with-param>
 490   </xsl:call-template>
 491 </xsl:template>
 492 <xsl:template match="namespace[@name]">
 493   <xsl:call-template name="name-to-linked-namespace">
 494     <xsl:with-param name="name"><xsl:value-of select="@name" /></xsl:with-param>
 495   </xsl:call-template>
 496 </xsl:template>
 497 <xsl:template match="namespace[@current and @relative]">
 498   <xsl:element name="a">
 499     <xsl:attribute name="class">discrete</xsl:attribute>
 500     <xsl:attribute name="href">
 501       <xsl:call-template name="namespace-to-href"><xsl:with-param name="name"><xsl:value-of select="@current" />..<xsl:value-of select="@relative" /></xsl:with-param></xsl:call-template>
 502     </xsl:attribute>
 503     <xsl:call-template name="format-namespace-name">
 504       <xsl:with-param name="name"><xsl:value-of select="@relative" /></xsl:with-param>
 505     </xsl:call-template>
 506   </xsl:element>
 507 </xsl:template>
 508 <xsl:template match="/book[namespace]//namespace[@relative and not(@current)]">
 509   <xsl:element name="a">
 510     <xsl:attribute name="class">discrete</xsl:attribute>
 511     <xsl:attribute name="href">
 512       <xsl:call-template name="namespace-to-href"><xsl:with-param name="name"><xsl:value-of select="/book/namespace" />..<xsl:value-of select="@relative" /></xsl:with-param></xsl:call-template>
 513     </xsl:attribute>
 514     <xsl:call-template name="format-namespace-name">
 515       <xsl:with-param name="name"><xsl:value-of select="@relative" /></xsl:with-param>
 516     </xsl:call-template>
 517   </xsl:element>
 518 </xsl:template>
 519
 520 <xsl:template match="em"><em><xsl:apply-templates/></em></xsl:template>
 521 <xsl:template match="b"><b><xsl:apply-templates/></b></xsl:template>
 522 <xsl:template match="weak"><span class="weak"><xsl:apply-templates/></span></xsl:template>
 523 <xsl:template match="inline"><span class="inline"><xsl:apply-templates/></span></xsl:template>
 524 <xsl:template match="bnf"><span class="bnf"><xsl:apply-templates/></span></xsl:template>
 525 <xsl:template match="union-type">
 526         <span class="typename"><xsl:text>( </xsl:text></span>
 527         <xsl:for-each select="./*">
 528                 <xsl:if test="position() > 1">
 529                         <span class="typename"><xsl:text>| </xsl:text></span>
 530                 </xsl:if>
 531                 <xsl:apply-templates select="." />
 532                 <xsl:text> </xsl:text>
 533         </xsl:for-each>
 534         <span class="typename">)</span>
 535 </xsl:template>
 536 <xsl:template match="structure-type">
 537         <span class="typename"><xsl:text>(&gt; </xsl:text></span>
 538         <xsl:for-each select="field">
 539                 <xsl:if test="@name">
 540                         <xsl:value-of select="@name" /><xsl:text>::</xsl:text>
 541                 </xsl:if>
 542                 <xsl:if test="not(@name)">
 543                         <xsl:value-of select="position( )" /><xsl:text>::</xsl:text>
 544                 </xsl:if>
 545                 <xsl:if test="not(type)">
 546                         <span class="typename">Any-Type</span>
 547                 </xsl:if>
 548                 <xsl:apply-templates select="type" />
 549                 <xsl:text> </xsl:text>
 550         </xsl:for-each>
 551         <span class="typename">&lt;)</span>
 552 </xsl:template>
 553 <xsl:template match="structure-type/field">
 554 </xsl:template>
 555 <xsl:template match="function-type">
 556         <span class="typename"><xsl:text>( </xsl:text></span>
 557         <xsl:apply-templates select="arguments" />
 558         <xsl:text> → </xsl:text>
 559         <xsl:apply-templates select="result" />
 560         <span class="typename"><xsl:text> )</xsl:text></span>
 561 </xsl:template>
 562 <xsl:template match="typename"><span class="typename"><xsl:apply-templates/></span></xsl:template>
 563 <xsl:template match="typename[@class='replacable']">
 564   <span class="typename replacable"><xsl:apply-templates/></span>
 565 </xsl:template>
 566 <xsl:template match="replacable-text[@name]">
 567   <span class="varname replacable"><xsl:value-of select="@name" /></span>
 568 </xsl:template>
 569
 570 <xsl:template name="name-to-argument">
 571         <xsl:param name="name" />
 572         <xsl:param name="class" />
 573         <xsl:element name="span">
 574                 <xsl:attribute name="class">varname <xsl:value-of select="$class" /></xsl:attribute>
 575                 <xsl:value-of select="$name" />
 576         </xsl:element>
 577 </xsl:template>
 578 <xsl:template match="p/arg[@name] | td/arg[@name]">
 579         <xsl:call-template name="name-to-argument">
 580                 <xsl:with-param name="name"><xsl:value-of select="@name" /></xsl:with-param>
 581                 <xsl:with-param name="class"><xsl:value-of select="@class" /></xsl:with-param>
 582         </xsl:call-template>
 583 </xsl:template>
 584
 585 <xsl:template name="name-to-state-argument">
 586         <xsl:param name="name" />
 587         <xsl:param name="class" />
 588         <xsl:element name="span">
 589                 <xsl:attribute name="class">varname <xsl:value-of select="$class" /></xsl:attribute>
 590                 <xsl:call-template name="format-state-name">
 591                         <xsl:with-param name="name"><xsl:value-of select="$name" /></xsl:with-param>
 592                 </xsl:call-template>
 593         </xsl:element>
 594 </xsl:template>
 595 <xsl:template match="state-arg[@name]">
 596         <xsl:call-template name="name-to-state-argument">
 597                 <xsl:with-param name="name"><xsl:value-of select="@name" /></xsl:with-param>
 598                 <xsl:with-param name="class"><xsl:value-of select="@class" /></xsl:with-param>
 599         </xsl:call-template>
 600 </xsl:template>
 601
 602 <xsl:template match="field[@name and not(@class)]">
 603   <span class="varname"><xsl:value-of select="@name" /></span>
 604 </xsl:template>
 605 <xsl:template match="field[@name and @class='replacable']">
 606   <span class="varname replacable"><xsl:value-of select="@name" /></span>
 607 </xsl:template>
 608
 609 <xsl:template match="lexerregexp">
 610   <span class="lexerregexp"><xsl:apply-templates/></span>
 611 </xsl:template>
 612 <xsl:template match="syntax[@name and @class='new']">
 613   <xsl:element name="a">
 614     <xsl:attribute name="name">stx-.<xsl:value-of select="@name" /></xsl:attribute>
 615     <span class="syntaxname-new"><xsl:value-of select="@name"/></span>
 616   </xsl:element>
 617 </xsl:template>
 618 <xsl:template match="syntax[@name and not(@class)]">
 619   <xsl:element name="a">
 620     <xsl:attribute name="class">discrete</xsl:attribute>
 621     <xsl:attribute name="href"><xsl:call-template name="part-to-href"><xsl:with-param name="name">syntax</xsl:with-param></xsl:call-template>#stx-.<xsl:value-of select="@name" /></xsl:attribute>
 622     <span class="syntaxname"><xsl:value-of select="@name"/></span>
 623   </xsl:element>
 624 </xsl:template>
 625 <xsl:template match="a[@href]">
 626   <xsl:element name="a">
 627     <xsl:attribute name="href"><xsl:value-of select="@href" /></xsl:attribute>
 628     <xsl:apply-templates/>
 629   </xsl:element>
 630 </xsl:template>
 631
 632 <xsl:template match="unit">
 633   <xsl:element name="span">
 634     <xsl:attribute name="class">
 635       <xsl:text>unit</xsl:text>
 636       <xsl:if test="@class"><xsl:text> </xsl:text><xsl:value-of select="@class" /></xsl:if>
 637     </xsl:attribute>
 638     <xsl:apply-templates/>
 639   </xsl:element>
 640 </xsl:template>
 641
 642 <xsl:template match="filename"><span class="filename"><xsl:value-of select="." /></span></xsl:template>
 643 <xsl:template match="progname"><span class="terminal"><xsl:value-of select="." /></span></xsl:template>
 644 <xsl:template match="command-line">
 645 <pre class="terminal">
 646 <xsl:apply-templates/>
 647 </pre>
 648 </xsl:template>
 649
 650 <xsl:template match="tight-table">
 651   <table class="tight"><xsl:apply-templates select="head/tr | body/tr"/></table>
 652 </xsl:template>
 653 <xsl:template match="loose-table">
 654   <table class="loose"><xsl:apply-templates select="head/tr | body/tr"/></table>
 655 </xsl:template>
 656
 657 <xsl:template match="tr">
 658   <tr><xsl:apply-templates/></tr>
 659 </xsl:template>
 660 <xsl:template match="tr[@align]">
 661   <xsl:element name="tr">
 662     <xsl:attribute name="align"><xsl:value-of select="./@align" /></xsl:attribute>
 663     <xsl:apply-templates/>
 664   </xsl:element>
 665 </xsl:template>
 666 <xsl:template match="head/tr/td">
 667   <th><xsl:apply-templates/></th>
 668 </xsl:template>
 669 <xsl:template match="td">
 670   <td><xsl:apply-templates/></td>
 671 </xsl:template>
 672 <xsl:template match="th">
 673   <th><xsl:apply-templates/></th>
 674 </xsl:template>
 675 <xsl:template match="th[@colspan]">
 676   <xsl:element name="th">
 677     <xsl:attribute name="colspan"><xsl:value-of select="./@colspan" /></xsl:attribute>
 678     <xsl:apply-templates/>
 679   </xsl:element>
 680 </xsl:template>
 681
 682 <xsl:template match="img">
 683         <xsl:choose>
 684                 <xsl:when test="@target">
 685                         <xsl:element name="a">
 686                                 <xsl:attribute name="href"><xsl:value-of select="iri-to-uri(replace(@src,'%','%25'))" /></xsl:attribute>
 687                                 <xsl:attribute name="target"><xsl:value-of select="@target" /></xsl:attribute>
 688                                 <xsl:element name="img">
 689                                         <xsl:if test="@class">
 690                                                 <xsl:attribute name="class"><xsl:value-of select="@class" /></xsl:attribute>
 691                                         </xsl:if>
 692                                         <xsl:attribute name="src"><xsl:value-of select="iri-to-uri(replace(@src,'%','%25'))" /></xsl:attribute>
 693                                         <xsl:attribute name="alt"><xsl:value-of select="@alt" /></xsl:attribute>
 694                                         <xsl:if test="@width"><xsl:attribute name="width"><xsl:value-of select="@width" /></xsl:attribute></xsl:if>
 695                                         <xsl:if test="@height"><xsl:attribute name="height"><xsl:value-of select="@height" /></xsl:attribute></xsl:if>
 696                                 </xsl:element>
 697                         </xsl:element>
 698                 </xsl:when>
 699                 <xsl:otherwise>
 700                         <xsl:element name="img">
 701                                         <xsl:if test="@class">
 702                                                 <xsl:attribute name="class"><xsl:value-of select="@class" /></xsl:attribute>
 703                                         </xsl:if>
 704                                 <xsl:attribute name="src"><xsl:value-of select="iri-to-uri(replace(@src,'%','%25'))" /></xsl:attribute>
 705                                 <xsl:attribute name="alt"><xsl:value-of select="@alt" /></xsl:attribute>
 706                                 <xsl:if test="@width"><xsl:attribute name="width"><xsl:value-of select="@width" /></xsl:attribute></xsl:if>
 707                                 <xsl:if test="@height"><xsl:attribute name="height"><xsl:value-of select="@height" /></xsl:attribute></xsl:if>
 708                         </xsl:element>
 709                 </xsl:otherwise>
 710         </xsl:choose>
 711 </xsl:template>
 712 <xsl:template match="figure[image]">
 713         <div class="p">
 714                 <table class="figure">
 715                         <tr align="center"><td>
 716                                 <xsl:if test="@id">
 717                                         <xsl:element name="a">
 718                                                 <xsl:attribute name="name"><xsl:call-template name="id-to-anchor-name"><xsl:with-param name="id"><xsl:value-of select="@id" /></xsl:with-param></xsl:call-template></xsl:attribute>
 719                                         </xsl:element>
 720                                 </xsl:if>
 721                                 <xsl:apply-templates select="image/*" />
 722                         </td></tr>
 723                         <tr><td class="here-caption">
 724                                 <xsl:apply-templates select="caption/*" />
 725                         </td></tr>
 726                 </table>
 727         </div>
 728 </xsl:template>
 729
 730
 731 <xsl:template match="arguments">
 732         <xsl:apply-templates select="arg | state"/>
 733         <xsl:apply-templates select="sink"/>
 734 </xsl:template>
 735
 736 <xsl:template match="arguments/arg">
 737         <xsl:if test="@identifier">
 738                 <xsl:call-template name="name-to-argument"><xsl:with-param name="name"><xsl:value-of select="@identifier" /></xsl:with-param></xsl:call-template>
 739         </xsl:if>
 740         <xsl:apply-templates select="default"/>
 741         <xsl:apply-templates select="type"/>
 742         <xsl:text>   </xsl:text>
 743 </xsl:template>
 744 <xsl:template match="arguments/arg/default">:<xsl:apply-templates /></xsl:template>
 745 <xsl:template match="arguments/arg/type"><xsl:text>::</xsl:text><xsl:apply-templates /></xsl:template>
 746
 747 <xsl:template match="arguments/state[@identifier]">
 748         <xsl:call-template name="name-to-state-argument"><xsl:with-param name="name"><xsl:value-of select="@identifier" /></xsl:with-param></xsl:call-template>
 749         <xsl:apply-templates select="type"/>
 750         <xsl:text>   </xsl:text>
 751 </xsl:template>
 752 <xsl:template match="arguments/state[not(@identifier)]">
 753         <xsl:apply-templates select="type"/>
 754         <xsl:text>   </xsl:text>
 755 </xsl:template>
 756 <xsl:template match="arguments/state/type"><xsl:text>::</xsl:text><xsl:apply-templates /></xsl:template>
 757
 758 <xsl:template match="arguments/sink[@identifier]">
 759         <xsl:text>&lt;&gt;</xsl:text><xsl:call-template name="name-to-argument"><xsl:with-param name="name"><xsl:value-of select="@identifier" /></xsl:with-param></xsl:call-template>
 760         <xsl:apply-templates select="type"/>
 761         <xsl:text>   </xsl:text>
 762 </xsl:template>
 763 <xsl:template match="arguments/sink[not(@identifier)]">
 764         <xsl:text>&lt;&gt;</xsl:text>
 765         <xsl:apply-templates select="type"/>
 766         <xsl:text>   </xsl:text>
 767 </xsl:template>
 768 <xsl:template match="arguments/sink/type"><xsl:text>::{</xsl:text><xsl:apply-templates /><xsl:text>}</xsl:text></xsl:template>
 769
 770 <xsl:template match="type-templates">
 771         <table class="type-templates">
 772                 <xsl:apply-templates />
 773         </table>
 774 </xsl:template>
 775 <xsl:template match="type-templates/template[@name]">
 776         <tr>
 777                 <td align="right"><xsl:call-template name="format-template-type-name"><xsl:with-param name="name"><xsl:value-of select="@name" /></xsl:with-param></xsl:call-template>  </td>
 778                 <td>
 779                         <xsl:apply-templates select="description"/>
 780                 </td>
 781         </tr>
 782 </xsl:template>
 783 <xsl:template match="type-templates/template-state[@name]">
 784         <tr>
 785                 <td align="right"><xsl:call-template name="format-template-statetype-name"><xsl:with-param name="name"><xsl:value-of select="@name" /></xsl:with-param></xsl:call-template>  </td>
 786                 <td>
 787                         <xsl:apply-templates select="description"/>
 788                 </td>
 789         </tr>
 790 </xsl:template>
 791
 792 <xsl:template match="book[namespace and not(extension)]/title/self">
 793   <xsl:value-of select="../../namespace" />
 794 </xsl:template>
 795 <xsl:template match="/book[namespace and not(extension)]/top/p/self">
 796   <xsl:call-template name="format-namespace-name">
 797     <xsl:with-param name="name"><xsl:value-of select="/book/namespace" /></xsl:with-param>
 798   </xsl:call-template>
 799 </xsl:template>
 800
 801 <xsl:template match="book[namespace and extension]/title/self">
 802   <xsl:value-of select="../../extension" />
 803 </xsl:template>
 804 <xsl:template match="/book[namespace and extension]/top/p/self">
 805   <span class="filename"><xsl:value-of select="ancestor::book/extension" /></span>
 806 </xsl:template>
 807
 808 <xsl:template match="book[namespace and not(extension)]/meta-selflink/self-href">
 809   <xsl:call-template name="namespace-to-href">
 810     <xsl:with-param name="name"><xsl:value-of select="../../namespace" /></xsl:with-param>
 811   </xsl:call-template>
 812 </xsl:template>
 813 <xsl:template match="book[namespace and extension]/meta-selflink/self-href">
 814   <xsl:call-template name="extension-to-href">
 815     <xsl:with-param name="namespace"><xsl:value-of select="../../namespace" /></xsl:with-param>
 816     <xsl:with-param name="name"><xsl:value-of select="../../extension" /></xsl:with-param>
 817   </xsl:call-template>
 818 </xsl:template>
 819
 820 <xsl:template match="book[namespace and not(extension)]/up-link/parent-namespace">
 821   <xsl:variable name="ns"><xsl:value-of select="../../namespace" /></xsl:variable>
 822   <xsl:call-template name="name-to-linked-namespace">
 823     <xsl:with-param name="name"><xsl:value-of select="replace($ns, '\.\.[^.]*$', '')" /></xsl:with-param>
 824   </xsl:call-template>
 825 </xsl:template>
 826 <xsl:template match="book[namespace and extension]/up-link/parent-namespace">
 827   <xsl:call-template name="name-to-linked-namespace">
 828     <xsl:with-param name="name"><xsl:value-of select="../../namespace" /></xsl:with-param>
 829   </xsl:call-template>
 830 </xsl:template>
 831
 832 <xsl:template name="SF-placeholder" >
 833         <xsl:comment>PUT-SF-LOGO-HERE</xsl:comment>
 834 </xsl:template>
 835
 836 <xsl:template match="eq"><span class="eq"><xsl:apply-templates/></span></xsl:template>
 837 <xsl:template match="eq//op"><span class="rm"><xsl:apply-templates/></span></xsl:template>
 838 <xsl:template match="eq//rm"><span class="rm"><xsl:apply-templates/></span></xsl:template>
 839 <xsl:template match="eq//text"><span class="text"><xsl:apply-templates/></span></xsl:template>
 840 <xsl:template match="eq//sub"><sub><xsl:apply-templates/></sub></xsl:template>
 841 <xsl:template match="eq//sup"><sup><xsl:apply-templates/></sup></xsl:template>
 842
 843 </xsl:stylesheet>