tests/run-tests.lisp

   1 #+#.(cl:if (cl:find-package "ASDF") '(or) '(and))
   2 (load (merge-pathnames "../contrib/asdf/asdf.fasl"))
   3
   4 #+#.(cl:if (cl:find-package "SB-POSIX") '(or) '(and))
   5 (let ((asdf:*central-registry*
   6        (cons "../contrib/systems/" asdf:*central-registry*)))
   7   (asdf:oos 'asdf:load-op 'sb-posix))
   8
   9 (load "test-util.lisp")
  10
  11 (defpackage :run-tests
  12     (:use :cl :test-util :sb-ext))
  13
  14 (load "assertoid.lisp")
  15
  16 (in-package run-tests)
  17
  18 (defvar *all-failures* nil)
  19 (defvar *break-on-error* nil)
  20 (defvar *accept-files* nil)
  21
  22 (defun run-all ()
  23   (dolist (arg (cdr *posix-argv*))
  24     (cond ((string= arg "--break-on-failure")
  25            (setf *break-on-error* t)
  26            (setf test-util:*break-on-failure* t))
  27           ((string= arg "--break-on-expected-failure")
  28            (setf test-util:*break-on-expected-failure* t))
  29           (t
  30            (push (truename (parse-namestring arg)) *accept-files*))))
  31   (pure-runner (pure-load-files) #'load-test)
  32   (pure-runner (pure-cload-files) #'cload-test)
  33   (impure-runner (impure-load-files) #'load-test)
  34   (impure-runner (impure-cload-files) #'cload-test)
  35   (impure-runner (sh-files) #'sh-test)
  36   (report)
  37   (sb-ext:quit :unix-status (if (unexpected-failures)
  38                                 1
  39                                 104)))
  40
  41 (defun report ()
  42   (terpri)
  43   (format t "Finished running tests.~%")
  44   (cond (*all-failures*
  45          (format t "Status:~%")
  46          (dolist (fail (reverse *all-failures*))
  47            (cond ((eq (car fail) :unhandled-error)
  48                   (format t " ~20a ~a~%"
  49                           "Unhandled error"
  50                           (enough-namestring (second fail))))
  51                  ((eq (car fail) :invalid-exit-status)
  52                   (format t " ~20a ~a~%"
  53                           "Invalid exit status:"
  54                           (enough-namestring (second fail))))
  55                  (t
  56                   (format t " ~20a ~a / ~a~%"
  57                           (ecase (first fail)
  58                             (:expected-failure "Expected failure:")
  59                             (:unexpected-failure "Failure:")
  60                             (:unexpected-success "Unexpected success:"))
  61                           (enough-namestring (second fail))
  62                           (third fail))))))
  63         (t
  64          (format t "All tests succeeded~%"))))
  65
  66 (defun pure-runner (files test-fun)
  67   (format t "// Running pure tests (~a)~%" test-fun)
  68   (let ((*package* (find-package :cl-user))
  69         (*failures* nil))
  70     (setup-cl-user)
  71     (dolist (file files)
  72       (when (accept-test-file file)
  73         (format t "// Running ~a~%" file)
  74         (handler-bind ((error (make-error-handler file)))
  75           (funcall test-fun file))))
  76     (append-failures)))
  77
  78 (defun impure-runner (files test-fun)
  79   (format t "// Running impure tests (~a)~%" test-fun)
  80   (let ((*package* (find-package :cl-user)))
  81     (setup-cl-user)
  82     (dolist (file files)
  83       (when (accept-test-file file)
  84         (force-output)
  85         (let ((pid (sb-posix:fork)))
  86           (cond ((= pid 0)
  87                  (format t "// Running ~a~%" file)
  88                  (handler-bind ((error (make-error-handler file)))
  89                    (funcall test-fun file))
  90                  (report-test-status)
  91                  (sb-ext:quit :unix-status 104))
  92                 (t
  93                  (let ((status (make-array 1 :element-type '(signed-byte 32))))
  94                    (sb-posix:waitpid pid 0 status)
  95                    (if (and (sb-posix:wifexited (aref status 0))
  96                             (= (sb-posix:wexitstatus (aref status 0))
  97                                104))
  98                        (with-open-file (stream "test-status.lisp-expr"
  99                                                :direction :input
 100                                                :if-does-not-exist :error)
 101                          (append-failures (read stream)))
 102                        (push (list :invalid-exit-status file)
 103                              *all-failures*))))))))))
 104
 105 (defun make-error-handler (file)
 106   (lambda (condition)
 107     (push (list :unhandled-error file)
 108           *all-failures*)
 109     (cond (*break-on-error*
 110            (test-util:really-invoke-debugger condition))
 111           (t
 112            (format *error-output* "~&Unhandled ~a: ~a~%"
 113                    (type-of condition) condition)
 114            (sb-debug:backtrace)))))
 115
 116 (defun append-failures (&optional (failures *failures*))
 117   (setf *all-failures* (append failures *all-failures*)))
 118
 119 (defun unexpected-failures ()
 120   (remove-if (lambda (x)
 121                (or (eq (car x) :expected-failure)
 122                    (eq (car x) :unexpected-success)))
 123              *all-failures*))
 124
 125 (defun setup-cl-user ()
 126   (use-package :test-util)
 127   (use-package :assertoid))
 128
 129 (defun load-test (file)
 130   (load file))
 131
 132 (defun cload-test (file)
 133   (let ((compile-name (compile-file-pathname file)))
 134     (unwind-protect
 135          (progn
 136            (compile-file file)
 137            (load compile-name))
 138       (ignore-errors
 139         (delete-file compile-name)))))
 140
 141 (defun sh-test (file)
 142   ;; What? No SB-POSIX:EXECV?
 143   (let ((process (sb-ext:run-program "/bin/sh"
 144                                      (list (namestring file))
 145                                      :output *error-output*)))
 146     (sb-ext:quit :unix-status (process-exit-code process))))
 147
 148 (defun accept-test-file (file)
 149   (if *accept-files*
 150       (find (truename file) *accept-files* :test #'equalp)
 151       t))
 152
 153 (defun pure-load-files ()
 154   (directory "*.pure.lisp"))
 155
 156 (defun pure-cload-files ()
 157   (directory "*.pure-cload.lisp"))
 158
 159 (defun impure-load-files ()
 160   (directory "*.impure.lisp"))
 161
 162 (defun impure-cload-files ()
 163   (directory "*.impure-cload.lisp"))
 164
 165 (defun sh-files ()
 166   (directory "*.test.sh"))