src/code/signal.lisp

   1 ;;;; handling UNIX signals
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!UNIX")
  13 \f
  14 ;;;; macros for dynamically enabling and disabling signal handling
  15
  16 ;;; Notes on how the without-interrupts/with-interrupts stuff works:
  17 ;;;
  18 ;;; Before invoking the supplied handler for any of the signals that
  19 ;;; can be blocked, the C interrupt support code checks to see whether
  20 ;;; *interrupts-enabled* has been bound to NIL. If so, it saves the
  21 ;;; signal number and the value of the signal mask (from the signal
  22 ;;; context), sets the signal mask to block all blockable signals,
  23 ;;; sets *interrupt-pending* and returns without handling the signal.
  24 ;;;
  25 ;;; When we drop out the without interrupts, we check to see whether
  26 ;;; *INTERRUPT-PENDING* has been set. If so, we call
  27 ;;; RECEIVE-PENDING-INTERRUPT, which generates a SIGTRAP. The C code
  28 ;;; invokes the handler for the saved signal instead of the SIGTRAP
  29 ;;; after replacing the signal mask in the signal context with the
  30 ;;; saved value. When that hander returns, the original signal mask is
  31 ;;; installed, allowing any other pending signals to be handled.
  32 ;;;
  33 ;;; This means that the cost of WITHOUT-INTERRUPTS is just a special
  34 ;;; binding in the case when no signals are delivered (the normal
  35 ;;; case). It's only when a signal is actually delivered that we use
  36 ;;; any system calls, and by then the cost of the extra system calls
  37 ;;; are lost in the noise when compared with the cost of delivering
  38 ;;; the signal in the first place.
  39
  40 (defvar *interrupts-enabled* t)
  41 (defvar *interrupt-pending* nil)
  42
  43 (sb!xc:defmacro without-interrupts (&body body)
  44   #!+sb-doc
  45   "Execute BODY in a context impervious to interrupts."
  46   (let ((name (gensym "WITHOUT-INTERRUPTS-BODY-")))
  47     `(flet ((,name () ,@body))
  48       (if *interrupts-enabled*
  49           (unwind-protect
  50                (let ((*interrupts-enabled* nil))
  51                  (,name))
  52             ;; If we were interrupted in the protected section, then
  53             ;; the interrupts are still blocked and it remains so
  54             ;; until the pending interrupt is handled.
  55             ;;
  56             ;; If we were not interrupted in the protected section,
  57             ;; but here, then even if the interrupt handler enters
  58             ;; another WITHOUT-INTERRUPTS, the pending interrupt will
  59             ;; be handled immediately upon exit from said
  60             ;; WITHOUT-INTERRUPTS, so it is as if nothing has
  61             ;; happened.
  62             (when *interrupt-pending*
  63               (receive-pending-interrupt)))
  64           (,name)))))
  65
  66 (sb!xc:defmacro with-interrupts (&body body)
  67   #!+sb-doc
  68   "Allow interrupts while executing BODY. As interrupts are normally allowed,
  69   this is only useful inside a WITHOUT-INTERRUPTS."
  70   (let ((name (gensym)))
  71     `(flet ((,name () ,@body))
  72        (if *interrupts-enabled*
  73            (,name)
  74            (let ((*interrupts-enabled* t))
  75              (when *interrupt-pending*
  76                (receive-pending-interrupt))
  77              (,name))))))