src/code/gc.lisp

   1 ;;;; garbage collection and allocation-related code
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!KERNEL")
  13 \f
  14 ;;;; DYNAMIC-USAGE and friends
  15
  16 (declaim (special sb!vm:*read-only-space-free-pointer*
  17                   sb!vm:*static-space-free-pointer*))
  18
  19 (eval-when (:compile-toplevel :execute)
  20   (sb!xc:defmacro def-c-var-fun (lisp-fun c-var-name)
  21     `(defun ,lisp-fun ()
  22        (sb!alien:extern-alien ,c-var-name (sb!alien:unsigned 32)))))
  23
  24 #!-sb-fluid
  25 (declaim (inline current-dynamic-space-start))
  26 #!+gencgc
  27 (defun current-dynamic-space-start () sb!vm:dynamic-space-start)
  28 #!-gencgc
  29 (def-c-var-fun current-dynamic-space-start "current_dynamic_space")
  30
  31 #!-sb-fluid
  32 (declaim (inline dynamic-usage))
  33 #!+gencgc
  34 (def-c-var-fun dynamic-usage "bytes_allocated")
  35 #!-gencgc
  36 (defun dynamic-usage ()
  37   (the (unsigned-byte 32)
  38        (- (sb!sys:sap-int (sb!c::dynamic-space-free-pointer))
  39           (current-dynamic-space-start))))
  40
  41 (defun static-space-usage ()
  42   (- (* sb!vm:*static-space-free-pointer* sb!vm:n-word-bytes)
  43      sb!vm:static-space-start))
  44
  45 (defun read-only-space-usage ()
  46   (- (* sb!vm::*read-only-space-free-pointer* sb!vm:n-word-bytes)
  47      sb!vm:read-only-space-start))
  48
  49 (defun control-stack-usage ()
  50   #!-stack-grows-downward-not-upward
  51   (- (sb!sys:sap-int (sb!c::control-stack-pointer-sap))
  52      (sb!sys:sap-int (sb!di::descriptor-sap sb!vm:*control-stack-start*)))
  53   #!+stack-grows-downward-not-upward
  54   (- (sb!sys:sap-int (sb!di::descriptor-sap sb!vm:*control-stack-end*))
  55      (sb!sys:sap-int (sb!c::control-stack-pointer-sap))))
  56
  57 (defun binding-stack-usage ()
  58   (- (sb!sys:sap-int (sb!c::binding-stack-pointer-sap))
  59      (sb!sys:sap-int (sb!di::descriptor-sap sb!vm:*binding-stack-start*))))
  60 \f
  61 ;;;; ROOM
  62
  63 (defun room-minimal-info ()
  64   (format t "Dynamic space usage is:   ~10:D bytes.~%" (dynamic-usage))
  65   (format t "Read-only space usage is: ~10:D bytes.~%" (read-only-space-usage))
  66   (format t "Static space usage is:    ~10:D bytes.~%" (static-space-usage))
  67   (format t "Control stack usage is:   ~10:D bytes.~%" (control-stack-usage))
  68   (format t "Binding stack usage is:   ~10:D bytes.~%" (binding-stack-usage))
  69   #!+sb-thread
  70   (format t
  71           "Control and binding stack usage is for the current thread only.~%")
  72   (format t "Garbage collection is currently ~:[enabled~;DISABLED~].~%"
  73           *gc-inhibit*))
  74
  75 (defun room-intermediate-info ()
  76   (room-minimal-info)
  77   (sb!vm:memory-usage :count-spaces '(:dynamic)
  78                       :print-spaces t
  79                       :cutoff 0.05f0
  80                       :print-summary nil))
  81
  82 (defun room-maximal-info ()
  83   ;; FIXME: SB!VM:INSTANCE-USAGE calls suppressed until bug 344 is fixed
  84   (room-intermediate-info)
  85   ;; old way, could be restored when bug 344 fixed:
  86   ;;x (room-minimal-info)
  87   ;;x (sb!vm:memory-usage :count-spaces '(:static :dynamic))
  88   ;;x (sb!vm:instance-usage :dynamic :top-n 10)
  89   ;;x (sb!vm:instance-usage :static :top-n 10)
  90   )
  91
  92 (defun room (&optional (verbosity :default))
  93   #!+sb-doc
  94   "Print to *STANDARD-OUTPUT* information about the state of internal
  95   storage and its management. The optional argument controls the
  96   verbosity of output. If it is T, ROOM prints out a maximal amount of
  97   information. If it is NIL, ROOM prints out a minimal amount of
  98   information. If it is :DEFAULT or it is not supplied, ROOM prints out
  99   an intermediate amount of information."
 100   (fresh-line)
 101   (ecase verbosity
 102     ((t)
 103      (room-maximal-info))
 104     ((nil)
 105      (room-minimal-info))
 106     (:default
 107      (room-intermediate-info)))
 108   (values))
 109 \f
 110 ;;;; GET-BYTES-CONSED
 111
 112 ;;; the total number of bytes freed so far (including any freeing
 113 ;;; which goes on in PURIFY)
 114 ;;;
 115 ;;; (We save this so that we can calculate the total number of bytes
 116 ;;; ever allocated by adding this to the number of bytes currently
 117 ;;; allocated and never freed.)
 118 (declaim (type unsigned-byte *n-bytes-freed-or-purified*))
 119 (defvar *n-bytes-freed-or-purified* 0)
 120 (defun gc-reinit ()
 121   (gc-on)
 122   (gc)
 123   (setf *n-bytes-freed-or-purified* 0
 124         *gc-run-time* 0
 125         ;; See comment in interr.lisp
 126         *heap-exhausted-error-condition* (make-condition 'heap-exhausted-error)))
 127
 128 (declaim (ftype (function () unsigned-byte) get-bytes-consed))
 129 (defun get-bytes-consed ()
 130   #!+sb-doc
 131   "Return the number of bytes consed since the program began. Typically
 132 this result will be a consed bignum, so if you have an application (e.g.
 133 profiling) which can't tolerate the overhead of consing bignums, you'll
 134 probably want either to hack in at a lower level (as the code in the
 135 SB-PROFILE package does), or to design a more microefficient interface
 136 and submit it as a patch."
 137   (+ (dynamic-usage)
 138      *n-bytes-freed-or-purified*))
 139 \f
 140 ;;;; GC hooks
 141
 142 (defvar *after-gc-hooks* nil
 143   "Called after each garbage collection, except for garbage collections
 144 triggered during thread exits. In a multithreaded environment these hooks may
 145 run in any thread.")
 146
 147 \f
 148 ;;;; internal GC
 149
 150 (sb!alien:define-alien-routine collect-garbage sb!alien:int
 151   (#!+gencgc last-gen #!-gencgc ignore sb!alien:int))
 152
 153 #!+sb-thread
 154 (progn
 155   (sb!alien:define-alien-routine gc-stop-the-world sb!alien:void)
 156   (sb!alien:define-alien-routine gc-start-the-world sb!alien:void))
 157 #!-sb-thread
 158 (progn
 159   (defun gc-stop-the-world ())
 160   (defun gc-start-the-world ()))
 161
 162 \f
 163 ;;;; SUB-GC
 164
 165 ;;; SUB-GC does a garbage collection.  This is called from three places:
 166 ;;; (1) The C runtime will call here when it detects that we've consed
 167 ;;;     enough to exceed the gc trigger threshold.  This is done in
 168 ;;;     alloc() for gencgc or interrupt_maybe_gc() for cheneygc
 169 ;;; (2) The user may request a collection using GC, below
 170 ;;; (3) At the end of a WITHOUT-GCING section, we are called if
 171 ;;;     *NEED-TO-COLLECT-GARBAGE* is true
 172 ;;;
 173 ;;; This is different from the behaviour in 0.7 and earlier: it no
 174 ;;; longer decides whether to GC based on thresholds.  If you call
 175 ;;; SUB-GC you will definitely get a GC either now or when the
 176 ;;; WITHOUT-GCING is over
 177
 178 ;;; For GENCGC all generations < GEN will be GC'ed.
 179
 180 (defvar *already-in-gc*
 181   (sb!thread:make-mutex :name "GC lock") "ID of thread running SUB-GC")
 182
 183 (defun sub-gc (&key (gen 0))
 184   (unless (eq sb!thread:*current-thread*
 185               (sb!thread::mutex-value *already-in-gc*))
 186     ;; With gencgc, unless *GC-PENDING* every allocation in this
 187     ;; function triggers another gc, potentially exceeding maximum
 188     ;; interrupt nesting. If *GC-INHIBIT* is not true, however,
 189     ;; there is no guarantee that we would ever check for pending
 190     ;; GC -- so in that case we must first disable interrupts, which
 191     ;; needs to be done for GC anyways...
 192     (cond (*gc-inhibit*
 193            (setf *gc-pending* t))
 194           (t
 195            (without-interrupts
 196              (setf *gc-pending* t)
 197              (sb!thread:with-mutex (*already-in-gc*)
 198                (let ((old-usage (dynamic-usage))
 199                      (new-usage 0))
 200                  (unsafe-clear-roots)
 201
 202                  (gc-stop-the-world)
 203                  (let ((start-time (get-internal-run-time)))
 204                    (collect-garbage gen)
 205                    (incf *gc-run-time*
 206                          (- (get-internal-run-time) start-time)))
 207                  (setf *gc-pending* nil
 208                        new-usage (dynamic-usage))
 209                  (gc-start-the-world)
 210
 211                  ;; In a multithreaded environment the other threads will
 212                  ;; see *n-b-f-o-p* change a little late, but that's OK.
 213                  (let ((freed (- old-usage new-usage)))
 214                    ;; GENCGC occasionally reports negative here, but the
 215                    ;; current belief is that it is part of the normal order
 216                    ;; of things and not a bug.
 217                    (when (plusp freed)
 218                      (incf *n-bytes-freed-or-purified* freed))))))
 219
 220            ;; Outside the mutex, interrupts enabled: these may cause
 221            ;; another GC. FIXME: it can potentially exceed maximum
 222            ;; interrupt nesting by triggering GCs.
 223            ;;
 224            ;; Can that be avoided by having the finalizers and hooks
 225            ;; run only from the outermost SUB-GC?
 226            ;;
 227            ;; KLUDGE: Don't run the hooks in GC's triggered by dying
 228            ;; threads, so that user-code never runs with
 229            ;;   (thread-alive-p *current-thread*) => nil
 230            ;; The long-term solution will be to keep a separate thread
 231            ;; for finalizers and after-gc hooks.
 232            (when (sb!thread:thread-alive-p sb!thread:*current-thread*)
 233              (run-pending-finalizers)
 234              (dolist (hook *after-gc-hooks*)
 235                (handler-case
 236                    (funcall hook)
 237                  (serious-condition (c)
 238                    (warn "Error calling after-GC hook ~S:~% ~A" hook c)))))))))
 239
 240 ;;; This is the user-advertised garbage collection function.
 241 (defun gc (&key (gen 0) (full nil) &allow-other-keys)
 242   #!+(and sb-doc gencgc)
 243   "Initiate a garbage collection. GEN controls the number of generations
 244   to garbage collect."
 245   #!+(and sb-doc (not gencgc))
 246   "Initiate a garbage collection. GEN may be provided for compatibility with
 247   generational garbage collectors, but is ignored in this implementation."
 248   (sub-gc :gen (if full 6 gen)))
 249
 250 (defun unsafe-clear-roots ()
 251   ;; KLUDGE: Do things in an attempt to get rid of extra roots. Unsafe
 252   ;; as having these cons more then we have space left leads to huge
 253   ;; badness.
 254   (scrub-control-stack)
 255   ;; Power cache of the bignum printer: drops overly large bignums and
 256   ;; removes duplicate entries.
 257   (scrub-power-cache)
 258   ;; FIXME: CTYPE-OF-CACHE-CLEAR isn't thread-safe.
 259   #!-sb-thread
 260   (ctype-of-cache-clear))
 261
 262 \f
 263 ;;;; auxiliary functions
 264
 265 (defun bytes-consed-between-gcs ()
 266   #!+sb-doc
 267   "Return the amount of memory that will be allocated before the next garbage
 268    collection is initiated. This can be set with SETF."
 269   (sb!alien:extern-alien "bytes_consed_between_gcs"
 270                          (sb!alien:unsigned 32)))
 271
 272 (defun (setf bytes-consed-between-gcs) (val)
 273   (declare (type index val))
 274   (setf (sb!alien:extern-alien "bytes_consed_between_gcs"
 275                                (sb!alien:unsigned 32))
 276         val))
 277
 278 (declaim (inline maybe-handle-pending-gc))
 279 (defun maybe-handle-pending-gc ()
 280   (when (and (not *gc-inhibit*)
 281              (or #!+sb-thread *stop-for-gc-pending*
 282                  *gc-pending*))
 283     (sb!unix::receive-pending-interrupt)))
 284
 285 ;;; These work both regardless of whether we're inside WITHOUT-GCING
 286 ;;; or not.
 287 (defun gc-on ()
 288   #!+sb-doc
 289   "Enable the garbage collector."
 290   (setq *gc-inhibit* nil)
 291   (maybe-handle-pending-gc)
 292   nil)
 293
 294 (defun gc-off ()
 295   #!+sb-doc
 296   "Disable the garbage collector."
 297   (setq *gc-inhibit* t)
 298   nil)