| blob | 60cf2e7cec6463a090974edde0ceacdf8d6d1d1c |
1 #
2 # SpeakGoodChinese 2.0
3 #
4 # Master Praat script
5 #
6 # SpeakGoodChinese: sgc2.praat is the master GUI of SpeakGoodChinese
7 # It is written in Praat script for the Demo window
8 #
9 # Copyright (C) 2007-2010 R.J.J.H. van Son and 2010 the Netherlands Cancer Institute
10 # The SpeakGoodChinese team are:
11 # Guangqin Chen, Zhonyan Chen, Stefan de Koning, Eveline van Hagen,
12 # Rob van Son, Dennis Vierkant, David Weenink
13 #
14 # This program is free software; you can redistribute it and/or modify
15 # it under the terms of the GNU General Public License as published by
16 # the Free Software Foundation; either version 2 of the License, or
17 # (at your option) any later version.
18 #
19 # This program is distributed in the hope that it will be useful,
20 # but WITHOUT ANY WARRANTY; without even the implied warranty of
21 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
22 # GNU General Public License for more details.
23 #
24 # You should have received a copy of the GNU General Public License
25 # along with this program; if not, write to the Free Software
26 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA
27 #
28 # The real application name
29 sgc2.demoAppName$ = "SpeakGoodChinese2"
31 # Define variable that might be reset in Initialise*.praat
32 if not variableExists("build_SHA$")
33 build_SHA$ = "-"
34 endif
36 # These are simply "useful" defaults
37 localTableDir$ = "Data"
38 buttonsTableName$ = "MainPage"
39 configTableName$ = "Config"
40 buttons$ = ""
41 config$ = ""
42 recordedSound$ = ""
43 samplingFrequency = 44100
44 recordingTime = 4
46 # Pop-Up window colors
47 sgc2.popUp_bordercolor$ = "{0.5,0.5,1}"
48 sgc2.popUp_backgroundcolor$ = "{0.9,0.9,1}"
50 # If running in a packed script binary
51 if index_regex(preferencesDirectory$, "(?i'sgc2.demoAppName$')$")
52 preferencesAppDir$ = preferencesDirectory$
53 elsif index_regex(preferencesDirectory$, "[pP]raat(\-dir| Prefs)?$")
54 # If running as a Praat script, create a new preferences directory
55 if unix
56 preferencesAppDir$ = "'preferencesDirectory$'/../.'sgc2.demoAppName$'"
57 else
58 preferencesAppDir$ = "'preferencesDirectory$'/../'sgc2.demoAppName$'"
59 endif
60 else
61 # It has to go somewhere. Make a subdirectory in the current preferences directory
62 preferencesAppDir$ = "'preferencesDirectory$'/'sgc2.demoAppName$'"
63 endif
66 # Parameters for isolating recorded speech from noise
67 # Should be mostly left alone unless you are using ultra clean
68 # or very noisy recordings
69 noiseThresshold = -30
70 minimumPitch = 60
71 soundMargin = 0.25
72 minimumIntensity = 30
74 # Set up button height
75 buttonbevel = 0
77 # Define canvas
78 viewportMargin = 5
79 defaultFontSize = 12
80 defaultFont$ = "Helvetica"
81 defaultLineWidth = 1
83 # Set up system
84 call reset_viewport
86 # Load supporting scripts
87 # Load tables in script format
88 include CreateTables.praat
89 include CreateWordlists.praat
90 # Set up system and load preferences
91 include InitialiseSGC2.praat
92 # Include the main page buttons and procedures
93 include MainPage.praat
94 # Include the configuration page buttons and procedures
95 include Config.praat
97 # Start instruction loop
98 while demoWaitForInput()
99 .label$ = ""
100 .clickX = -1
101 .clickY = -1
102 .pressed$ = ""
103 if demoClicked()
104 .clickX = demoX()
105 .clickY = demoY()
106 call buttonClicked 'buttons$' '.clickX' '.clickY'
107 .label$ = buttonClicked.label$
108 elsif demoKeyPressed()
109 .pressed$ = demoKey$()
110 call keyPressed 'buttons$' '.pressed$'
111 .label$ = keyPressed.label$
112 endif
114 # You cannot select a text field
115 if startsWith(.label$, "$")
116 .label$ = ""
117 endif
119 # Do things
120 if .label$ != ""
121 # Push button down
122 call Draw_button 'buttons$' '.label$' 1
123 call process_label '.label$' '.clickX' '.clickY' '.pressed$'
124 # push button up
125 call Draw_button 'buttons$' '.label$' 0
126 endif
127 endwhile
129 call end_program
132 ########################################################
133 #
134 # Definitions of procedures
135 #
136 ########################################################
137 #
138 # Do what is asked
139 procedure process_label .label$ .clickX .clickY .pressed$
140 # Log raw commands to replay in file
141 call log_command 'buttons$' '.label$' '.clickX' '.clickY' '.pressed$'
143 # Prcoess the command
144 if .label$ <> "" and not startsWith(.label$,"!")
145 .label$ = replace$(.label$, "_", " ", 0)
146 call process'buttons$''.label$' '.clickX' '.clickY' '.pressed$'
147 endif
148 endproc
150 # Intialize buttons
151 procedure init_buttons
152 noerase = 1
153 call Draw_all_buttons 'buttons$'
154 noerase = 0
155 endproc
157 # Draw all buttons
158 noerase = 0
159 procedure Draw_all_buttons .table$
160 .varPrefix$ = replace_regex$(.table$, "^(.)", "\l\1", 0)
161 select Table '.table$'
162 .numRows = Get number of rows
164 for .row to .numRows
165 .label$ = Get value... '.row' Label
166 if not startsWith(.label$, "!")
167 .pressed = 0
168 # Determine the "pressed" state of a button
169 # A variable with the same name as the button will act as a
170 # "pressed state"
171 .variableName$ = .varPrefix$+"."+(replace_regex$(.label$, "^(.)", "\l\1", 0))
172 # Simple boolean vairables
173 if index(.variableName$, "_") <= 0 and variableExists(.variableName$)
174 # True: Pressed
175 if '.variableName$' > 0
176 .pressed = 2
177 # <0: Grayed out
178 elsif '.variableName$' < 0
179 .pressed = -1
180 endif
181 # Complex buttons with an variableName+'_'+value structure
182 # varableName$ -> name of button, e.g., "language"
183 elsif index(.variableName$, "_")
184 .generalVar$ = left$(.variableName$, rindex(.variableName$, "_") - 1)
185 .currentVariableName$ = .generalVar$
186 # Is it a string?
187 if variableExists(.generalVar$+"$")
188 .currentVariableName$ = .generalVar$ + "$"
189 endif
190 # Remove one level of indirection
191 if variableExists(.currentVariableName$)
192 if index(.currentVariableName$, "$")
193 .currentVariableName$ = '.currentVariableName$'
194 else
195 .currentValue = '.currentVariableName$'
196 .currentVariableName$ = "'.currentValue'"
197 endif
198 # Remove next level of indirection
199 .currentContent$ = "'.currentVariableName$'"
200 if .currentContent$ = "_DISABLED_"
201 .pressed = -1
202 endif
203 # Reconstruct label from current values
204 .currentLabelValue$ = .generalVar$ + "_" + .currentContent$
205 # Set PRESSED from label
206 if .variableName$ = .currentLabelValue$
207 .pressed = 2
208 endif
209 endif
210 endif
211 # You did erase everything before you started here? So do not do that again
212 call Draw_button_internal 0 '.table$' '.label$' '.pressed'
213 endif
214 endfor
215 endproc
217 # Draw a button from a predefined button table
218 # Normally, erase the area around a button
219 procedure Draw_button .table$ .label$ .push
220 call Draw_button_internal 1 '.table$' '.label$' '.push'
221 endproc
223 # Use this function if you want to control erasing
224 procedure Draw_button_internal .erase_button_area .table$ .label$ .push
225 # Scale rounding of rounded rectangles
226 .wc = 1
227 .mm = demo Horizontal wc to mm... '.wc'
228 # Allow to overide ! skip directive
229 .forceDraw = 0
230 if startsWith(.label$, "+")
231 .label$ = right$(.label$, length(.label$)-1)
232 .forceDraw = 1
233 endif
235 select Table '.table$'
236 .row = Search column... Label '.label$'
237 if .row < 1
238 call emergency_table_exit Button Table '.table$' does not have a row with label '.label$'
239 endif
241 # Perspective shift sizes
242 .shiftDown = 0
243 .shiftX = 0
244 .shiftY = 0
245 if buttonbevel <> 0
246 .shiftDown = 0.05
247 .shiftX = 0.30
248 .shiftY = 0.50
249 endif
251 # Set drawing parameters
252 .topBackGroundColorUp$ = "{0.93,0.93,0.93}"
253 .topLineColorUp$ = "Black"
254 .topLineWidthUp = 1.5
255 .topBackGroundColorDown$ = "{0.89,0.89,0.94}"
256 .topLineColorDown$ = "{0.3,0.3,0.3}"
257 .topLineWidthDown = 1.5
258 .topBackGroundColorDisabled$ = "{0.85,0.85,0.85}"
259 .topLineColorDisabled$ = "{0.70,0.70,0.70}"
260 .topLineWidthDisabled = 1.5
261 .flankBackGroundColorUp$ = "{0.6,0.6,0.6}"
262 .flankLineColorUp$ = "{0.2,0.2,0.2}"
263 .flankLineWidthUp = 1.5
264 .flankBackGroundColorDown$ = "{0.75,0.75,0.75}"
265 .flankLineColorDown$ = .flankLineColorUp$
266 .flankLineWidthDown = 1.5
267 .buttonFontSize = defaultFontSize
269 # Get button values
270 .leftX = Get value... '.row' LeftX
271 .rightX = Get value... '.row' RightX
272 .lowY = Get value... '.row' LowY
273 .highY = Get value... '.row' HighY
274 .buttonText$ = Get value... '.row' Text
275 .buttonColor$ = Get value... '.row' Color
276 .buttonDraw$ = Get value... '.row' Draw
277 .buttonKey$ = Get value... '.row' Key
279 .rotation = 0
280 if index_regex(.buttonText$, "^![0-9\.]+!")
281 .rotation = extractNumber(.buttonText$, "!")
282 .buttonText$ = replace_regex$(.buttonText$, "^![0-9\.]+!", "", 0)
283 endif
285 goto NOBUTTON startsWith(.label$, "!") and not .forceDraw
287 # Replace button text with ALERT
288 if .push = 3
289 .buttonText$ = alertText$
290 endif
292 # Adapt font size to button size
293 .maxWidth = (.rightX - .leftX) - 2
294 .maxHeight = (.highY - .lowY) - 1
295 if .rotation = 0
296 # Adapt size of button to length of text if necessary
297 call adjustFontSizeOnWidth 'defaultFont$' '.buttonFontSize' '.maxWidth' '.buttonText$'
298 .buttonFontSize = adjustFontSizeOnWidth.newFontSize
299 if adjustFontSizeOnWidth.diff > 0
300 .rightX += adjustFontSizeOnWidth.diff/2
301 .leftX -= adjustFontSizeOnWidth.diff/2
302 endif
303 call set_font_size '.buttonFontSize'
305 # Adapt size of button to length of text
306 call adjustFontSizeOnHeight 'defaultFont$' '.buttonFontSize' '.maxHeight'
307 if adjustFontSizeOnHeight.diff > 0
308 .lowY -= adjustFontSizeOnHeight.diff/2
309 .highY += adjustFontSizeOnHeight.diff/2
310 endif
311 .buttonFontSize = adjustFontSizeOnHeight.newFontSize
312 else
313 # With non-horizontal text, only change font size
314 call adjustRotatedFontSizeOnBox 'defaultFont$' '.buttonFontSize' '.maxWidth' '.maxHeight' '.rotation' '.buttonText$'
315 .buttonFontSize = adjustRotatedFontSizeOnBox.newFontSize
316 endif
318 # Reset and erase button area
319 call reset_viewport
320 demo Line width... 'defaultLineWidth'
321 .shiftLeftX = .leftX - .shiftX
322 .shiftRightX = .rightX
323 .shiftLowY = .lowY - .shiftY
324 .shiftHighY = .highY
325 if .erase_button_area
326 # Make erase area minutely larger
327 .eraseLeft = .shiftLeftX - 0.01
328 .eraseRight = .shiftRightX + 0.01
329 .eraseBottom = .shiftLowY - 0.01
330 .eraseTop = .shiftHighY + 0.01
331 demo Paint rectangle... White .eraseLeft .eraseRight .eraseBottom .eraseTop
332 endif
334 # If label starts with "$", it is a text field. Then do not draw the button
335 if not startsWith(.label$, "$")
336 # Give some depth to button: Draw flank outline
337 if .shiftDown or .shiftX or .shiftY
338 if .push <= 0
339 demo Paint rounded rectangle... '.flankBackGroundColorUp$' .shiftLeftX .shiftRightX .shiftLowY .shiftHighY '.mm'
340 demo Colour... '.flankLineColorUp$'
341 demo Line width... '.flankLineWidthUp'
342 else
343 demo Paint rounded rectangle... '.flankBackGroundColorDown$' .shiftLeftX .shiftRightX .shiftLowY .shiftHighY '.mm'
344 demo Colour... '.flankLineColorDown$'
345 demo Line width... '.flankLineWidthDown'
346 endif
347 demo Draw rounded rectangle... .shiftLeftX .shiftRightX .shiftLowY .shiftHighY '.mm'
348 endif
350 # Button Down will shift the top perspective
352 # Draw the button top
353 if .push = 0
354 demo Paint rounded rectangle... '.topBackGroundColorUp$' '.leftX' '.rightX' '.lowY' '.highY' '.mm'
355 demo Colour... '.topLineColorUp$'
356 demo Line width... '.topLineWidthUp'
357 elsif .push < 0
358 demo Paint rounded rectangle... '.topBackGroundColorDisabled$' '.leftX' '.rightX' '.lowY' '.highY' '.mm'
359 demo Colour... '.topLineColorDisabled$'
360 demo Line width... '.topLineWidthDisabled'
361 else
362 # Button Down
363 .leftX -= .shiftDown
364 .rightX -= .shiftDown
365 .lowY -= .shiftDown
366 .highY -= .shiftDown
368 demo Paint rounded rectangle... '.topBackGroundColorDown$' .leftX .rightX .lowY .highY '.mm'
369 demo Colour... '.topLineColorDown$'
370 demo Line width... '.topLineWidthDown'
371 endif
372 demo Draw rounded rectangle... '.leftX' '.rightX' '.lowY' '.highY' '.mm'
373 endif
375 # The button text and symbol
376 .horWC = demo Horizontal mm to wc... 10.0
377 .verWC = demo Vertical mm to wc... 10.0
378 if .verWC > 0
379 .verCoeff = .horWC / .verWC
380 else
381 .verCoeff = 1
382 endif
384 .centerX = (.leftX + .rightX)/2
385 .centerY = .lowY + 0.6*(.highY-.lowY)
386 .radius = min(.verCoeff * (.highY - .lowY ), (.rightX - .leftX))/3
387 .buttonKey$ = replace$(.buttonKey$, "\", "\\", 0)
388 .buttonKey$ = replace$(.buttonKey$, """", "\""""", 0)
389 .newText$ = replace_regex$(.buttonText$, "['.buttonKey$']", "#%&", 1)
390 if .newText$ = ""
391 .newText$ = .buttonText$
392 endif
393 if .push = 1 or .push = -1
394 demo Grey
395 if .buttonColor$ = "Red"
396 .buttonColor$ = "Pink"
397 elsif .buttonColor$ = "Blue"
398 .buttonColor$ = "{0.5,0.5,1}"
399 else
400 .buttonColor$ = "Grey"
401 endif
402 elsif .push >= 2
403 .buttonColor$ = "Maroon"
404 else
405 demo Colour... Black
406 endif
408 call '.buttonDraw$' '.buttonColor$' '.centerX' '.centerY' '.radius'
409 call set_font_size '.buttonFontSize'
410 demo Colour... '.buttonColor$'
411 if .rotation = 0
412 .anchorY = .lowY
413 .verticalAlignment$ = "Bottom"
414 else
415 .anchorY = .lowY + 0.5*(.highY-.lowY)
416 .verticalAlignment$ = "Half"
417 endif
418 demo Text special... '.centerX' Centre '.anchorY' '.verticalAlignment$' 'defaultFont$' '.buttonFontSize' '.rotation' '.newText$'
419 demoShow()
421 # Reset
422 call set_font_size 'defaultFontSize'
423 demo Black
424 demo Line width... 'defaultLineWidth'
426 label NOBUTTON
427 endproc
429 procedure set_window_title .table$ .addedText$
430 select Table '.table$'
431 .row = Search column... Label !WindowTitle
432 if .row < 1
433 call emergency_table_exit Button Table '.table$' does not have a row with label !WindowTitle
434 endif
435 .windowText$ = Get value... '.row' Text
436 call convert_praat_to_latin1 '.windowText$'
437 .windowText$ = convert_praat_to_latin1.text$
439 demoWindowTitle(.windowText$+ .addedText$)
440 endproc
442 # Handle language setting
443 procedure processLanguageCodes .table$ .label$
444 .table$ = "Config"
445 call Draw_button 'config$' Language_'config.language$' 0
446 call Draw_button 'config$' '.label$' 2
447 # Someone might have to use more than 2 chars for the language code
448 .numChars = length(.label$) - length("Language_")
449 .lang$ = right$(.label$, .numChars)
450 # Load new tables
451 call set_language '.lang$'
452 endproc
454 # Set the language
455 procedure set_language .lang$
456 .redraw_config = 0
457 # Remove old tables
458 if buttons$ <> ""
459 select Table 'buttons$'
460 Remove
461 .redraw_config = 1
462 endif
463 if config$ <> ""
464 select Table 'config$'
465 Remove
466 .redraw_config = 1
467 endif
469 # Set language
470 call checkTable 'buttonsTableName$'_'.lang$'
471 if checkTable.available
472 config.language$ = .lang$
473 else
474 config.language$ = "EN"
475 endif
477 # Load buttons tables
478 call loadTable 'buttonsTableName$'
479 buttons$ = selected$("Table")
480 Append column... Text
481 Append column... Key
482 Append column... Helptext
483 .numLabels = Get number of rows
484 call loadTable 'buttonsTableName$'_'config.language$'
485 .buttonsLang$ = selected$("Table")
486 for .row to .numLabels
487 select Table 'buttons$'
488 .label$ = Get value... '.row' Label
489 call findLabel '.buttonsLang$' '.label$'
490 if findLabel.row > 0
491 select Table '.buttonsLang$'
492 .valueText$ = Get value... 'findLabel.row' Text
493 .valueKey$ = Get value... 'findLabel.row' Key
494 .valueHelp$ = Get value... 'findLabel.row' Helptext
495 select Table 'buttons$'
496 Set string value... '.row' Text '.valueText$'
497 Set string value... '.row' Key '.valueKey$'
498 Set string value... '.row' Helptext '.valueHelp$'
499 elsif index(.label$, "_")
500 # Load alternative language table
501 .startChar = rindex(.label$, "_")
502 .otherLanguage$ = right$(.label$, length(.label$) - .startChar)
503 call loadTable 'buttonsTableName$'_'.otherLanguage$'
504 .otherbuttonsLang$ = selected$("Table")
505 call findLabel '.otherbuttonsLang$' '.label$'
506 if findLabel.row > 0
507 select Table '.buttonsLang$'
508 .valueText$ = Get value... 'findLabel.row' Text
509 .valueKey$ = Get value... 'findLabel.row' Key
510 .valueHelp$ = Get value... 'findLabel.row' Helptext
511 select Table 'buttons$'
512 Set string value... '.row' Text '.valueText$'
513 Set string value... '.row' Key '.valueKey$'
514 Set string value... '.row' Helptext '.valueHelp$'
515 else
516 call emergency_table_exit Cannot find Label: '.otherbuttonsLang$' '.label$'
517 endif
518 select Table '.otherbuttonsLang$'
519 Remove
520 else
521 call emergency_table_exit Cannot find Label: '.buttonsLang$' '.label$'
522 endif
523 endfor
524 select Table '.buttonsLang$'
525 Remove
527 # Load configuration table
528 call loadTable 'configTableName$'
529 config$ = selected$("Table")
530 Append column... Text
531 Append column... Key
532 Append column... Helptext
533 .numLabels = Get number of rows
534 call loadTable 'configTableName$'_'config.language$'
535 .configLang$ = selected$("Table")
536 for .row to .numLabels
537 select Table 'config$'
538 .label$ = Get value... '.row' Label
539 call findLabel '.configLang$' '.label$'
540 if findLabel.row > 0
541 select Table '.configLang$'
542 .valueText$ = Get value... 'findLabel.row' Text
543 .valueKey$ = Get value... 'findLabel.row' Key
544 .valueHelp$ = Get value... 'findLabel.row' Helptext
545 select Table 'config$'
546 Set string value... '.row' Text '.valueText$'
547 Set string value... '.row' Key '.valueKey$'
548 Set string value... '.row' Helptext '.valueHelp$'
549 elsif index(.label$, "_")
550 .startChar = rindex(.label$, "_")
551 .otherLanguage$ = right$(.label$, length(.label$) - .startChar)
552 call loadTable 'configTableName$'_'.otherLanguage$'
553 .otherconfigLang$ = selected$("Table")
554 call findLabel '.otherconfigLang$' '.label$'
555 if findLabel.row > 0
556 select Table '.otherconfigLang$'
557 .valueText$ = Get value... 'findLabel.row' Text
558 .valueKey$ = Get value... 'findLabel.row' Key
559 .valueHelp$ = Get value... 'findLabel.row' Helptext
560 select Table 'config$'
561 Set string value... '.row' Text '.valueText$'
562 Set string value... '.row' Key '.valueKey$'
563 Set string value... '.row' Helptext '.valueHelp$'
564 else
565 call emergency_table_exit Cannot find Label: '.otherconfigLang$' '.label$'
566 endif
567 select Table '.otherconfigLang$'
568 Remove
569 else
570 call emergency_table_exit Cannot find Label: '.configLang$' '.label$'
571 endif
572 endfor
573 select Table '.configLang$'
574 Remove
576 # Make language change visible
577 if .redraw_config
578 call Draw_config_page
579 endif
581 endproc
583 ###############################################################
584 #
585 # Button Drawing Routines
586 #
587 ###############################################################
589 # A stub for buttons that do not have a drawing routine (yet)
590 procedure DrawNull .color$ .x .y .size
591 endproc
593 procedure DrawHelp .color$ .x .y .size
594 .currentFontSize = 24
595 .y -= .size
596 .maxHeight = 2*.size
597 call adjustFontSizeOnHeight 'defaultFont$' '.currentFontSize' '.maxHeight'
598 .currentFontSize = adjustFontSizeOnHeight.currentFontSize
599 call set_font_size '.currentFontSize'
600 demo Colour... '.color$'
601 demo Text... '.x' Centre '.y' Bottom ?
602 call set_font_size 'defaultFontSize'
603 endproc
605 ###############################################################
606 #
607 # Button Processing Routines
608 #
609 ###############################################################
611 # Search row in table on label
612 procedure findKey .table$ .label$
613 .row = 0
614 select Table '.table$'
615 .to$ = selected$("Table")
616 .to$ = "Table_"+.to$
617 .numRows = Get number of rows
618 for .i to .numRows
619 .currentKey$ = '.to$'$[.i, "Key"]
620 if .label$ = .currentKey$
621 .row = .i
622 goto KEYFOUND
623 endif
624 endfor
625 label KEYFOUND
626 if .row <= 0 and index(.label$, "_") <= 0
627 printline "'.label$'" is not a key in '.table$'
628 endif
629 endproc
631 procedure findLabel .table$ .label$
632 .row = 0
633 select Table '.table$'
634 .to$ = selected$("Table")
635 .to$ = "Table_"+.to$
636 .numRows = Get number of rows
637 for .i to .numRows
638 .currentKey$ = '.to$'$[.i, "Label"]
639 if .label$ = .currentKey$
640 .row = .i
641 goto LABELFOUND
642 endif
643 endfor
644 label LABELFOUND
645 if .row <= 0 and index(.label$, "_") <= 0
646 call emergency_table_exit "'.label$'" is not a key in '.table$'
647 endif
648 endproc
650 # Get the label
651 procedure buttonClicked table$ .x .y
652 .label$ = ""
653 select Table 'table$'
654 .bo$ = selected$("Table")
655 .bo$ = "Table_"+.bo$
656 .numRows = Get number of rows
657 for .i to .numRows
658 if .label$ = ""
659 .leftX = '.bo$'[.i, "LeftX"]
660 .rightX = '.bo$'[.i, "RightX"]
661 .lowY = '.bo$'[.i, "LowY"]
662 .highY = '.bo$'[.i, "HighY"]
663 if .x > .leftX and .x < .rightX and .y > .lowY and .y < .highY
664 .label$ = '.bo$'$[.i, "Label"]
665 endif
666 endif
667 endfor
668 endproc
670 procedure keyPressed table$ .pressed$
671 .label$ = ""
672 # Magic
673 if .pressed$ = "" and not demoShiftKeyPressed()
674 .label$ = "Refresh"
675 endif
676 .lowerPressed$ = replace_regex$(.pressed$, ".", "\L&", 0)
677 .upperPressed$ = replace_regex$(.pressed$, ".", "\U&", 0)
678 select Table 'table$'
679 .bo$ = selected$("Table")
680 .bo$ = "Table_"+.bo$
681 .numRows = Get number of rows
682 for .i to .numRows
683 if .label$ = ""
684 .key$ = '.bo$'$[.i, "Key"]
685 if index(.key$, .lowerPressed$) or index(.key$, .upperPressed$)
686 .label$ = '.bo$'$[.i, "Label"]
687 endif
688 endif
689 endfor
690 endproc
693 procedure play_sound .sound$
694 if .sound$ <> ""
695 select Sound '.sound$'
696 Play
697 endif
698 endproc
700 procedure record_sound
701 if recordedSound$ != ""
702 select Sound 'recordedSound$'
703 Remove
704 recordedSound$ = ""
705 endif
706 if sgc2.alignedTextGrid > 0
707 select sgc2.alignedTextGrid
708 Remove
709 sgc2.alignedTextGrid = -1
710 endif
712 # There is a very nasty delay before the first recording starts, do a dummy record
713 if not variableExists("recordingInitialized")
714 noprogress nowarn Record Sound (fixed time)... 'config.input$' 0.99 0.5 'samplingFrequency' 0.1
715 Remove
716 recordingInitialized = 1
717 endif
718 # Recording light
719 demo Paint circle... Red 5 95 2
720 demoShow()
721 # In Windows interaction between demoWaitForInput and Record Sound blocks drawing the feedback
722 if windows and endsWith(build_SHA$, " XP")
723 # Display a pause window to flush the graphics buffer
724 beginPause ("DESTROY WINDOW ")
725 comment (" ")
726 endPause ("DESTROY WINDOW ", 1)
727 #call init_window
728 demo Paint circle... Red 5 95 2
729 demoShow()
730 endif
731 noprogress nowarn Record Sound (fixed time)... 'config.input$' 0.99 0.5 'samplingFrequency' 'recordingTime'
732 demo Paint circle... White 5 95 2.5
733 call wipeArea 'wipeFeedbackArea$'
735 # Feedback on recording level
736 .extremum = Get absolute extremum... 0 0 None
737 .radius = 2 * .extremum
738 .blue = 0
739 .green = 0
740 .red = 0
741 if .extremum >= 0.95
742 .red = 1
743 elsif .extremum >= 0.49
744 .green = 1
745 else
746 .green = .extremum / 0.5
747 endif
748 .color$ = "{'.red','.green','.blue'}"
749 demo Colour... '.color$'
750 demo Line width... 1
751 demo Draw circle... 5 95 '.radius'
752 # Reset
753 demoShow()
754 demo Colour... Black
755 demo Line width... 'defaultLineWidth'
756 # Process sound
757 Rename... Tmp
758 Resample... 10000 50
759 Rename... Pronunciation
760 recordedSound$ = selected$("Sound")
761 select Sound Tmp
762 Remove
763 select Sound 'recordedSound$'
765 # Cut out real sound from silences/noise
766 call sound_detection 'recordedSound$' 'soundMargin'
767 select Sound 'recordedSound$'
768 endproc
771 # Select real sound from recording
772 # Uses some global variable
773 procedure sound_detection .sound$ .margin
774 select Sound '.sound$'
775 .soundlength = Get total duration
776 .internalSilence = 2*.margin
778 # Silence and remove noise, DANGEROUS
779 To TextGrid (silences)... 'minimumPitch' 0 'noiseThresshold' '.internalSilence' 0.1 silent sounding
780 Rename... Input'.sound$'
782 select TextGrid Input'.sound$'
783 .numberofIntervals = Get number of intervals... 1
785 # Remove buzzing and other obnoxious sounds (if switched on)
786 for .i from 1 to .numberofIntervals
787 select TextGrid Input'.sound$'
788 .value$ = Get label of interval... 1 '.i'
789 .begintime = Get starting point... 1 '.i'
790 .endtime = Get end point... 1 '.i'
792 # Remove noise
793 if .value$ = "silent"
794 select Sound '.sound$'
795 Set part to zero... '.begintime' '.endtime' at nearest zero crossing
796 endif
797 endfor
799 # Select target sound
800 .maximumIntensity = -1
801 .counter = 1
802 for i from 1 to .numberofIntervals
803 select TextGrid Input'.sound$'
805 .value$ = Get label of interval... 1 'i'
806 .begintime = Get starting point... 1 'i'
807 .endtime = Get end point... 1 'i'
809 if .value$ != "silent"
810 if .begintime > .margin
811 .begintime -= .margin
812 else
813 .begintime = 0
814 endif
815 if .endtime + .margin < .soundlength
816 .endtime += .margin
817 else
818 .endtime = .soundlength
819 endif
821 select Sound '.sound$'
822 Extract part... '.begintime' '.endtime' Rectangular 1.0 no
823 Rename... Tmp'.sound$'
824 Subtract mean
825 .newIntensity = Get intensity (dB)
826 if .newIntensity > .maximumIntensity
827 if .maximumIntensity > 0
828 select Sound New'.sound$'
829 Remove
830 endif
831 select Sound Tmp'.sound$'
832 Rename... New'.sound$'
833 .maximumIntensity = .newIntensity
834 else
835 select Sound Tmp'.sound$'
836 Remove
837 endif
838 #
839 endif
840 endfor
841 if .maximumIntensity > minimumIntensity
842 select Sound '.sound$'
843 Remove
844 select Sound New'.sound$'
845 Rename... '.sound$'
846 elsif .maximumIntensity > -1
847 select Sound New'.sound$'
848 Remove
849 endif
850 select TextGrid Input'.sound$'
851 Remove
852 endproc
854 procedure end_program
855 call write_preferences ""
856 demo Erase all
857 select all
858 Remove
859 exit
860 endproc
862 ######################################################
863 #
864 # Configuration Page
865 #
866 ######################################################
867 procedure config_page
868 demo Erase all
869 demoWindowTitle("Speak Good Chinese: Change settings")
870 .label$ = ""
871 call Draw_config_page
873 while (.label$ <> "Return") and demoWaitForInput()
874 .clickX = -1
875 .clickY = -1
876 .pressed$ = ""
877 .label$ = ""
878 if demoClicked()
879 .clickX = demoX()
880 .clickY = demoY()
881 call buttonClicked 'config$' '.clickX' '.clickY'
882 .label$ = buttonClicked.label$
883 elsif demoKeyPressed()
884 .pressed$ = demoKey$()
885 call keyPressed 'config$' '.pressed$'
886 .label$ = keyPressed.label$
887 endif
889 # You cannot select a text field
890 if startsWith(.label$, "$")
891 .label$ = ""
892 endif
894 # Do things
895 if .label$ != ""
896 # Handle push button in process_config
897 call process_config '.label$' '.clickX' '.clickY' '.pressed$'
898 endif
900 if .label$ = "Return"
901 goto GOBACK
902 endif
903 endwhile
905 # Go back
906 label GOBACK
907 call init_window
908 endproc
910 procedure Draw_config_page
911 demo Erase all
912 # Draw background
913 if config.showBackground
914 call draw_background Background
915 endif
916 # Draw buttons
917 call Draw_all_buttons 'config$'
918 call set_window_title 'config$'
919 # Set correct buttons (alert)
920 call setConfigMainPage
921 endproc
923 # Do what is asked
924 procedure process_config .label$ .clickX .clickY .pressed$
925 if .label$ = "!Logging"
926 config.logPerformance = not config.logPerformance
927 .displayButton = config.logPerformance
928 call Draw_button 'config$' +'.label$' '.displayButton'
929 if config.logPerformance
930 call start_logging
931 endif
932 elsif .label$ <> "" and not startsWith(.label$,"!")
933 .label$ = replace$(.label$, "_", " ", 0)
934 call process'config$''.label$' '.clickX' '.clickY' '.pressed$'
935 endif
936 endproc
938 ###############################################################
939 #
940 # Presenting help texts
941 #
942 ###############################################################
944 # Process Help
945 procedure help_loop .table$ .redrawProc$
946 # General Help text
947 call write_help_title '.table$'
949 .label$ = ""
950 call Draw_button '.table$' Help 2
951 .redrawScreen = 0
952 while (.label$ <> "Help") and demoWaitForInput()
953 .label$ = ""
954 if demoClicked()
955 .clickX = demoX()
956 .clickY = demoY()
957 call buttonClicked '.table$' '.clickX' '.clickY'
958 .label$ = buttonClicked.label$
959 elsif demoKeyPressed()
960 .pressed$ = demoKey$()
961 call keyPressed '.table$' '.pressed$'
962 .label$ = keyPressed.label$
963 endif
965 if .label$ != "" and .label$ <> "Help"
966 # Redraw screen
967 if .redrawScreen
968 demo Erase all
969 call '.redrawProc$'
970 else
971 .redrawScreen = 1
972 endif
973 call Draw_button '.table$' Help 2
974 call write_help_title '.table$'
976 # Handle push button in process_config
977 call write_help_text '.table$' '.label$'
978 endif
980 endwhile
982 # Reset button
983 call Draw_button '.table$' Help 0
984 demo Erase all
985 call '.redrawProc$'
986 endproc
988 # Write help text
989 procedure write_help_text .table$ .label$
990 call findLabel '.table$' '.label$'
991 .row = findLabel.row
992 select Table '.table$'
993 # Get text
994 if .row <= 0
995 call findLabel '.table$' Help
996 .row = findLabel.row
997 select Table '.table$'
998 endif
999 .helpText$ = Get value... '.row' Helptext
1000 .helpKey$ = Get value... '.row' Key
1001 .helpKey$ = replace$(.helpKey$, "\", "", 0)
1002 .helpKey$ = replace$(.helpKey$, "_", "\_ ", 0)
1003 if index_regex(.helpKey$, "\S")
1004 .helpText$ = .helpText$+" ("+.helpKey$+")"
1005 endif
1006 # Get button values
1007 .leftX = Get value... '.row' LeftX
1008 .rightX = Get value... '.row' RightX
1009 .lowY = Get value... '.row' LowY
1010 .highY = Get value... '.row' HighY
1012 # PopUp dimensions
1013 .currentHelpFontSize = defaultFontSize
1014 call set_font_size '.currentHelpFontSize'
1015 .helpTextSize = demo Text width (wc)... '.helpText$'
1016 .helpTextSize += 4
1017 if .leftX > 50
1018 .htXleft = 20
1019 .htXright = .htXleft + .helpTextSize + 5
1020 .xstart = .leftX
1021 else
1022 .htXright = 80
1023 .htXleft = .htXright - .helpTextSize - 5
1024 .xstart = .rightX
1025 endif
1026 if .lowY > 50
1027 .htYlow = 40
1028 .htYhigh = .htYlow + 7
1029 .ystart = .lowY
1030 .yend = .htYhigh
1031 else
1032 .htYhigh = 60
1033 .htYlow = .htYhigh - 7
1034 .ystart = .highY
1035 .yend = .htYlow
1036 endif
1038 # Adapt font size to horizontal dimensions
1039 .maxWidth = 90
1040 call adjustFontSizeOnWidth 'defaultFont$' '.currentHelpFontSize' '.maxWidth' '.helpText$'
1041 .currentHelpFontSize = adjustFontSizeOnWidth.newFontSize
1042 if .htXleft < 0 or .htXright > 100
1043 .htXleft = 0
1044 .htXright = .htXleft + adjustFontSizeOnWidth.textWidth + 5
1045 endif
1046 call set_font_size '.currentHelpFontSize'
1048 # Adapt vertical dimensions to font height
1049 call points_to_wc '.currentHelpFontSize'
1050 .lineHeight = points_to_wc.wc
1051 if .lineHeight > .htYhigh - .htYlow - 4
1052 .htYhigh = .htYlow + .lineHeight + 4
1053 endif
1055 # Determine arrow endpoints
1056 .xend = .htXleft
1057 if abs(.htXleft - .xstart) > abs(.htXright - .xstart)
1058 .xend = .htXright
1059 endif
1060 if abs((.htXleft+.htXright)/2 - .xstart) < min(abs(.htXright - .xstart),abs(.htXleft - .xstart))
1061 .xend = (.htXleft+.htXright)/2
1062 endif
1064 .xtext = .htXleft + 2
1065 .ytext = .htYlow + 1
1067 # Draw pop-up
1068 .mm2wc = demo Horizontal mm to wc... 1
1069 .lineWidth = 2/.mm2wc
1070 demo Line width... '.lineWidth'
1071 demo Arrow size... '.lineWidth'
1072 demo Colour... 'sgc2.popUp_bordercolor$'
1073 demo Paint rectangle... 'sgc2.popUp_backgroundcolor$' '.htXleft' '.htXright' '.htYlow' '.htYhigh'
1074 demo Draw rectangle... '.htXleft' '.htXright' '.htYlow' '.htYhigh'
1075 demo Draw arrow... '.xstart' '.ystart' '.xend' '.yend'
1076 demo Line width... 'defaultLineWidth'
1077 demo Arrow size... 1
1078 demo Black
1079 demo Text... '.xtext' Left '.ytext' Bottom '.helpText$'
1080 demoShow()
1081 call set_font_size 'defaultFontSize'
1083 endproc
1085 procedure write_help_title .table$
1086 # Set help text title
1087 # General Help text
1088 call findLabel '.table$' Help
1089 .row = findLabel.row
1090 select Table '.table$'
1091 .helpTitle$ = Get value... '.row' Helptext
1092 .helpKey$ = Get value... '.row' Key
1093 .helpKey$ = replace$(.helpKey$, "\", "", 0)
1094 .helpKey$ = replace$(.helpKey$, "_", "\_ ", 0)
1095 .helpTitle$ = .helpTitle$+" ("+.helpKey$+")"
1097 call reset_viewport
1098 .helpTitleFontSize = 14
1099 # Adapt size of button to length of text
1100 .maxWidth = 80
1101 call adjustFontSizeOnWidth 'defaultFont$' '.helpTitleFontSize' '.maxWidth' '.helpTitle$'
1102 .helpTitleFontSize = adjustFontSizeOnWidth.newFontSize
1103 call set_font_size '.helpTitleFontSize'
1104 .helpTop = 100
1106 demo Select inner viewport... 0 100 0 100
1107 demo Axes... 0 100 0 100
1108 demo Text... 50 Centre '.helpTop' Top '.helpTitle$'
1109 call set_font_size 'defaultFontSize'
1110 call reset_viewport
1111 endproc
1113 ###############################################################
1114 #
1115 # Miscelaneous procedures
1116 #
1117 ###############################################################
1118 procedure printPageToPrinter
1119 call print_window
1120 demo Print... 'printerName$' 'printerPresets$'
1121 call init_window
1122 endproc
1124 procedure getOpenFile .openDialogue$
1125 call convert_praat_to_latin1 '.openDialogue$'
1126 .openDialogue$ = convert_praat_to_latin1.text$
1127 .filename$ = chooseReadFile$ (.openDialogue$)
1128 if .filename$ <> "" and fileReadable(.filename$)
1129 Read from file... '.filename$'
1130 call log_fileOpen '.filename$'
1132 # Get only the filename
1133 .startName = rindex_regex(.filename$, "[/\\:]") + 1
1134 .nameLength = rindex(.filename$, ".") - .startName
1135 currentSoundName$ = mid$(.filename$, .startName, .nameLength)
1136 else
1137 Create Sound from formula... Speech Mono 0 1 44100 0
1138 endif
1139 recordedSound$ = selected$("Sound")
1140 currentStartTime = 0
1141 currentEndTime = Get total duration
1142 # Reset selected window
1143 selectedStartTime = currentStartTime
1144 selectedEndTime = currentEndTime
1145 endproc
1147 procedure points_to_wc .points
1148 .mm = .points * 0.3527777778
1149 .wc = demo Vertical mm to wc... '.mm'
1150 endproc
1152 procedure reset_viewport
1153 .low = viewportMargin
1154 .high = 100 - viewportMargin
1155 demo Select inner viewport... '.low' '.high' '.low' '.high'
1156 demo Axes... 0 100 0 100
1157 endproc
1159 procedure set_font_size .fontSize
1160 call reset_viewport
1161 demo Font size... '.fontSize'
1162 call reset_viewport
1163 endproc
1165 procedure wipeArea .areaCommand$
1166 call reset_viewport
1167 '.areaCommand$'
1168 endproc
1170 procedure adjustFontSizeOnWidth .font$ .currentFontSize .maxWidth .text$
1171 demo '.font$'
1172 call set_font_size '.currentFontSize'
1173 .textWidth = demo Text width (wc)... '.text$'
1174 while .textWidth > .maxWidth and .currentFontSize > 2
1175 .currentFontSize -= 0.5
1176 call set_font_size '.currentFontSize'
1177 .textWidth = demo Text width (wc)... '.text$'
1178 endwhile
1179 .diff = .textWidth - .maxWidth
1180 .newFontSize = .currentFontSize
1181 demo 'defaultFont$'
1182 endproc
1184 procedure adjustRotatedFontSizeOnBox .font$ .currentFontSize .maxWidth .maxHeight .rotation .text$
1185 demo '.font$'
1186 .radians = .rotation/360 * 2 * pi
1187 .horWC = demo Horizontal mm to wc... 10.0
1188 .verWC = demo Vertical mm to wc... 10.0
1189 if .horWC > 0
1190 .verCoeff = .verWC / .horWC
1191 else
1192 .verCoeff = 1
1193 endif
1194 call set_font_size '.currentFontSize'
1195 .textLength = demo Text width (wc)... '.text$'
1196 while (.textLength * .verCoeff * sin(.radians) > .maxHeight or .textLength * cos(.radians) > .maxWidth) and .currentFontSize > 2
1197 .currentFontSize -= 0.5
1198 call set_font_size '.currentFontSize'
1199 .textLength = demo Text width (wc)... '.text$'
1200 endwhile
1201 .diff = .textLength - .maxHeight
1202 .newFontSize = .currentFontSize
1203 demo 'defaultFont$'
1204 endproc
1206 procedure adjustFontSizeOnHeight .font$ .currentFontSize .maxHeight
1207 demo '.font$'
1208 call points_to_wc '.currentFontSize'
1209 .lineHeight = points_to_wc.wc
1210 while .lineHeight > .maxHeight and .currentFontSize > 2
1211 .currentFontSize -= 0.5
1212 call points_to_wc '.currentFontSize'
1213 .lineHeight = points_to_wc.wc
1214 endwhile
1215 .diff = .lineHeight - .maxHeight
1216 .newFontSize = .currentFontSize
1217 demo 'defaultFont$'
1218 endproc
1220 # Load a table with button info etc.
1221 # Load local tables if present. Else load
1222 # build-in scripted tables
1223 procedure loadTable .tableName$
1224 # Search for the table in local, preference, and global directories
1225 if fileReadable("'localTableDir$'/'.tableName$'.Table")
1226 Read from file... 'localTableDir$'/'.tableName$'.Table
1227 elsif fileReadable("'preferencesTableDir$'/'.tableName$'.Table")
1228 Read from file... 'preferencesTableDir$'/'.tableName$'.Table
1229 elsif fileReadable("'globaltablelists$'/'.tableName$'.Table")
1230 Read from file... 'globaltablelists$'/'.tableName$'.Table
1231 # Load them from script
1232 elsif variableExists("procCreate'.tableName$'$")
1233 call Create'.tableName$'
1234 else
1235 exit '.tableName$' cannot be found
1236 endif
1237 endproc
1239 procedure checkTable .tableName$
1240 .available = 0
1241 if fileReadable("'localTableDir$'/'.tableName$'.Table")
1242 .available = 1
1243 elsif fileReadable("'preferencesTableDir$'/'.tableName$'.Table")
1244 .available = 1
1245 elsif fileReadable("'globaltablelists$'/'.tableName$'.Table")
1246 .available = 1
1247 # Load them from script
1248 elsif variableExists("procCreate'.tableName$'$")
1249 .available = 1
1250 else
1251 .available = 0
1252 endif
1253 endproc
1255 # Create a pop-up window with text from a Text Table
1256 procedure write_text_table .table$
1257 .xleft = 10
1258 .xright = 90
1259 .ylow = 20
1260 .yhigh = 85
1261 .lineHeight = 2.5
1263 # Get table with text and longest line
1264 call loadTable '.table$'
1265 .instructionText = selected()
1266 .numLines = Get number of rows
1267 .instructionFontSize = 14
1268 .referenceText$ = ""
1269 .maxlenght = 0
1270 .maxLine = 0
1271 .maxFontSize = 0
1272 .maxWidth = 0
1273 for .l to .numLines
1274 select '.instructionText'
1275 .currentText$ = Get value... '.l' text
1276 # Expand variables, eg, 'praatVersion$'
1277 call expand_praat_variables '.currentText$'
1278 .currentText$ = expand_praat_variables.text$
1280 .font$ = Get value... '.l' font
1281 .fontSize = Get value... '.l' size
1282 call set_font_size '.fontSize'
1283 .textWidth = demo Text width (wc)... '.currentText$'
1284 if .fontSize > .maxFontSize
1285 .maxFontSize = .fontSize
1286 endif
1287 if .textWidth > .maxWidth
1288 .maxWidth = .textWidth
1289 .instructionFontSize = .fontSize
1290 .maxLine = .l
1291 endif
1292 endfor
1293 select '.instructionText'
1294 .referenceText$ = Get value... '.maxLine' text
1295 .maxLineFont$ = Get value... '.maxLine' font
1296 .instructionFontSize = Get value... '.maxLine' size
1297 call set_font_size '.maxFontSize'
1299 # Adapt size of button to length of text
1300 .maxWidth = (.xright - .xleft) - 4
1301 .origFontSize = .instructionFontSize
1302 call adjustFontSizeOnWidth 'defaultFont$' '.instructionFontSize' '.maxWidth' '.referenceText$'
1303 call adjustFontSizeOnHeight 'defaultFont$' '.maxFontSize' '.lineHeight'
1304 .instructionFontSize = min(adjustFontSizeOnWidth.newFontSize, adjustFontSizeOnHeight.newFontSize)
1305 if adjustFontSizeOnWidth.diff > 0
1306 .xright += adjustFontSizeOnWidth.diff/4
1307 .xleft -= 3*adjustFontSizeOnWidth.diff/4
1308 endif
1309 call set_font_size '.instructionFontSize'
1310 .fontSizeFactor = .instructionFontSize / .origFontSize
1312 .numRows = Get number of rows
1313 # Calculate length from number of lines.
1314 .dy = .lineHeight
1315 .midY = .yhigh - (.yhigh - .ylow)/2
1316 .yhigh = .midY + (.numRows+1) * .dy / 2
1317 .ylow = .yhigh - (.numRows+1) * .dy
1318 .textleft = .xleft + 2
1320 demo Line width... 8
1321 demo Colour... 'sgc2.popUp_bordercolor$'
1322 demo Paint rectangle... 'sgc2.popUp_backgroundcolor$' '.xleft' '.xright' '.ylow' '.yhigh'
1323 demo Draw rectangle... '.xleft' '.xright' '.ylow' '.yhigh'
1324 demo Line width... 'defaultLineWidth'
1325 demo Black
1326 .ytext = .yhigh - 2 - .dy
1327 for .i to .numRows
1328 select '.instructionText'
1329 .font$ = Get value... '.i' font
1330 .fontSize = Get value... '.i' size
1331 .font$ = extractWord$(.font$, "")
1332 # Scale font
1333 .fontSize = floor(.fontSize*.fontSizeFactor)
1334 if .fontSize < 4
1335 .fontSize = 4
1336 endif
1337 .line$ = Get value... '.i' text
1338 # Expand variables, eg, 'praatVersion$'
1339 call expand_praat_variables '.line$'
1340 .line$ = expand_praat_variables.text$
1342 # Display text
1343 demo Text special... '.textleft' Left '.ytext' Bottom '.font$' '.fontSize' 0 '.line$'
1344 .ytext -= .dy
1345 endfor
1346 demoShow()
1347 call set_font_size 'defaultFontSize'
1349 select '.instructionText'
1350 Remove
1351 endproc
1354 # Create a pop-up window with text from an existing Table object
1355 procedure write_tabbed_table .table$ .labelTextTable$
1356 .xleft = 0
1357 .xright = 100
1358 .ylow = 20
1359 .yhigh = 85
1360 .lineHeight = 2.5
1362 # Get table with text and longest line
1363 call loadTable '.labelTextTable$'
1364 .labelText$ = selected$("Table")
1366 select Table '.table$'
1367 .tabbedText = selected()
1368 .numLines = Get number of rows
1369 .numCols = Get number of columns
1370 .font$ = defaultFont$
1371 .fontSize = defaultFontSize
1372 # Standard width
1373 .widthCanvas = .xright - .xleft
1374 .dx = (.widthCanvas - 4) / (.numCols)
1376 # Get longest entry
1377 demo '.font$'
1378 call set_font_size '.fontSize'
1379 .maxWidth = 0
1380 for .i from 0 to .numLines
1381 .xtext = .xleft + .dx / 2
1382 for .j to .numCols
1383 select '.tabbedText'
1384 .currentLabel$ = Get column label... '.j'
1385 if .i > 0
1386 .line$ = Get value... '.i' '.currentLabel$'
1387 else
1388 .line$ = .currentLabel$
1389 select Table '.labelText$'
1390 call findLabel '.labelText$' '.line$'
1391 select Table '.labelText$'
1392 .line$ = Get value... 'findLabel.row' Text
1393 endif
1394 # Expand variables, eg, 'praatVersion$'
1395 call expand_praat_variables '.line$'
1396 .line$ = expand_praat_variables.text$
1397 .textWidth = demo Text width (wc)... '.line$'
1398 if .textWidth > .maxWidth
1399 .maxWidth = .textWidth
1400 endif
1401 endfor
1402 endfor
1403 if .dx > 1.2 * .maxWidth
1404 .widthCanvas = 1.2 * .maxWidth * .numCols + 4
1405 .xleft = 50 - .widthCanvas / 2
1406 .xright = 50 + .widthCanvas / 2
1407 .dx = (.widthCanvas - 4) / (.numCols)
1408 else
1409 .maxWidth = .dx - 1
1410 endif
1412 # Calculate length from number of lines.
1413 .dy = .lineHeight + 0.5
1414 .midY = .yhigh - (.yhigh - .ylow)/2
1415 .yhigh = .midY + (.numLines+2) * .dy / 2
1416 .ylow = .yhigh - (.numLines+2) * .dy
1417 .textleft = .xleft + 2
1419 demo Line width... 8
1420 demo Colour... 'sgc2.popUp_bordercolor$'
1421 demo Paint rectangle... 'sgc2.popUp_backgroundcolor$' '.xleft' '.xright' '.ylow' '.yhigh'
1422 demo Draw rectangle... '.xleft' '.xright' '.ylow' '.yhigh'
1423 demo Line width... 'defaultLineWidth'
1424 demo Black
1425 .ytext = .yhigh - 2 - .dy
1426 # First the column names, then the items
1427 for .i from 0 to .numLines
1428 .xtext = .textleft + .dx / 2
1429 for .j to .numCols
1430 select '.tabbedText'
1431 .currentLabel$ = Get column label... '.j'
1432 if .i > 0
1433 .line$ = Get value... '.i' '.currentLabel$'
1434 else
1435 .line$ = .currentLabel$
1436 select Table '.labelText$'
1437 call findLabel '.labelText$' '.line$'
1438 select Table '.labelText$'
1439 .line$ = Get value... 'findLabel.row' Text
1440 endif
1441 # Expand variables, eg, 'praatVersion$'
1442 call expand_praat_variables '.line$'
1443 .line$ = expand_praat_variables.text$
1444 call adjustFontSizeOnWidth '.font$' '.fontSize' '.maxWidth' '.line$'
1445 .currentFontSize = adjustFontSizeOnWidth.newFontSize
1447 # Display text
1448 demo Text special... '.xtext' Centre '.ytext' Bottom '.font$' '.currentFontSize' 0 '.line$'
1449 .xtext += .dx
1450 endfor
1451 .ytext -= .dy
1452 endfor
1453 demoShow()
1454 call set_font_size 'defaultFontSize'
1455 select Table '.labelText$'
1456 Remove
1458 endproc
1460 # Create a pop-up window with a given text
1461 procedure write_text_popup .font$ .size .text$
1462 .xleft = 10
1463 .xright = 90
1464 .ylow = 20
1465 .yhigh = 85
1466 .lineHeight = 3
1468 # Adapt size of button to length of text
1469 .maxWidth = (.xright - .xleft) - 4
1470 call adjustFontSizeOnWidth 'defaultFont$' '.size' '.maxWidth' '.text$'
1471 call adjustFontSizeOnHeight 'defaultFont$' '.size' '.lineHeight'
1472 .popupFontSize = min(adjustFontSizeOnWidth.newFontSize, adjustFontSizeOnHeight.newFontSize)
1473 if adjustFontSizeOnWidth.diff > 0
1474 .xright += adjustFontSizeOnWidth.diff/4
1475 .xleft -= 3*adjustFontSizeOnWidth.diff/4
1476 else
1477 .xleft = ((.xright + .xleft) - adjustFontSizeOnWidth.textWidth)/2 - 2
1478 .xright = ((.xright + .xleft) + adjustFontSizeOnWidth.textWidth)/2 + 2
1479 endif
1481 .numRows = 1
1482 # Calculate length from number of lines.
1483 .dy = .lineHeight
1484 .midY = .yhigh - (.yhigh - .ylow)/2
1485 .yhigh = .midY + (.numRows+1) * .dy / 2
1486 .ylow = .yhigh - (.numRows+1) * .dy
1487 .textleft = .xleft + 2
1488 .xmid = (.textleft + .xright - 2)/2
1490 demo Line width... 8
1491 demo Colour... 'sgc2.popUp_bordercolor$'
1492 demo Paint rectangle... 'sgc2.popUp_backgroundcolor$' '.xleft' '.xright' '.ylow' '.yhigh'
1493 demo Draw rectangle... '.xleft' '.xright' '.ylow' '.yhigh'
1494 demo Line width... 'defaultLineWidth'
1495 demo Black
1496 .ytext = .yhigh - 2 - .dy
1497 # Write text
1498 demo Text special... '.xmid' Centre '.ytext' Bottom '.font$' '.popupFontSize' 0 '.text$'
1500 demoShow()
1501 demo 'defaultFont$'
1502 call set_font_size 'defaultFontSize'
1503 endproc
1505 # Write the background from a Text Table
1506 procedure draw_background .table$
1507 .xleft = 0
1508 .xright = 100
1509 .ylow = 0
1510 .yhigh = 100
1511 .lineHeight = 5
1512 .defaultColour$ = "{0.9,0.9,0.9}"
1513 .defaultAlign$ = "centre"
1515 # Get table with text and longest line
1516 call loadTable '.table$'
1517 .backgroundText = selected()
1518 .numLines = Get number of rows
1519 .backgroundFontSize = 28
1520 .referenceText$ = ""
1521 .maxlenght = 0
1522 .maxLine = 0
1523 .maxFontSize = 0
1524 .maxWidth = 0
1525 .textLines = 0
1526 for .l to .numLines
1527 select '.backgroundText'
1528 .currentText$ = Get value... '.l' text
1529 # Expand variables, eg, 'praatVersion$'
1530 call expand_praat_variables '.currentText$'
1531 .currentText$ = expand_praat_variables.text$
1533 .font$ = Get value... '.l' font
1534 .fontSize = Get value... '.l' size
1535 if .fontSize > .maxFontSize
1536 .maxFontSize = .fontSize
1537 endif
1538 if not startsWith(.font$, "!")
1539 call set_font_size '.fontSize'
1540 .textWidth = demo Text width (wc)... '.currentText$'
1541 if .textWidth > .maxWidth
1542 .maxWidth = .textWidth
1543 .backgroundFontSize = .fontSize
1544 .maxLine = .l
1545 endif
1547 .textLines += 1
1548 endif
1549 endfor
1550 if .maxLine > 0
1551 select '.backgroundText'
1552 .referenceText$ = Get value... '.maxLine' text
1553 .maxLineFont$ = Get value... '.maxLine' font
1554 .backgroundFontSize = Get value... '.maxLine' size
1555 .backgroundFontColour$ = Get value... '.maxLine' colour
1556 call set_font_size '.maxFontSize'
1557 else
1558 .maxFontSize = .backgroundFontSize
1559 endif
1561 # Adapt size of button to length of text
1562 .maxWidth = (.xright - .xleft) - 4
1563 .origFontSize = .backgroundFontSize
1564 call adjustFontSizeOnWidth 'defaultFont$' '.backgroundFontSize' '.maxWidth' '.referenceText$'
1565 .fontSizeFactor = adjustFontSizeOnWidth.newFontSize / .backgroundFontSize
1566 .backgroundFontSize = adjustFontSizeOnWidth.newFontSize
1567 call set_font_size '.backgroundFontSize'
1569 call adjustFontSizeOnHeight 'defaultFont$' '.backgroundFontSize' '.lineHeight'
1570 .lineHeight /= adjustFontSizeOnHeight.newFontSize / .backgroundFontSize
1571 if adjustFontSizeOnHeight.newFontSize >= .origFontSize and (.textLines+1) * .lineHeight > (.yhigh - .ylow - 4)
1572 .lineHeight = (.yhigh - .ylow - 4)/(.textLines + 1)
1573 call adjustFontSizeOnHeight 'defaultFont$' '.maxFontSize' '.lineHeight'
1574 .fontSizeFactor = adjustFontSizeOnHeight.newFontSize / .backgroundFontSize
1575 endif
1577 .numRows = Get number of rows
1578 # Calculate length from number of lines.
1579 .dy = .lineHeight
1580 .midY = .yhigh - (.yhigh - .ylow)/2
1581 .yhigh = .midY + (.textLines+1) * .dy / 2
1582 .ylow = .yhigh - (.textLines+1) * .dy
1583 .textleft = .xleft + 2
1584 .textright = .xright - 2
1585 .textmid = (.xright - .xleft)/2
1587 demo Black
1588 .ytext = .yhigh - 2 - .dy
1589 for .i to .numRows
1590 select '.backgroundText'
1591 .font$ = Get value... '.i' font
1592 .fontSize = Get value... '.i' size
1593 .fontColour$ = Get value... '.i' colour
1594 .fontColour$ = replace_regex$(.fontColour$, "^[\- ]$", ".defaultColour$", 1)
1595 .fontAlign$ = Get value... '.i' align
1596 .fontAlign$ = replace_regex$(.fontAlign$, "^[\- ]$", ".defaultAlign$", 1)
1597 .line$ = Get value... '.i' text
1598 # Expand variables, eg, 'praatVersion$'
1599 call expand_praat_variables '.line$'
1600 .line$ = expand_praat_variables.text$
1602 # Scale font
1603 .fontSize = floor(.fontSize*.fontSizeFactor)
1604 if not startsWith(.font$, "!")
1605 .font$ = extractWord$(.font$, "")
1607 if .fontAlign$ = "centre"
1608 .xtext = .textmid
1609 elsif .fontAlign$ = "right"
1610 .xtext = .textright
1611 else
1612 .xtext = .textleft
1613 endif
1614 if .fontSize < 4
1615 .fontSize = 4
1616 endif
1617 # Clean up text
1618 demo Colour... '.fontColour$'
1619 demo Text special... '.xtext' '.fontAlign$' '.ytext' Bottom '.font$' '.fontSize' 0 '.line$'
1620 .ytext -= .dy
1621 elsif .font$ = "!demo command"
1622 demo Colour... '.fontColour$'
1623 .line$ = replace_regex$(.line$, "\{FONTSIZE\$\}", "'.fontSize'", 0)
1624 .line$ = replace_regex$(.line$, "\{XTEXT\$\}", "'.xtext'", 0)
1625 .line$ = replace_regex$(.line$, "\{YTEXT\$\}", "'.ytext'", 0)
1626 .line$ = replace_regex$(.line$, "\{DY\$\}", "'.dy'", 0)
1627 .line$ = replace_regex$(.line$, "\{[^\}]*\}", "", 0)
1628 while index(.line$, "[[")
1629 .nextBracketOpen = index(.line$, "[[")
1630 .nextBracketOpen += 2
1631 .nextBracketClose = index(.line$, "]]")
1632 .bracketLength = .nextBracketClose - .nextBracketOpen
1633 .result$ = ""
1634 if .bracketLength > 0
1635 .expression$ = mid$(.line$, .nextBracketOpen, .bracketLength)
1636 .expression$ = replace_regex$(.expression$, "\s", "", 0)
1637 if length(.expression$) > 0
1638 # Test expression for security, only allow explicitely defined functions
1639 .allowedStrings$ = "e|pi|not|and|or|div|mod|abs|round|floor|ceiling"
1640 .allowedStrings$ = .allowedStrings$ + "|sqrt|min|max|imin|imax|sin|cos|tan|arcsin|arccos|arctan|arctan2|sinc|sincpi"
1641 .allowedStrings$ = .allowedStrings$ + "|exp|ln|log10|log2|sinh|cosh|tanh|arcsinh|arccosh|arctanh"
1642 .allowedStrings$ = .allowedStrings$ + "|sigmoid|invSigmoid|erf|erfc|randomUniform|randomInteger|randomGauss|randomPoisson"
1643 .allowedStrings$ = .allowedStrings$ + "|lnGamma|gaussP|gaussQ|invGaussQ|chiSquareP|chiSquareQ"
1644 .allowedStrings$ = .allowedStrings$ + "|invChiSquareP|invChiSquareQ|studentP|studentQ|invStudentP|invStudentQ"
1645 .allowedStrings$ = .allowedStrings$ + "|beta|besselI|besselK"
1646 .testExpression$ = replace_regex$(.expression$, "(^|\W)('.allowedStrings$')(?=$|\W)", "\1\3", 0)
1647 .testExpression$ = replace_regex$(.testExpression$, "[0-9\.,\-+/*^()<>= ]", "", 0)
1648 if .testExpression$ = ""
1649 .calc = '.expression$'
1650 .result$ = "'.calc'"
1651 endif
1652 endif
1653 endif
1655 # Replace expression by result
1656 .lastLeft = .nextBracketOpen - 3
1657 .newLine$ = left$(.line$, .lastLeft)
1658 .newLine$ = .newLine$ + .result$
1659 .numCopy = length(.line$) - .nextBracketClose - 1
1660 .newLine$ = .newLine$ + right$(.line$, .numCopy)
1661 .line$ = .newLine$
1662 endwhile
1663 demo '.line$'
1664 endif
1665 endfor
1666 demo Black
1667 demoShow()
1668 call set_font_size 'defaultFontSize'
1670 select '.backgroundText'
1671 Remove
1672 endproc
1674 procedure convert_praat_to_utf8 .text$
1675 .text$ = replace_regex$(.text$, "\\a""", "\xc3\xa4", 0)
1676 .text$ = replace_regex$(.text$, "\\A""", "\xc3\x84", 0)
1677 .text$ = replace_regex$(.text$, "\\o""", "\xc3\xb6", 0)
1678 .text$ = replace_regex$(.text$, "\\O""", "\xc3\x96", 0)
1679 .text$ = replace_regex$(.text$, "\\u""", "\xc3\xbc", 0)
1680 .text$ = replace_regex$(.text$, "\\U""", "\xc3\x9c", 0)
1681 .text$ = replace_regex$(.text$, "\\i""", "\xc3\xaf", 0)
1682 .text$ = replace_regex$(.text$, "\\I""", "\xc3\x8f", 0)
1683 .text$ = replace_regex$(.text$, "\\e""", "\xc3\xab", 0)
1684 .text$ = replace_regex$(.text$, "\\E""", "\xc3\x8b", 0)
1685 .text$ = replace_regex$(.text$, "\\y""", "\xc3\xbf", 0)
1686 .text$ = replace_regex$(.text$, "\\e'", "\xc3\xa9", 0)
1687 .text$ = replace_regex$(.text$, "\\E'", "\xc3\x89", 0)
1688 .text$ = replace_regex$(.text$, "\\ss", "\xc3\x9f", 0)
1689 endproc
1691 procedure convert_praat_to_latin1 .text$
1692 .text$ = replace_regex$(.text$, "\\a""", "\xe4", 0)
1693 .text$ = replace_regex$(.text$, "\\A""", "\xc4", 0)
1694 .text$ = replace_regex$(.text$, "\\o""", "\xf6", 0)
1695 .text$ = replace_regex$(.text$, "\\O""", "\xd6", 0)
1696 .text$ = replace_regex$(.text$, "\\u""", "\xfc", 0)
1697 .text$ = replace_regex$(.text$, "\\U""", "\xdc", 0)
1698 .text$ = replace_regex$(.text$, "\\i""", "\xef", 0)
1699 .text$ = replace_regex$(.text$, "\\I""", "\xcf", 0)
1700 .text$ = replace_regex$(.text$, "\\e""", "\xeb", 0)
1701 .text$ = replace_regex$(.text$, "\\E""", "\xcb", 0)
1702 .text$ = replace_regex$(.text$, "\\y""", "\xff", 0)
1703 .text$ = replace_regex$(.text$, "\\Y""", "Y", 0)
1704 .text$ = replace_regex$(.text$, "\\e'", "\xe9", 0)
1705 .text$ = replace_regex$(.text$, "\\E'", "\xc9", 0)
1706 .text$ = replace_regex$(.text$, "\\ss", "\xdf", 0)
1707 endproc
1709 # Expand 'variable$' into the value of variable$.
1710 # Eg, 'praatVersion$' becomes 5.1.45 or whatever is the current version
1711 # Single quotes can be protected by \'
1712 procedure expand_praat_variables .text$
1713 if index(.text$, "'")
1714 .tempText$ = replace_regex$(.text$, "(^|[^\\])'([\w\$\.]+)'", "\1""+\2+""", 0)
1715 .tempText$ = replace_regex$(.tempText$, "[\\]'", "'", 0)
1716 .tempText$ = """"+.tempText$+""""
1717 # Check whether all the variables actually exist. Ignore any variable that does not exist
1718 .checkVars$ = .tempText$
1719 while length(.checkVars$) > 0 and index(.checkVars$, "+")
1720 .start = index(.checkVars$, "+")
1721 .checkVars$ = right$(.checkVars$, length(.checkVars$) - .start)
1722 .end = index(.checkVars$, "+")
1723 if .end
1724 .variable$ = left$(.checkVars$, .end - 1)
1725 if not variableExists(.variable$)
1726 .tempText$ = replace$(.tempText$, """+'.variable$'+""", "'"+.variable$+"'", 0)
1727 endif
1728 .checkVars$ = right$(.checkVars$, length(.checkVars$) - .end)
1729 else
1730 .checkVars$ = ""
1731 endif
1732 endwhile
1733 .text$ = '.tempText$'
1734 endif
1735 endproc
1737 # Get a time stamp in normalized format
1738 procedure getTimeStamp
1739 .currentDateTime$ = date$()
1740 .string$ = replace_regex$(.currentDateTime$, "[A-Z][a-z]+\s+([A-Z][a-z]+)\s+(\d+)\s+(\d+)\W(\d+)\W(\d+)\s+(\d+)$", "\6-\1-\2T\3-\4-\5", 0)
1741 endproc
1743 # A table error, can be insiduously caused by an outdate preferences file!
1744 procedure emergency_table_exit .message$
1745 # If you come here as a user, your preferences file is borked
1746 if preferencesAppFile$ <> "" and fileReadable(preferencesAppFile$)
1747 deleteFile(preferencesAppFile$)
1748 endif
1749 exit '.message$'
1750 endproc