src/code/cold-init.lisp

   1 ;;;; cold initialization stuff, plus some other miscellaneous stuff
   2 ;;;; that we don't have any better place for
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; burning our ships behind us
  16
  17 ;;; There's a fair amount of machinery which is needed only at cold
  18 ;;; init time, and should be discarded before freezing the final
  19 ;;; system. We discard it by uninterning the associated symbols.
  20 ;;; Rather than using a special table of symbols to be uninterned,
  21 ;;; which might be tedious to maintain, instead we use a hack:
  22 ;;; anything whose name matches a magic character pattern is
  23 ;;; uninterned.
  24 ;;;
  25 ;;; FIXME: Are there other tables that need to have entries removed?
  26 ;;; What about symbols of the form DEF!FOO?
  27 (defun !unintern-init-only-stuff ()
  28   (do ((any-changes? nil nil))
  29       (nil)
  30     (dolist (package (list-all-packages))
  31       (do-symbols (symbol package)
  32         (let ((name (symbol-name symbol)))
  33           (when (or (string= name "!" :end1 1 :end2 1)
  34                     (and (>= (length name) 2)
  35                          (string= name "*!" :end1 2 :end2 2)))
  36             (/show0 "uninterning cold-init-only symbol..")
  37             (/primitive-print name)
  38             ;; FIXME: Is this (FIRST (LAST *INFO-ENVIRONMENT*)) really
  39             ;; meant to be an idiom to use?  Is there a more obvious
  40             ;; name for this? [e.g. (GLOBAL-ENVIRONMENT)?]
  41             (do-info ((first (last *info-environment*))
  42                             :name entry :class class :type type)
  43               (when (eq entry symbol)
  44                 (clear-info class type entry)))
  45             (unintern symbol package)
  46             (setf any-changes? t)))))
  47     (unless any-changes?
  48       (return))))
  49 \f
  50 ;;;; putting ourselves out of our misery when things become too much to bear
  51
  52 (declaim (ftype (function (simple-string) nil) !cold-lose))
  53 (defun !cold-lose (msg)
  54   (%primitive print msg)
  55   (%primitive print "too early in cold init to recover from errors")
  56   (%halt))
  57
  58 ;;; last-ditch error reporting for things which should never happen
  59 ;;; and which, if they do happen, are sufficiently likely to torpedo
  60 ;;; the normal error-handling system that we want to bypass it
  61 (declaim (ftype (function (simple-string) nil) critically-unreachable))
  62 (defun critically-unreachable (where)
  63   (%primitive print "internal error: Control should never reach here, i.e.")
  64   (%primitive print where)
  65   (%halt))
  66 \f
  67 ;;;; !COLD-INIT
  68
  69 ;;; a list of toplevel things set by GENESIS
  70 (defvar *!reversed-cold-toplevels*)
  71
  72 ;;; a SIMPLE-VECTOR set by GENESIS
  73 (defvar *!load-time-values*)
  74
  75 (eval-when (:compile-toplevel :execute)
  76   ;; FIXME: Perhaps we should make SHOW-AND-CALL-AND-FMAKUNBOUND, too,
  77   ;; and use it for most of the cold-init functions. (Just be careful
  78   ;; not to use it for the COLD-INIT-OR-REINIT functions.)
  79   (sb!xc:defmacro show-and-call (name)
  80     `(progn
  81        (/primitive-print ,(symbol-name name))
  82        (,name))))
  83
  84 ;;; called when a cold system starts up
  85 (defun !cold-init ()
  86   #!+sb-doc "Give the world a shove and hope it spins."
  87
  88   (/show0 "entering !COLD-INIT")
  89
  90   ;; FIXME: It'd probably be cleaner to have most of the stuff here
  91   ;; handled by calls like !GC-COLD-INIT, !ERROR-COLD-INIT, and
  92   ;; !UNIX-COLD-INIT. And *TYPE-SYSTEM-INITIALIZED* could be changed to
  93   ;; *TYPE-SYSTEM-INITIALIZED-WHEN-BOUND* so that it doesn't need to
  94   ;; be explicitly set in order to be meaningful.
  95   (setf *after-gc-hooks* nil
  96         *gc-inhibit* t
  97         *gc-pending* nil
  98         #!+sb-thread *stop-for-gc-pending* #!+sb-thread nil
  99         *allow-with-interrupts* t
 100         *interrupts-enabled* t
 101         *interrupt-pending* nil
 102         *break-on-signals* nil
 103         *maximum-error-depth* 10
 104         *current-error-depth* 0
 105         *cold-init-complete-p* nil
 106         *type-system-initialized* nil
 107         sb!vm:*alloc-signal* nil)
 108
 109   ;; I'm not sure where eval is first called, so I put this first.
 110   #!+sb-eval
 111   (show-and-call sb!eval::!full-eval-cold-init)
 112
 113   (show-and-call thread-init-or-reinit)
 114   (show-and-call !typecheckfuns-cold-init)
 115
 116   ;; Anyone might call RANDOM to initialize a hash value or something;
 117   ;; and there's nothing which needs to be initialized in order for
 118   ;; this to be initialized, so we initialize it right away.
 119   (show-and-call !random-cold-init)
 120
 121   ;; Must be done before any non-opencoded array references are made.
 122   (show-and-call !hairy-data-vector-reffer-init)
 123
 124   (show-and-call !character-database-cold-init)
 125   (show-and-call !character-name-database-cold-init)
 126
 127   (show-and-call !early-package-cold-init)
 128   (show-and-call !package-cold-init)
 129
 130   ;; All sorts of things need INFO and/or (SETF INFO).
 131   (/show0 "about to SHOW-AND-CALL !GLOBALDB-COLD-INIT")
 132   (show-and-call !globaldb-cold-init)
 133
 134   ;; This needs to be done early, but needs to be after INFO is
 135   ;; initialized.
 136   (show-and-call !function-names-cold-init)
 137   (show-and-call !fdefn-cold-init)
 138
 139   ;; Various toplevel forms call MAKE-ARRAY, which calls SUBTYPEP, so
 140   ;; the basic type machinery needs to be initialized before toplevel
 141   ;; forms run.
 142   (show-and-call !type-class-cold-init)
 143   (show-and-call !typedefs-cold-init)
 144   (show-and-call !classes-cold-init)
 145   (show-and-call !early-type-cold-init)
 146   (show-and-call !late-type-cold-init)
 147   (show-and-call !alien-type-cold-init)
 148   (show-and-call !target-type-cold-init)
 149   (show-and-call !vm-type-cold-init)
 150   ;; FIXME: It would be tidy to make sure that that these cold init
 151   ;; functions are called in the same relative order as the toplevel
 152   ;; forms of the corresponding source files.
 153
 154   ;;(show-and-call !package-cold-init)
 155   (show-and-call !policy-cold-init-or-resanify)
 156   (/show0 "back from !POLICY-COLD-INIT-OR-RESANIFY")
 157
 158   (show-and-call !constantp-cold-init)
 159   (show-and-call !early-proclaim-cold-init)
 160
 161   ;; KLUDGE: Why are fixups mixed up with toplevel forms? Couldn't
 162   ;; fixups be done separately? Wouldn't that be clearer and better?
 163   ;; -- WHN 19991204
 164   (/show0 "doing cold toplevel forms and fixups")
 165   (/show0 "(LISTP *!REVERSED-COLD-TOPLEVELS*)=..")
 166   (/hexstr (if (listp *!reversed-cold-toplevels*) "true" "NIL"))
 167   (/show0 "about to calculate (LENGTH *!REVERSED-COLD-TOPLEVELS*)")
 168   (/show0 "(LENGTH *!REVERSED-COLD-TOPLEVELS*)=..")
 169   #!+sb-show (let ((r-c-tl-length (length *!reversed-cold-toplevels*)))
 170                (/show0 "(length calculated..)")
 171                (let ((hexstr (hexstr r-c-tl-length)))
 172                  (/show0 "(hexstr calculated..)")
 173                  (/primitive-print hexstr)))
 174   (let (#!+sb-show (index-in-cold-toplevels 0))
 175     #!+sb-show (declare (type fixnum index-in-cold-toplevels))
 176
 177     (dolist (toplevel-thing (prog1
 178                                 (nreverse *!reversed-cold-toplevels*)
 179                               ;; (Now that we've NREVERSEd it, it's
 180                               ;; somewhat scrambled, so keep anyone
 181                               ;; else from trying to get at it.)
 182                               (makunbound '*!reversed-cold-toplevels*)))
 183       #!+sb-show
 184       (when (zerop (mod index-in-cold-toplevels 1024))
 185         (/show0 "INDEX-IN-COLD-TOPLEVELS=..")
 186         (/hexstr index-in-cold-toplevels))
 187       #!+sb-show
 188       (setf index-in-cold-toplevels
 189             (the fixnum (1+ index-in-cold-toplevels)))
 190       (typecase toplevel-thing
 191         (function
 192          (funcall toplevel-thing))
 193         (cons
 194          (case (first toplevel-thing)
 195            (:load-time-value
 196             (setf (svref *!load-time-values* (third toplevel-thing))
 197                   (funcall (second toplevel-thing))))
 198            (:load-time-value-fixup
 199             (setf (sap-ref-word (second toplevel-thing) 0)
 200                   (get-lisp-obj-address
 201                    (svref *!load-time-values* (third toplevel-thing)))))
 202            #!+(and (or x86 x86-64) gencgc)
 203            (:load-time-code-fixup
 204             (sb!vm::!envector-load-time-code-fixup (second toplevel-thing)
 205                                                    (third  toplevel-thing)
 206                                                    (fourth toplevel-thing)
 207                                                    (fifth  toplevel-thing)))
 208            (t
 209             (!cold-lose "bogus fixup code in *!REVERSED-COLD-TOPLEVELS*"))))
 210         (t (!cold-lose "bogus function in *!REVERSED-COLD-TOPLEVELS*")))))
 211   (/show0 "done with loop over cold toplevel forms and fixups")
 212
 213   ;; Set sane values again, so that the user sees sane values instead
 214   ;; of whatever is left over from the last DECLAIM/PROCLAIM.
 215   (show-and-call !policy-cold-init-or-resanify)
 216
 217   ;; Only do this after toplevel forms have run, 'cause that's where
 218   ;; DEFTYPEs are.
 219   (setf *type-system-initialized* t)
 220
 221   ;; now that the type system is definitely initialized, fixup UNKNOWN
 222   ;; types that have crept in.
 223   (show-and-call !fixup-type-cold-init)
 224   ;; run the PROCLAIMs.
 225   (show-and-call !late-proclaim-cold-init)
 226
 227   (show-and-call os-cold-init-or-reinit)
 228
 229   (show-and-call stream-cold-init-or-reset)
 230   (show-and-call !loader-cold-init)
 231   (show-and-call !foreign-cold-init)
 232   #!-win32 (show-and-call signal-cold-init-or-reinit)
 233   (/show0 "enabling internal errors")
 234   (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 235
 236   (show-and-call float-cold-init-or-reinit)
 237
 238   (show-and-call !class-finalize)
 239
 240   ;; The reader and printer are initialized very late, so that they
 241   ;; can do hairy things like invoking the compiler as part of their
 242   ;; initialization.
 243   (show-and-call !reader-cold-init)
 244   (let ((*readtable* *standard-readtable*))
 245     (show-and-call !sharpm-cold-init)
 246     (show-and-call !backq-cold-init))
 247   (setf *readtable* (copy-readtable *standard-readtable*))
 248   (setf sb!debug:*debug-readtable* (copy-readtable *standard-readtable*))
 249   (sb!pretty:!pprint-cold-init)
 250
 251   ;; the ANSI-specified initial value of *PACKAGE*
 252   (setf *package* (find-package "COMMON-LISP-USER"))
 253
 254   (/show0 "done initializing, setting *COLD-INIT-COMPLETE-P*")
 255   (setf *cold-init-complete-p* t)
 256
 257   ;; The system is finally ready for GC.
 258   (/show0 "enabling GC")
 259   (gc-on)
 260   (/show0 "doing first GC")
 261   (gc :full t)
 262   (/show0 "back from first GC")
 263
 264   ;; The show is on.
 265   (terpri)
 266   (/show0 "going into toplevel loop")
 267   (handling-end-of-the-world
 268     (toplevel-init)
 269     (critically-unreachable "after TOPLEVEL-INIT")))
 270
 271 (defun quit (&key recklessly-p (unix-status 0))
 272   #!+sb-doc
 273   "Terminate the current Lisp. Things are cleaned up (with
 274 UNWIND-PROTECT and so forth) unless RECKLESSLY-P is non-NIL. On
 275 UNIX-like systems, UNIX-STATUS is used as the status code."
 276   (declare (type (signed-byte 32) unix-status))
 277   (/show0 "entering QUIT")
 278   (if recklessly-p
 279       (sb!unix:unix-exit unix-status)
 280       (throw '%end-of-the-world unix-status))
 281   (critically-unreachable "after trying to die in QUIT"))
 282 \f
 283 ;;;; initialization functions
 284
 285 (defun thread-init-or-reinit ()
 286   (sb!thread::init-initial-thread)
 287   (sb!thread::init-job-control)
 288   (sb!thread::get-foreground))
 289
 290 (defun reinit ()
 291   (setf *default-external-format* nil)
 292   (setf sb!alien::*default-c-string-external-format* nil)
 293   ;; WITHOUT-GCING implies WITHOUT-INTERRUPTS.
 294   (without-gcing
 295     (os-cold-init-or-reinit)
 296     (thread-init-or-reinit)
 297     (stream-reinit t)
 298     #!-win32
 299     (signal-cold-init-or-reinit)
 300     (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 301     (float-cold-init-or-reinit))
 302   (gc-reinit)
 303   (foreign-reinit)
 304   (time-reinit)
 305   ;; If the debugger was disabled in the saved core, we need to
 306   ;; re-disable ldb again.
 307   (when (eq *invoke-debugger-hook* 'sb!debug::debugger-disabled-hook)
 308     (sb!debug::disable-debugger))
 309   (dolist (hook *init-hooks*)
 310     (with-simple-restart (continue "Skip this initialization hook.")
 311       (funcall hook))))
 312 \f
 313 ;;;; some support for any hapless wretches who end up debugging cold
 314 ;;;; init code
 315
 316 ;;; Decode THING into hexadecimal notation using only machinery
 317 ;;; available early in cold init.
 318 #!+sb-show
 319 (defun hexstr (thing)
 320   (/noshow0 "entering HEXSTR")
 321   (let ((addr (get-lisp-obj-address thing))
 322         (str (make-string 10 :element-type 'base-char)))
 323     (/noshow0 "ADDR and STR calculated")
 324     (setf (char str 0) #\0
 325           (char str 1) #\x)
 326     (/noshow0 "CHARs 0 and 1 set")
 327     (dotimes (i 8)
 328       (/noshow0 "at head of DOTIMES loop")
 329       (let* ((nibble (ldb (byte 4 0) addr))
 330              (chr (char "0123456789abcdef" nibble)))
 331         (declare (type (unsigned-byte 4) nibble)
 332                  (base-char chr))
 333         (/noshow0 "NIBBLE and CHR calculated")
 334         (setf (char str (- 9 i)) chr
 335               addr (ash addr -4))))
 336     str))
 337
 338 #!+sb-show
 339 (defun cold-print (x)
 340   (typecase x
 341     (simple-string (sb!sys:%primitive print x))
 342     (symbol (sb!sys:%primitive print (symbol-name x)))
 343     (list (let ((count 0))
 344             (sb!sys:%primitive print "list:")
 345             (dolist (i x)
 346               (when (>= (incf count) 4)
 347                 (sb!sys:%primitive print "...")
 348                 (return))
 349               (cold-print i))))
 350     (t (sb!sys:%primitive print (hexstr x)))))