src/code/pred.lisp

   1 ;;;; predicate functions (EQUAL and friends, and type predicates)
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13 \f
  14 ;;;; miscellaneous non-primitive predicates
  15
  16 #!-sb-fluid (declaim (inline streamp))
  17 (defun streamp (stream)
  18   (typep stream 'stream))
  19
  20 ;;; various (VECTOR FOO) type predicates, not implemented as simple
  21 ;;; widetag tests
  22 (macrolet
  23     ((def ()
  24        `(progn
  25           ,@(loop for (name spec) in *vector-without-complex-typecode-infos*
  26                   collect `(defun ,name (x)
  27                              (or (typep x '(simple-array ,spec (*)))
  28                                  (and (complex-vector-p x)
  29                                       (do ((data (%array-data-vector x) (%array-data-vector data)))
  30                                           ((not (array-header-p data)) (typep data '(simple-array ,spec (*))))))))))))
  31   (def))
  32
  33 ;;; Is X an extended sequence?
  34 (defun extended-sequence-p (x)
  35   (and (not (listp x))
  36        (not (vectorp x))
  37        (let* ((slayout #.(info :type :compiler-layout 'sequence))
  38              (depthoid #.(layout-depthoid (info :type :compiler-layout 'sequence)))
  39              (layout (layout-of x)))
  40         (when (layout-invalid layout)
  41           (setq layout (update-object-layout-or-invalid x slayout)))
  42         (if (eq layout slayout)
  43             t
  44             (let ((inherits (layout-inherits layout)))
  45               (declare (optimize (safety 0)))
  46               (and (> (length inherits) depthoid)
  47                    (eq (svref inherits depthoid) slayout)))))))
  48
  49 ;;; Is X a SEQUENCE?  Harder than just (OR VECTOR LIST)
  50 (defun sequencep (x)
  51   (or (listp x)
  52       (vectorp x)
  53       (let* ((slayout #.(info :type :compiler-layout 'sequence))
  54              (depthoid #.(layout-depthoid (info :type :compiler-layout 'sequence)))
  55              (layout (layout-of x)))
  56         (when (layout-invalid layout)
  57           (setq layout (update-object-layout-or-invalid x slayout)))
  58         (if (eq layout slayout)
  59             t
  60             (let ((inherits (layout-inherits layout)))
  61               (declare (optimize (safety 0)))
  62               (and (> (length inherits) depthoid)
  63                    (eq (svref inherits depthoid) slayout)))))))
  64 \f
  65 ;;;; primitive predicates. These must be supported directly by the
  66 ;;;; compiler.
  67
  68 (defun not (object)
  69   #!+sb-doc
  70   "Return T if X is NIL, otherwise return NIL."
  71   (not object))
  72
  73 ;;; All the primitive type predicate wrappers share a parallel form..
  74 (macrolet ((def-type-predicate-wrapper (pred)
  75              (let* ((name (symbol-name pred))
  76                     (stem (string-left-trim "%" (string-right-trim "P-" name)))
  77                     (article (if (position (schar name 0) "AEIOU") "an" "a")))
  78                `(defun ,pred (object)
  79                   ,(format nil
  80                            "Return true if OBJECT is ~A ~A, and NIL otherwise."
  81                            article
  82                            stem)
  83                   ;; (falling through to low-level implementation)
  84                   (,pred object)))))
  85   (def-type-predicate-wrapper array-header-p)
  86   (def-type-predicate-wrapper arrayp)
  87   (def-type-predicate-wrapper atom)
  88   (def-type-predicate-wrapper base-char-p)
  89   (def-type-predicate-wrapper base-string-p)
  90   #!+sb-unicode (def-type-predicate-wrapper character-string-p)
  91   (def-type-predicate-wrapper bignump)
  92   (def-type-predicate-wrapper bit-vector-p)
  93   (def-type-predicate-wrapper characterp)
  94   (def-type-predicate-wrapper code-component-p)
  95   (def-type-predicate-wrapper consp)
  96   (def-type-predicate-wrapper compiled-function-p)
  97   (def-type-predicate-wrapper complexp)
  98   (def-type-predicate-wrapper complex-double-float-p)
  99   (def-type-predicate-wrapper complex-float-p)
 100   #!+long-float (def-type-predicate-wrapper complex-long-float-p)
 101   (def-type-predicate-wrapper complex-rational-p)
 102   (def-type-predicate-wrapper complex-single-float-p)
 103   ;; (COMPLEX-VECTOR-P is not included here since it's awkward to express
 104   ;; the type it tests for in the Common Lisp type system, and since it's
 105   ;; only used in the implementation of a few specialized things.)
 106   (def-type-predicate-wrapper double-float-p)
 107   (def-type-predicate-wrapper extended-char-p)
 108   (def-type-predicate-wrapper fdefn-p)
 109   (def-type-predicate-wrapper fixnump)
 110   (def-type-predicate-wrapper floatp)
 111   (def-type-predicate-wrapper functionp)
 112   (def-type-predicate-wrapper integerp)
 113   (def-type-predicate-wrapper listp)
 114   (def-type-predicate-wrapper long-float-p)
 115   #!+(and sb-thread sb-lutex)
 116   (def-type-predicate-wrapper lutexp)
 117   (def-type-predicate-wrapper lra-p)
 118   (def-type-predicate-wrapper null)
 119   (def-type-predicate-wrapper numberp)
 120   (def-type-predicate-wrapper rationalp)
 121   (def-type-predicate-wrapper ratiop)
 122   (def-type-predicate-wrapper realp)
 123   (def-type-predicate-wrapper short-float-p)
 124   (def-type-predicate-wrapper single-float-p)
 125   (def-type-predicate-wrapper %instancep)
 126   (def-type-predicate-wrapper symbolp)
 127   (def-type-predicate-wrapper system-area-pointer-p)
 128   (def-type-predicate-wrapper weak-pointer-p)
 129   #!+#.(cl:if (cl:= 32 sb!vm:n-word-bits) '(and) '(or))
 130   (progn
 131     (def-type-predicate-wrapper unsigned-byte-32-p)
 132     (def-type-predicate-wrapper signed-byte-32-p))
 133   #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 134   (progn
 135     (def-type-predicate-wrapper unsigned-byte-64-p)
 136     (def-type-predicate-wrapper signed-byte-64-p))
 137   ;; Specialized array types
 138   (macrolet ((saetp-defs ()
 139                `(progn
 140                   ,@(map 'list
 141                          (lambda (saetp)
 142                            `(def-type-predicate-wrapper
 143                                 ,(symbolicate (sb!vm:saetp-primitive-type-name saetp) "-P")))
 144                          sb!vm:*specialized-array-element-type-properties*))))
 145     (saetp-defs))
 146   ;; Other array types
 147   (def-type-predicate-wrapper simple-array-p)
 148   (def-type-predicate-wrapper simple-string-p)
 149   (def-type-predicate-wrapper stringp)
 150   (def-type-predicate-wrapper vectorp)
 151   (def-type-predicate-wrapper vector-nil-p))
 152 \f
 153 ;;; Return the specifier for the type of object. This is not simply
 154 ;;; (TYPE-SPECIFIER (CTYPE-OF OBJECT)) because CTYPE-OF has different
 155 ;;; goals than TYPE-OF. In particular, speed is more important than
 156 ;;; precision, and it is not permitted to return member types.
 157 (defun type-of (object)
 158   #!+sb-doc
 159   "Return the type of OBJECT."
 160   (typecase object
 161     (fixnum
 162      (cond
 163        ((<= 0 object 1) 'bit)
 164        ((< object 0) 'fixnum)
 165        (t '(integer 0 #.sb!xc:most-positive-fixnum))))
 166     (integer
 167      (if (>= object 0)
 168          '(integer #.(1+ sb!xc:most-positive-fixnum))
 169          'bignum))
 170     (standard-char 'standard-char)
 171     (base-char 'base-char)
 172     (extended-char 'extended-char)
 173     ((member t) 'boolean)
 174     (keyword 'keyword)
 175     ((or array complex)
 176      (type-specifier (ctype-of object)))
 177     (t
 178      (let* ((classoid (layout-classoid (layout-of object)))
 179             (name (classoid-name classoid)))
 180        (if (%instancep object)
 181            (case name
 182              (sb!alien-internals:alien-value
 183               `(sb!alien:alien
 184                 ,(sb!alien-internals:unparse-alien-type
 185                   (sb!alien-internals:alien-value-type object))))
 186              (t
 187               (let ((pname (classoid-proper-name classoid)))
 188                 (if (classoid-p pname)
 189                     (classoid-pcl-class pname)
 190                     pname))))
 191            name)))))
 192 \f
 193 ;;;; equality predicates
 194
 195 ;;; This is real simple, 'cause the compiler takes care of it.
 196 (defun eq (obj1 obj2)
 197   #!+sb-doc
 198   "Return T if OBJ1 and OBJ2 are the same object, otherwise NIL."
 199   (eq obj1 obj2))
 200
 201 (declaim (inline %eql))
 202 (defun %eql (obj1 obj2)
 203   #!+sb-doc
 204   "Return T if OBJ1 and OBJ2 represent the same object, otherwise NIL."
 205   (or (eq obj1 obj2)
 206       (if (or (typep obj2 'fixnum)
 207               (not (typep obj2 'number)))
 208           nil
 209           (macrolet ((foo (&rest stuff)
 210                        `(typecase obj2
 211                           ,@(mapcar (lambda (foo)
 212                                       (let ((type (car foo))
 213                                             (fn (cadr foo)))
 214                                         `(,type
 215                                           (and (typep obj1 ',type)
 216                                                (,fn obj1 obj2)))))
 217                                     stuff))))
 218             (foo
 219              (single-float eql)
 220              (double-float eql)
 221              #!+long-float
 222              (long-float eql)
 223              (bignum
 224               (lambda (x y)
 225                 (zerop (bignum-compare x y))))
 226              (ratio
 227               (lambda (x y)
 228                 (and (eql (numerator x) (numerator y))
 229                      (eql (denominator x) (denominator y)))))
 230              (complex
 231               (lambda (x y)
 232                 (and (eql (realpart x) (realpart y))
 233                      (eql (imagpart x) (imagpart y))))))))))
 234
 235 (defun eql (x y)
 236   (%eql x y))
 237
 238 (defun bit-vector-= (x y)
 239   (declare (type bit-vector x y))
 240   (if (and (simple-bit-vector-p x)
 241            (simple-bit-vector-p y))
 242       (bit-vector-= x y) ; DEFTRANSFORM
 243       (and (= (length x) (length y))
 244            (do ((i 0 (1+ i))
 245                 (length (length x)))
 246                ((= i length) t)
 247              (declare (fixnum i))
 248              (unless (= (bit x i) (bit y i))
 249                (return nil))))))
 250
 251 (defun equal (x y)
 252   #!+sb-doc
 253   "Return T if X and Y are EQL or if they are structured components whose
 254 elements are EQUAL. Strings and bit-vectors are EQUAL if they are the same
 255 length and have identical components. Other arrays must be EQ to be EQUAL."
 256   ;; Non-tail self-recursion implemented with a local auxiliary function
 257   ;; is a lot faster than doing it the straightforward way (at least
 258   ;; on x86oids) due to calling convention differences. -- JES, 2005-12-30
 259   (labels ((equal-aux (x y)
 260              (cond ((%eql x y)
 261                     t)
 262                    ((consp x)
 263                     (and (consp y)
 264                          (equal-aux (car x) (car y))
 265                          (equal-aux (cdr x) (cdr y))))
 266                    ((stringp x)
 267                     (and (stringp y) (string= x y)))
 268                    ((pathnamep x)
 269                     (and (pathnamep y) (pathname= x y)))
 270                    ((bit-vector-p x)
 271                     (and (bit-vector-p y)
 272                          (bit-vector-= x y)))
 273                    (t nil))))
 274     ;; Use MAYBE-INLINE to get the inline expansion only once (instead
 275     ;; of 200 times with INLINE). -- JES, 2005-12-30
 276     (declare (maybe-inline equal-aux))
 277     (equal-aux x y)))
 278
 279 ;;; EQUALP comparison of HASH-TABLE values
 280 (defun hash-table-equalp (x y)
 281   (declare (type hash-table x y))
 282   (or (eq x y)
 283       (and (hash-table-p y)
 284            (eql (hash-table-count x) (hash-table-count y))
 285            (eql (hash-table-test x) (hash-table-test y))
 286            (block comparison-of-entries
 287              (maphash (lambda (key x-value)
 288                         (multiple-value-bind (y-value y-value-p)
 289                             (gethash key y)
 290                           (unless (and y-value-p (equalp x-value y-value))
 291                             (return-from comparison-of-entries nil))))
 292                       x)
 293              t))))
 294
 295 (defun equalp (x y)
 296   #+nil ; KLUDGE: If doc string, should be accurate: Talk about structures
 297   ; and HASH-TABLEs.
 298   "This is like EQUAL, except more liberal in several respects.
 299   Numbers may be of different types, as long as the values are identical
 300   after coercion. Characters may differ in alphabetic case. Vectors and
 301   arrays must have identical dimensions and EQUALP elements, but may differ
 302   in their type restriction."
 303   (cond ((eq x y) t)
 304         ((characterp x) (and (characterp y) (char-equal x y)))
 305         ((numberp x) (and (numberp y) (= x y)))
 306         ((consp x)
 307          (and (consp y)
 308               (equalp (car x) (car y))
 309               (equalp (cdr x) (cdr y))))
 310         ((pathnamep x)
 311          (and (pathnamep y) (pathname= x y)))
 312         ((hash-table-p x)
 313          (and (hash-table-p y)
 314               (hash-table-equalp x y)))
 315         ((%instancep x)
 316          (let* ((layout-x (%instance-layout x))
 317                 (raw-len (layout-n-untagged-slots layout-x))
 318                 (total-len (layout-length layout-x))
 319                 (normal-len (- total-len raw-len)))
 320            (and (%instancep y)
 321                 (eq layout-x (%instance-layout y))
 322                 (structure-classoid-p (layout-classoid layout-x))
 323                 (dotimes (i normal-len t)
 324                   (let ((x-el (%instance-ref x i))
 325                         (y-el (%instance-ref y i)))
 326                     (unless (or (eq x-el y-el)
 327                                 (equalp x-el y-el))
 328                       (return nil))))
 329                 (if (zerop raw-len)
 330                     t
 331                     (raw-instance-slots-equalp layout-x x y)))))
 332         ((vectorp x)
 333          (let ((length (length x)))
 334            (and (vectorp y)
 335                 (= length (length y))
 336                 (dotimes (i length t)
 337                   (let ((x-el (aref x i))
 338                         (y-el (aref y i)))
 339                     (unless (or (eq x-el y-el)
 340                                 (equalp x-el y-el))
 341                       (return nil)))))))
 342         ((arrayp x)
 343          (and (arrayp y)
 344               (= (array-rank x) (array-rank y))
 345               (dotimes (axis (array-rank x) t)
 346                 (unless (= (array-dimension x axis)
 347                            (array-dimension y axis))
 348                   (return nil)))
 349               (dotimes (index (array-total-size x) t)
 350                 (let ((x-el (row-major-aref x index))
 351                       (y-el (row-major-aref y index)))
 352                   (unless (or (eq x-el y-el)
 353                               (equalp x-el y-el))
 354                     (return nil))))))
 355         (t nil)))
 356
 357 (/show0 "about to do test cases in pred.lisp")
 358 #!+sb-test
 359 (let ((test-cases `((0.0 ,(load-time-value (make-unportable-float :single-float-negative-zero)) t)
 360                     (0.0 1.0 nil)
 361                     (#c(1 0) #c(1.0 0.0) t)
 362                     (#c(0 1) #c(0.0 1.0) t)
 363                     (#c(1.1 0.0) #c(11/10 0) nil) ; due to roundoff error
 364                     ("Hello" "hello" t)
 365                     ("Hello" #(#\h #\E #\l #\l #\o) t)
 366                     ("Hello" "goodbye" nil))))
 367   (/show0 "TEST-CASES bound in pred.lisp")
 368   (dolist (test-case test-cases)
 369     (/show0 "about to do a TEST-CASE in pred.lisp")
 370     (destructuring-bind (x y expected-result) test-case
 371       (let* ((result (equalp x y))
 372              (bresult (if result 1 0))
 373              (expected-bresult (if expected-result 1 0)))
 374         (unless (= bresult expected-bresult)
 375           (/show0 "failing test in pred.lisp")
 376           (error "failed test (EQUALP ~S ~S)" x y))))))
 377 (/show0 "done with test cases in pred.lisp")