contrib/sb-bsd-sockets/sb-bsd-sockets.asd

   1 ;;; -*-  Lisp -*-
   2 (eval-when (:compile-toplevel :load-toplevel :execute)
   3   (require :sb-grovel))
   4 (defpackage #:sb-bsd-sockets-system (:use #:asdf #:sb-grovel #:cl))
   5 (in-package #:sb-bsd-sockets-system)
   6
   7 ;;; we also have a shared library with some .o files in it
   8
   9 (defclass unix-dso (module) ())
  10 (defun unix-name (pathname)
  11   (namestring
  12    (typecase pathname
  13      (logical-pathname (translate-logical-pathname pathname))
  14      (t pathname))))
  15
  16 (defmethod asdf::input-files ((operation compile-op) (dso unix-dso))
  17   (mapcar #'component-pathname (module-components dso)))
  18
  19 (defmethod output-files ((operation compile-op) (dso unix-dso))
  20   (let ((dir (component-pathname dso)))
  21     (list
  22      (make-pathname :type "so"
  23                     :name (car (last (pathname-directory dir)))
  24                     :directory (butlast (pathname-directory dir))
  25                     :defaults dir))))
  26
  27
  28 (defmethod perform :after ((operation compile-op) (dso unix-dso))
  29   (let ((dso-name (unix-name (car (output-files operation dso)))))
  30     (unless (zerop
  31              (run-shell-command
  32               "gcc ~A -o ~S ~{~S ~}"
  33               (concatenate 'string
  34                            (sb-ext:posix-getenv "EXTRA_LDFLAGS")
  35                            " "
  36                            #+sunos "-shared -lresolv -lsocket -lnsl"
  37                            #+darwin "-bundle"
  38                            #-(or darwin sunos) "-shared")
  39               dso-name
  40               (mapcar #'unix-name
  41                       (mapcan (lambda (c)
  42                                 (output-files operation c))
  43                               (module-components dso)))))
  44       (error 'operation-error :operation operation :component dso))))
  45
  46 ;;; if this goes into the standard asdf, it could reasonably be extended
  47 ;;; to allow cflags to be set somehow
  48 (defmethod output-files ((op compile-op) (c c-source-file))
  49   (list
  50    (make-pathname :type "o" :defaults
  51                   (component-pathname c))))
  52 (defmethod perform ((op compile-op) (c c-source-file))
  53   (unless
  54       (= 0 (run-shell-command "gcc ~A -o ~S -c ~S"
  55                               (concatenate 'string
  56                                            (sb-ext:posix-getenv "EXTRA_CFLAGS")
  57                                            " "
  58                                            "-fPIC")
  59                               (unix-name (car (output-files op c)))
  60                               (unix-name (component-pathname c))))
  61     (error 'operation-error :operation op :component c)))
  62
  63 (defmethod perform ((operation load-op) (c c-source-file))
  64   t)
  65
  66 (defmethod perform ((o load-op) (c unix-dso))
  67   (let ((co (make-instance 'compile-op)))
  68     (let ((filename (car (output-files co c))))
  69       #+cmu (ext:load-foreign filename)
  70       #+sbcl (sb-alien:load-shared-object filename))))
  71
  72 (defsystem sb-bsd-sockets
  73     :version "0.58"
  74     :depends-on (sb-grovel)
  75     #+sb-building-contrib :pathname
  76     #+sb-building-contrib "SYS:CONTRIB;SB-BSD-SOCKETS;"
  77     :components ((:file "defpackage")
  78                  (:file "split" :depends-on ("defpackage"))
  79                  (:unix-dso "alien"
  80                             :components ((:c-source-file "undefs")
  81                                          (:c-source-file "get-h-errno")))
  82                  (:file "malloc" :depends-on ("defpackage"))
  83                  (sb-grovel:grovel-constants-file
  84                   "constants"
  85                   :package :sockint
  86                   :depends-on  ("defpackage"))
  87                  (:file "sockets"
  88                         :depends-on ("constants"))
  89
  90                  (:file "sockopt" :depends-on ("sockets"))
  91                  (:file "inet" :depends-on ("sockets" "split"  "constants" ))
  92                  (:file "local" :depends-on ("sockets" "split" "constants" ))
  93                  (:file "name-service" :depends-on ("sockets" "constants" "alien"))
  94                  (:file "misc" :depends-on ("sockets" "constants"))
  95
  96                  (:static-file "NEWS")
  97                  ;; (:static-file "INSTALL")
  98                  ;; (:static-file "README")
  99                  ;; (:static-file "index" :pathname "index.html")
 100                  (:static-file "doc" :pathname "doc.lisp")
 101                  (:static-file "TODO")))
 102
 103 (defmethod perform :after ((o load-op) (c (eql (find-system :sb-bsd-sockets))))
 104   (provide 'sb-bsd-sockets))
 105
 106 (defmethod perform ((o test-op) (c (eql (find-system :sb-bsd-sockets))))
 107   (operate 'load-op 'sb-bsd-sockets-tests)
 108   (operate 'test-op 'sb-bsd-sockets-tests))
 109
 110 (defsystem sb-bsd-sockets-tests
 111   :depends-on (sb-rt sb-bsd-sockets sb-posix)
 112   :components ((:file "tests")))
 113
 114 (defmethod perform ((o test-op) (c (eql (find-system :sb-bsd-sockets-tests))))
 115   (or (funcall (intern "DO-TESTS" (find-package "SB-RT")))
 116       (error "test-op failed")))