tests/debug.impure.lisp

   1 ;;;; This file is for testing debugging functionality, using
   2 ;;;; test machinery which might have side effects (e.g.
   3 ;;;; executing DEFUN).
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; While most of SBCL is derived from the CMU CL system, the test
   9 ;;;; files (like this one) were written from scratch after the fork
  10 ;;;; from CMU CL.
  11 ;;;;
  12 ;;;; This software is in the public domain and is provided with
  13 ;;;; absolutely no warranty. See the COPYING and CREDITS files for
  14 ;;;; more information.
  15
  16 (cl:in-package :cl-user)
  17
  18 ;;; The debugger doesn't have any native knowledge of the interpreter
  19 (when (eq sb-ext:*evaluator-mode* :interpret)
  20   (sb-ext:quit :unix-status 104))
  21
  22 \f
  23 ;;;; Check that we get debug arglists right.
  24
  25 ;;; FIXME: This should use some get-argslist like functionality that
  26 ;;; we actually export.
  27 ;;;
  28 ;;; Return the debug arglist of the function object FUN as a list, or
  29 ;;; punt with :UNKNOWN.
  30 (defun get-arglist (fun)
  31   (declare (type function fun))
  32   ;; The Lisp-level type FUNCTION can conceal a multitude of sins..
  33   (case (sb-kernel:widetag-of fun)
  34     (#.sb-vm:simple-fun-header-widetag
  35       (sb-kernel:%simple-fun-arglist fun))
  36     (#.sb-vm:closure-header-widetag (get-arglist
  37                                      (sb-kernel:%closure-fun fun)))
  38     ;; In code/describe.lisp, ll. 227 (%describe-fun), we use a scheme
  39     ;; like above, and it seems to work. -- MNA 2001-06-12
  40     ;;
  41     ;; (There might be other cases with arglist info also.
  42     ;; SIMPLE-FUN-HEADER-WIDETAG and CLOSURE-HEADER-WIDETAG just
  43     ;; happen to be the two case that I had my nose rubbed in when
  44     ;; debugging a GC problem caused by applying %SIMPLE-FUN-ARGLIST to
  45     ;; a closure. -- WHN 2001-06-05)
  46     (t
  47      #+sb-eval
  48      (if (typep fun 'sb-eval::interpreted-function)
  49          (sb-eval::interpreted-function-lambda-list fun)
  50          :unknown)
  51      #-sb-eval
  52      :unknown)))
  53
  54 (defun zoop (zeep &key beep)
  55   blurp)
  56 (assert (equal (get-arglist #'zoop) '(zeep &key beep)))
  57
  58 ;;; Check some predefined functions too.
  59 ;;;
  60 ;;; (We don't know exactly what the arguments are, e.g. the first
  61 ;;; argument of PRINT might be SB-IMPL::OBJECT or SB-KERNEL::OBJ or
  62 ;;; whatever. But we do know the general structure that a correct
  63 ;;; answer should have, so we can safely do a lot of checks.)
  64 (destructuring-bind (object-sym &optional-sym stream-sym) (get-arglist #'print)
  65   (assert (symbolp object-sym))
  66   (assert (eql &optional-sym '&optional))
  67   (assert (symbolp stream-sym)))
  68 (destructuring-bind (dest-sym control-sym &rest-sym format-args-sym)
  69     (get-arglist #'format)
  70   (assert (symbolp dest-sym))
  71   (assert (symbolp control-sym))
  72   (assert (eql &rest-sym '&rest))
  73   (assert (symbolp format-args-sym)))
  74
  75 ;;; Check for backtraces generally being correct.  Ensure that the
  76 ;;; actual backtrace finishes (doesn't signal any errors on its own),
  77 ;;; and that it contains the frames we expect, doesn't contain any
  78 ;;; "bogus stack frame"s, and contains the appropriate toplevel call
  79 ;;; and hasn't been cut off anywhere.
  80 (defun verify-backtrace (test-function frame-specs &key (allow-stunted nil))
  81   (labels ((args-equal (want real)
  82              (cond ((eq '&rest (car want))
  83                     t)
  84                    ((endp want)
  85                     (endp real))
  86                    ((or (eq '? (car want)) (equal (car want) (car real)))
  87                     (args-equal (cdr want) (cdr real)))
  88                    (t
  89                     nil))))
  90     (let ((result nil))
  91       (block outer-handler
  92         (handler-bind
  93             ((error (lambda (condition)
  94                       ;; find the part of the backtrace we're interested in
  95                       (let* ((full-backtrace (sb-debug:backtrace-as-list))
  96                              (backtrace (member (caar frame-specs) full-backtrace
  97                                                 :key #'car
  98                                                 :test #'equal)))
  99
 100                         (setf result condition)
 101
 102                         (unless backtrace
 103                           (format t "~&//~S not in backtrace:~%   ~S~%"
 104                                   (caar frame-specs)
 105                                   full-backtrace)
 106                           (setf result nil))
 107
 108                         ;; check that we have all the frames we wanted
 109                         (mapcar
 110                          (lambda (spec frame)
 111                            (unless (or (not spec)
 112                                        (and (equal (car spec) (car frame))
 113                                             (args-equal (cdr spec)
 114                                                         (cdr frame))))
 115                              (print (list :mismatch spec frame))
 116                              (setf result nil)))
 117                          frame-specs
 118                          backtrace)
 119
 120                         ;; Make sure the backtrace isn't stunted in
 121                         ;; any way.  (Depends on running in the main
 122                         ;; thread.) FIXME: On Windows we get two
 123                         ;; extra foreign frames below regular frames.
 124                         (let ((end (last backtrace #-win32 2 #+win32 4)))
 125                           (unless (equal (caar end)
 126                                          'sb-impl::toplevel-init)
 127                             (print (list :backtrace-stunted (caar end)))
 128                             (setf result nil)))
 129                         (return-from outer-handler)))))
 130           (funcall test-function)))
 131       result)))
 132
 133 (defvar *undefined-function-frame*
 134   ;; bug 353
 135   '(#+(or x86 x86-64) "bogus stack frame"
 136     #-(or x86 x86-64) "undefined function"))
 137
 138 ;;; Test for "undefined function" (undefined_tramp) working properly.
 139 ;;; Try it with and without tail call elimination, since they can have
 140 ;;; different effects.  (Specifically, if undefined_tramp is incorrect
 141 ;;; a stunted stack can result from the tail call variant.)
 142 (flet ((optimized ()
 143          (declare (optimize (speed 2) (debug 1))) ; tail call elimination
 144          (#:undefined-function 42))
 145        (not-optimized ()
 146          (declare (optimize (speed 1) (debug 2))) ; no tail call elimination
 147          (#:undefined-function 42))
 148        (test (fun)
 149          (declare (optimize (speed 1) (debug 2))) ; no tail call elimination
 150          (funcall fun)))
 151
 152   (with-test (:name (:undefined-function :bug-346)
 153               :fails-on '(or :alpha :ppc :sparc :mips
 154                           (and :x86-64 (or :freebsd :darwin))))
 155     (assert (verify-backtrace
 156              (lambda () (test #'optimized))
 157              (list *undefined-function-frame*
 158                    (list '(flet test) #'optimized)))))
 159
 160   ;; bug 353: This test fails at least most of the time for x86/linux
 161   ;; ca. 0.8.20.16. -- WHN
 162   (with-test (:name (:undefined-function :bug-353)
 163               ;; This used to have fewer :fails-on features pre-0.9.16.38,
 164               ;; but it turns out that the bug was just being masked by
 165               ;; the presence of the IR1 stepper instrumentation (and
 166               ;; is thus again failing now that the instrumentation is
 167               ;; no more).
 168               :fails-on '(or :x86 :x86-64 :alpha :mips))
 169     (assert (verify-backtrace
 170              (lambda () (test #'not-optimized))
 171              (list *undefined-function-frame*
 172                    (list '(flet not-optimized))
 173                    (list '(flet test) #'not-optimized))))))
 174
 175 ;;; Division by zero was a common error on PPC. It depended on the
 176 ;;; return function either being before INTEGER-/-INTEGER in memory,
 177 ;;; or more than MOST-POSITIVE-FIXNUM bytes ahead. It also depends on
 178 ;;; INTEGER-/-INTEGER calling SIGNED-TRUNCATE. I believe Raymond Toy
 179 ;;; says that the Sparc backend (at least for CMUCL) inlines this, so
 180 ;;; if SBCL does the same this test is probably not good for the
 181 ;;; Sparc.
 182 ;;;
 183 ;;; Disabling tail call elimination on this will probably ensure that
 184 ;;; the return value (to the flet or the enclosing top level form) is
 185 ;;; more than MOST-POSITIVE-FIXNUM with the current spaces on OS X.
 186 ;;; Enabling it might catch other problems, so do it anyway.
 187 (flet ((optimized ()
 188          (declare (optimize (speed 2) (debug 1))) ; tail call elimination
 189          (/ 42 0))
 190        (not-optimized ()
 191          (declare (optimize (speed 1) (debug 2))) ; no tail call elimination
 192          (/ 42 0))
 193        (test (fun)
 194          (declare (optimize (speed 1) (debug 2))) ; no tail call elimination
 195          (funcall fun)))
 196   (with-test (:name (:divide-by-zero :bug-346)
 197               :fails-on '(or :alpha (and :x86-64 :darwin)))   ; bug 346
 198     (assert (verify-backtrace (lambda () (test #'optimized))
 199                               (list '(/ 42 &rest)
 200                                     (list '(flet test) #'optimized)))))
 201   (with-test (:name (:divide-by-zero :bug-356)
 202               :fails-on '(or :alpha (and :x86-64 :darwin)))   ; bug 356
 203     (assert (verify-backtrace (lambda () (test #'not-optimized))
 204                               (list '(/ 42 &rest)
 205                                     '((flet not-optimized))
 206                                     (list '(flet test) #'not-optimized))))))
 207
 208 (with-test (:name (:throw :no-such-tag)
 209             :fails-on '(or
 210                         (and :x86 :sunos)
 211                         (and :x86 :darwin)
 212                         (and :x86-64 :darwin)
 213                         (and :sparc :linux)
 214                         :alpha
 215                         :mips))
 216   (progn
 217     (defun throw-test ()
 218       (throw 'no-such-tag t))
 219     (assert (verify-backtrace #'throw-test '((throw-test))))))
 220
 221 ;;; test entry point handling in backtraces
 222
 223 (defun oops ()
 224   (error "oops"))
 225
 226 (defmacro defbt (n ll &body body)
 227   `(progn
 228      ;; normal debug info
 229      (defun ,(intern (format nil "BT.~A.1" n)) ,ll
 230        ,@body)
 231      ;; no arguments saved
 232      (defun ,(intern (format nil "BT.~A.2" n)) ,ll
 233        (declare (optimize (debug 1) (speed 3)))
 234        ,@body)
 235      ;; no lambda-list saved
 236      (defun ,(intern (format nil "BT.~A.3" n)) ,ll
 237        (declare (optimize (debug 0)))
 238        ,@body)))
 239
 240 (defbt 1 (&key key)
 241   (list key))
 242
 243 (defbt 2 (x)
 244   (list x))
 245
 246 (defbt 3 (&key (key (oops)))
 247   (list key))
 248
 249 ;;; ERROR instead of OOPS so that tail call elimination doesn't happen
 250 (defbt 4 (&optional opt)
 251   (list (error "error")))
 252
 253 (defbt 5 (&optional (opt (oops)))
 254   (list opt))
 255
 256 (defmacro with-details (bool &body body)
 257   `(let ((sb-debug:*show-entry-point-details* ,bool))
 258      ,@body))
 259
 260 (defun bug-354 (x)
 261   (error "XEPs in backtraces: ~S" x))
 262
 263 (with-test (:name :bug-354)
 264   (with-details t
 265     (assert (not (verify-backtrace (lambda () (bug-354 354))
 266                                    '((bug-354 &rest)
 267                                      ((sb-c::tl-xep bug-354) &rest))))))
 268   (assert (verify-backtrace (lambda () (bug-354 354)) '((bug-354 354)))))
 269
 270 ;;; FIXME: This test really should be broken into smaller pieces
 271 (with-test (:name (:backtrace :misc)
 272             :fails-on '(or (and :x86 (or :sunos)) (and :x86-64 :darwin)))
 273   (write-line "//tl-xep")
 274   (with-details t
 275     (assert (verify-backtrace #'namestring
 276                               '(((sb-c::tl-xep namestring) 0 ?)))))
 277   (with-details nil
 278     (assert (verify-backtrace #'namestring
 279                               '((namestring)))))
 280
 281   ;; &MORE-PROCESSOR
 282   (with-details t
 283     (assert (verify-backtrace (lambda () (bt.1.1 :key))
 284                               '(((sb-c::&more-processor bt.1.1) &rest))))
 285     (assert (verify-backtrace (lambda () (bt.1.2 :key))
 286                               '(((sb-c::&more-processor bt.1.2) &rest))))
 287     (assert (verify-backtrace (lambda () (bt.1.3 :key))
 288                               '(((sb-c::&more-processor bt.1.3) &rest)))))
 289   (with-details nil
 290     (assert (verify-backtrace (lambda () (bt.1.1 :key))
 291                               '((bt.1.1 :key))))
 292     (assert (verify-backtrace (lambda () (bt.1.2 :key))
 293                               '((bt.1.2 &rest))))
 294     (assert (verify-backtrace (lambda () (bt.1.3 :key))
 295                               '((bt.1.3 &rest)))))
 296
 297   ;; XEP
 298   (write-line "//xep")
 299   (with-details t
 300     (assert (verify-backtrace #'bt.2.1
 301                               '(((sb-c::xep bt.2.1) 0 ?))))
 302     (assert (verify-backtrace #'bt.2.2
 303                               '(((sb-c::xep bt.2.2) &rest))))
 304     (assert (verify-backtrace #'bt.2.3
 305                               '(((sb-c::xep bt.2.3) &rest)))))
 306   (with-details nil
 307     (assert (verify-backtrace #'bt.2.1
 308                               '((bt.2.1))))
 309     (assert (verify-backtrace #'bt.2.2
 310                               '((bt.2.2 &rest))))
 311     (assert (verify-backtrace #'bt.2.3
 312                               '((bt.2.3 &rest)))))
 313
 314   ;; VARARGS-ENTRY
 315   (write-line "//varargs-entry")
 316   (with-details t
 317     (assert (verify-backtrace #'bt.3.1
 318                               '(((sb-c::varargs-entry bt.3.1) :key nil))))
 319     (assert (verify-backtrace #'bt.3.2
 320                               '(((sb-c::varargs-entry bt.3.2) :key ?))))
 321     (assert (verify-backtrace #'bt.3.3
 322                               '(((sb-c::varargs-entry bt.3.3) &rest)))))
 323   (with-details nil
 324     (assert (verify-backtrace #'bt.3.1
 325                               '((bt.3.1 :key nil))))
 326     (assert (verify-backtrace #'bt.3.2
 327                               '((bt.3.2 :key ?))))
 328     (assert (verify-backtrace #'bt.3.3
 329                               '((bt.3.3 &rest)))))
 330
 331   ;; HAIRY-ARG-PROCESSOR
 332   (write-line "//hairy-args-processor")
 333   (with-details t
 334     (assert (verify-backtrace #'bt.4.1
 335                               '(((sb-c::hairy-arg-processor bt.4.1) ?))))
 336     (assert (verify-backtrace #'bt.4.2
 337                               '(((sb-c::hairy-arg-processor bt.4.2) ?))))
 338     (assert (verify-backtrace #'bt.4.3
 339                               '(((sb-c::hairy-arg-processor bt.4.3) &rest)))))
 340   (with-details nil
 341     (assert (verify-backtrace #'bt.4.1
 342                               '((bt.4.1 ?))))
 343     (assert (verify-backtrace #'bt.4.2
 344                               '((bt.4.2 ?))))
 345     (assert (verify-backtrace #'bt.4.3
 346                               '((bt.4.3 &rest)))))
 347
 348   ;; &OPTIONAL-PROCESSOR
 349   (write-line "//optional-processor")
 350   (with-details t
 351     (assert (verify-backtrace #'bt.5.1
 352                               '(((sb-c::&optional-processor bt.5.1)))))
 353     (assert (verify-backtrace #'bt.5.2
 354                               '(((sb-c::&optional-processor bt.5.2) &rest))))
 355     (assert (verify-backtrace #'bt.5.3
 356                               '(((sb-c::&optional-processor bt.5.3) &rest)))))
 357   (with-details nil
 358     (assert (verify-backtrace #'bt.5.1
 359                               '((bt.5.1))))
 360     (assert (verify-backtrace #'bt.5.2
 361                               '((bt.5.2 &rest))))
 362     (assert (verify-backtrace #'bt.5.3
 363                               '((bt.5.3 &rest))))))
 364
 365 (write-line "//compile nil")
 366 (defvar *compile-nil-error* (compile nil '(lambda (x) (cons (when x (error "oops")) nil))))
 367 (defvar *compile-nil-non-tc* (compile nil '(lambda (y) (cons (funcall *compile-nil-error* y) nil))))
 368 (assert (verify-backtrace (lambda () (funcall *compile-nil-non-tc* 13))
 369                           '(((lambda (x)) 13)
 370                             ((lambda (y)) 13))))
 371
 372 ;;;; test TRACE
 373
 374 (defun trace-this ()
 375   'ok)
 376
 377 (defun trace-fact (n)
 378   (if (zerop n)
 379       1
 380       (* n (trace-fact (1- n)))))
 381
 382 (let ((out (with-output-to-string (*trace-output*)
 383              (trace trace-this)
 384              (assert (eq 'ok (trace-this)))
 385              (untrace))))
 386   (assert (search "TRACE-THIS" out))
 387   (assert (search "returned OK" out)))
 388
 389 ;;; bug 379
 390 ;;; This is not a WITH-TEST :FAILS-ON PPC DARWIN since there are
 391 ;;; suspicions that the breakpoint trace might corrupt the whole image
 392 ;;; on that platform.
 393 #-(and (or ppc x86 x86-64) darwin)
 394 (with-test (:name (trace :encapsulate nil)
 395             :fails-on '(or :ppc :sparc :mips))
 396   (let ((out (with-output-to-string (*trace-output*)
 397                (trace trace-this :encapsulate nil)
 398                (assert (eq 'ok (trace-this)))
 399                (untrace))))
 400     (assert (search "TRACE-THIS" out))
 401     (assert (search "returned OK" out))))
 402
 403 #-(and (or ppc x86 x86-64) darwin)
 404 (with-test (:name (trace-recursive :encapsulate nil)
 405             :fails-on '(or :ppc :sparc :mips))
 406   (let ((out (with-output-to-string (*trace-output*)
 407                (trace trace-fact :encapsulate nil)
 408                (assert (= 120 (trace-fact 5)))
 409                (untrace))))
 410     (assert (search "TRACE-FACT" out))
 411     (assert (search "returned 1" out))
 412     (assert (search "returned 120" out))))
 413
 414 (with-test (:name :bug-414)
 415   (handler-bind ((warning #'error))
 416     (load (compile-file "bug-414.lisp"))
 417     (disassemble 'bug-414)))
 418
 419 ;;;; test infinite error protection
 420
 421 (defmacro nest-errors (n-levels error-form)
 422   (if (< 0 n-levels)
 423       `(handler-bind ((error (lambda (condition)
 424                                (declare (ignore condition))
 425                                ,error-form)))
 426         (nest-errors ,(1- n-levels) ,error-form))
 427       error-form))
 428
 429 (defun erroring-debugger-hook (condition old-debugger-hook)
 430   (let ((*debugger-hook* old-debugger-hook))
 431     (format t "recursive condition: ~A~%" condition) (force-output)
 432     (error "recursive condition: ~A" condition)))
 433
 434 (defun test-inifinite-error-protection ()
 435   ;; after 50 successful throws to SB-IMPL::TOPLEVEL-CATCHER sbcl used
 436   ;; to halt, it produces so much garbage that's hard to suppress that
 437   ;; it is tested only once
 438   (write-line "--HARMLESS BUT ALARMING BACKTRACE COMING UP--")
 439   (let ((*debugger-hook* #'erroring-debugger-hook))
 440     (loop repeat 1 do
 441           (let ((error-counter 0)
 442                 (*terminal-io* (make-broadcast-stream)))
 443             (assert
 444              (not (eq
 445                    :normal-exit
 446                    (catch 'sb-impl::toplevel-catcher
 447                      (nest-errors 20 (error "infinite error ~s"
 448                                             (incf error-counter)))
 449                      :normal-exit)))))))
 450   (write-line "--END OF H-B-A-B--"))
 451
 452 (enable-debugger)
 453
 454 (test-inifinite-error-protection)
 455
 456 #+sb-thread
 457 (let ((thread (sb-thread:make-thread #'test-inifinite-error-protection)))
 458   (loop while (sb-thread:thread-alive-p thread)))
 459
 460 (disable-debugger)
 461
 462 (write-line "/debug.impure.lisp done")