src/compiler/x86/static-fn.lisp

   1 ;;;; the VOPs and macro magic required to call static functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13
  14 (define-vop (static-fun-template)
  15   (:save-p t)
  16   (:policy :safe)
  17   (:variant-vars function)
  18   (:vop-var vop)
  19   (:node-var node)
  20   (:temporary (:sc unsigned-reg :offset ebx-offset
  21                    :from (:eval 0) :to (:eval 2)) ebx)
  22   (:temporary (:sc unsigned-reg :offset ecx-offset
  23                    :from (:eval 0) :to (:eval 2)) ecx))
  24
  25 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
  26
  27 (defun static-fun-template-name (num-args num-results)
  28   (intern (format nil "~:@(~R-arg-~R-result-static-fun~)"
  29                   num-args num-results)))
  30
  31 (defun moves (dst src)
  32   (collect ((moves))
  33     (do ((dst dst (cdr dst))
  34          (src src (cdr src)))
  35         ((or (null dst) (null src)))
  36       (moves `(move ,(car dst) ,(car src))))
  37     (moves)))
  38
  39 (defun static-fun-template-vop (num-args num-results)
  40   (unless (and (<= num-args register-arg-count)
  41                (<= num-results register-arg-count))
  42     (error "either too many args (~W) or too many results (~W); max = ~W"
  43            num-args num-results register-arg-count))
  44   (let ((num-temps (max num-args num-results)))
  45     (collect ((temp-names) (temps) (arg-names) (args) (result-names) (results))
  46       (dotimes (i num-results)
  47         (let ((result-name (intern (format nil "RESULT-~D" i))))
  48           (result-names result-name)
  49           (results `(,result-name :scs (any-reg descriptor-reg)))))
  50       (dotimes (i num-temps)
  51         (let ((temp-name (intern (format nil "TEMP-~D" i))))
  52           (temp-names temp-name)
  53           (temps `(:temporary (:sc descriptor-reg
  54                                :offset ,(nth i *register-arg-offsets*)
  55                                :from ,(if (< i num-args)
  56                                           `(:argument ,i)
  57                                           '(:eval 1))
  58                                :to ,(if (< i num-results)
  59                                         `(:result ,i)
  60                                         '(:eval 1))
  61                                ,@(when (< i num-results)
  62                                    `(:target ,(nth i (result-names)))))
  63                               ,temp-name))))
  64       (dotimes (i num-args)
  65         (let ((arg-name (intern (format nil "ARG-~D" i))))
  66           (arg-names arg-name)
  67           (args `(,arg-name
  68                   :scs (any-reg descriptor-reg)
  69                   :target ,(nth i (temp-names))))))
  70       `(define-vop (,(static-fun-template-name num-args num-results)
  71                     static-fun-template)
  72         (:args ,@(args))
  73         ,@(temps)
  74         (:results ,@(results))
  75         (:generator ,(+ 50 num-args num-results)
  76          ,@(moves (temp-names) (arg-names))
  77
  78          ;; If speed not more important than size, duplicate the
  79          ;; effect of the ENTER with discrete instructions. Takes
  80          ;; 2+1+3+2=8 bytes as opposed to 4+3=7 bytes.
  81          (cond ((policy node (>= speed space))
  82                 (inst mov ebx esp-tn)
  83                 ;; Save the old-fp
  84                 (inst push ebp-tn)
  85                 ;; Ensure that at least three slots are available; one
  86                 ;; above, two more needed.
  87                 (inst sub esp-tn (fixnumize 2))
  88                 (inst mov ebp-tn ebx))
  89                (t
  90                 (inst enter (fixnumize 2))
  91                 ;; The enter instruction pushes EBP and then copies
  92                 ;; ESP into EBP. We want the new EBP to be the
  93                 ;; original ESP, so we fix it up afterwards.
  94                 (inst add ebp-tn (fixnumize 1))))
  95
  96          ,(if (zerop num-args)
  97               '(inst xor ecx ecx)
  98               `(inst mov ecx (fixnumize ,num-args)))
  99
 100          (note-this-location vop :call-site)
 101          ;; Old CMU CL comment:
 102          ;;   STATIC-FUN-OFFSET gives the offset from the start of
 103          ;;   the NIL object to the static function FDEFN and has the
 104          ;;   low tag of 1 added. When the NIL symbol value with its
 105          ;;   low tag of 3 is added the resulting value points to the
 106          ;;   raw address slot of the fdefn (at +4).
 107          ;; FIXME: Since the fork from CMU CL, we've swapped
 108          ;; FUN-POINTER-LOWTAG and INSTANCE-POINTER-LOWTAG, so the
 109          ;; text above is no longer right. Mysteriously, things still
 110          ;; work. It would be good to explain why. (Is this code no
 111          ;; longer executed? Does it not depend on the
 112          ;; 1+3=4=fdefn_raw_address_offset relationship above?
 113          ;; Is something else going on?)
 114          (inst call (make-ea :dword
 115                              :disp (+ nil-value
 116                                       (static-fun-offset function))))
 117          ,(collect ((bindings) (links))
 118                    (do ((temp (temp-names) (cdr temp))
 119                         (name 'values (gensym))
 120                         (prev nil name)
 121                         (i 0 (1+ i)))
 122                        ((= i num-results))
 123                      (bindings `(,name
 124                                  (make-tn-ref ,(car temp) nil)))
 125                      (when prev
 126                        (links `(setf (tn-ref-across ,prev) ,name))))
 127                    `(let ,(bindings)
 128                      ,@(links)
 129                      (default-unknown-values
 130                          vop
 131                          ,(if (zerop num-results) nil 'values)
 132                        ,num-results)))
 133          ,@(moves (result-names) (temp-names)))))))
 134
 135 ) ; EVAL-WHEN
 136
 137 (macrolet ((frob (num-args num-res)
 138              (static-fun-template-vop (eval num-args) (eval num-res))))
 139   (frob 0 1)
 140   (frob 1 1)
 141   (frob 2 1)
 142   (frob 3 1))
 143
 144 (defmacro define-static-fun (name args &key (results '(x)) translate
 145                                   policy cost arg-types result-types)
 146   `(define-vop (,name
 147                 ,(static-fun-template-name (length args)
 148                                            (length results)))
 149      (:variant ',name)
 150      (:note ,(format nil "static-fun ~@(~S~)" name))
 151      ,@(when translate
 152          `((:translate ,translate)))
 153      ,@(when policy
 154          `((:policy ,policy)))
 155      ,@(when cost
 156          `((:generator-cost ,cost)))
 157      ,@(when arg-types
 158          `((:arg-types ,@arg-types)))
 159      ,@(when result-types
 160          `((:result-types ,@result-types)))))